Télécharger psury.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : psury.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *****************************************************
  5. * *
  6. * TEST DE VALIDATION DE LA LOI *
  7. * D'ENDOMMAGEMENT TRIAXIAL P/Y *
  8. * *
  9. * TEST: *
  10. * UN BARREAU EST CHARGE EN TRACTION *
  11. * LE CHARGEMENT EST DES DEPLACEMENTS IMPOSES *
  12. * CALCUL EN MASSIF 3D *
  13. * *
  14. * MAILLAGE: *
  15. * UN BARREAU DE SECTION CARREE DE .5 M SUR .01 M *
  16. * 50 ELEMENTS *
  17. * *
  18. *****************************************************
  19. opti echo 0 dime 3 elem cub8 ;
  20. * ajout de option epsilon lineaire pour la precision des test!
  21. OPTION epsilon lineaire;
  22. *
  23. *
  24. * Maillage
  25. *
  26. l1 = .5 ;
  27. l2 = .01 ;
  28. l3 = .01 ;
  29. n1 = 50 ;
  30. n2 = 1 ;
  31. n3 = 1 ;
  32. p1 = 0. 0. 0. ;
  33. p2 = l1 0. 0. ;
  34. p3 = l1 l2 0. ;
  35. p4 = 0. l2 0. ;
  36. p5 = 0. 0. l3 ;
  37. p6 = l1 0. l3 ;
  38. p7 = l1 l2 l3 ;
  39. p8 = 0. l2 l3 ;
  40. d1 = d p1 n3 p5 ;
  41. d2 = d p5 n2 p8 ;
  42. d3 = d p8 n3 p4 ;
  43. d4 = d p4 n2 p1 ;
  44. sur1 = 'DALL' d1 d2 d3 d4 ;
  45. d5 = d p2 n3 p6 ;
  46. d6 = d p6 n2 p7 ;
  47. d7 = d p7 n3 p3 ;
  48. d8 = d p3 n2 p2 ;
  49. sur2 = 'DALL' d5 d6 d7 d8 ;
  50. vol1 = sur1 'VOLU' n1 sur2 ;
  51. *
  52. * Deplacement maximal
  53. *
  54. depmax = .1 ;
  55. *
  56. * Courbe d'ecrouissage
  57. *
  58. beta0 = 125. ;
  59. sig0 = 410.E6 ;
  60. xm = .1 ;
  61. youn0 = 2.1E11 ;
  62. epsp0 = 'PROG' 0. ;
  63. deb0 = 'PROG' 0. ;
  64. epsmax0 = depmax / l1 ;
  65. pas0 = epsmax0 / 50 ;
  66. epsp1 = 'PROG' 0. 'PAS' pas0 epsmax0 ;
  67. dim00 = 'DIME' epsp1 ;
  68. un = 'PROG' dim00 '*' 1. ;
  69. Y0 = sig0 ;
  70. epsp2 = beta0 * epsp1 ;
  71. epsp3 = epsp2 + un ;
  72. epsp31 = log epsp3 ;
  73. epsp32 = epsp31 * xm ;
  74. epsp4 = exp epsp32 ;
  75. Y1 = Y0 * epsp4 ;
  76. *
  77. epsp1 = epsp0 'ET' epsp1 ;
  78. Y1 = deb0 'ET' Y1 ;
  79. epsp2 = epsp1 + ( Y1 / youn0 ) ;
  80. *
  81. * Courbe d'evolution de l'endommagement
  82. *
  83. n10 = 5. ;
  84. alp0 = 'PROG' 0. 'PAS' .01 1. ;
  85. *dd10 = 'SIN' ( 90. * alp0 ) ;
  86. dd10 = ( alp0 ) ** ( 1. / n10 ) ;
  87. evol0 = 'EVOL' 'MANU' 'defo' alp0 'sigm' dd10 ;
  88. *
  89. * Modele de calcul
  90. *
  91. trac0 = 'EVOL' 'MANU' 'defo' epsp2 'sigm' Y1 ;
  92. endo0 = 'EVOL' 'MANU' 'defo' ( 'PROG' .05 .1 .25 .5 )
  93. 'sigm' ( 'PROG' .6 .3 .15 .1 ) ;
  94. mod0 = 'MODE' vol1 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'
  95. 'PLASTIQUE_ENDOM' 'PSURY' ;
  96. mat0 = 'MATE' mod0 'YOUN' youn0 'NU' 0.3 'RHO' 7800.
  97. 'TRAC' trac0 'EVOL' endo0 'COMP' evol0 ;
  98. *
  99. * Conditions aux limites
  100. *
  101. cl1 = 'BLOQ' sur1 'UX' ;
  102. cl2 = 'BLOQ' sur2 'UX' ;
  103. cl3 = 'BLOQ' p1 'UX' 'UY' 'UZ' ;
  104. cl4 = 'BLOQ' p5 'UX' 'UY' ;
  105. cl5 = 'BLOQ' p4 'UX' 'UZ' ;
  106. cl0 = cl1 'ET' cl2 'ET' cl3 'ET' cl4 'ET' cl5 ;
  107. *
  108. * Chargement
  109. *
  110. dep1 = 'DEPI' cl2 depmax ;
  111. ev0 = 'EVOL' 'MANU' temps ( 'PROG' 0. 10. ) y ( 'PROG' 0. 1. ) ;
  112. cha0 = 'CHAR' 'DIMP' dep1 ev0 ;
  113. *
  114. * Temps du calcul
  115. *
  116. dt0 = 1. ;
  117. tfin0 = 10. ;
  118. *
  119. *
  120. * Resolution par PASAPAS
  121. *---------------------------------------
  122. *
  123. ta1 = 'TABLE' ;
  124. ta1 .'MODELE' = mod0 ;
  125. ta1 .'CARACTERISTIQUES' = mat0 ;
  126. ta1 .'BLOCAGES_MECANIQUES' = cl0 ;
  127. ta1 .'CHARGEMENT' = cha0 ;
  128. ta1 .'TEMPS_CALCULES' = 'PROG' 0. 'PAS' dt0 tfin0 ;
  129. *
  130. TMASAU=table;
  131. ta1 . 'MES_SAUVEGARDES'=TMASAU;
  132. TMASAU .'DEFTO'=VRAI;
  133. TMASAU .'DEFIN'=VRAI;
  134. PASAPAS ta1 ;
  135. *
  136. *
  137. * Post-traitement
  138. *-----------------------------------------
  139. *
  140. err = faux ;
  141. coeff = 1. ;
  142. rho_thf = 0. ;
  143. epsp1 = 'PROG' 0. ;
  144. epst_x1 = 'PROG' 0. ;
  145. def_1 = 'PROG' 0. ;
  146. sig1 = 'PROG' 0. ;
  147. sig_x1 = 'PROG' 0. ;
  148. eps_th1 = 'PROG' 0. ;
  149. con_th1 = 'PROG' 0. ;
  150. err_e1 = 'PROG' 0. ;
  151. err_s1 = 'PROG' 0. ;
  152. err_g1 = 'PROG' 0. ;
  153. g1 = 'PROG' 1. ;
  154. g_th1 = 'PROG' 1. ;
  155. eps_th0 = 0. ;
  156. dim0 = 'DIME' ta1 .'TEMPS' - 1 ;
  157. mod0 = ta1 .'MODELE' ;
  158. 'REPETER' bloc1 dim0 ;
  159. i1 = &bloc1 ;
  160. *
  161. mat0 = ta1 .'CARACTERISTIQUES' ;
  162. youn0 = 'MAXI' ( 'EXCO' mat0 'YOUN' ) ;
  163. rho0 = 'MAXI' ( 'EXCO' mat0 'RHO' ) ;
  164. depl0 = ta1 .'DEPLACEMENTS'.i1 ;
  165. sigm0 = ta1 .'CONTRAINTES'.i1 ;
  166. depeq0 = ta1 .'VARIABLES_INTERNES'.i1 ;
  167. def0 = ta1 .'DEFORMATIONS_INELASTIQUES'.i1 ;
  168. eps0 = 'EPSI' mod0 depl0 ;
  169. *
  170. def_0 = 'MAXI' ( 'EXCO' def0 'EIXX' 'SCAL' ) ;
  171. g0 = 'MAXI' ( 'EXCO' depeq0 'VHWG' 'SCAL' ) ;
  172. epsp0 = 'MAXI' ( 'EXCO' depeq0 'EPSE' 'SCAL' ) ;
  173. rho1 = 'MAXI' ( 'EXCO' depeq0 'VHHO' 'SCAL' ) ;
  174. rho_f = 'MAXI' ( 'EXCO' depeq0 'VHOF' 'SCAL' ) ;
  175. sig_0 = 'MAXI' ( 'VMIS' mod0 sigm0 ) ;
  176. sig_x0 = 'MAXI' ( 'EXCO' sigm0 'SMXX' 'SCAL' ) ;
  177. epst_x0 = 'MAXI' ( 'EXCO' eps0 'EPXX' 'SCAL' ) ;
  178. epst_y0 = 'MAXI' ( 'EXCO' eps0 'EPYY' 'SCAL' ) ;
  179. epst_z0 = 'MAXI' ( 'EXCO' eps0 'EPZZ' 'SCAL' ) ;
  180. tr_eps0 = epst_x0 + epst_y0 + epst_z0 ;
  181. *
  182. *
  183. * Endommagement theorique
  184. *--------------------------------------
  185. *
  186. * Calcul de la densite rho
  187. *
  188. rho = rho0 / ( 1. + tr_eps0 ) ;
  189. *
  190. * deformation plastique de debut d'endommagement
  191. *
  192. absc0 = 'EXTR' endo0 'ABSC' ;
  193. ordo0 = 'EXTR' endo0 'ORDO' ;
  194. 'REPETER' bloc00 ( 'DIME' absc0 ) ;
  195. i00 = &bloc00 ;
  196. ab1 = 'EXTR' absc0 i00 ;
  197. or1 = 'EXTR' ordo0 i00 ;
  198. 'SI' ( i00 'EGA' ( 'DIME' absc0 ) ) ;
  199. eps1 = ab1 ;
  200. 'SINON' ;
  201. ab2 = 'EXTR' absc0 ( i00 + 1 ) ;
  202. or2 = 'EXTR' ordo0 ( i00 + 1 ) ;
  203. 'SI' ( ( or1 '>EG' ( 1. / 3. ) ) 'ET'
  204. ( or2 '<' ( 1. / 3. ) ) ) ;
  205. eps1 = ( ab2 - ab1 ) / ( or2 - or1 ) ;
  206. eps1 = eps1 * ( ( 1. / 3. ) - or1 ) ;
  207. eps1 = eps1 + ab1 ;
  208. 'QUITTER' bloc00 ;
  209. 'FINSI' ;
  210. 'FINSI' ;
  211. 'FIN' bloc00 ;
  212. *
  213. *
  214. * Courbe theorique
  215. *--------------------------------------
  216. *
  217. m0 = xm ;
  218. 'SI' ( ( youn0 * epst_x0 ) '>EG' sig0 ) ;
  219. x0 = 0. ;
  220. x2 = x0 ;
  221. y2 = ( sig0 * ( ( 1 + ( beta0 * x2 ) ) ** m0 ) ) ;
  222. y2 = y2 + ( youn0 * x2 ) ;
  223. y2 = y2 - ( youn0 * epst_x0 ) ;
  224. *
  225. x1 = epst_x0 ;
  226. x2 = x1 ;
  227. y2 = ( sig0 * ( ( 1 + ( beta0 * x2 ) ) ** m0 ) ) ;
  228. y2 = y2 + ( youn0 * x2 ) ;
  229. y2 = y2 - ( youn0 * epst_x0 ) ;
  230. *
  231. 'REPETER' bloc2 ;
  232. *
  233. x2 = ( x0 + x1 ) / 2. ;
  234. y2 = ( sig0 * ( ( 1 + ( beta0 * x2 ) ) ** m0 ) ) ;
  235. y2 = y2 + ( youn0 * x2 ) ;
  236. y2 = y2 - ( youn0 * epst_x0 ) ;
  237. *
  238. 'SI' ( y2 > 1.E-4 ) ;
  239. x1 = x2 ;
  240. 'SINON' ;
  241. 'SI' ( y2 < -1.E-4 ) ;
  242. x0 = x2 ;
  243. 'SINON' ;
  244. eps_th0 = x2 ;
  245. con_th0 = youn0 * ( epst_x0 - x2 ) ;
  246. 'QUITTER' bloc2 ;
  247. 'FINSI' ;
  248. 'FINSI' ;
  249. *
  250. 'FIN' bloc2 ;
  251. *
  252. 'SINON' ;
  253. eps_th0 = 0. ;
  254. con_th0 = youn0 * epst_x0 ;
  255. 'FINSI' ;
  256. *
  257. 'SI' ( eps_th0 '>EG' eps1 ) ;
  258. *
  259. * Calcul de rho_thf ( debut d'endommagement)
  260. *
  261. 'SI' ( rho_thf '&lt;EG' 0. ) ;
  262. tr_f = tr_eps0 ;
  263. sig_f = ( 1. + ( beta0 * eps1 ) ) ** ( m0 ) ;
  264. sig_f = sig0 * sig_f ;
  265. tr_f = sig_f / ( 3. * 1.75E11 ) ;
  266. rho_thf = rho0 / ( 1. + tr_f ) ;
  267. err_rho = ( 'ABS' ( rho_f - rho_thf ) ) / rho_thf ;
  268. err_rho = err_rho * 100. ;
  269. 'SI' ( err_rho '>' 1.E-3 ) ;
  270. err = vrai ;
  271. 'FINSI' ;
  272. 'FINSI' ;
  273. *
  274. alpha = 1. - ( rho / rho_f ) ;
  275. absc0 = 'EXTR' evol0 'ABSC' ;
  276. ordo0 = 'EXTR' evol0 'ORDO' ;
  277. 'REPETER' bloc01 ( 'DIME' absc0 ) ;
  278. i01 = &bloc01 ;
  279. ab1 = 'EXTR' absc0 i01 ;
  280. or1 = 'EXTR' ordo0 i01 ;
  281. 'SI' ( i01 'EGA' ( 'DIME' absc0 ) ) ;
  282. eps1 = ab1 ;
  283. 'SINON' ;
  284. ab2 = 'EXTR' absc0 ( i01 + 1 ) ;
  285. or2 = 'EXTR' ordo0 ( i01 + 1 ) ;
  286. 'SI' ( ( alpha '>EG' or1 ) 'ET'
  287. ( alpha '<' or2 ) ) ;
  288. D_end0 = ( or2 - or1 ) / ( ab2 - ab1 ) ;
  289. D_end0 = D_end0 * ( alpha - ab1 ) ;
  290. D_end0 = D_end0 + or1 ;
  291. 'QUITTER' bloc01 ;
  292. 'FINSI' ;
  293. 'FINSI' ;
  294. 'FIN' bloc01 ;
  295. *
  296. g_th0 = 1. - D_end0 ;
  297. 'SINON' ;
  298. g_th0 = 1. ;
  299. 'FINSI' ;
  300. *
  301. * Calcul des contraintes endommagées
  302. *
  303. con_th0 = con_th0 * g_th0 ;
  304. *
  305. * 'MESS' ' Fin du calcul de restitution pour le pas' ta1 .'TEMPS'.i1 ;
  306. max0 = ( 'ABS' ( con_th0 - sig_x0 ) + con_th0 + sig_x0 ) ;
  307. max0 = 0.5 * max0 ;
  308. max1 = ( 'ABS' ( eps_th0 - def_0 ) + eps_th0 + def_0 ) ;
  309. max1 = 0.5 * max1 ;
  310. max2 = ( 'ABS' ( g_th0 - g0 ) + g_th0 + g0 ) ;
  311. max2 = 0.5 * max2 ;
  312. 'SI' ( ( 'ABS' max0 ) > 0. ) ;
  313. err_s0 = ( 'ABS' ( con_th0 - sig_x0 ) ) / max0 ;
  314. err_s0 = err_s0 * 100. ;
  315. 'SINON' ;
  316. err_s0 = 0. ;
  317. 'FINSI' ;
  318. 'SI' ( ( 'ABS' max1 ) > 0. ) ;
  319. err_e0 = ( 'ABS' ( eps_th0 - def_0 ) ) / max1 ;
  320. err_e0 = err_e0 * 100. ;
  321. 'SINON' ;
  322. err_e0 = 0. ;
  323. 'FINSI' ;
  324. 'SI' ( ( 'ABS' max2 ) > 0. ) ;
  325. err_g0 = ( 'ABS' ( g_th0 - g0 ) ) / max2 ;
  326. err_g0 = err_g0 * 100. ;
  327. 'SINON' ;
  328. err_g0 = 0. ;
  329. 'FINSI' ;
  330. 'SI' ( ( err_s0 '>' .5 ) 'OU' ( err_e0 '>' .5 ) 'OU'
  331. ( err_g0 '>' 1.E-2 ) ) ;
  332. err = vrai ;
  333. 'FINSI' ;
  334. *
  335. *
  336. 'FIN' bloc1 ;
  337. *
  338. 'SI' ( err ) ;
  339. 'ERRE' 5 ;
  340. 'SINON' ;
  341. 'ERRE' 0 ;
  342. 'FINSI' ;
  343. *
  344. *
  345. 'FIN' ;
  346.  
  347.  
  348.  
  349.  
  350.  
  351.  
  352.  
  353.  
  354.  
  355.  
  356.  
  357.  
  358.  
  359.  
  360.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales