Télécharger Coulomb3D.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : Coulomb3D.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *----------------------------------------------------------------------*
  5. * Ce cas-test permet de tester la gestion du frottement de Coulomb par *
  6. * PASAPAS. *
  7. * Il calcule la mise en contact d'un lopin parallelipedique sur une *
  8. * surface rigide, puis sa mise en glissement partiel dans la dir. Ox. *
  9. * On pilote la face superieure du lopin en deplacements imposes. *
  10. * La convergence en glissement partiel necessite une trentaine *
  11. * d'iterations. *
  12. * On ne verifie que le respect de la condition de contact et de la loi *
  13. * de Coulomb (T <= mu*N). *
  14. * Si IG1 = VRAI, on visualise la solution, notamment les points en *
  15. * glissement et ceux adherents. *
  16. *----------------------------------------------------------------------*
  17. * *
  18. * Si TRACes desires, mettre IG1 a VRAI : *
  19. IG1 = FAUX ;
  20. * *
  21. 'OPTI' 'DIME' 3 'ELEM' CUB8 ;
  22. * *
  23. *----------------------------------------------------------------------*
  24. * MAILLAGE *
  25. *----------------------------------------------------------------------*
  26. * *
  27. * Maillage "Sol" : *
  28. S1 = -10. -5. 0. ;
  29. S2 = +10. -5. 0. ;
  30. NLS1 = 5 ;
  31. LS1 = S1 'DROI' NLS1 S2 ;
  32. SOL1 = LS1 'TRAN' NLS1 (0. 20. 0.) ;
  33. SOL1 = SOL1 'COUL' 'OLIV' ;
  34. * *
  35. * Maillage "Cube" : *
  36. C1 = -5. 0. 0.1 ;
  37. M2 = +5. 0. 0.1 ;
  38. NLC1 = 7 ;
  39. LC1 = C1 'DROI' NLC1 M2 ;
  40. SC1 = LC1 'TRAN' NLC1 (0. 10. 0.) ;
  41. LOP1 = SC1 'VOLU' NLC1 'TRAN' (0. 0. 8.) ;
  42. LOP1 = LOP1 'COUL' 'ORAN' ;
  43. * *
  44. MTOT1 = (SOL1 'ET' LOP1) 'COUL' 'DEFA' ;
  45. * *
  46. * Maillages de contact orientes : *
  47. SOL2 = 'ORIE' ('CHAN' 'TRI3' SOL1) (0. 0. +1.) ;
  48. SCC1 = 'ORIE' ('CHAN' 'TRI3' SC1 ) (0. 0. -1.) ;
  49. MCONT1 = ('IMPO' 'MAIL' SOL2 SCC1) 'COUL' 'ROUG' ;
  50. * *
  51. * Traces : *
  52. 'SI' IG1 ;
  53. 'TITR' 'Maillages Cube / Sol ' ;
  54. 'TRAC' 'FACE' (LOP1 ET SOL1) ;
  55. 'TITR' 'Maillages Cube / Sol & Maillage de contact (rouge) ' ;
  56. 'TRAC' 'FACE' (MTOT1 ET MCONT1) ;
  57. 'FINS' ;
  58. * *
  59. *----------------------------------------------------------------------*
  60. * MODELES / CARACTERISTIQUES *
  61. *----------------------------------------------------------------------*
  62. * *
  63. MOD1 = 'MODE' LOP1 'MECANIQUE' 'ELASTIQUE' ;
  64. MAT1 = 'MATE' MOD1 'YOUN' 1.E1 'NU' 0.3 ;
  65. * *
  66. MU1 = 0.5 ;
  67. MODF1 = 'MODE' MCONT1 'CONTACT' 'FROTTANT' 'COULOMB' ;
  68. MATF1 = 'MATE' MODF1 'MU' MU1 ;
  69. * *
  70. MOD0 = MOD1 'ET' MODF1 ;
  71. MAT0 = MAT1 'ET' MATF1 ;
  72. * *
  73. *----------------------------------------------------------------------*
  74. * C.L. / CHARGEMENT *
  75. *----------------------------------------------------------------------*
  76. * *
  77. * Deplacements imposes : *
  78. CL1 = 'BLOQ' SOL1 'DEPL' ;
  79. * *
  80. SCZ1 = (LOP1 'COOR' 3) 'POIN' 'MAXI' ;
  81. CL2 = 'BLOQ' 'UX' SCZ1 ;
  82. CL3 = 'BLOQ' 'UY' SCZ1 ;
  83. CL4 = 'BLOQ' 'UZ' SCZ1 ;
  84. *
  85. CL0 = CL1 'ET' CL2 'ET' CL3 'ET' CL4 ;
  86. * *
  87. UX0 = +0.600 ;
  88. UZ0 = -0.500 ;
  89. DCL2 = 'DEPI' CL2 UX0 ;
  90. DCL4 = 'DEPI' CL4 UZ0 ;
  91. * *
  92. 'SI' IG1 ;
  93. 'TRAC' ('VECT' ('EXCO' DCL4 'FLX' 'UZ') 'DEPL' 'ROUG') ('ARET' MTOT1)
  94. 'TITR'
  95. 'Deplacement impose a la surface superieure du lopin : mise en contact.'
  96. ;
  97. 'TRAC' ('VECT' ('EXCO' DCL2 'FLX' 'UX') 'DEPL' 'ROUG') ('ARET' MTOT1)
  98. 'TITR'
  99. 'Deplacement impose a la surface superieure du lopin : glissement.' ;
  100. 'FINS' ;
  101. * *
  102. * Chargements : *
  103. LTPS1 = 'PROG' 0. 1. 2. ;
  104. EV1 = 'EVOL' 'MANU' 'TEMPS' LTPS1 ('PROG' 0. 1. 1.) ;
  105. EV2 = 'EVOL' 'MANU' 'TEMPS' LTPS1 ('PROG' 0. 0. 1.) ;
  106. CHARU1 = 'CHAR' 'DIMP' DCL4 EV1 ;
  107. CHARU2 = 'CHAR' 'DIMP' DCL2 EV2 ;
  108. CHAR0 = CHARU1 'ET' CHARU2 ;
  109. * *
  110. *----------------------------------------------------------------------*
  111. * RESOLUTION *
  112. *----------------------------------------------------------------------*
  113. * *
  114. * Construction de la table PASAPAS : *
  115. * *
  116. PREC1 = 2.E-5 ;
  117. TAB1 = 'TABL' ;
  118. TAB1 . 'MODELE' = MOD0 ;
  119. TAB1 . 'CARACTERISTIQUES' = MAT0 ;
  120. TAB1 . 'BLOCAGES_MECANIQUES' = CL0 ;
  121. TAB1 . 'CHARGEMENT' = CHAR0 ;
  122. TAB1 . 'TEMPS_CALCULES' = 'PROG' 0. 1. 2. ;
  123. TAB1 . 'PRECISION' = PREC1 ;
  124. * *
  125. * Resolution : *
  126. * *
  127. TAB2 = PASAPAS TAB1 ;
  128. * *
  129. *----------------------------------------------------------------------*
  130. * DEPOUILLEMENT *
  131. *----------------------------------------------------------------------*
  132. * *
  133. IND1 = ('DIME' TAB2 . 'DEPLACEMENTS') - 1 ;
  134. DEP1 = (TAB2 . 'DEPLACEMENTS' . IND1) 'ENLE' 'LX' ;
  135. REA1 = TAB2 . 'REACTIONS' . IND1 ;
  136. * Reactions sur la surface du lopin en contact : *
  137. MREA1 = 'EXTR' REA1 'MAIL' ;
  138. SCREA1 = SC1 'ELEM' 'APPU' 'STRI' MREA1 ;
  139. REASC1 = 'REDU' (TAB1 . REACTIONS . IND1) SCREA1 ;
  140. * *
  141. *--------------------------- Visualisations ---------------------------*
  142. 'SI' IG1 ;
  143. * *
  144. * Deformee : *
  145. DEFO0 = 'DEFO' (LOP1 'ET' SOL1) DEP1 0. 'VERT' ;
  146. DEFO1 = 'DEFO' (LOP1 'ET' SOL1) DEP1 1. 'ROUG' ;
  147. MOT1 = 'CHAI'
  148. 'Geometrie non deformee (vert) et deformee (rouge)' ;
  149. 'TITR' MOT1 ;
  150. 'TRAC' 'CACH' (DEFO0 'ET' DEFO1) ;
  151. OEIL1 = (0. -1.E5 0.) ;
  152. 'TRAC' 'CACH' (DEFO0 'ET' DEFO1) OEIL1 ;
  153. * *
  154. * Deplacements : *
  155. UXF1 = 'DEFO' (LOP1 'ET' SOL1) DEP1 1. ('EXCO' DEP1 'UX' 'UX') ;
  156. UYF1 = 'DEFO' (LOP1 'ET' SOL1) DEP1 1. ('EXCO' DEP1 'UY' 'UY') ;
  157. UZF1 = 'DEFO' (LOP1 'ET' SOL1) DEP1 1. ('EXCO' DEP1 'UZ' 'UZ') ;
  158. 'TRAC' UXF1 'TITR' 'Deplacements Ux' ;
  159. 'TRAC' UYF1 'TITR' 'Deplacements Uy' ;
  160. 'TRAC' UZF1 'TITR' 'Deplacements Uz' ;
  161. * *
  162. * Contraintes : *
  163. CONF0 = 'FORM' ;
  164. 'FORM' DEP1 ;
  165. SIG1 = TAB1 . 'CONTRAINTES' . IND1 ;
  166. 'TITR' ' Contraintes dans la CONFiguration deformee ' ;
  167. 'TRAC' SIG1 MOD1 (LOP1 ET SOL1) ;
  168. 'FORM' CONF0 ;
  169. * *
  170. * Reactions : *
  171. VR1 = 'VECT' REA1 'FORC' 'ROUG' ;
  172. OEIL1 = (1.E5 -1.E5 1.E5) ;
  173. 'TRAC' OEIL1 VR1 ('ARET' MTOT1) 'TITR' 'Forces de reaction.' ;
  174. 'FINS' ;
  175. * *
  176. * Critere de glissement (T = mu*N) : *
  177. RN1 = 'EXCO' REASC1 'FZ' ;
  178. RX1 = 'EXCO' REASC1 'FX' ;
  179. RY1 = 'EXCO' REASC1 'FY' ;
  180. RT1 = ((RX1 * RX1) + (RY1 * RY1)) ** 0.5 ;
  181. * La partie en glissement verifie mu*N-T=0 a la precision pres : *
  182. CGLIS1 = (MU1 * RN1 - RT1) / ('MAXI' 'ABS' RN1) ;
  183. GLISS1 = ('ABS' CGLIS1) 'MASQ' 'INFE' PREC1 ;
  184. * *
  185. 'SI' IG1 ;
  186. 'TITR' ' Parties adherentes (Bleu) / en glissement (rouge) ' ;
  187. 'TRAC' GLISS1 SCREA1 ;
  188. 'FINS' ;
  189. * *
  190. *-------------------- Verifications de la solution --------------------*
  191. * *
  192. * On verifie qu'on ne tranverse pas la surface : *
  193. ERR1 = ('MAXI' (SOL1 'COOR' 3))
  194. - ('MINI' ((LOP1 'COOR' 3) + ('EXCO' 'UZ' DEP1))) ;
  195. 'MESS' ' ****** ECART RELATIF POSITION DE CONTACT : ' ERR1 ;
  196. * *
  197. * On verifie la loi de Coulomb au critere pres : *
  198. ERR2 = 'ABS' ('MINI' CGLIS1) ;
  199. ERR0 = 'MAXI' ('PROG' ERR1 ERR2) ;
  200. * *
  201. 'OPTI' 'ECHO' 0 ;
  202. 'SAUT' 1 'LIGN' ;
  203. '---------------------- RESULTAT CAS-TEST ------------------------' ;
  204. 'MESS' ' ' ;
  205. 'Ecart relatif a la solution calculee sur les deplacements' ;
  206. 'et les contraintes :' ;
  207. 'MESS' ;
  208. 'SI' (ERR0 '&lt;EG' PREC1) ;
  209. 'MESS' ('CHAI' ' ==> MAXI ERREUR =' ERR0 ' < ' PREC1 ) ;
  210. 'MESS' ' ' ;
  211. 'MESS' ' __________________' ;
  212. 'MESS' ' | |' ;
  213. 'MESS' ' | TEST REUSSI ! |' ;
  214. 'MESS' ' |________________|' ;
  215. 'SAUT' 1 'LIGN' ;
  216. 'SINO' ;
  217. 'MESS' ('CHAI' ' ==> MAXI ERREUR =' ERR0 ' > ' PREC1 ) ;
  218. 'MESS' ' ' ;
  219. 'MESS' ' __________________' ;
  220. 'MESS' ' | |' ;
  221. 'MESS' ' | ERREUR ! |' ;
  222. 'MESS' ' |________________|' ;
  223. 'SAUT' 1 'LIGN' ;
  224. 'ERRE' 5 ;
  225. 'FINS' ;
  226. '------------------------ FIN CAS-TEST ---------------------------' ;
  227. * *
  228. 'FIN' ;
  229. 'OPTI' 'ECHO' 1 ;
  230.  
  231.  
  232.  
  233.  
  234.  
  235.  
  236.  
  237.  
  238.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales