Télécharger corrig.dgibi

Retour à la liste

Numérotation des lignes :

  1. **
  2. ************************************************************************
  3. ************************************************************************
  4. * chute d une structure sur une autre
  5. **
  6. opti dime 3 elem cub8 ;
  7. graph = FAUX ;
  8. * graph = VRAI ; opti trac PSC;
  9.  
  10. p_ori = 0. 0. 0. ; e_x = 1. 0. 0. ; e_y = 0. 1. 0. ; e_z = 0. 0. 1. ;
  11.  
  12. r1 = 0.5 ; n1 = 3 ; n2 = 4 ; n3 = 5 ;
  13. h_chute = 0.1 ;
  14. p_c0 = p_ori plus e_z ; p_0 = p_c0 plus (r1*e_x) ;
  15. lr_0 = p_c0 d n1 p_0 ;
  16. p_90 = p_c0 plus (r1*e_y) ; lr_90 = p_c0 d n1 p_90 ;
  17. lp_1 = p_0 c n2 p_ori p_90 ;
  18. ch2 = manu chpo lp_1 uz 1. ; ch1 = nomc (coor 3 lp_1) uz;
  19. depl lp_1 moins (ch1 - ch2) ;
  20. ls_0 = lr_0 et lp_1 et lr_90 ; elim 1.e-4 ls_0 ;
  21. opti elem tri3 ;
  22. s_0i = surf plan ls_0 ; s_0 = oriente s_0i direction ((-1.)*e_z) ;
  23. opti elem cub8 ;
  24. v_0 = volu n3 s_0 tran e_z ;
  25.  
  26. s_ei = s_0 moins (h_chute*e_z) coul cyan ;
  27. s_e = oriente s_ei direction e_z;
  28. v_e = s_e volu trans 1 ((-1.)*e_z) ; s_eb = face 2 v_e ;
  29. v_e = v_e coul vert ;
  30.  
  31. v_0 depl plus (r1*0.*e_x) ;
  32. **macont1 = ('IMPO' 'MAIL' s_0 s_e) 'COUL' 'CYAN' ;
  33. si graph ;
  34. titre 'maillages projectile, cible, contact ' ;
  35. **trac cach (v_0 et macont1 et v_e);
  36. finsi ;
  37.  
  38. mo_c = mode v_0 mecanique elastique ;
  39. ca_c = mate mo_c youn 2.e11 nu 0.3 rho 8.e4 ;
  40. mocont1= mode s_0 contact unilateral s_e;
  41. mo_e = mode v_e mecanique elastique ;
  42. ca_e = mate mo_e youn 1.e12 nu 0.4 rho 1.e4 ;
  43.  
  44. mass_c = mass mo_c ca_c ;
  45. po_c = mass_c * (manu chpo v_0 -9.81 uz) ;
  46. ev_1 = evol manu (prog 0. 1.e3) (prog 1. 1.) ;
  47. chg1= char meca ev_1 po_c ;
  48.  
  49. bl_e = bloq depl s_eb ;
  50.  
  51. *------------modal
  52. nmod2 = 10 ;
  53. rig_c = rigi mo_c ca_c ;
  54. tab_c= vibr simul 0.1 nmod2 rig_c mass_c ;
  55. def_0 = defo v_0 tab_c . modes . 1 . deformee_modale 0. ;
  56. repeter b_mol nmod2 ;
  57. vsm_i = vmis mo_c
  58. (sigma mo_c ca_c tab_c . modes . &b_mol . deformee_modale) ;
  59. def_i = defo v_0 tab_c . modes . &b_mol . deformee_modale 0.1
  60. vsm_i mo_c ;
  61. titre ' mode ' tab_c . modes . &b_mol . numero_mode
  62. ' frequence ' tab_c . modes . &b_mol . frequence ;
  63. *list tab_c . modes . &b_mol . point_repere ;
  64. si graph ;
  65. trac (def_0 et def_i) cach ;
  66. finsi ;
  67.  
  68. *bp, 2017-10-03 : on interdit dans MATE les frequences<0
  69. *--> petit ajustement :
  70. si (tab_c. modes . &b_mol . frequence < 0.);
  71. tab_c. modes . &b_mol . frequence = 0.;
  72. finsi;
  73.  
  74. ma_i = manu poi1 tab_c . modes . &b_mol . point_repere ;
  75. mo_i = mode ma_i mecanique elastique modal ;
  76. ca_i = mate mo_i frequence tab_c . modes . &b_mol . frequence
  77. mass tab_c . modes . &b_mol . masse_generalisee
  78. defo tab_c . modes . &b_mol . deformee_modale ;
  79. si (&b_mol ega 1) ;
  80. m_dal = mo_i ; c_dal = ca_i ;
  81. sinon ;
  82. m_dal = m_dal et mo_i ; c_dal = c_dal et ca_i ;
  83. finsi ;
  84.  
  85. fin b_mol ;
  86.  
  87. chg_al = pjba chg1 m_dal c_dal ;
  88.  
  89. t_chu = table 'PASAPAS' ;
  90. t_chu . modele = m_dal et mocont1 et mo_e ;
  91. t_chu . caracteristiques = c_dal et ca_e ;
  92. t_chu . chargement = chg_al ;
  93. t_chu . blocages_mecaniques = bl_e ;
  94. t_chu . dynamique = vrai ;
  95. t_chu . temps_calcules = prog 0. pas 0.02 0.3 ;
  96. t_chu . hypothese_deformations = 'LINEAIRE' ;
  97.  
  98. pasapas t_chu ;
  99.  
  100. chd_0 = reco t_chu . deplacements . 1 m_dal c_dal ;
  101. defm_0 = defo s_0 (redu chd_0 s_0 ) 0. ;
  102. defm_i = def_0 ;
  103. defm_ti = defo (v_0 et v_e) chd_0 0. ;
  104. omp_0 = prog 0. ; am_t = prog 0. ;
  105. l_coul = (prog 1.5 pas 1. 22.5)*1.e6 ;
  106. repeter b_mchu ((dime t_chu . temps ) - 1) ;
  107. chd_i = reco t_chu . deplacements . &b_mchu m_dal c_dal ;
  108. sig_i = sigma mo_c ca_c chd_i ;
  109. vmm_i = (vmis mo_c sig_i) et
  110. (vmis mo_e (redu t_chu . contraintes . &b_mchu mo_e)) ;
  111. defm_i = defm_i et
  112. (defo s_0 (redu chd_i s_0 ) 1. ) ;
  113. defm_ii = defo (v_0 et v_e)
  114. (chd_i et (redu t_chu . deplacements . &b_mchu v_e)) 1.
  115. vmm_i (mo_e et mo_c) ;
  116. defm_ti = defm_ti et defm_ii ;
  117. si graph ;
  118. titre 'modal - temps : ' t_chu . temps . &b_mchu ;
  119. trac defm_ii l_coul;
  120. finsi ;
  121. omp_0 = omp_0 et (prog (extr t_chu . deplacements . &b_mchu uz p_0) );
  122. am_t = am_t et (prog t_chu . temps . &b_mchu) ;
  123.  
  124. fin b_mchu ;
  125.  
  126. evmp_0 = evol rouge manu 'TEMPS (s)' am_t 'DEPL (m)' omp_0 ;
  127. si graph ;
  128. trac anim defm_i s_0 ;trac anim defm_ti vmm_i (mo_e et mo_c) l_coul;
  129. dess evmp_0 ;
  130. finsi ;
  131. *--------------
  132. *opti donn 3 ;
  133.  
  134. tabchu = table 'PASAPAS' ;
  135. tabchu . modele = mo_c et mocont1 et mo_e;
  136. tabchu . caracteristiques = ca_c et ca_e ;
  137. tabchu . chargement = chg1 ;
  138. tabchu . blocages_mecaniques = bl_e ;
  139. tabchu . dynamique = vrai ;
  140. tabchu . temps_calcules = prog 0. pas 0.02 0.3 ;
  141. tabchu . hypothese_deformations = 'LINEAIRE' ;
  142.  
  143. pasapas tabchu ;
  144.  
  145. def_0 = defo s_0 (redu tabchu . deplacements . 1 s_0 ) 0. ;
  146. def_i = def_0 ;
  147. def_ti = defo (v_0 et v_e) tabchu . deplacements . 1 0. ;
  148. o_p_0 = prog 0. ; a_t = prog 0. ;
  149. l_coul = (prog 1.5 pas 1. 22.5)*1.e6 ;
  150. repeter b_chu ((dime tabchu . temps ) - 1) ;
  151. * vm_i = vmis tabchu . contraintes . &b_chu tabchu . modele ;
  152. vm_i = vmis (mo_e et mo_c) tabchu . contraintes . &b_chu ;
  153. def_i = def_i et
  154. (defo s_0 (redu tabchu . deplacements . &b_chu s_0 ) 1. ) ;
  155. def_ii = defo (v_0 et v_e) tabchu . deplacements . &b_chu 1.
  156. vm_i (mo_e et mo_c) ;
  157. def_ti = def_ti et def_ii ;
  158. si graph ;
  159. titre 'EF - temps : ' tabchu . temps . &b_chu ;
  160. * trac def_ii l_coul;
  161. finsi ;
  162. o_p_0 = o_p_0 et (prog (extr tabchu . deplacements . &b_chu uz p_0) ) ;
  163. a_t = a_t et (prog tabchu . temps . &b_chu) ;
  164.  
  165. fin b_chu ;
  166.  
  167. ev_p_0 = evol bleu manu 'TEMPS (s)' a_t 'DEPL (m)' o_p_0 ;
  168. si graph ;
  169. trac anim def_i s_0 ;trac anim def_ti vm_i (mo_e et mo_c) l_coul;
  170. dess ev_p_0 ;
  171. finsi ;
  172.  
  173. si graph ;
  174. titre ' chute ';
  175. dess (ev_p_0 et evmp_0) ;
  176. finsi ;
  177.  
  178. si ((abs(((extr o_p_0 10) - (extr omp_0 10))/(extr omp_0 10))) < 3.e-3);
  179. erre 0 ;
  180. finsi ;
  181.  
  182. fin ;
  183.  
  184.  
  185.  
  186.  
  187.  
  188.  
  189.  
  190.  
  191.  
  192.  
  193.  
  194.  
  195.  
  196.  
  197.  
  198.  
  199.  
  200.  
  201.  
  202.  
  203.  
  204.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales