Télécharger dy_devo4.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : dy_devo4.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Test Dy_devo4.dgibi: Jeux de donnees *
  5. * ------------------------------------ *
  6. * *
  7. * si GRAPH = N, les graphiques ne sont pas affiches
  8. * si GRAPH different de N, tous les graphiques
  9. * sont affiches
  10. *
  11. GRAPH = 'N' ; d_dyne = faux ;
  12. * test comparaison pasapas et dyn
  13. *
  14. SAUT PAGE ;
  15. *
  16. *-----------------------------------------------------*
  17. * DY_DEVO4 *
  18. *-----------------------------------------------------*
  19. * *
  20. * Tests de l'op{rateur DYNE option DE_VOGELAERE *
  21. * _____________________________________________ *
  22. * *
  23. * *
  24. * 1 poutre encastree, 10 elements finis, *
  25. * masse negligeable *
  26. * 1 masse concentree e son extremite *
  27. * Test PROFIL_PROFIL_EXTERIEUR avec des carres *
  28. * Comparaison avec la liaison POINT_PLAN *
  29. * NB_M: nombre de segments sur le cote du carre mobile*
  30. * NB_F: nombre de segments sur le cote du carre fixe *
  31. * *
  32. *-----------------------------------------------------*
  33.  
  34. OPTION ECHO 1 ;
  35. TEMPS ;
  36. *
  37. NB_M = 3 ;
  38. NB_F = 1 ;
  39. R_PPL = 1.E+05 ;
  40. R_PP = R_PPL ;
  41. EXPO = 0.5 ;
  42. *
  43. OPTION ELEM SEG2 DIME 3 ;
  44. OPTI EPSI LINEAIRE;
  45. *
  46. * Definition geometrie
  47. *
  48. P1 = 0. 0. 0. ;
  49. P2 = 0. 0. 0.9 ;
  50. LIG1 = P1 D 10 P2 ;
  51. *
  52. * Definition materiau
  53. *
  54. MODL1 = MODE LIG1 MECANIQUE ELASTIQUE POUT;
  55.  
  56. MA1 = MATE MODL1 YOUNG 2.1E11 NU 0.3 RHO 78. ;
  57. CA1 = 'CARA' MODL1 SECT 1.1E-6 INRY 8.33E-10
  58. INRZ 8.33E-10 TORS 5.0E-7 VECT (1. 0. 1. );
  59. *
  60. RIG1 = RIGI MODL1 (MA1 ET CA1) ;
  61. MAST = (MASSE MODL1 (MA1 ET CA1)) ET
  62. ( MASSE DEPL 2.0 P2 ) ;
  63. *
  64. * Conditions aux limites
  65. *
  66. ENC1 = BLOQUE DEPL ROTA P1 ;
  67. ENC2 = BLOQUE 'UY' LIG1 ;
  68. RIGT = RIG1 ET ENC1 ET ENC2 ;
  69. *
  70. * Calcul des modes
  71. *
  72. TBAS = VIBR PROCHE ( PROG 1.0 ) RIGT MAST ;
  73. *
  74. TB1 = TBAS.'MODES';
  75.  
  76.  
  77. ma1 = manu poi1 tb1 . 1 . point_repere ;
  78. mo1 = mode ma1 mecanique elastique modal ;
  79. ca1 = mate mo1 freq tb1 . 1 . frequence
  80. mass tb1 . 1 . masse_generalisee defo tb1 . 1 . deformee_modale
  81. amor 0. ;
  82.  
  83. *
  84. RIGI1 = RIGI TB1 ;
  85. *
  86. * Amortissement
  87. *
  88. AMOR1 = AMOR TBAS ( PROG 0.0 ) ;
  89. amor2 = amor mo1 ca1 ;
  90. *
  91. TA = TABLE 'AMORTISSEMENT' ;
  92. TA.'AMORTISSEMENT' = AMOR1 ;
  93. *
  94. * Deplacement initial
  95. *
  96. FE2 = FORCE FX 1. P2 ;
  97. XE2 = RESOU RIGT FE2 ;
  98. XMAX = MAXI XE2 AVEC (MOTS UX ) ;
  99. FE1 = FE2 * (0.139E-2 / XMAX );
  100. FGE1 = PJBA TBAS FE1 ;
  101. ALO = RESO RIGI1 FGE1 ;
  102. *
  103. TINIT = TABLE 'INITIAL' ;
  104. TINIT.'DEPLACEMENT' = ALO ;
  105. *
  106. *--- Definition des liaisons
  107. *
  108. TLIA = TABLE 'LIAISON' ;
  109. TLB = TABLE 'LIAISON_B' ;
  110. TLIA.'LIAISON_B' = TLB ;
  111. NORM1 = 0 0 1 ;
  112. *
  113. * Liaison PROFIL_PROFIL_EXTERIEUR
  114. *
  115. * profil mobile
  116. P1_1 = -0.5 0.0 0.9 ;
  117. P1_2 = 0.0 -0.5 0.9 ;
  118. P1_3 = 0.5 0.0 0.9 ;
  119. P1_4 = 0.0 0.5 0.9 ;
  120. MAIL_1 = P1_1 D NB_M P1_2 D NB_M P1_3 D NB_M P1_4 D
  121. NB_M P1_1 ;
  122. *
  123. * profil fixe
  124. P2_1 = 0.501 1.0 0.9 ;
  125. P2_2 = 0.501 -1.0 0.9 ;
  126. P2_3 = 0.601 -1.0 0.9 ;
  127. P2_4 = 0.601 1.0 0.9 ;
  128. MAIL_2 = P2_1 D NB_F P2_2 D NB_F P2_3 D NB_F P2_4 D
  129. NB_F P2_1 ;
  130. *
  131. SI ( NEG GRAPH 'N' ) ;
  132. TRAC ( 0 0 1000 ) ( MAIL_1 ET MAIL_2 ) ;
  133. FINSI ;
  134. *
  135. TL1 = TABLE 'LIAISON_ELEMENTAIRE' ;
  136. TL1.'TYPE_LIAISON' = MOT 'PROFIL_PROFIL_EXTERIEUR';
  137. TL1.'SUPPORT' = P2 ;
  138. TL1.'PROFIL_FIXE' = MAIL_2 ;
  139. TL1.'PROFIL_MOBILE' = MAIL_1 ;
  140. TL1.'NORMALE' = NORM1 ;
  141. TL1.'RAIDEUR' = R_PP ;
  142. TL1.'EXPOSANT_RAIDEUR' = EXPO ;
  143. *
  144. TLB . 1 = TL1 ;
  145. mappe1 = manu poi1 p2 ;
  146. moppe1 = modele mappe1 liaison PROFIL_PROFIL EXTERIEUR ;
  147. tuppe1 = table ; tuppe1 . moppe1 = vrai ;
  148. cappe1 = mate moppe1 'NORM' norm1 'RAID' r_pp 'ERAI' expo
  149. 'PFIX' mail_2 'PMOB' mail_1 'SORT' tuppe1 ;
  150.  
  151. *
  152. *--- Definition des resultats en sortie
  153. *
  154. TSORT = TABLE 'SORTIE' ;
  155. TSOR1 = TABLE 'SORTIE' ;
  156. TSORT . 'VARIABLE' = TSOR1 ;
  157. TSOR1 . 'DEPLACEMENT' = VRAI ;
  158. TSOR1 . 'VITESSE' = VRAI ;
  159. *
  160. TSOR2 = TABLE 'SORTIE' ;
  161. TSORT.'LIAISON_B' = TSOR2 ;
  162. TSOR2.TL1 = VRAI ;
  163. *
  164. * Temps
  165. *
  166. PDT = 0.1E-3 ;
  167. NP1 = 5000 ;
  168. NINS = 5 ;
  169. *
  170. ev1 = evol manu (prog 0. 1000.) (prog 1. 1.) ;
  171. cha1 = char force ev1 FGE1 ;
  172. *
  173. SI d_dyne ;
  174. tabdyn = table 'PASAPAS' ;
  175. tabdyn . modele = mo1 et moppe1 ;
  176. tabdyn . caracteristiques = ca1 et cappe1 ;
  177. tabdyn . sortie = table ;
  178. tabdyn . sortie . moppe1 = vrai ;
  179. tabdyn . sortie . vitesses = faux ;
  180. tabdyn . pas_de_temps = pdt ;
  181. tabdyn . nombre_pas = np1 ;
  182. tabdyn . pas_de_sortie = nins ;
  183. tabdyn . temps = table ;
  184. tabdyn . temps . 0 = 0. ;
  185. tabdyn . deplacements = table ;
  186. tabdyn . deplacements . 0 = ALO ;
  187. dyne de_vogelaere tabdyn ;
  188. SINON ;
  189. * pour pasapas
  190. * etape precontrainte
  191. t_prec = table ;
  192. t_prec . modele = mo1 ;
  193. t_prec . caracteristiques = ca1 ;
  194. t_prec . chargement = cha1 ;
  195. t_prec . temps_calcules = prog 0. 1000. ;
  196. t_prec . mes_sauvegardes = table ;
  197. t_prec . mes_sauvegardes . defto = vrai ;
  198. pasapas t_prec ;
  199.  
  200. *lacher
  201. tabdyn = table 'PASAPAS' ;
  202. tabdyn . modele = mo1 et moppe1 ;
  203. tabdyn . caracteristiques = ca1 et cappe1 ;
  204. *tabdyn . modele = mo1 ;
  205. *tabdyn . caracteristiques = ca1 ;
  206. tabdyn . temps = table ;
  207. tabdyn . temps . 0 = 0. ;
  208. tabdyn . deplacements = table ;
  209. tabdyn . deplacements . 0 = t_prec . deplacements . 1 ;
  210. tabdyn . contraintes = table ;
  211. tabdyn . contraintes . 0 = t_prec . contraintes . 1 ;
  212. tabdyn . deformations = table;
  213. tabdyn . deformations . 0 = t_prec . deformations . 1;
  214. tabdyn . dynamique = vrai ;
  215. tabdyn . temps_calcules = prog 0 pas (4*nins*pdt) (np1*pdt);
  216. pasapas tabdyn ;
  217.  
  218. FINSI ;
  219. *------ Op{rateur DYNE ------
  220. *
  221. TRESU1 = DYNE 'DE_VOGELAERE' TBAS TA TINIT TSORT TLIA
  222. NP1 PDT NINS ;
  223.  
  224. nsu1 = dime tresu1 . temps_de_sortie ;
  225. ovi1 = prog ;
  226. repeter bsu1 nsu1 ;
  227. ovi1 = ovi1 et
  228. (prog (extr tresu1 . &bsu1 . vitesse alfa tb1 . 1 . point_repere)) ;
  229. fin bsu1 ;
  230. evvi1 = evol manu 'temps' TRESU1 . 'TEMPS_DE_SORTIE'
  231. 'vitesse' ovi1 ;
  232. *
  233. * Trac{ des courbes
  234. *
  235. SI ( NEG GRAPH 'N' ) ;
  236. si d_dyne ;
  237. l_t2 = prog ;
  238. repeter bs (dime tabdyn . temps) ;
  239. si (ega &bs 1) ; iterer bs ; finsi ;
  240. l_t2 = l_t2 et (prog tabdyn . temps . (&bs - 1)) ;
  241. fin bs ;
  242. evfn1 = evol manu l_t2 tabdyn . force_de_choc ;
  243. evux1 = evol manu l_t2 tabdyn . ux ;
  244. TITRE '***** LIAISON PROFIL_PROFIL_EXTERIEUR *****';
  245. DESS (( EVOL MANU 'TEMPS' TRESU1 . 'TEMPS_DE_SORTIE'
  246. 'FN' TRESU1 . TL1 . 'FORCE_DE_CHOC') et (evfn1 coul bleu))
  247. 'MIMA' ;
  248. *
  249. DESS (( EVOL MANU 'TEMPS' TRESU1 . 'TEMPS_DE_SORTIE'
  250. 'UX' TRESU1 . TL1 . 'UX' ) et (evux1 coul bleu)) 'MIMA';
  251. *
  252. sinon ;
  253. *
  254. l_t20 = prog tabdyn . temps . 1 ;
  255. tt1 = 'EXTR' tabdyn . variables_internes . 1 'SLIA' 2 1 1 ;
  256. lutt1 = dime tt1 . force_de_choc ;
  257. l_fdc20 = extr tt1 . force_de_choc lutt1;
  258. l_ux20 = extr tt1 . ux lutt1 ;
  259. l_vi20 = prog
  260. (extr tabdyn . vitesses . 1 alfa tb1 . 1 . point_repere);
  261. indi1 = 1 ;
  262.  
  263. repeter bs ((dime tabdyn . temps) - 2) ;
  264. indi1 = indi1 + 1 ;
  265. ttu1 = 'EXTR' tabdyn . variables_internes . indi1 'SLIA' 2 1 1 ;
  266. l_ux20 = l_ux20 et ttu1 . ux ;
  267. l_fdc20 = l_fdc20 et ttu1 . force_de_choc ;
  268. l_vi20 = l_vi20 et
  269. (prog (extr tabdyn . vitesses . indi1 alfa tb1 . 1 . point_repere));
  270. l_t20 = l_t20 et (prog tabdyn . temps . indi1) ;
  271. fin bs ;
  272. evfdc20 = evol manu 'temps' l_t20 'force' l_fdc20 ;
  273. evux20 = evol manu 'temps' l_t20 'dep_pl' l_ux20 ;
  274. evit20 = evol manu 'temps' l_t20 'vitesse' l_vi20 ;
  275. evfdcr1 = evol manu 'temps' TRESU1 . 'TEMPS_DE_SORTIE'
  276. 'FN' TRESU1 . TL1 . 'FORCE_DE_CHOC' ;
  277. evuxr1 = EVOL MANU 'TEMPS' TRESU1 . 'TEMPS_DE_SORTIE'
  278. 'UX' TRESU1 . TL1 . 'UX' ;
  279. titre ' vitesse ' ;
  280. DESS (evvi1 et (evit20 coul bleu)) 'MIMA' ;
  281. titre 'force de choc' ;
  282. DESS (( EVOL MANU 'TEMPS' TRESU1 . 'TEMPS_DE_SORTIE'
  283. 'FN' TRESU1 . TL1 . 'FORCE_DE_CHOC') et (evfdc20 coul bleu))
  284. 'MIMA' ;
  285. titre ' ux liaison ' ;
  286. DESS (( EVOL MANU 'TEMPS' TRESU1 . 'TEMPS_DE_SORTIE'
  287. 'UX' TRESU1 . TL1 . 'UX' ) et (evux20 coul bleu)) 'MIMA';
  288. *
  289. finsi ;
  290. FINSI ;
  291.  
  292.  
  293. * mess (extr tresu1 . temps_de_sortie 801) tabdyn . temps . 200 ;
  294. D_FC_1 = EXTRAIRE ( TRESU1 . TL1 . 'FORCE_DE_CHOC' )
  295. 801 ;
  296. D_DE_1 = EXTRAIRE ( TRESU1 . TL1 . 'UX' ) 801 ;
  297.  
  298. tt200 = 'EXTR' tabdyn . variables_internes . 200 'SLIA' 2 1 1 ;
  299. D_FC_2 =EXTRAIRE (tt200 . 'FORCE_DE_CHOC') 1;
  300. D_DE_2 =EXTRAIRE (tt200 . 'UX') 1;
  301.  
  302. *
  303. SAUT PAGE ;
  304. MESS '-----> liaison PROFIL_PROFIL_EXTERIEUR' ;
  305. MESS ' valeur de la force de choc :' D_FC_1 D_FC_2;
  306. MESS ' valeur du deplacement :' D_DE_1 D_DE_2;
  307. *
  308. R_FC = ABS ( ( D_FC_1 - D_FC_2 ) / D_FC_2 ) ;
  309. R_DE = ABS ( ( D_DE_1 - D_DE_2 ) / D_DE_2 ) ;
  310. R_DE0 = ABS((D_DE_1 - 1.29833E-03) / 1.29833E-03) ;
  311.  
  312. SI ( ( R_FC <EG (1.4497 * 1.2) ) ET ( R_DE <EG (0.15738 *1.2) )
  313. ET (R_DE0 < 1.e-2) ) ;
  314. ERRE 0 ;
  315. SINON ;
  316. ERRE 5 ;
  317. FINSI ;
  318.  
  319.  
  320. * Liaison POINT_PLAN
  321. *
  322. NORM1 = 1 0 0 ;
  323. TL1 = TABLE 'LIAISON_ELEMENTAIRE' ;
  324. TL1.'TYPE_LIAISON' = MOT 'POINT_PLAN' ;
  325. TL1.'SUPPORT' = P2 ;
  326. TL1.'NORMALE' = NORM1 ;
  327. TL1.'RAIDEUR' = R_PPL ;
  328. TL1.'JEU' = 0.001 ;
  329. *
  330. TLB . 1 = TL1 ;
  331. TSOR2.TL1 = VRAI ;
  332. mapp2 = manu poi1 p2 ;
  333. mopp2 = modele mapp2 liaison POINT_PLAN ;
  334. tuppe2 = table ; tuppe2 . mopp2 = vrai ;
  335. capp2 = mate mopp2 'NORM' norm1 'RAID' r_ppl 'JEU' 0.001 'SORT' tuppe2;
  336. *
  337. tabdyn2 = table 'PASAPAS' ;
  338. tabdyn2 . modele = mo1 et mopp2 ;
  339. tabdyn2 . caracteristiques = ca1 et capp2 ;
  340. tabdyn2 . temps = table ;
  341. tabdyn2 . temps . 0 = 0. ;
  342.  
  343. SI d_dyne ;
  344. tabdyn2 . deplacements = table ;
  345. tabdyn2 . deplacements . 0 = ALO ;
  346. tabdyn2 . sortie = table ;
  347. tabdyn2 . sortie . mopp2 = vrai ;
  348. tabdyn2 . sortie . vitesses = faux ;
  349. tabdyn2 . pas_de_temps = pdt ;
  350. tabdyn2 . nombre_pas = np1 ;
  351. tabdyn2 . pas_de_sortie = nins ;
  352. dyne de_vogelaere tabdyn2 ;
  353.  
  354. SINON ;
  355. tabdyn2 . deplacements = table ;
  356. tabdyn2 . deplacements . 0 = t_prec . deplacements . 1 ;
  357. tabdyn2 . contraintes = table ;
  358. tabdyn2 . contraintes . 0 = t_prec . contraintes . 1 ;
  359. tabdyn2 . deformations = table;
  360. tabdyn2 . deformations . 0 = t_prec . deformations . 1;
  361. tabdyn2 . dynamique = vrai ;
  362. tabdyn2 . temps_calcules = prog 0 pas (4*nins*pdt) (np1*pdt);
  363. *tabdyn2 . temps_calcules = prog 0 pas (pdt) .0005;
  364. *tabdyn2 . temps_sauves = prog 0 pas (nins*pdt) (np1*pdt) ;
  365. *tabdyn2 . temps_sauves = prog 0 pas (nins*pdt) .01 ;
  366. pasapas tabdyn2 ;
  367.  
  368. FINSI ;
  369.  
  370. *np1 = 5 ; nins = 1;
  371. TRESU2 = DYNE 'DE_VOGELAERE' TBAS TA TINIT TSORT TLIA
  372. NP1 PDT NINS ;
  373.  
  374. nsu2 = dime tresu2 . temps_de_sortie ;
  375. ovi2 = prog ;
  376. repeter bsu2 nsu2 ;
  377. ovi2 = ovi2 et
  378. (prog (extr tresu2 . &bsu2 . vitesse alfa tb1 . 1 . point_repere)) ;
  379. fin bsu2 ;
  380. evvi2 = evol manu 'temps' TRESU2 . 'TEMPS_DE_SORTIE'
  381. 'vitesse' ovi2 ;
  382. *
  383. * Trace des courbes
  384. *
  385. SI ( NEG GRAPH 'N' ) ;
  386. si d_dyne ;
  387. l_t22 = prog ;
  388. repeter bs (dime tabdyn2 . temps) ;
  389. si (&bs ega 1) ; iterer bs ; finsi ;
  390. l_t22 = l_t22 et (prog tabdyn2 . temps . (&bs - 1)) ;
  391. fin bs ;
  392. evfn2 = evol manu l_t22 tabdyn2 . force_de_choc;
  393. evux2 = evol manu l_t22 tabdyn2 . ux ;
  394. TITRE '***** LIAISON POINT_PLAN *****' ;
  395. DESS (( EVOL MANU 'TEMPS' TRESU2 . 'TEMPS_DE_SORTIE'
  396. 'FN' TRESU2 . TL1 . 'FORCE_DE_CHOC') et (evfn2 coul
  397. vert)) 'MIMA' ;
  398. *
  399. DESS (( EVOL MANU 'TEMPS' TRESU2 . 'TEMPS_DE_SORTIE'
  400. 'UX' TRESU2 . TL1 . 'UX' ) et (evux2 coul vert)) 'MIMA' ;
  401. sinon ;
  402. *
  403. l_t202 = prog tabdyn2 . temps . 1 ;
  404. tt2 = 'EXTR' tabdyn2 . variables_internes . 1 'SLIA' 2 1 1 ;
  405. lutt2 = dime tt2 . force_de_choc ;
  406. l_fdc202 = extr tt2 . force_de_choc lutt2;
  407. l_ux202 = extr tt2 . ux lutt2 ;
  408. l_vi202 = prog
  409. (extr tabdyn2 . vitesses . 1 alfa tb1 . 1 . point_repere);
  410. indi1 = 1 ;
  411.  
  412. repeter bs ((dime tabdyn2 . temps) - 2) ;
  413. indi1 = indi1 + 1 ;
  414. ttu2 = 'EXTR' tabdyn2 . variables_internes . indi1 'SLIA' 2 1 1 ;
  415. l_ux202 = l_ux202 et ttu2 . ux ;
  416. l_fdc202 = l_fdc202 et ttu2 . force_de_choc ;
  417. l_vi202 = l_vi202 et
  418. (prog (extr tabdyn2 . vitesses .indi1 alfa tb1 . 1 . point_repere)) ;
  419. l_t202 = l_t202 et (prog tabdyn2 . temps . indi1) ;
  420. fin bs ;
  421. evfdc202 = evol manu 'temps' l_t202 'force' l_fdc202 ;
  422. evux202 = evol manu 'temps' l_t202 'dep_pl' l_ux202 ;
  423. evit202 = evol manu 'temps' l_t202 'vitesse' l_vi202 ;
  424. evfdcr2 = evol manu 'temps' TRESU2 . 'TEMPS_DE_SORTIE'
  425. 'FN' TRESU2 . TL1 . 'FORCE_DE_CHOC' ;
  426. evuxr2 = EVOL MANU 'TEMPS' TRESU2 . 'TEMPS_DE_SORTIE'
  427. 'UX' TRESU2 . TL1 . 'UX' ;
  428. titre ' vitesse ' ;
  429. DESS (evvi2 et (evit202 coul bleu)) 'MIMA' ;
  430. titre 'force de choc' ;
  431. DESS (( EVOL MANU 'TEMPS' TRESU2 . 'TEMPS_DE_SORTIE'
  432. 'FN' TRESU2 . TL1 . 'FORCE_DE_CHOC') et (evfdc202 coul bleu))
  433. 'MIMA' ;
  434. titre ' ux liaison ' ;
  435. DESS (( EVOL MANU 'TEMPS' TRESU2 . 'TEMPS_DE_SORTIE'
  436. 'UX' TRESU2 . TL1 . 'UX' ) et (evux202 coul bleu)) 'MIMA';
  437. *
  438. finsi ;
  439. FINSI ;
  440. *
  441. TEMPS ;
  442. *
  443. * Code de bon fonctionnement
  444. *
  445. D_FC_20 =EXTRAIRE ( TRESU2 . TL1 . 'FORCE_DE_CHOC' ) 801;
  446. D_DE_20 =EXTRAIRE ( TRESU2 . TL1 . 'UX' ) 801 ;
  447. tt2200 = 'EXTR' tabdyn2 . variables_internes . 200 'SLIA' 2 1 1 ;
  448. D_FC_21 =EXTRAIRE (tt2200 . 'FORCE_DE_CHOC') 1;
  449. D_DE_21 =EXTRAIRE (tt2200 . 'UX') 1;
  450.  
  451. SAUT 2 LIGNES ;
  452. MESS '-----> liaison POINT_PLAN ' ;
  453. MESS ' valeur de la force de choc :' D_FC_20 D_FC_21 ;
  454. MESS ' valeur du deplacement :' D_DE_20 D_DE_21 ;
  455. SAUT 3 LIGNES ;
  456. R_FC = ABS ( ( D_FC_20 - D_FC_21 ) / D_FC_20 ) ;
  457. R_DE = ABS ( ( D_DE_20 - D_DE_21 ) / D_DE_20 ) ;
  458. R_DE0 = ABS ((D_DE_20 - 1.29833E-03) / 1.29833E-03) ;
  459. SI ( ( R_FC &lt;EG (0.59178 *1.2)) ET ( R_DE &lt;EG (0.13598 * 1.2))
  460. ET (R_DE0 < 1.e-2) ) ;
  461. ERRE 0 ;
  462. SINON ;
  463. ERRE 5 ;
  464. FINSI ;
  465. *
  466.  
  467. FIN ;
  468.  
  469.  
  470.  
  471.  
  472.  
  473.  
  474.  
  475.  
  476.  
  477.  
  478.  
  479.  
  480.  
  481.  
  482.  
  483.  
  484.  
  485.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales