Télécharger plas14.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : plas14.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Test Plas14.dgibi: Jeux de données *
  5. * --------------------------------- *
  6. * *
  7. graph='N';
  8. saut page;
  9. opti echo 1;
  10. *------------------------------------------------------
  11. *
  12. * EXEMPLE OF A CONCRETE SQUARE SECTION WITH 4 STEEL
  13. * 20mm BARS
  14. * CONCRETE DIMENSIONS: (0.25*0.25)m2 - ALL SECTION
  15. * (0.20*0.20)m2 - CORE SECTION
  16. * TRANSVERSAL REINFORCEMENT: 10mm Bars / 7.0cm
  17. * NOVEMBER 1993
  18. *
  19. *------------------------------------------------------
  20. * Quadrangular Elements
  21. *------------------------------------------
  22. * opti dime 2 elem qua4 echo 1 ;
  23. opti dime 2 echo 1 ;
  24. *------------------------------------------
  25. * Triangular Elements
  26. *------------------------------------------
  27. * opti dime 2 elem tri3;
  28. *------------------------------------------
  29. * DEFINITION OF THE STEEL GEOMETRY
  30. *------------------------------------------
  31. secste = 3.14159*((10.e-3)**2);
  32. *
  33. cars1 = ( 8.50e-2 8.50e-2);
  34. cars2 = ( 8.50e-2 -8.50e-2);
  35. cars3 = (-8.50e-2 -8.50e-2);
  36. cars4 = (-8.50e-2 8.50e-2);
  37. *
  38. meshf = cars1 et cars2 et cars3 et cars4;
  39. meshf = coul meshf bleu;
  40. *------------------------------------------------------
  41. * Quadrangular Elements
  42. *------------------------------------------
  43. opti dime 2 elem qua4 echo 1 ;
  44. *------------------------------------------
  45. * DEFINITION OF THE CONCRETE GEOMETRY
  46. *------------------------------------------
  47. * - UNCONFINED
  48. *------------------------------------------
  49. * verd - vertical number of divisions
  50. * hord - horizontal number of divisions
  51. *------------------------------------------
  52. verd = 4;
  53. hord = 4;
  54. *
  55. divu = 1;
  56. *------------------------------------------
  57. pc1 = -12.5d-2 12.5d-2;
  58. pc2 = -12.5d-2 10.0d-2;
  59. pc3 = 2.5d-2 0.0d-2;
  60. carc1 = pc1 d (divu) pc2 tran (divu) pc3;
  61. *
  62. carc2 = carc1 plus ( 22.5d-2 0.0);
  63. carc3 = carc2 plus ( 0.0 -22.5d-2);
  64. carc4 = carc3 plus (-22.5d-2 0.0);
  65. *
  66. pc4 = -10.0d-2 12.5d-2;
  67. pc5 = -10.0d-2 10.0d-2;
  68. pc6 = 20.0d-2 0.0d-2;
  69. carc5 = pc4 d (divu) pc5 tran (verd) pc6;
  70. *
  71. carc6 = carc5 plus ( 0.0 -22.5d-2);
  72. *
  73. pc7 = -12.5d-2 10.0d-2;
  74. pc8 = -10.0d-2 10.0d-2;
  75. pc9 = 0.0d-2 -20.0d-2;
  76. carc7 = pc7 d (divu) pc8 tran (hord) pc9;
  77. *
  78. carc8 = carc7 plus ( 22.5d-2 0.0);
  79. *
  80. meshu = carc1 et carc2 et carc3 et carc4 et
  81. carc5 et carc6 et carc7 et carc8;
  82. meshu = coul meshu jaune;
  83. *opti donn 5;
  84. *------------------------------------------
  85. * - CONFINED
  86. *------------------------------------------
  87. pc10 = -10.0d-2 10.0d-2;
  88. pc11 = 10.0d-2 10.0d-2;
  89. pc12 = 0.0d-2 -20.0d-2;
  90. meshc = pc10 d (verd) pc11 tran (hord) pc12;
  91. meshc = coul meshc rouge;
  92. *
  93. elim (meshf et meshu et meshc) 0.001;
  94. *
  95. titre
  96. 'Section:blue=steel,yellow=unconfined concrete
  97. ,red=confined concrete';
  98. *
  99. si (ega graph 'Y');
  100. trac (meshf et meshu et meshc);
  101. finsi;
  102. *
  103. opti dime 3 elem seg2;
  104. *
  105. pp0 = 0.0 .0 .0;
  106. pp1 = 1.0 .0 .0;
  107. *
  108. llb = pp0 d 1 pp1;
  109. *
  110. elim (llb et pp0 et pp1) 0.001;
  111. *------------------------------------------
  112. * CARACTERIZATION OF THE STEEL AND CONCRETE MODELS
  113. *------------------------------------------
  114. *------------------------------------------
  115. * Quadrangular Elements
  116. *------------------------------------------
  117. modf = MODE meshf mecanique elastique PLASTIQUE
  118. ACIER_UNI pojs;
  119. modbs = MODE meshf mecanique elastique PLASTIQUE
  120. ACIER_ANCRAGE pojs;
  121. modu = MODE meshu mecanique elastique PLASTIQUE
  122. BETON_UNI quas;
  123. modc = MODE meshc mecanique elastique PLASTIQUE
  124. BETON_UNI quas;
  125. modlab = MODE (meshc et meshu) mecanique elastique PLASTIQUE
  126. UNILATERAL quas;
  127. modshea = MODE (meshc et meshu) mecanique elastique
  128. plastique cisail_nl quas;
  129. modshea2 = MODE (meshc et meshu) mecanique elastique
  130. plastique cisail_nl quas;
  131. *------------------------------------------
  132. * Triangular Elements
  133. *------------------------------------------
  134. * modf = MODE meshf mecanique elastique fibre_nl
  135. * ferraille tris;
  136. * modu = MODE meshu mecanique elastique fibre_nl
  137. * beton tris;
  138. * modc = MODE meshc mecanique elastique fibre_nl
  139. * beton tris;
  140. *------------------------------------------
  141. * Steel
  142. *------------------------------------------
  143. matf = MATE modf 'YOUN' 2.03e5 'NU' 0.30
  144. 'STSY' 440.0 'EPSU' .090 'STSU' 760.0 'EPSH' 0.030
  145. 'FALD' 4.375 'A6FA' 620.0 'CFAC' 0.5 'AFAC' 0.008
  146. 'ROFA' 20.0 'BFAC' 0.010 'A1FA' 18.5 'A2FA' 0.15
  147. 'RHO ' 7.8D-3 ;
  148. carf = 'CARA' modf 'ALPY' 1. 'ALPZ' 2. 'SECT' secste;
  149. *------------------------------------------
  150. * Bond slip for lap splices
  151. *------------------------------------------
  152. G12 = 0.1*(30000./(2.*(1+0.25)*0.05));
  153. xs1t = 0.0006;
  154. xs2t = 0.0020;
  155. xs3t = 0.0060;
  156. xt1t = 5.;
  157. xt3t = 0.15*xt1t;
  158. xalfa = 0.4;
  159. *
  160. mess G12;
  161. mess (xt1t/xs1t);
  162. *
  163. matbs = MATE modbs 'YOUN' 2.03e5 'NU' 0.30
  164. 'STSY' 440.0 'EPSU' .090 'STSU' 760.0 'EPSH' 0.030
  165. 'FALD' 4.375 'A6FA' 620.0 'CFAC' 0.5 'AFAC' 0.008
  166. 'ROFA' 20.0 'BFAC' 0.010 'A1FA' 18.5 'A2FA' 0.15
  167. 'RHO ' 7.8D-3 'G12 ' G12 'S1T' xs1t 'S2T' xs2t
  168. 'S3T' xs3t 'T1T' xt1t 'T3T' xt3t 'ALFA' xalfa
  169. 'SECB' (pi*((0.020/2.)**2)) 'LANC' (10.*0.020)
  170. 'SECT' secste;
  171. carbs = 'CARA' modbs 'ALPY' 0. 'ALPZ' 0.;
  172.  
  173. *------------------------------------------
  174. * Unconfined concrete
  175. *------------------------------------------
  176. matu = MATE modu 'YOUN' 0.30e5 'NU' .20
  177. 'STFC' 30.0 'EZER' .002 'STFT' 3.0
  178. 'ALF1' .22687 'OME1' .32912 'ZETA' 100.0 'ST85' .0
  179. 'TRAF' 3.0 'FACL' 1. 'FAMX' 10. 'STPT' .0 'FAM1' 1.
  180. 'FAM2' 10. 'RHO ' 2.3D-3;
  181. caru = 'CARA' modu 'ALPY' .66 'ALPZ' .00;
  182. *------------------------------------------
  183. * Confined concrete
  184. *------------------------------------------
  185. * Initial concrete Young modulus =
  186. * 2 * STIFC / ( BETA * EZERO )
  187. *------------------------------------------
  188. matc = MATE modc 'YOUN' 0.2254e5 'NU' .25 'STFC' 30.0
  189. 'EZER' .002 'STFT' 3.0 'ALF1' .22687 'OME1' .32912
  190. 'ZETA' 0.0 'ST85' 6.0 'TRAF' 3.0
  191. 'FACL' 1. 'FAMX' 10. 'STPT' .0 'FAM1' 1. 'FAM2' 10.
  192. 'RHO ' 2.3D-3;
  193. carc = 'CARA' modc 'ALPY' .66 'ALPZ' .00;
  194. *
  195. * Laborderie
  196. *
  197. matlab = MATE modlab 'YOUN' 0.297E+5 'NU' .20 'YS1 ' 2.5E-4
  198. 'YS2 ' 1.5E-3 'A1 ' 5000. 'A2 ' 10.
  199. 'B1 ' 1.5 'B2 ' 1.5 'BET1' 1.0
  200. 'BET2' -40. 'SIGF' 3.5 'RHO ' 7.8D-3;
  201. carlab = 'CARA' modlab 'ALPY' .66 'ALPZ' .00;
  202. *----------------------------------------------
  203. * Linear shear behaviour
  204. *-----------------------------------------------
  205. EbetJoi = 22540.;
  206. xnub = 0.25;
  207. *
  208. tultshea = (0.9*500.*pi*((10./2000.)**2))/(0.20*0.07);
  209. *
  210. GY = EbetJoi/(2.*(1.+XNUB));
  211. *
  212. UXX1=PROG 0. (0.98*tultshea/GY) (tultshea/GY) (2.*(tultshea/GY))
  213. (10.*(tultshea/GY)) ;
  214. SHEAR1=PROG 0. (0.99*tultshea) tultshea tultshea tultshea;
  215. *
  216. EP = (extr SHEAR1 2)/(extr UXX1 2);
  217. *
  218. DMAXP = 1. - ((extr SHEAR1 3)/(EP*(extr UXX1 3)));
  219. DMAXN = DMAXP;
  220. DELAP = (extr UXX1 2);
  221. DELAN = DELAP;
  222. E2F = (1.-DMAXP)*EP;
  223. XNU = 0.;
  224. *
  225. XMONOP = PROG;
  226. XMONON = PROG;
  227. YMONOP = PROG;
  228. YMONON = PROG;
  229. *
  230. *
  231. J0 = 2;
  232. REPETER LAB2 ((DIME SHEAR1) - 2);
  233. J0 = J0 + 1;
  234. YY = (EXTR SHEAR1 J0);
  235. XX = ((EXTR UXX1 J0) - ((extr SHEAR1 J0)/E2F));
  236. XMONOP = INSE XMONOP (J0 - 2) (MAXI (PROG XX 0.));
  237. YMONOP = INSE YMONOP (J0 - 2) YY;
  238. FIN LAB2;
  239. *
  240. XMONON = (XMONOP);
  241. YMONON = (YMONOP);
  242. *
  243. monop = evol manu XMONOP YMONOP;
  244. monon = evol manu XMONON YMONON;
  245. *
  246. matshea = mate modshea 'YOUN' ebetjoi 'NU ' XNUB
  247. 'DELP' delap 'DMAP' dmaxp
  248. 'DELN' delan 'DMAN' dmaxn
  249. 'BETA' 0.2 'ALFA' 0. 'TETA' 1.
  250. 'MONP' monop 'MONN' monon
  251. 'RHO ' 0. 'ALPY' 0. 'ALPZ' 1.;
  252. *
  253. modq = modf et modu et modc et modshea;
  254. macq = matf et matu et matc et carf et caru et carc et matshea;
  255. *
  256. modq2 = modbs et modu et modc et modshea;
  257. macq2 = matbs et matu et matc et carbs
  258. et caru et carc et matshea;
  259. modq3 = modf et modlab et modshea;
  260. macq3 = matf et matlab et carf et carlab et matshea;
  261. *
  262. *
  263. *------------------------------------------
  264. * USE OF "MOMCUR" PROCEDURE FOR THE ANALYSIS OF THE
  265. * PLASTIC BEHAVIOUR SECCION
  266. *------------------------------------------
  267. * CARACTERIZATION OF THE ACTION
  268. * (CURVATURES ALONG OY AXIS AND CONSTANT AXIAL FORCE)
  269. *------------------------------------------
  270. eppl = 440.0/2.03e5;
  271. *
  272. cy = prog 0 pas .0005 .005 pas .005 .138;
  273. *
  274. ncur = dime cy;
  275. cz = prog ncur * .00;
  276. fa = (prog ncur * -.25);
  277. *------------------------------------------
  278. * RESOLUTION
  279. *------------------------------------------
  280. my mz ea moc1 = mocu cy cz fa modq macq (1.d-6*eppl) verif;
  281. *opti donn 5;
  282. si (ega graph 'Y');
  283. nste = dime (moc1 . contraintes);
  284. repete bouc nste;
  285. toto = redu (modc et modu) (moc1 . contraintes . (&bouc - 1));
  286. titre 'pas' &bouc '---' 'SMXX' '---' 'deformation normale ='
  287. (moc1 . deformations .(&bouc - 1));
  288. trac (exco toto SMXX) (modc et modu) (matc et matu)
  289. (meshu et meshc) ;
  290. toto = redu (modc et modu) (moc1 . variables_internes . (&bouc - 1));
  291. titre 'pas' &bouc 'EPSO';
  292. trac (exco toto EPSO) (modc et modu) (matc et matu)
  293. (meshu et meshc) ;
  294.  
  295. fin bouc;
  296. finsi;
  297. my2 mz2 ea2 moc2 = mocu cy cz fa modq2 macq2 (1.d-6*eppl) verif;
  298. si (ega graph 'Y');
  299. nste = dime (moc2 . contraintes);
  300. repete bouc nste;
  301. toto = redu (modc et modu) (moc2 . contraintes . (&bouc - 1));
  302. titre 'pas' &bouc 'SMXX';
  303. trac (exco toto SMXX) (modc et modu) (matc et matu)
  304. (meshu et meshc) ;
  305. fin bouc;
  306. finsi;
  307. my3 mz3 ea3 = mocu cy cz fa modq3 macq3 (1.d-6*eppl);
  308.  
  309. *------------------------------------------
  310. * OUTPUT DIAGRAMS
  311. *------------------------------------------
  312. c1= evol rouge manu 'Curvature' cy 'Moment' (my*1.d3);
  313. c2= evol vert manu 'Curvature' cy 'Moment' (my2*1.d3);
  314. c3= evol bleu manu 'Curvature' cy 'Moment' (my3*1.d3);
  315. *------------------------------------------
  316. * TRILINEAR CURVE FOR A TAKEDA MODEL
  317. * FOR THE SAME SECTION
  318. *------------------------------------------
  319. *abstak=prog 0. 2.03791E-03 1.85207E-02 1.38834E-01;
  320. abstak=prog 0. 2.03791E-03 1.85207E-02 1.38E-01;
  321. *ordtak=prog 0. 2.05353E+01 7.10923E+01 7.06633E+01;
  322. ordtak=prog 0. 21.133 71.1 72.817;
  323. albnl=evol vert manu 'Curvature' abstak 'Moment' ordtak;
  324. *------------------------------------------
  325. * PLOT
  326. *------------------------------------------
  327. si (ega graph 'Y');
  328. tt = table;
  329. tt.1 = 'MARQ CARR';
  330. tt.2 = '';
  331. *
  332. titre 'courbe mocu (blanc: beton uni et bleu: unilateral)
  333. , takeda (vert) et avec lap splices (rouge)';
  334. dess (albnl et c1 et c2 et c3) tt;
  335. *
  336. finsi;
  337. *------------------------------------------
  338. * ERREUR
  339. *------------------------------------------
  340. ordtak=ipol cy abstak ordtak;
  341. errlis=ordtak - (my*1.d3);
  342. errea=((ltl errlis errlis)**0.5) / (dime ordtak);
  343. denom=((ltl ordtak ordtak)**0.5) / (dime ordtak);
  344. errel=errea/denom;
  345. mess 'erreur relative=' errel '(+-=3.5%)';
  346. *
  347. si (errel > 4.d-2); erre 5;
  348. sinon; erre 0;
  349. finsi;
  350. *------------------------------------------
  351. * TEST 3D
  352. * Modèle avec une rotule non lineaire
  353. * et un element de poutre linéaire
  354. *------------------------------------------
  355. pp0 = 0.0 .0 .0;
  356. pp1 = 0.10 0. 0.;
  357. pp2 = 1.0 .0 .0;
  358. *
  359. llhinge = pp0 d 1 pp1;
  360. llelast = pp1 d 2 pp2;
  361. *
  362. modhing = 'MODE' llhinge mecanique elastique SECTION PLASTIQUE
  363. SECTION TIMO;
  364. mathing = MATE modhing MODS modq MATS macq
  365. 'VECT' (0. 1. 0.);
  366. *
  367. modhing2 = 'MODE' llhinge mecanique elastique SECTION PLASTIQUE
  368. SECTION TIMO;
  369. mathing2 = MATE modhing2 MODS modq2 MATS macq2
  370. 'VECT' (0. 1. 0.);
  371. *
  372. *
  373. *modelas = 'MODE' llelast mecanique elastique SECTION PLASTIQUE
  374. * SECTION TIMO;
  375. *matelas = MATE modelas MODS modq MATS macq
  376. * 'VECT' (0. 1. 0.);
  377. XXINRZ = (0.25**4)/12.;
  378. *
  379. modelas = 'MODE' llelast mecanique elastique POUT;
  380. matelas = MATE modelas YOUN ((1./3.)*0.297E+5) NU .20
  381. INRZ XXINRZ INRY XXINRZ TORS XXINRZ
  382. SECT (0.25*0.25)
  383. 'VECT' (0. 1. 0.) 'RHO ' 2.3D-3;
  384. *
  385. MODTOT = MODELAS et MODHING;
  386. MATTOT = MATELAS et MATHING;
  387. *
  388. MODTOT2 = MODELAS et MODHING2;
  389. MATTOT2 = MATELAS et MATHING2;
  390. *
  391. *---------------------------------------------
  392. * Check of the total mass
  393. *--------------------------------------------
  394. MASTOT = MASS MODTOT MATTOT;
  395. valmas = maxi (resu (MASTOT * (manu chpo
  396. (llhinge et llelast) UX 9.81)));
  397. valmasth = 1.41019E-03;
  398. errel = (valmas - valmasth)/valmasth;
  399. *
  400. si (errel > 4.d-2); erre 5;
  401. sinon; erre 0;
  402. finsi;
  403. *
  404. bl0 = BLOQ DEPL ROTA pp0;
  405. bl2 = BLOQ UZ pp2;
  406. dep2 = DEPI bl2 1.;
  407. FV = FORC ((-0.25) 0. 0.) pp2;
  408. *
  409. time = prog 0. 0.1 1.0;
  410. tidep = prog 0. 0. 0.01;
  411. tiforv = prog 0. 1. 1.;
  412. timecalc = prog 0. 0.1 pas 0.05 1.;
  413. *
  414. evde = evol manu time tidep;
  415. evfv =evol manu time tiforv;
  416. chade = charg dimp dep2 evde;
  417. chafv = charg fv evfv;
  418. *
  419. *------------------------------------------------------------
  420. * Linear shear
  421. *------------------------------------------------------------
  422. TAB = TABLE ;
  423. TAB.'BLOCAGES_MECANIQUES' = BL0 et BL2;
  424. TAB.'MODELE' = MODTOT;
  425. TAB.'CHARGEMENT' = CHADE et CHAFV;
  426. TAB.'TEMPS_CALCULES' = timecalc;
  427. TAB.'CARACTERISTIQUES' = MATTOT;
  428. TAB.'MOVA' = RIEN;
  429. *
  430. TMASAU=table;
  431. tab . 'MES_SAUVEGARDES'=TMASAU;
  432. TMASAU .'DEFTO'=VRAI;
  433. TMASAU .'DEFIN'=VRAI;
  434. PASAPAS TAB ;
  435. *
  436. dtab1=index(tab.deplacements) ;
  437. *
  438. ndime=dime dtab1 ;
  439. *
  440. prdep = prog 0.;
  441. prfor = prog 0.;
  442. *
  443. i=1 ;
  444. *
  445. REPETER BOU1 (ndime - 1);
  446. *
  447. i=i+1 ;
  448. *
  449. d=dtab1.i ;
  450. *
  451. dep0 = tab.deplacements.d ;
  452. sig0 = tab.contraintes.d ;
  453. var0 = tab.variables_internes.d ;
  454. def0 = tab.deformations_inelastiques.d ;
  455. *
  456. prdep = prdep et (prog (extr dep0 pp2 UZ));
  457. *
  458. reabase = reac bl0 dep0;
  459. *
  460. prfor = prfor et (prog ((-1.)*(extr reabase pp0 FZ)));
  461. *
  462. FIN BOU1;
  463. *
  464. depfor = evol manu prdep prfor;
  465. *
  466. si (ega graph 'Y');
  467. titre 'courbe effort tranchant - déplacement';
  468. dess depfor;
  469. finsi;
  470. *
  471. *
  472. errl = abs ((maxi (extr depfor ordo) abs) - 7.72465E-02);
  473. *
  474. *
  475. si (errl > 4.d-2); erre 5;
  476. sinon; erre 0;
  477. finsi;
  478. *
  479. fin;
  480. *
  481.  
  482.  
  483.  
  484.  
  485.  
  486.  
  487.  
  488.  
  489.  
  490.  
  491.  
  492.  
  493.  
  494.  
  495.  
  496.  
  497.  
  498.  
  499.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales