Télécharger la plaquette Cast3M


fr en

Télécharger xfem3d_03.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : xfem3d_03.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. ************************************************************************
  5. *          Cas-test propose par F. MERAY, modifié par JB251061         *
  6. *                                                                      *
  7. *    VERIFICATION QUE LE TERME DE FROTTEMENT EST BIEN NUL AVEC UNE     *
  8. *                    FORCE DE FROTTEMENT NULLE                         *
  9. *                                                                      *
  10. ************************************************************************
  11. ************************************************************************
  12.  
  13.  
  14. *******************************************************
  15. ********************** Options ************************
  16. *******************************************************
  17.  
  18. OPTI DIME 3 ELEM CUB8 MODE TRID ;
  19.  
  20. BTRAC = FAUX ;
  21. OEIL1 = -100. -100. 50. ;
  22.  
  23. * PARAMETRES MATERIAUX
  24. YOUN1 = 2.1E5 ;
  25. NU1 = 0.3 ;
  26. RHO1 = 7.8E-9 ;
  27.  
  28. *******************************************************
  29. **************        MAILLAGES        ****************
  30. *******************************************************
  31.  
  32. * DEFINITION D'UNE BASE ORTHONORMEE DIRECTE
  33. EX = 1. 0. 0. ;
  34. EY = 0. 1. 0. ;
  35. EZ = 0. 0. 1. ;
  36.  
  37. * PARAMETRES DU MAILLAGE X-FEM
  38.  
  39. * DISCRETISATION X-FEM
  40. MULT1 = 3. ;
  41. DX = 0.02*MULT1 ;
  42. DY = 0.02*MULT1 ;
  43. DZ = 0.02*MULT1 ;
  44.  
  45. * DECALAGE ENTRE LA POSITION DE LA FISSURE ET LE CENTRE DU VOLUME X-FEM
  46. SHIFT = 4. ;
  47.  
  48. * CENTRE DU VOLUME X-FEM
  49. CXMODL = (0.60 + (SHIFT * DX)) ;
  50. CYMODL = 0. ;
  51. CZMODL = 0.13 ;
  52.  
  53. * TAILLE DU VOLUME X-FEM
  54. LX = 0.8 ;
  55. LY = 0.8 ;
  56. LZ = 0.26 ;
  57.  
  58.  
  59. * PARAMETRES DU MAILLAGE DE LA FISSURE CIRCULAIRE
  60.  
  61. * DISCRETISATION DE LA FISSURE
  62. DXCRACK = DX / 1. ;
  63.  
  64. * RAYON DE LA FISSURE
  65. A0 = 0.20 ;
  66.  
  67. * INCLINAISON
  68. BETA = +75. ;
  69.  
  70.  
  71. *******************************************************
  72. ************** MAILLAGE : VOLUME X-FEM ****************
  73. *******************************************************
  74.  
  75. * * POINTS NECESSAIRES A LA CONSTRUCTION DU VOLUME X-FEM
  76. PB1 = (CXMODL-(0.5*LX)) (CYMODL+(0.5*LY)) (CZMODL+(0.5*LZ)) ;
  77. PB2 = (CXMODL+(0.5*LX)) (CYMODL+(0.5*LY)) (CZMODL+(0.5*LZ)) ;
  78. PB3 = (CXMODL-(SHIFT*DX)-DX) (CYMODL+(0.5*LY)) (CZMODL+(0.5*LZ)) ;
  79. PB4 = (CXMODL-(SHIFT*DX)+(1.*DX)) (CYMODL+(0.5*LY)) (CZMODL+(0.5*LZ)) ;
  80. * RAFFINEMENT 1 DU MAILLAGE EN SURFACE
  81. PB5 = (CXMODL-(0.5*LX)) (CYMODL+(0.5*LY)) (CZMODL-(0.5*LZ)+(3.*DZ)) ;
  82. PB6 = (CXMODL+(0.5*LX)) (CYMODL+(0.5*LY)) (CZMODL-(0.5*LZ)+(3.*DZ)) ;
  83. PB7 = (CXMODL-(SHIFT*DX)-DX) (CYMODL+(0.5*LY))
  84.       (CZMODL-(0.5*LZ)+(3.*DZ)) ;
  85. PB8 = (CXMODL-(SHIFT*DX)+(1.*DX)) (CYMODL+(0.5*LY)) 
  86.       (CZMODL-(0.5*LZ)+(3.*DZ)) ;
  87. * RAFFINEMENT 2 DU MAILLAGE EN SURFACE
  88. PB9 = (CXMODL-(0.5*LX)) (CYMODL+(0.5*LY)) (CZMODL-(0.5*LZ)+(0.5*DZ)) ;
  89. PB10 = (CXMODL+(0.5*LX)) (CYMODL+(0.5*LY)) (CZMODL-(0.5*LZ)+(0.5*DZ)) ;
  90. PB11 = (CXMODL-(SHIFT*DX)-DX) (CYMODL+(0.5*LY))
  91.        (CZMODL-(0.5*LZ)+(0.5*DZ)) ;
  92. PB12 = (CXMODL-(SHIFT*DX)+(1.*DX)) (CYMODL+(0.5*LY))
  93.        (CZMODL-(0.5*LZ)+(0.5*DZ)) ;
  94. * RAFFINEMENT 3 DU MAILLAGE EN SURFACE
  95. PB13 = (CXMODL-(0.5*LX)) (CYMODL+(0.5*LY)) (CZMODL-(0.5*LZ)+(0.25*DZ)) ;
  96. PB14 = (CXMODL+(0.5*LX)) (CYMODL+(0.5*LY)) (CZMODL-(0.5*LZ)+(0.25*DZ)) ;
  97. PB15 = (CXMODL-(SHIFT*DX)-DX) (CYMODL+(0.5*LY))
  98.        (CZMODL-(0.5*LZ)+(0.25*DZ)) ;
  99. PB16 = (CXMODL-(SHIFT*DX)+(1.*DX)) (CYMODL+(0.5*LY))
  100.        (CZMODL-(0.5*LZ)+(0.25*DZ)) ;
  101.  
  102. PB17 = (CXMODL+(0.5*LX)) (CYMODL-(0.5*LY)) (CZMODL+(0.5*LZ)) ;
  103. PB18 = (CXMODL-(0.5*LX)) (CYMODL+(0.5*LY)) (CZMODL-(0.5*LZ)) ;
  104.  
  105. * DEFINITION DES DROITES NECESSAIRES AU MAILLAGE 
  106. DRB11 = PB1 DROI PB3 'DINI' DX 'DFIN' DX ; 
  107. DRB12 = PB3 DROI PB4 'DINI' (0.5*DX) 'DFIN' (0.5*DX) ; 
  108. DRB13 = PB4 DROI PB2 'DINI' DX 'DFIN' DX ; 
  109. DRB1 = DRB11 ET DRB12 ET DRB13 ;
  110. DRB21 = PB5 DROI PB7 'DINI' DX 'DFIN' DX ; 
  111. DRB22 = PB7 DROI PB8 'DINI' (0.5*DX) 'DFIN' (0.5*DX) ; 
  112. DRB23 = PB8 DROI PB6 'DINI' DX 'DFIN' DX ; 
  113. DRB2 = DRB21 ET DRB22 ET DRB23 ;
  114. DRB31 = PB9 DROI PB11 'DINI' DX 'DFIN' DX ; 
  115. DRB32 = PB11 DROI PB12 'DINI' (0.5*DX) 'DFIN' (0.5*DX) ; 
  116. DRB33 = PB12 DROI PB10 'DINI' DX 'DFIN' DX ; 
  117. DRB3 = DRB31 ET DRB32 ET DRB33 ;
  118. DRB41 = PB13 DROI PB15 'DINI' DX 'DFIN' DX ; 
  119. DRB42 = PB15 DROI PB16 'DINI' (0.5*DX) 'DFIN' (0.5*DX) ; 
  120. DRB43 = PB16 DROI PB14 'DINI' DX 'DFIN' DX ; 
  121. DRB4 = DRB41 ET DRB42 ET DRB43 ;
  122.  
  123.  
  124. * MAILLAGE SURFACE
  125. LZ1 = MESU (PB1 DROI PB5 'DINI' DZ 'DFIN' DZ) ;
  126. LZ2 = MESU (PB5 DROI PB9 'DINI' DZ 'DFIN' DZ) ;
  127. LZ3 = MESU (PB9 DROI PB13 'DINI' DZ 'DFIN' DZ) ;
  128. LZ4 = MESU (PB13 DROI PB18 'DINI' DZ 'DFIN' DZ) ;
  129.  
  130. SB11 = DRB1 TRAN 'DINI' DZ 'DFIN' DZ (-1*LZ1*EZ) COUL 'JAUNE' ;
  131. SB12 = DRB2 TRAN 'DINI' (0.5*DZ) 'DFIN' (0.5*DZ) (-1*LZ2*EZ) ;
  132. SB13 = DRB3 TRAN 'DINI' (0.25*DZ) 'DFIN' (0.25*DZ) (-1*LZ3*EZ) ;
  133. SB14 = DRB4 TRAN 'DINI' (0.125*DZ) 'DFIN' (0.125*DZ) (-1*LZ4*EZ) ;
  134.  
  135. SB1 = SB11 ET SB12 ET SB13 ET SB14 ;
  136. ELIM SB1 (1.E-3*DX) ;
  137.  
  138.  
  139. * MAILLAGE VOLUME
  140. LY1 = MESU (PB2 DROI PB17 'DINI' DY 'DFIN' DY) ;
  141.  
  142. VOL1 = SB1 VOLU 'TRAN' 'DINI' DY 'DFIN' DY (-1*LY1*EY) COUL 'BLEU' ;
  143.  
  144. * DEFINITION DU CONTOUR ET DE L'ENVELOPPE
  145. CON1 = ARET VOL1 ;
  146. ENV1 = ENVE VOL1 COUL 'BLEU' ;
  147.  
  148.  
  149. *******************************************************
  150. *******     MAILLAGE : FISSURE CIRCULAIRE     *********
  151. *******************************************************
  152.  
  153. &ELEM = VALE 'ELEM' ;
  154. OPTI ELEM TRI3 ;
  155.  
  156. * POINTS NECESSAIRES A LA CONSTRUCTION DE LA FISSURE
  157. DENS (DXCRACK) ;
  158. CF = (CXMODL-(SHIFT*DX)) CYMODL (CZMODL-(0.5*LZ)) ;
  159. PF1 = (CXMODL-(SHIFT*DX)) (CYMODL-A0) (CZMODL-(0.5*LZ)) ;
  160. PF2 = (CXMODL-(SHIFT*DX)) (CYMODL+A0) (CZMODL-(0.5*LZ)) ;
  161. PF3 = (CXMODL-(SHIFT*DX)) CYMODL (CZMODL-(0.5*LZ)+A0) ;
  162. PF4 = (CXMODL-(SHIFT*DX)) (CYMODL-A0*(COS(45)))
  163.       (CZMODL-(0.5*LZ)+(A0*(SIN(45)))) ;
  164. PF5 = (CXMODL-(SHIFT*DX)) (CYMODL+A0*(COS(45)))
  165.       (CZMODL-(0.5*LZ)+(A0*(SIN(45)))) ;
  166.  
  167. LF1 = (PF1 DROI CF) DROI PF2 ;
  168.  
  169. * DEFINITION DU FRONT DE FISSURE
  170. LF2 = CERC 'CENTR' PF2 CF PF5 ;
  171. LF3 = CERC 'CENTR' PF5 CF PF3 ;
  172. LF4 = CERC 'CENTR' PF3 CF PF4 ;
  173. LF5 = CERC 'CENTR' PF4 CF PF1 ;
  174. LCRACK = LF2 ET LF3 ET LF4 ET LF5 ;
  175.  
  176. * ROTATION DE L'ANGLE BETA
  177. LCRACK = LCRACK TOUR BETA PF1 PF2 ;
  178.  
  179. ELIM (LF1 ET LCRACK) (1.E-6 * DX) ;
  180. FRONT1 = LCRACK COUL 'ORAN' ;
  181.  
  182. * MAILLAGE DE LA FISSURE
  183. CRACK1 = SURF (LF1 ET LCRACK) 'PLAN' COUL 'ROUG' ;
  184.  
  185. *FRONT1 = INVE FRONT1 ;
  186. *CRACK1 = ORIE CRACK1 (-1*EZ) ;
  187.  
  188. * ON REPASSE EN CUB8
  190.  
  191.  
  192. *******************************************************
  193. ************** GENERATION DES LEVEL-SETS **************
  194. *******************************************************
  195.  
  196. * DEFINITION / MISE A JOUR DES LEVEL-SETS
  197. PSI1 PHI1 = PSIP VOL1 CRACK1 'DEUX' FRONT1 ;
  198.  
  199. * TRACE DES LEVEL-SETS
  200. SI BTRAC ;
  202. * ISOVALEUR POUR LE TRACE DES LEVEL-SETS
  203.  ISOV1 = 2.E-2 * (PROG -10. PAS 0.5 10.) ;
  204.  TRAC PHI1 VOL1 ISOV1 OEIL1 TITR 'LEVEL SET PHI1' ;
  205.  TRAC PSI1 VOL1 ISOV1 OEIL1 COUP (0. 0. 0.) EZ EX
  206.       TITR 'LEVEL SET PSI1' ;
  207. FINSI ;
  208.  
  209.  
  210. ********************************************************
  211. ******************* MODELE & MATERIAU ******************
  212. ********************************************************
  213.  
  214. MOD1 = MODE VOL1 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' 'XC8R' ;
  215. MAT1 = MATE MOD1 'YOUN' YOUN1 'NU' NU1 'RHO' RHO1 ;
  216. * TRIE LES ELEMENTS D'UN MODELE XFEM ET SORT UN MCHAML
  217. * D'ENRICHISSEMENT EN FONCTION DE LA VALEUR DES LEVEL-SETS.
  218. CHE1X = TRIE MOD1 PSI1 PHI1 ;
  219. * CONSTRUCTION DES BLOCAGES DES DDL XFEM NON ACTIFS DANS
  220. * LES ELEMENTS DE TRANSITION.
  221. REL1X = RELA MOD1 ;
  222.  
  223.  
  224. ********************************************************
  225. ***** DEFINITION DU REPERE LOCAL LIE A LA FISSURE ******
  226. ********************************************************
  227.  
  228. * PROCEDURE LOCABA3D
  229. DEBP LOCABA3D MOD_INT*MMODEL ;
  230.  
  231. ** DETERMINATION DES NORMALES AU MAILLAGE DE LA FISSURE (CHPO) 
  232.  CHN = VSUR MOD_INT 'NORM' ;
  233.  MO1 = 'EXTRAIRE' CHN 'COMP' ;
  234.  MO2 = 'MOTS' 'NX  ' 'NY  ' 'NZ  ' ;
  235.  CHN = 'CHANGER' 'CHPO' MOD_INT CHN 'MOYE' ;
  236.  CHN = 'NOMC' CHN MO1 MO2 ;
  237.  CHN = -1. * CHN ;
  238.  
  239.  
  240. ** DEFINITION DE PARAMETRES
  241.  CHT1 = 0. * CHN ; CHT2 = 0. * CHN ;
  242.  MXN1 = 'MOTS' 'NX  ' ; MYN1 = 'MOTS' 'NY  ' ; MZN1 = 'MOTS' 'NZ  ' ;
  243.  MXV1 = 'MOTS' 'V1X ' ; MYV1 = 'MOTS' 'V1Y ' ; MZV1 = 'MOTS' 'V1Z ' ;
  244.  MXV2 = 'MOTS' 'V2X ' ; MYV2 = 'MOTS' 'V2Y ' ; MZV2 = 'MOTS' 'V2Z ' ;
  245.  MXT1 = 'MOTS' 'T1X ' ; MYT1 = 'MOTS' 'T1Y ' ; MZT1 = 'MOTS' 'T1Z ' ;
  246.  MXT2 = 'MOTS' 'T2X ' ; MYT2 = 'MOTS' 'T2Y ' ; MZT2 = 'MOTS' 'T2Z ' ;
  247.  MSCA = 'MOTS' 'SCAL ' ;
  248.  
  249.  
  250. ** CREATION DES VECTEURS EX ET EY
  251.  CRACK = 'EXTRAIRE' MOD_INT 'MAIL' ;
  252.  CHV1 = MANU 'CHPO' CRACK 3 'V1X ' 1. 'V1Y ' 0. 'V1Z ' 0. ;
  253.  CHV2 = MANU 'CHPO' CRACK 3 'V2X ' 0. 'V2Y ' 1. 'V2Z ' 0. ;
  254.  
  255.  
  256. ** CALCUL DE LA PREMIERE TANGENTE T1 
  257. * CREATION D UN VECTEUR ALEATOIRE -> PREMIER POSSIBILITE : EX
  258.  XN1 = 'NOMC' 'NX  ' ('EXCO' 'NX  ' CHN) ;
  259.  YN1 = 'NOMC' 'NY  ' ('EXCO' 'NY  ' CHN) ;
  260.  ZN1 = 'NOMC' 'NZ  ' ('EXCO' 'NZ  ' CHN) ;
  261.  XV1 = 'NOMC' 'V1X ' ('EXCO' 'V1X ' CHV1) ;
  262.  YV1 = 'NOMC' 'V1Y ' ('EXCO' 'V1Y ' CHV1) ;
  263.  ZV1 = 'NOMC' 'V1Z ' ('EXCO' 'V1Z ' CHV1) ;
  264. * PRODUIT VECTORIEL
  265.  XT1_EX =(YN1 '*' ZV1 MYN1 MZV1 MXT1) '-' (ZN1 '*' YV1 MZN1 MYV1 MXT1) ;
  266.  YT1_EX =(ZN1 * XV1 MZN1 MXV1 MYT1) '-' (XN1 * ZV1 MXN1 MZV1 MYT1) ;
  267.  ZT1_EX =(XN1 * YV1 MXN1 MYV1 MZT1) '-' (YN1 * XV1 MYN1 MXV1 MZT1) ;
  268.  CHT1_EX = XT1_EX '+' YT1_EX '+' ZT1_EX ;
  269.  
  270. * CREATION D UN VECTEUR ALEATOIRE -> DEUXIEME POSSIBILITE : EY
  271.  XN1 = 'NOMC' 'NX  ' ('EXCO' 'NX  ' CHN) ;
  272.  YN1 = 'NOMC' 'NY  ' ('EXCO' 'NY  ' CHN) ;
  273.  ZN1 = 'NOMC' 'NZ  ' ('EXCO' 'NZ  ' CHN) ;
  274.  XV2 = 'NOMC' 'V2X ' ('EXCO' 'V2X ' CHV2) ;
  275.  YV2 = 'NOMC' 'V2Y ' ('EXCO' 'V2Y ' CHV2) ;
  276.  ZV2 = 'NOMC' 'V2Z ' ('EXCO' 'V2Z ' CHV2) ;
  277. * PRODUIT VECTORIEL
  278.  XT1_EY =(YN1 '*' ZV2 MYN1 MZV2 MXT1) '-' (ZN1 '*' YV2 MZN1 MYV2 MXT1) ;
  279.  YT1_EY =(ZN1 * XV2 MZN1 MXV2 MYT1) '-' (XN1 * ZV2 MXN1 MZV2 MYT1) ;
  280.  ZT1_EY =(XN1 * YV2 MXN1 MYV2 MZT1) '-' (YN1 * XV2 MYN1 MXV2 MZT1) ;
  281.  CHT1_EY = XT1_EY '+' YT1_EY '+' ZT1_EY ;
  282.  
  283.  
  284. *** ON VERIFIE QUE CHT1_EX NON COLINAIRE A CHN (PRODUIT VECTORIEL NUL)
  285.  M1 = 'EXTRAIRE' CHT1_EX 'COMP' ;
  286.  N1 = (('PSCAL' CHT1_EX CHT1_EX M1 M1)**0.5) ;
  287.  MASQ_EY = MASQ N1 'INFERIEUR' 10.E-6 ;
  288.  MASQ_EX = -1 * (MASQ_EY - 1.) ;
  289.  
  290.  
  291. *** CONSTRUCTION DE CHT1
  292.  XT1 = (MASQ_EX '*' XT1_EX MSCA MXT1 MXT1) '+' 
  293.        (MASQ_EY '*' XT1_EY MSCA MXT1 MXT1) ;
  294.  YT1 = (MASQ_EX '*' YT1_EX MSCA MYT1 MYT1) '+' 
  295.        (MASQ_EY '*' YT1_EY MSCA MYT1 MYT1) ;
  296.  ZT1 = (MASQ_EX '*' ZT1_EX MSCA MZT1 MZT1) '+' 
  297.        (MASQ_EY '*' ZT1_EY MSCA MZT1 MZT1) ;
  298.  CHT1 = XT1 '+' YT1 '+' ZT1 ;
  299. * NORMALISATION DE CHT1
  300.  M1 = 'EXTRAIRE' CHT1 'COMP' ;
  301.  CHT1 = CHT1 '/' (('PSCAL' CHT1 CHT1 M1 M1)**0.5) ;
  302.  
  303.  
  304. ** CALCUL DE LA DEUXIEME TANGENTE CHT2 
  305. *  => PRODUIT VECTORIEL ENTRE CHN ET CHT1
  306.  XT1 = 'NOMC' 'T1X ' ('EXCO' 'T1X ' CHT1) ;
  307.  YT1 = 'NOMC' 'T1Y ' ('EXCO' 'T1Y ' CHT1) ;
  308.  ZT1 = 'NOMC' 'T1Z ' ('EXCO' 'T1Z ' CHT1) ;
  309. * PRODUIT VECTORIEL
  310.  XT2 = (YN1 '*' ZT1 MYN1 MZT1 MXT2) '-' (ZN1 '*' YT1 MZN1 MYT1 MXT2) ;
  311.  YT2 = (ZN1 * XT1 MZN1 MXT1 MYT2) '-' (XN1 * ZT1 MXN1 MZT1 MYT2) ;
  312.  ZT2 = (XN1 * YT1 MXN1 MYT1 MZT2) '-' (YN1 * XT1 MYN1 MXT1 MZT2) ;
  313.  CHT2 = XT2 '+' YT2 '+' ZT2 ;
  314. * NORMALISATION DE T2
  315.  M2 = 'EXTRAIRE' CHT2 'COMP' ;
  316.  CHT2 = CHT2 '/' (('PSCAL' CHT2 CHT2 M2 M2)**0.5) ;
  317.  
  318. FINP CHN CHT1 CHT2 ;
  319.  
  320. * CONSTRUCTION REPERE LOCAL
  321. MOD_INT = MODE CRACK1 'MECANIQUE' 'ZCO3' ;
  322. * APPEL DE LA VERSION MODIFIEE DE LOCABA3D (LOCBA3D2)
  323. CHN CHT1 CHT2 = LOCABA3D MOD_INT ;
  324. CHN = 1. * CHN ;
  325. CHT1 = 1. * CHT1 ;
  326. CHT2 = 1. * CHT2 ;
  327.  
  328. * AFFICHAGE REPERE LOCAL
  329. VN = VECT CHN 'NX  ' 'NY  ' 'NZ  ' JAUNE ;
  330. VT1 = VECT CHT1 'T1X ' 'T1Y ' 'T1Z ' BLANC ;
  331. VT2 = VECT CHT2 'T2X ' 'T2Y ' 'T2Z ' BLEU ;
  332. VLOC = (VN ET VT1 ET VT2) ;
  333. SI BTRAC ;
  334.  TRAC VLOC CRACK1 OEIL1 TITR 'REPERE LOCAL' ;
  335. FINSI ;
  336.  
  337.  
  338. ********************************************************
  339. *************** CONDITIONS AUX LIMITES *****************
  340. ********************************************************
  341.  
  342. X Y Z = COOR ENV1 ;
  343. PINF = Z POIN 'MINI' ;
  344. PSUP = Z POIN 'MAXI' ;
  345. ESUP = ENV1 ELEM 'APPUYE' PSUP ;
  346.  
  347. BLOQ1 = BLOQ 'DEPL' PINF ;
  348. FORTOT = PRES 'MASS' MOD1 1. ESUP ;
  349.  
  350. SI BTRAC ;
  351.  TRAC (VECT FORTOT 'FORC') VOL1 OEIL1 TITR 'Chargement' ;
  352. FINSI ;
  353.  
  354.  
  355. ********************************************************
  356. *** CONSTRUCTION DES DIFFERENTES MATRICES DE RAIDEUR ***
  357. ********************************************************
  358.  
  359. * RIGIDITE FORMULATION XFEM 1 CHAMP
  360. K1 = RIGI MOD1 MAT1 ;
  361.  
  362. * RIGIDITE TOTALE
  363. KTOT = K1 ET BLOQ1 ET REL1X ;
  364.  
  365.  
  366. *******************************************************
  367. ********************** Resolution *********************
  368. *******************************************************
  369.  
  370. U1 = RESO KTOT FORTOT ;
  371.  
  372.  
  373. *******************************************************
  374. ******************** Calcul des FICs ******************
  375. *******************************************************
  376.  
  377. * CREATION D'UN CHAMP DE SAUT DE DEPLACEMENT TANGENT A LA FISSURE
  378. X Y Z = COOR CRACK1 ;
  379. WSAUT = MANU 'CHPO' CRACK1 (MOTS 'AX' 'AZ') (PROG 0. 0.) ;
  380. WSAUT = WSAUT + (NOMC 'AY' X) ;
  381.  
  382. * CREATION D'UN CHAMP DE VECTEUR CONTRAINTE NORMAL A LA FISSURE
  383. VOL2 = CRACK1 VOLU 1 'TRAN' (1. 0. 0.) ;
  384. MOD2 = MODE VOL2 'MECANIQUE' ;
  385. PRES1 = PRES 'MASS' MOD2 1.E3 CRACK1 ;
  386. PREFIS = NOMC (MOTS 'FX' 'FY' 'FZ') (MOTS 'SMX' 'SMY' 'SMZ') PRES1 ;
  387.  
  388. SUPTAB = TABL ;
  389. SUPTAB . 'OBJECTIF' = MOT 'DECOUPLAGE' ;
  390. SUPTAB . 'PSI' = PSI1 ;
  391. SUPTAB . 'PHI' = PHI1 ;
  392. SUPTAB . 'FRONT_FISSURE' = FRONT1 ;
  393. SUPTAB . 'MODELE' = MOD1 ;
  394. SUPTAB . 'CARACTERISTIQUES' = MAT1 ;
  395. SUPTAB . 'SOLUTION_RESO' = U1 ;
  396. SUPTAB . 'CHARGEMENTS_MECANIQUES' = FORTOT ;
  397. SUPTAB . 'COUCHE' = 2 ;
  398. SUPTABF = COPI SUPTAB ;
  399. SUPTABF.'MODELE_FISSURE' = MOD_INT ;
  400. SUPTABF.'DEPLACEMENT_FISSURE' = WSAUT ;
  401. SUPTABF.'PRESSION_FISSURE' = PREFIS ;
  402.  
  403. G_THETA SUPTAB ;
  404. G_THETA SUPTABF ;
  405.  
  406. CHPO1 = SUPTAB.'CHPO_RESULTATS' ;
  407. CHPO1F = SUPTABF.'CHPO_RESULTATS' ;
  408.  
  409. REPE IMOD 3 ;
  410.     FIC = CHAI 'K' &IMOD ;
  411.     KREF = EVOL 'BLEU' 'CHPO' CHPO1 FIC FRONT1 ;
  412.     KFROT = EVOL 'VERT' 'CHPO' CHPO1F FIC FRONT1 ;
  413.     ERR1 = INTG (KFROT - KREF) 'ABS' ;
  414.     CRIT1 = (INTG KREF 'ABS') * 1.E-5 ;
  415.     SI BTRAC ;
  416.         DESS (KREF ET KFROT) ;
  417.     FINSI ;
  418.     SI (ERR1 > CRIT1) ;
  419.         ERRE 5 ;
  420.     FINSI ;
  421. FIN IMOD ;
  422.  
  423. FIN ;
  424.  
  425.  
  426.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales