Télécharger pasapas.procedur

Retour à la liste

Numérotation des lignes :

  1. * PASAPAS PROCEDUR MB234859 24/03/13 21:15:02 11867
  2.  
  3. 'DEBP' PASAPAS PRECED*'TABLE';
  4. 'SAUT' 1 'LIGNE';
  5. '------------------ DEBUT DE LA PROCEDURE PASAPAS --------------------';
  6. ************************************************************************
  7. * *
  8. * PRECED objet de type TABLE *
  9. * C'est une table donnant , les arguments d'entrees, les *
  10. * options, puis les resultats des pas precedents *
  11. * *
  12. * Etat initial au debut du pas de temps decrit par le MCHELM WTAB.ETAT1*
  13. * champs de materiaux : *
  14. * WTAB.'MAT_REF' materiau etat a la temperature de REFERENCE *
  15. * WTAB.'MAT0' materiau etat debut de calcul *
  16. * WTAB.'MAT1' materiau fin du pas de temps *
  17. * *
  18. ************************************************************************
  19.  
  20. **************** I PARTIE ******************************************
  21. * Verifications des infos transmises et valeurs par defaut
  22. PAS_DEFA PRECED ;
  23. * Creation des tables de sortie et initialisations
  24. PAS_INIT PRECED ;
  25.  
  26. WTAB = PRECED.'WTABLE' ;
  27. conti = PRECED.'CONTINUATION';
  28. estim = PRECED.'ESTIMATION' ;
  29. *-----------------------------------------------------------------------
  30. * Appel aux procedures utilisateurs
  31. *-----------------------------------------------------------------------
  32. 'SI' WTAB.'PROCEDURE_PERSO1';
  33. PRECED.'PERSO1_APPEL' = 1 ;
  34. PERSO1 PRECED ;
  35. 'SI' ('EXIS' PRECED 'ARRET') ;
  36. WTAB.'ARRET' = PRECED.'ARRET' ;
  37. 'FINSI' ;
  38. 'FINSI';
  39. *
  40. 'SI' WTAB.'PROCEDURE_REEV_MEC' ;
  41. REEV_MEC PRECED 0 ;
  42. 'FINSI' ;
  43. *
  44. 'SI' WTAB.'PROCEDURE_REEV_THE' ;
  45. REEV_THE PRECED 0 ;
  46. 'FINSI' ;
  47. *-----------------------------------------------------------------------
  48. * Initialisation ETAT et MATERIAUX
  49. *-----------------------------------------------------------------------
  50. WTAB.'ETAT0' = PAS_ETAT PRECED WTAB.'TEMPS0' ;
  51. WTAB.'ETAT1' = WTAB.'ETAT0' ;
  52. WTAB.'MAT0' = PAS_MATE PRECED WTAB.'ETAT0' ;
  53. WTAB.'MAT1' = WTAB.'MAT0' ;
  54. *
  55. *--------- initialisation deformation thermique de reference
  56. 'SI' WTAB.'FOR_MECA' ;
  57. 'SI' WTAB.'ITHER' ;
  58. 'SI' ('EGA' WTAB.'ETREF' 'INCONNU');
  59. WTAB.'ETAT_REF'= PAS_ETAT PRECED WTAB.'TEMPS0' 'REFERENCE';
  60. WTAB.'MAT_REF' = PAS_MATE PRECED WTAB.'ETAT_REF' ;
  61. WTAB.'ETREF' ='EPTH' WTAB.'MO_TOT' WTAB.'MAT_REF' WTAB.'TEMPERATURE_REFERENCE' ;
  62. 'FINS' ;
  63. *
  64. 'SI' ('EGA' ('TYPE' WTAB.'TET1') 'CHPOINT');
  65. TET1 ='CHAN' 'CHAM' WTAB.'TET1' WTAB.'MO_TOT' 'STRESSES' 'TEMPERATURES' ;
  66. 'FINS';
  67. ETT0 = 'EPTH' WTAB.'MO_TOT' WTAB.'MAT0' TET1 ;
  68. WTAB.'ETHER1' = ETT0 - WTAB.'ETREF' ;
  69. *
  70. 'SI' WTAB.'POR1';
  71. WTAB.'MSRTHER1'= PAS_EPTH PRECED WTAB.'MO_TOT' WTAB.'MAT0' TET1 ;
  72. 'FINS' ;
  73. 'FINS' ;
  74. 'FINS' ;
  75.  
  76. ************************** II PARTIE *************************
  77. ******************************************************************
  78. ******************* boucle sur les pas de temps *****************
  79. ******************************************************************
  80. * ------------quelques initialisations de l'algorithme
  81. PASFINAL = 0 ;
  82. IPAS = 0 ;
  83. IAUTO = 1 ;
  84. IREREDU = VRAI;
  85. TEMP0 = WTAB.'TEMPS0';
  86. ISAUV = VRAI;
  87. DTV = ('EXTR' WTAB.'TEMPS_CALCULES' 1) - TEMP0 ;
  88. 'SI' ( DTV '<' 1.e-15 );
  89. 'SI' WTAB.'FREQUENTIEL' ;
  90. DTV = 1.e-14 ;
  91. 'SINON' ;
  92. DTV =('EXTR' WTAB.'TEMPS_CALCULES' 2) - TEMP0 ;
  93. 'FINSI';
  94. 'FINSI';
  95. DT_AVANT = DTV ;
  96. *-----------------------------------------------------------------------
  97. * Debut de la boucle sur les pas de temps
  98. *-----------------------------------------------------------------------
  99. 'REPETER' BEXTERN ;
  100. *
  101. * ----- Determiner le nouvel instant a calculer TI
  102. *
  103. NPAS = 'DIME' WTAB.'TEMPS_CALCULES';
  104. ICHG = WTAB.'ICHG'; ICHG=ICHG + 1; WTAB.'ICHG'= ICHG;
  105. 'SI' ( ICHG '>' NPAS) ; 'QUITTER' BEXTERN; 'FINSI';
  106. TI = 'EXTRAIRE' WTAB.'TEMPS_CALCULES' ICHG ;
  107. TIV=TI;
  108. 'SI' WTAB.'FREQUENTIEL' ;
  109. 'SI' (TI '<' TEMP0 ) ; 'ITERER' BEXTERN ; 'FINSI' ;
  110. 'SINON' ;
  111. ITERTPS = (TI '<' TEMP0 ) 'OU' (TI 'EGA' PRECED.'TEMPS'. 0) ;
  112. 'SI' ('NON' WTAB.'REEQUILIBRAGE') ;
  113. ITERTPS = ITERTPS 'OU' ('EGA' TI TEMP0) ;
  114. 'FINSI';
  115. 'SI' ITERTPS ;
  116. 'ITERER' BEXTERN ;
  117. 'FINSI';
  118. 'FINSI';
  119. *
  120. * ----- Ajustement du pas en fonction du nb d iteration du pas precedent
  121. *
  122. PASFINAL=PASFINAL+1;
  123. 'SI' WTAB.'PAS_AJUSTE';
  124. DTV=DT_AVANT;
  125. 'SI' WTAB.'CONV';
  126. 'SI' (WTAB.'NOMBRE_ITERATIONS' > 20);
  127. DTV=DTV'/' (2. ** 0.5);
  128. 'FINSI';
  129. 'SI' (WTAB.'NOMBRE_ITERATIONS' < 7);
  130. 'SI' IREREDU;
  131. DTV=DTV '*' (2. ** 0.5);
  132. 'FINSI';
  133. 'FINSI';
  134. DT_AVANT= DTV;
  135. IREREDU=VRAI;
  136. 'SINON';
  137. DTV=0.0000000001D0* DT_AVANT;
  138. DT_AVANT= DT_AVANT /2.;
  139. IREREDU=FAUX;
  140. 'FINSI';
  141. TTI = DTV* 1.0000000001 + TEMP0;
  142. 'SI' ( TTI '&lt;EG' TIV );
  143. TI=TTI;
  144. PASFINAL=0;
  145. 'FINSI';
  146. 'FINSI';
  147. *
  148. estim.'TEMPS'=TI;
  149. 'SI' (PASFINAL '>EG' 1.5) ; DT_AVANT= TI-TEMP0; 'FINSI';
  150. WTAB.'T_FINAL' = TI;
  151. WTAB.'DT_INIT' = TI-TEMP0;
  152. 'SI'((WTAB.'CONSOLIDATION' 'OU' WTAB.'DYNAMIQUE')
  153. 'ET' (WTAB.'DT_INIT' 'EGA' 0.));
  154. 'ITERER' BEXTERN;
  155. 'FINSI';
  156. WTAB.'DT'= WTAB.'DT_INIT';
  157. *
  158. * ----- Compteur IPAS des pas de temps calcules
  159. IPAS = IPAS + 1;
  160. WTAB.'PAS'=IPAS;
  161.  
  162. * ----- Mise a jour du modele si chargement de type MODE :
  163. 'SI' WTAB.'CHAR_MODE' ;
  164. MOD1P = WTAB.'MODELE' ;
  165. MODEVOL1 = 'TIRE' PRECED.'MODELE' 'MODE' TI ;
  166. WTAB.'MODELE' = MODEVOL1 ;
  167.  
  168. 'SI' WTAB.'CHAR_MATE' ;
  169. MATEVOL1 = 'TIRE' PRECED.'CARACTERISTIQUES' 'MATE' TI ;
  170. WTAB.'CARACTERISTIQUES' = MATEVOL1 ;
  171. 'FINSI' ;
  172.  
  173. PAS_MODL PRECED ;
  174.  
  175. * MaJ table rayonnement :
  176. 'SI' WTAB.'RAYO' ;
  177. WTAB.'RAYONNEMENT' = 'PRRA' WTAB.'MOD_RAY' ;
  178. 'FINSI' ;
  179.  
  180. * On sauvegarde les modeles successifs pour analyse resultats :
  181. ESTIM.'MODELES' = WTAB.'MODELE' ;
  182.  
  183. * Initialisation TINI si thermique :
  184. 'SI' WTAB.'THE1' ;
  185. MODX = WTAB.'MOD_COND' ;
  186. MODXP = MOD1P 'EXTR' 'MATE' 'CONDUCTION' ;
  187. GEO1 = MODX 'EXTR' 'MAIL' ;
  188. GEO1P = MODXP 'EXTR' 'MAIL' ;
  189. DGEO1 = GEO1 'DIFF' GEO1P ;
  190.  
  191. * Adapation du modele : transport de la solution
  192. 'SI' ((WTAB.'ADAP_MODE') 'ET' ('NON' (TI '<' (WTAB.'TPS1_ADAP')))) ;
  193. mess '***** Transport solution adaptation' ;
  194. IADAP1 = (WTAB.'INDI_ADAP') + 1 ;
  195. 'SI' (IADAP1 '&lt;EG' ('DIME' (WTAB.'LTPS_ADAP'))) ;
  196. WTAB.'TPS1_ADAP' = WTAB.'LTPS_ADAP' 'EXTR' IADAP1 ;
  197. WTAB.'INDI_ADAP' = IADAP1 ;
  198. 'SINON' ;
  199. WTAB.'TPS1_ADAP' = 'MAXI' WTAB.'TEMPS_CALCULES' + 1. ;
  200. 'FINSI' ;
  201.  
  202. * Projection du champ de temperature sur la partie adaptee :
  203. DGEO1P = DGEO1 'INTE' GEO1P ;
  204. DGEO2P = (DGEO1 'INTE' GEO1) 'INCLU' DGEO1P 'VOLU' 'BARY' ;
  205. CHT1P = CONTI.'TEMPERATURES' 'EXCO' 'T' 'T' ;
  206. CHAMT1P = 'CHAN' 'CHAM' DGEO1P CHT1P ;
  207. CHT2P = 'PROI' CHAMT1P DGEO2P ;
  208. CHT1P = ('REDU' CHT1P (GEO1P 'DIFF' DGEO1P)) 'ET' CHT2P ;
  209. CONTI.'TEMPERATURES' = CHT1P ;
  210.  
  211. * Calcul de la capacite courante sur la partie adaptee :
  212. DMODX = 'REDU' MODX DGEO2P ;
  213. DMATX = 'REDU' (WTAB.'CARACTERISTIQUES') DMODX ;
  214. DMATX = 'VARI' 'NUAG' DMODX DMATX CHT2P ;
  215. CAPAX = 'CAPA' DMODX DMATX ;
  216. CAPA1P = ('REDU' (WTAB.'CAPA_COURANTE') (GEO1P 'DIFF' DGEO1P)) 'ET' CAPAX ;
  217. WTAB.'CAPA_COURANTE' = CAPA1P ;
  218.  
  219. DGEO1 = (DGEO1 'INTE' GEO1) 'DIFF' DGEO2P ;
  220. 'FINSI' ;
  221.  
  222. * Calcul temperature dans partie apportee du modele :
  223. 'SI' ('NON' (('VIDE' DGEO1) 'OU' ('VIDE' (DGEO1 'INTE' GEO1)))) ;
  224. * Quantite de chaleur sur geometrie GEO1P :
  225. CHT1P = CONTI.'TEMPERATURES' 'EXCO' 'T' 'T' ;
  226. CAPA1P = WTAB.'CAPA_COURANTE' lump ;
  227. CHQ1P = CAPA1P * CHT1P ;
  228. * Quantite de chaleur dans apport :
  229. DMODX = 'REDU' MODX DGEO1 ;
  230. DMATX = 'REDU' (WTAB.'CARACTERISTIQUES') DMODX ;
  231. CHTINIX = DMATX 'EXCO' 'TINI' 'T' ;
  232. CHTINIX = 'CHAN' 'CHPO' CHTINIX DMODX 'MOYE' ;
  233. DMATX = 'VARI' 'NUAG' DMODX DMATX CHTINIX ;
  234. CAPAX = ('CAPA' DMODX DMATX) lump ;
  235. CHQX = CAPAX * CHTINIX ;
  236. * Calcul T sur GEO1 :
  237. CAPA1 = CAPA1P et CAPAX ;
  238. CHTX1 = 'MANU' 'CHPO' GEO1 1 'T' 1. 'NATURE' 'DIFFUS' ;
  239. CHQX1 = CAPA1 * CHTX1;
  240. CHT1 = (CHQ1P + CHQX) * ('INVE' CHQX1) ('MOTS' 'Q') ('MOTS' 'Q') ('MOTS' 'T') ;
  241. * CHT1 = reso CAPA1 (CHQ1P + CHQX) ; comm plus lent avec RESO ;
  242. CONTI.'TEMPERATURES' = CHT1 ;
  243. 'FINSI' ;
  244.  
  245. * Sauvegarde TEMPERATURES au debut du pas apres APPORT :
  246. IND1 = ('DIME' PRECED.'TEMPERATURES_APPORT') - 1 ;
  247. CHTAPP1 = CONTI.'TEMPERATURES' 'EXCO' 'T' 'TAPP' ;
  248. PRECED.'TEMPERATURES_APPORT' . IND1 = CHTAPP1 ;
  249. ESTIM .'TEMPERATURES_APPORT' = CHTAPP1 ;
  250.  
  251. * Finsi formulation thermiquue
  252. 'FINSI' ;
  253.  
  254. * Initialisation PROPORTIONS_PHASES si metallurgie :
  255. 'SI' WTAB.'FOR_METALLU' ;
  256. MODX = WTAB.'MODELE' 'EXTR' 'FORM' 'METALLURGIE' ;
  257. MODXP = MOD1P 'EXTR' 'FORM' 'METALLURGIE' ;
  258. GEO1 = MODX 'EXTR' 'MAIL' ;
  259. GEO1P = MODXP 'EXTR' 'MAIL' ;
  260. DGEO1 = GEO1 'DIFF' GEO1P ;
  261. 'SI' ('NON' (('VIDE' DGEO1) 'OU' ('VIDE' (DGEO1 'INTE' GEO1)))) ;
  262. CHMET0 = CONTI.'PROPORTIONS_PHASES' ;
  263. DMODX = 'REDU' MODX DGEO1 ;
  264. CHMET1 = 'ZERO' DMODX 'VARINTER' ;
  265. LISCO = 'EXTR' DMODX 'VARI' ;
  266. CMP1 = 'EXCO' CHMET1 ('EXTR' LISCO 1) ('EXTR' LISCO 1) ;
  267. CHMET1 = CHMET1 + (CMP1 + 1.D0);
  268. CHMET1 = CHMET0 'ET' CHMET1 ;
  269. CONTI.'PROPORTIONS_PHASES' = CHMET1 'REDU' MODX ;
  270. *trac CHMET1 MODX ;
  271. 'FINSI' ;
  272. 'FINS' ;
  273.  
  274. * Initialisation MECA si besoin :
  275. 'SI' WTAB.'FOR_MECA' ;
  276. MODM1 = 'VIDE' 'MMODEL' ;
  277. MODM1P = 'VIDE' 'MMODEL' ;
  278. 'SI' WTAB.'MEC1' ;
  279. MODM1 = MODM1 'ET' WTAB.'MOD_MEC' ;
  280. MODM1P = MODM1P 'ET' ('EXTR' MOD1P 'FORM' 'MECANIQUE') ;
  281. 'FINSI' ;
  282. 'SI' WTAB.'POR1' ;
  283. MODM1 = MODM1 'ET' WTAB.'MOD_POR' ;
  284. MODM1P = MODM1P 'ET' ('EXTR' MOD1P 'FORM' 'POREUX') ;
  285. 'FINSI' ;
  286. 'SI' ('NON' ('VIDE' MODM1)) ;
  287. GEOM1 = 'EXTR' MODM1 'MAIL' ;
  288. GEOM1P = 'EXTR' MODM1P 'MAIL' ;
  289. DGEOM1 = GEOM1 'DIFF' GEOM1P ;
  290. 'SI' ('NON' (('VIDE' DGEOM1) 'OU' ('VIDE' (DGEOM1 'INTE' GEOM1)))) ;
  291. DMODM1 = 'REDU' MODM1 DGEOM1 ;
  292.  
  293. * Mise a jour ETREF :
  294. WTAB.'ETAT_REF'= PAS_ETAT PRECED WTAB.'TEMPS0' 'REFERENCE' ;
  295. WTAB.'MAT_REF' = PAS_MATE PRECED WTAB.'ETAT_REF' ;
  296. TREF1 = 'EXCO' WTAB.'MAT_REF' 'TREF' 'T' ;
  297. WTAB.'TEMPERATURE_REFERENCE' = 'CHAN' 'TYPE' TREF1 'TEMPERATURES' ;
  298. DETREF1 = 'EPTH' DMODM1 WTAB.'MAT_REF' WTAB.'TEMPERATURE_REFERENCE' ;
  299. WTAB.'ETREF' = WTAB.'ETREF' 'ET' DETREF1 ;
  300.  
  301. * Mise a jour ETHER1 :
  302. ETAT1 = PAS_ETAT PRECED TI ;
  303. MAT1 = PAS_MATE PRECED ETAT1 ;
  304. TET1 = ('TIRE' PRECED.'CHARGEMENT' 'TAPP' TI) 'EXCO' 'TAPP' 'T' ;
  305. DETHER1 = ('EPTH' DMODM1 MAT1 TET1) - DETREF1 ;
  306. WTAB.'ETHER1' = WTAB.'ETHER1' 'ET' DETHER1 ;
  307.  
  308. * Mise a jour deplacements et deformations :
  309. DEPDGEO1 = ('EXCO' ETAT1 ('EXTR' DMODM1 'DEPL')) 'CHAN' 'CHPO' DMODM1 ;
  310. DEPSL1 = ('EPSI' DMODM1 DEPDGEO1) - DETHER1 ;
  311.  
  312. * Mise a jour table estimation :
  313. estim.DEPLACEMENTS = conti.DEPLACEMENTS 'ET' DEPDGEO1 ;
  314. estim.CONTRAINTES = conti.CONTRAINTES 'ET' ('ZERO' DMODM1 'CONTRAIN') ;
  315. estim.VARIABLES_INTERNES = conti.VARIABLES_INTERNES 'ET' ('ZERO' DMODM1 'VARINTER') ;
  316. estim.DEFORMATIONS_INELASTIQUES = conti.DEFORMATIONS_INELASTIQUES 'ET' ('ZERO' DMODM1 'DEFINELA') ;
  317. estim.DEFORMATIONS = conti.DEFORMATIONS 'ET' ('ZERO' DMODM1 'DEFORMAT') ;
  318.  
  319. 'SI' ('EXISTE' PRECED 'DEFORMATIONS_APPORT');
  320. estim.DEFORMATIONS_APPORT = conti.DEFORMATIONS_APPORT 'ET' DEPSL1 ;
  321. 'FINSI' ;
  322. 'FINSI' ;
  323.  
  324. 'SINON' ;
  325. estim.DEFORMATIONS_APPORT = conti.DEFORMATIONS_APPORT ;
  326. 'FINSI' ;
  327. 'FINSI' ;
  328.  
  329. * Fin traitement CHAR_MODE
  330. 'FINSI' ;
  331. *
  332. * ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  333. * +++++++++++++++++ BOUCLE interne de bouclage mec_ther ++++++++++++++++
  334. * ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  335. I_BOTH = 0 ;
  336. 'REPETER' BO_BOTH WTAB.'BOU_METH' ;
  337. I_BOTH = I_BOTH + 1 ;
  338. *
  339. * Re-initialisation de WTAB.'CHARGEMENT' en tete de boucle mec-ther
  340. 'SI' WTAB.'CONVERGENCE_MEC_THE' ;
  341. WTAB.'CHARGEMENT' = WTAB.'CHARGEMENT_I' ;
  342. 'FINSI';
  343. *
  344. * ####################################################################
  345. * ########### RESOLUTION D'UN PAS SI THERMIQUE/DIFFUSION #############
  346. * ####################################################################
  347. 'SI' (WTAB.'FOR_THER' 'OU' WTAB.'FOR_DIFF') ;
  348. *
  349. * Se placer dans la configuration adequate
  350. 'SI' WTAB.'FOR_MECA' ;
  351. 'SI' (I_BOTH > 1) ;
  352. 'SI' WTAB.'GRANDS_DEPLACEMENTS' ;
  353. WTAB.'RECARI' = VRAI ;
  354. WTAB.'RECADET' = VRAI ;
  355. WTAB.'REA_GEOM' = VRAI ;
  356. 'FORM' WTAB.'FOR' ;
  357. 'FINSI';
  358. 'SINON' ;
  359. 'FORM' WTAB.'GE0_DEB' ;
  360. 'FINSI' ;
  361. 'FINSI' ;
  362. *
  363. 'SI' (TI 'NEG' TEMP0);
  364. 'SI' ('NON' ('EXISTE' PRECED 'PAS_MAX'));
  365. WTAB.'TEM_CALC' = 'PROG' TI;
  366. 'SINON';
  367. 'SI' ((TEMP0 + PRECED.'PAS_MAX') '>EG' TI);
  368. WTAB.'TEM_CALC' = 'PROG' TI;
  369. 'SINON';
  370. WTAB.'TEM_CALC' = 'PROG' TEMP0
  371. 'PAS' PRECED.'PAS_MAX' TI;
  372. WTAB.'TEM_CALC' = 'ENLE' WTAB.'TEM_CALC' 1;
  373. 'FINSI';
  374. 'FINSI';
  375.  
  376. * Mise a jour blocages passes dans chargement
  377. * -> ISO AVANT MAIS A FAIRE A CHAQUE FOIS SI DEPEND DE LA MECA ??
  378. 'SI' ('EGA' I_BOTH 1) ;
  379. * Cas BLOCAGES_THERMIQUES (BLOT) :
  380. 'SI' WTAB.'CHAR_BLOT' ;
  381. BLOT1 = 'TIRE' PRECED.'BLOCAGES_THERMIQUES' 'BLOT' TI ;
  382. WTAB.'BLOCAGES_THERMIQUES' = BLOT1 ;
  383. 'FINSI' ;
  384. *
  385. * Cas BLOCAGES_DIFFUSIONS (BLOD) :
  386. 'SI' WTAB.'CHAR_BLOD' ;
  387. BLOD1 = 'TIRE' PRECED.'BLOCAGES_DIFFUSIONS' 'BLOD' TI ;
  388. WTAB.'BLOCAGES_DIFFUSIONS' = BLOD1 ;
  389. 'FINSI' ;
  390. 'FINSI' ;
  391. *
  392. * ----- Appel a la procedure thermique (lineaire ou nonlineaire) ----
  393. *
  394. 'SI' ('NON' WTAB.'COUPLAGE'); 'MENAGE'; 'FINSI';
  395. 'SI' ('EGA' WTAB.'PROCEDURE_THERMIQUE' 'NONLINEAIRE');
  396. CHTER = TRANSNON PRECED;
  397. 'FINSI';
  398. 'SI' ('EGA' WTAB.'PROCEDURE_THERMIQUE' 'LINEAIRE');
  399. CHTER = TRANSLIN PRECED;
  400. 'FINSI';
  401. 'SI' ('EGA' WTAB.'PROCEDURE_THERMIQUE' 'DUPONT');
  402. WTAB.'NOUV_PAS' = ('EXTR' WTAB.'TEM_CALC' 1) - TEMP0;
  403. CHTER = DUPONT2 PRECED;
  404. 'FINSI';
  405. *
  406. * Verification d'une erreur en sortie
  407. 'SI' CHTER.'ERREUR';
  408. 'ERREUR' ' ';
  409. 'FINSI';
  410. *
  411. * Se placer sur la configuration de reference (appel proc ut.)
  412. 'FORM' WTAB.'FOR0' ;
  413. *
  414. * Reevaluation des donnees du calcul dependant de la temperature
  415. 'SI' WTAB.'PROCEDURE_REEV_THE' ;
  416. REEV_THE PRECED 1 ;
  417. 'FINSI' ;
  418. 'FINS';
  419. *
  420. 'FINSI' ;
  421. * ####################################################################
  422. * ###### RESOLUTION D'UN PAS SI MECANIQUE/MECANIQUE DES FLUIDES ######
  423. * ####################################################################
  424. 'SI' (WTAB.'FOR_MECA' 'OU' WTAB .'NVSTNL') ;
  425. 'SAUT' 1 'LIGN';
  426. 'MESSAGE' ' Numero du pas : ' IPAS ' Indice d evolution : ' ICHG ' -> temps :' TI;
  427.  
  428. *--------------------- calcul de la temperature ---------------------
  429. * CB215821 : On met la thermique dans le Chargement pour 'TIRER' le chargement
  430. * au bon instant dans UNPAS pour la MECANIQUE
  431. * Il faudra faire de meme avec la MECANIQUE si la THERMIQUE en depend
  432. * 'SI' WTAB.'FOR_THER';
  433. * THTA1='TABLE'; THTA2='TABLE';
  434. * THTA1.0=TEMP0; THTA1.1=TI;
  435. * THTA2.0= conti.'TEMPERATURES' 'ENLE' 'LX' ;
  436. * THTA2.1= estim.'TEMPERATURES' 'ENLE' 'LX' ;
  437. * CHTH='CHAR' 'T' THTA1 THTA2;
  438. * CHASANST= WTAB.'CHARGEMENT' 'ENLE' 'T';
  439. * WTAB.'CHARGEMENT'= CHASANST 'ET' CHTH;
  440. * 'FINSI';
  441. *
  442. * Se placer sur la configuration de debut de pas
  443. 'FORM' WTAB.'GE0_DEB' ;
  444. *
  445. 'MENA' ;
  446. IERRMEC = UNPAS PRECED;
  447. *
  448. * Se placer sur la configuration de reference (appel proc ut.)
  449. 'FORM' WTAB.'FOR0' ;
  450. *
  451. * Test si on a converge
  452. 'SI' IERRMEC ;
  453. 'ERREUR' 997 ;
  454. 'FINSI';
  455. *
  456. * Reevaluation des donnees du calcul dependant de la mecanique
  457. 'SI' WTAB.'PROCEDURE_REEV_MEC' ;
  458. REEV_MEC PRECED 1;
  459. 'FINSI' ;
  460. *
  461. 'FINSI';
  462. * ####################################################################
  463. * ############ TEST DE LA CONVERGENCE MECANIQUE THERMIQUE ############
  464. * ####################################################################
  465. 'SI' WTAB.'CONVERGENCE_MEC_THE' ;
  466. * je cherche la convergence thermo-mecanique : je dois au moins
  467. * calculer deux fois mon probleme
  468. WTAB.'CONV_THMEC' = FAUX ;
  469. 'SI' (I_BOTH > 1) ;
  470. * Test sur toutes les composantes (notamment, si DIFFUSION)
  471. CHT1 = WTAB.'THER_COURANT' ;
  472. DUABS2 = 'ABS' (WTAB.'THER_COURANTP' - CHT1) ;
  473. CRICOH1 = 0. ;
  474. NBINCO1 = 'DIME' WTAB.'PRIM_TOT' ;
  475. 'REPE' BINCO1 NBINCO1 ;
  476. LINCOI1 = 'MOTS' ('EXTR' WTAB.'PRIM_TOT' &BINCO1) ;
  477. MDUABSI1 = 'MAXI' DUABS2 'AVEC' LINCOI1 ;
  478. NORMI1 = 'MAXI' 'ABS' CHT1 'AVEC' LINCOI1 ;
  479. 'SI' (NORMI1 '&lt;EG' (1.E-14 * MDUABSI1)) ;
  480. NORMI1 = 1. ;
  481. 'FINS' ;
  482. CRICOHI1 = MDUABSI1 / NORMI1 ;
  483. 'SI' (CRICOHI1 '>' CRICOH1) ;
  484. CRICOH1 = CRICOHI1 ;
  485. 'FINS' ;
  486. 'FIN' BINCO1 ;
  487.  
  488. WTAB.'CONV_THMEC' = CRICOH1 '<' (WTAB . 'CRITERE_COHERENCE') ;
  489. * Fin de boucle Si ne converge Pas
  490. 'SI'('NON' WTAB.'CONV_THMEC') ;
  491. 'SI' (I_BOTH >EG WTAB.'BOU_METH');
  492. 'MESS' 'PAS DE COHERENCE TROUVEE MECANIQUE THERMIQUE' ;
  493. 'ERREUR' 999;
  494. 'FINSI' ;
  495. 'FINSI' ;
  496. 'FINSI' ;
  497. * THER_COURANTPrecedent dans WTAB pour test CONVERGENCE_MEC_THE
  498. WTAB.'THER_COURANTP' = WTAB.'THER_COURANT' ;
  499. 'SINON' ;
  500. * ici je ne cherche pas la convergence thermomecanique
  501. WTAB.'CONV_THMEC' = VRAI ;
  502. 'FINSI' ;
  503. *
  504. 'SI' WTAB.'CONV_THMEC' ;
  505. 'QUITTER' BO_BOTH ;
  506. 'FINSI' ;
  507. *
  508. 'FIN' BO_BOTH ;
  509. * ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  510. * +++++++++++++++++ BOUCLE interne de bouclage mec_ther ++++++++++++++++
  511. * ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  512. *
  513. * ----------------------------------------------------------------------
  514. * Mise a jour des champs a TEMPS0 a partir de ceux a TI
  515. * ----------------------------------------------------------------------
  516. *
  517. * Formulation THERMIQUE
  518. 'SI' WTAB.'FOR_THER';
  519. 'SI' ('EGA' WTAB.'PROCEDURE_THERMIQUE' 'DUPONT');
  520. WTAB.'TET0' = estim.'TEMPERATURES' ;
  521. WTAB.'VIEUXPAS' = WTAB.'NOUV_PAS' ;
  522. WTAB.'RELAXATION_DUPONT' = CHTER.'RELAXATION_DUPONT';
  523. 'FINSI';
  524. 'FINSI' ;
  525. *
  526. * Formulation MECANIQUE
  527. 'SI' WTAB.'FOR_MECA' ;
  528. *
  529. 'SI' WTAB.'ITHER' ;
  530. WTAB.'TET1' = WTAB.'TET2';
  531. WTAB.'ETHER1' = WTAB.'ETHER2';
  532. 'SI' WTAB.'POR1';
  533. WTAB.'MSRTHER1'= WTAB.'MSRTHER2';
  534. 'FINSI';
  535. 'FINSI' ;
  536. *
  537. 'SI' WTAB.'CHAR_DEFI' ;
  538. WTAB.'DEFOR1' = WTAB.'DEFOR2';
  539. 'FINSI';
  540. *
  541. * En dynamique : vitesse, forces de reactions, operateur
  542. 'SI' WTAB.'DYNAMIQUE' ;
  543. *
  544. * A REPORTER DANS UNPAS ??
  545. 'SI' WTAB.'LIAISON_PERSISTANTE' ;
  546. * correction des vitesses pour avoir des vitesses relatives nulles
  547. * aux points qui sont en contact
  548. estim.'VITESSES' = estim.'VITESSES' + WTAB.'VAUX' ;
  549. 'SINON' ;
  550. * forces d'acceleration et d'amortissement a la fin du pas *
  551. WTAB.'FREA1' = WTAB.'FOPL' - estim.'REACTIONS' ;
  552. * en cas d'appuis unilateraux avec choc elastique essai de corriger
  553. * les vitesses fournies par le schema
  554. estim.'VITESSES' = VITEUNIL WTAB.'ZRAIDV' WTAB.'MASSE' estim.'VITESSES'
  555. WTAB.'DEPT' conti.'DEPLACEMENTS' WTAB.'DT' WTAB.'SECOND_MEMBRE' WTAB;
  556. 'SI' ('EXIS' WTAB 'RATE_VITEUNIL');
  557. 'ERREUR' 'Probleme dans viteunil' ;
  558. 'FINSI';
  559. 'FINSI' ;
  560. *
  561. 'SI' ('NEG' WTAB.'REAPREC' 'INCONNU');
  562. maireac = 'EXTR' estim.'REACTIONS' 'MAIL' ;
  563. 'SI' ('EGA' ('TYPE' maireac) 'MAILLAGE');
  564. reacdif = 'REDU' WTAB.'REAPREC' maireac ;
  565. estim.'REACTIONS' = estim.'REACTIONS' - REACDIF;
  566. 'FINSI' ;
  567. 'FINSI';
  568. WTAB.'REAPREC' = estim.'REACTIONS';
  569. 'FINSI';
  570. *
  571. * Actualiser la configuration de debut de pas
  572. 'SI' ( WTAB.'GRANDS_DEPLACEMENTS' 'OU'
  573. (WTAB.'FEFP_FORMULATION' 'ET' WTAB.'UPDATE_LAGRANGIAN')) ;
  574. WTAB.'GE0_DEB' = WTAB.'FOR' ;
  575. 'FINSI';
  576. *
  577. 'FINSI';
  578. *
  579. * Mise a jour du temps initial du prochain pas de temps
  580. DT2 = (TI - TEMP0) / 10000.;
  581. 'SI' (WTAB.'AUTOMATIQUE' 'OU' ('NON' WTAB.'CONV'));
  582. TEMP0 = ( TI - TEMP0) * WTAB.'AUTOCOEF' + TEMP0;
  583. 'MESS' ' Temps effectivement calcule et non converge : ' TEMP0;
  584. 'SINON';
  585. TEMP0 = TI;
  586. 'FINSI';
  587. WTAB.'TEMPS0' = TEMP0;
  588.  
  589. * Procedure utilisateur
  590. 'SI' WTAB.'FOR_MECA' ;
  591. 'SI' WTAB.'PROCEDURE_PERSO1' ;
  592. PRECED.'PERSO1_APPEL' = 2 ;
  593. PERSO1 PRECED;
  594. 'SI' ('EXIS' PRECED 'ARRET') ;
  595. WTAB.'ARRET' = PRECED.'ARRET' ;
  596. 'FINSI' ;
  597. TEMP0 = WTAB.'TEMPS0' ;
  598. 'FINSI';
  599. *
  600. * Redefinir WTAB.'CHARGEMENT_I'
  601. 'SI' WTAB.'CONVERGENCE_MEC_THE' ;
  602. WTAB.'CHARGEMENT_I' = WTAB.'CHARGEMENT' ;
  603. 'FINSI';
  604. 'FINSI';
  605. *
  606. * pour ne pas sauvegarder la matrice de raideur si on doit la recalculer
  607. 'SI' ('EXIS' WTAB 'RRRR') ;
  608. 'SI' WTAB.'RECARI' ;
  609. 'OUBL' WTAB 'RRRR' ;
  610. 'FINSI';
  611. 'FINSI';
  612. *
  613. * ----------------------------------------------------------------------
  614. * Remplir CONTINUATION et table de resultats + sauvegarde
  615. * ----------------------------------------------------------------------
  616. ISAUV = PAS_RESU TEMP0 iauto PRECED ;
  617. *
  618. * Option AUTOMATIQUE
  619. 'SI' WTAB.'AUTOMATIQUE';
  620. IAUTO=IAUTO+1;
  621. 'SI' ((WTAB.'AUTOCOEF' 'EGA' 0.9999999D0) 'OU' (TEMP0 '>EG' TI)) ;
  622. TEMP0=TI;
  623. 'MESS' ' Objectif atteint '; 'MESS' ' ';
  624. WTAB.'AUTODEUX' = FAUX ;
  625. WTAB.'AUTORED1' = 0 ;
  626. WTAB.'AUTOREDU' = 1. ;
  627. IAUTO=1;
  628. 'SINON';
  629. 'MESS' ' Objectif non atteint: On recommence'; 'MESS' ' ';
  630. 'SI' ( IAUTO >EG WTAB.'AUTOPAS');
  631. 'ERREUR' 1000;
  632. * 'MESS' 'Pilotage non converge apres ' IAUTO ' pas.';
  633. 'FINSI';
  634. WTAB.'AUTODEUX'=VRAI;
  635. ICHG=ICHG - 1; WTAB.'ICHG' = ICHG ;
  636. 'FINSI';
  637. 'FINSI';
  638. *
  639. * Option PAS_AJUSTE
  640. 'SI' WTAB.'PAS_AJUSTE';
  641. 'SI' ((TI < TIV) 'OU' ('NON' WTAB.'CONV'));
  642. ICHG=ICHG-1; WTAB.'ICHG' = ICHG ;
  643. 'FINSI';
  644. 'FINSI';
  645. *
  646. 'SI' WTAB.'ARRET';
  647. 'QUITTER' BEXTERN;
  648. 'FINSI';
  649. *
  650. 'FIN' BEXTERN;
  651. *-----------------------------------------------------------------------
  652. * Fin de la boucle sur les pas de temps
  653. *-----------------------------------------------------------------------
  654. 'SI' ('NEG' WTAB.'AMORTISSEMENT' 'INCONNU');
  655. WTAB.'AMORTISSEMENT' = TOTO ;
  656. 'FINSI';
  657. *
  658. 'SI' ('NEG' ('TYPE' WTAB.'GE0_DEB') 'MOT') ;
  659. 'OUBL' WTAB 'GE0_DEB' ;
  660. 'FINSI' ;
  661. *
  662. * pour forcer le calcul de la rigidite si on rappele pasapas
  663. 'SI' ('EXIS' WTAB 'RRRR') ;
  664. 'OUBL' WTAB 'RRRR';
  665. 'FINSI';
  666. *
  667. * on tue WTAB.'MAT1' s'il existe car il peut etre tres gourmand en place
  668. WTAB.'MAT1' = 'MOT' 'INCONNU';
  669. *
  670. 'MESS' ' ';
  671. '------------------- FIN DE LA PROCEDURE PASAPAS ---------------------';
  672. 'SAUT' 1 'LIGNE';
  673. ************************************************************************
  674. 'FINPROC' PRECED ;
  675.  
  676.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales