Télécharger elas10.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : elas10.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. *******************************************************
  6. * Test elas10.dgibi: Jeux de données *
  7. * --------------------------------- *
  8. *******************************************************
  9. * CAS TEST DU 91/06/13 PROVENANCE : TEST
  10.  
  11. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  12. * SINON SI GRAPH DIFFERENT DE N TOUS
  13. * LES GRAPHIQUES SONT AFFICHES
  14.  
  15. GRAPH = 'N' ;
  16.  
  17. SAUT PAGE;
  18. SI (NEG GRAPH 'N') ;
  19. OPTI ECHO 1 ;
  20. OPTI TRAC PSC ;
  21. SINO ;
  22. OPTI ECHO 0 ;
  23. FINSI ;
  24.  
  25. SAUT PAGE;
  26. *___________________________________________________________________
  27. * TEST ELAS10 *
  28. * *
  29. * SOLIDE (CYLINDRE - CONE - SPHERE) SOUMIS A UN GRADIENT DE *
  30. * TEMPERATURE (Calcul massif 3D). *
  31. * *
  32. * Test NAFEMS : numero LE11 *
  33. * Nom : solid cylinder / taper / sphere temperature *
  34. * *
  35. * La structure est une enceinte epaisse. Elle est constituee *
  36. * d'une partie spherique surmontee d'une partie conique, elle - *
  37. * meme surmontee d'une partie cylindrique. *
  38. * *
  39. * Elle est soumis a un gradient lineaire de temperature *
  40. * s'exercant radialement et axialement. Le champs de temperature *
  41. * s'exprime comme suit : *
  42. * *
  43. * T(x,y,z) = (x**2 + y**2)**.5 + z *
  44. * ou *
  45. * T(r,z) = r + z *
  46. * *
  47. * L'ensemble est maille avec des elements massifs CU20. Le *
  48. * maillage est obtenue par rotation de 90 degres d'une coupe *
  49. * verticale. *
  50. * *
  51. * On se propose de calculer la contrainte smyy au point A. *
  52. * cette valeur est ensuite comparee avec la valeur de reference *
  53. * obtenue a l'aide d'un calcul axisymetrique sur un maillage fin.*
  54. * *
  55. *___________________________________________________________________
  56. *
  57. OPTI ELEM CU20;
  58. *
  59. *==================================================================*
  60. * geometrie : maillage *
  61. *==================================================================*
  62. *
  63. * Dimension en metres
  64. *
  65. * Points
  66. *
  67. PO = 0. 0. 0.;
  68. P1 = 0. 0. 1.;
  69. PA = 1. 0. 0.;
  70. PB = 1.4 0. 0.;
  71. PE = (1. * (COS 30)) 0. (1. * (SIN 30));
  72. PD = (1.4 * (COS 30)) 0. 0.7;
  73. PC = (COS 30) 0. (SIN 30);
  74. PE = (COS 45) 0. (SIN 45);
  75. PH = 0.7071 0. 1.79;
  76. PI = 1. 0. 1.79;
  77. PG = 1. 0. 1.39;
  78. *
  79. * Droites, cercles et lignes
  80. *
  81. * coefficient de finesse du maillage
  82. *
  83. K = 2;
  84. *
  85. SI (K EGA 1);
  86. TITR ' : MAILLAGE GROSSIER';
  87. SINON;
  88. TITR ' LE11 : MAILLAGE FIN';
  89. FINSI;
  90. *
  91. N1 = 1 * K;
  92. AB = PA DROI N1 PB;
  93. GI = PG DROI N1 PI;
  94. EC = PE CERC N1 PO PC;
  95. IH = PI DROI N1 PH;
  96. *
  97. N2 = 2 * K;
  98. BD = PB CERC N2 PO PD;
  99. DG = PD DROI N2 PG;
  100. CA = PC CERC N2 PO PA;
  101. HE = PH DROI N2 PE;
  102. *
  103. * maillage par elements massifs du volume
  104. *
  105. SUR1 = DALL AB (BD ET DG ET GI) IH (HE ET EC ET CA) PLAN;
  106. *
  107. N3 = 3 * K;
  108. VOL1 = SUR1 VOLU N3 ROTA 90 PO P1;
  109. *
  110. SI (NEG GRAPH 'N');
  111. SI (K EGA 1);
  112. TITR 'ELAS10 : MAILLAGE GROSSIER';
  113. SINON;
  114. TITR 'ELAS10 : MAILLAGE FIN';
  115. FINSI;
  116. TRAC (-1000 -1000 1000) FACE QUAL (COUL VOL1 BLAN);
  117. FINSI;
  118. *
  119. ELVOL1 = NBEL VOL1;
  120. NOVOL1 = NBNO VOL1;
  121. *
  122. *==================================================================*
  123. * modele - materiau *
  124. * caracteristique - rigidite *
  125. *==================================================================*
  126. *
  127. MODL1 = MODE VOL1 MECANIQUE ELASTIQUE ISOTROPE CU20;
  128. MATR1 = MATE MODL1 YOUN 210E9 NU 0.3 ALPH 2.3E-4;
  129. RI1 = RIGI MODL1 MATR1;
  130. *
  131. *==================================================================*
  132. * Conditions aux limites *
  133. *==================================================================*
  134. *
  135. * - symetrie par rapport on plan xz,
  136. * - symetrie par rapport au plan yz,
  137. * - deplacement vertical nul pour les faces superieure et inferieure.
  138. *
  139. CL1 = BLOQ UY (FACE 1 VOL1);
  140. CL2 = BLOQ UX (FACE 2 VOL1);
  141. *
  142. * Creation des surfaces inferieure et superieure.
  143. *
  144. SURINF = AB ROTA N3 90 PO P1;
  145. SURSUP = IH ROTA N3 90 PO P1;
  146. *
  147. ELIM (VOL1 ET SURINF ET SURSUP) 0.0001;
  148. *
  149. CL3 = BLOQ UZ (SURINF ET SURSUP);
  150. CL4 = BLOQ RY (SURINF ET SURSUP);
  151. CL5 = BLOQ RX (SURINF ET SURSUP);
  152. *
  153. RIG1 = RI1 ET CL1 ET CL2 ET CL3 ET CL4 ET CL5;
  154.  
  155. *
  156. *==================================================================*
  157. * Chargement thermique *
  158. *==================================================================*
  159. *
  160. * Le solide est soumis a un gradient de temperature lineaire,
  161. * s'appliquant radialement et axialement.
  162. * La temperature est la suivante :
  163. *
  164. * T(x,y,z) = (x**2 + y**2)**.5 + z
  165. *
  166. * Creation du champs de temperature
  167. *
  168. CHPX = COOR 1 VOL1;
  169. CHPY = COOR 2 VOL1;
  170. CHPZ = COOR 3 VOL1;
  171. *
  172. CHP1 = CHPX ** 2;
  173. CHP2 = CHPY ** 2;
  174. CHP3 = (CHP1 + CHP2)**.5;
  175. *
  176. CHP4 = CHP3 + CHPZ;
  177. *
  178. * Transformation du sous-type "scal" en sous-type "t" pour chp4
  179. * Utilisation de l'operateur "vari".
  180. *
  181. LIS10 = PROG 0. 200.;
  182. LIS20 = PROG 0. 200.;
  183. EVOL1 = EVOL MANU SCAL LIS10 T LIS20;
  184. CHP5 = VARI CHP4 EVOL1 T;
  185. *
  186. * Creation du champ de contraintes equivalentes
  187. *
  188. CHAM10 = THET MODL1 MATR1 CHP5;
  189. *
  190. * Creation du champ de forces equivalentes
  191. *
  192. CHAR1 = BSIG MODL1 CHAM10;
  193. *
  194. *==================================================================*
  195. * Resolution : champs de deplacements *
  196. *==================================================================*
  197. *
  198. DEP1 = RESO RIG1 CHAR1;
  199. *
  200. * Trace facultatif de la deformee et des reactions
  201. *
  202. SI (NEG GRAPH 'N');
  203. AMPVEC = 1.E-7;
  204. REA1 = REAC DEP1 RIG1;
  205. VECT1 = VECT REA1 AMPVEC FX FY FZ ROUGE;
  206. DEF0 = DEFO 0. DEP1 VOL1;
  207. DEF1 = DEFO 100. DEP1 VOL1 VECT1 VERT;
  208. TITR 'ELAS10 : DEFORMEE, REACTIONS';
  209. TRAC (-1000 -1000 1000) VOL1 (DEF0 ET DEF1);
  210. FINSI;
  211. *
  212. *==================================================================*
  213. * extraction d'une contrainte *
  214. * et comparaison avec solution analytique *
  215. *==================================================================*
  216. *
  217. * On cherche la contrainte tangentielle sigtt au noeud pd et
  218. * sur la surface exterieure.
  219. *
  220. * Calcul du champs de contraintes totales.
  221. *
  222. CHAM1 = SIGM MODL1 MATR1 DEP1;
  223. *
  224. * On retranche les contraintes dites d'origine thermique
  225. *
  226. CHAM1 = CHAM1 - CHAM10;
  227. *
  228. * Interpolation aux noeuds du maillage des contraintes.
  229. *
  230. CHAM2 = CHAN NOEUD MODL1 CHAM1;
  231. CHPO10 = CHAN CHPO MODL1 CHAM2;
  232. *
  233. * Trace facultatif des contraintes aux noeuds.
  234. *
  235. SI (NEG GRAPH 'N');
  236. TITR 'ELAS9 : Contraintes Nodales';
  237. TRAC (-1000 -1000 1000) CACH VOL1 ((EXCO CHPO10 SMZZ)*1e-6);
  238. FINSI;
  239. *
  240. * Extraction de la valeur cherchee.
  241. *
  242. SMZZA = EXTR CHPO10 SMZZ PA;
  243. SMZZA = SMZZA / 1.E6;
  244. *
  245. SMZZA1 = -105;
  246. *
  247. * Calcul de l'ecart avec la valeur de reference.
  248. *
  249. ERGZZA = 100 * (ABS ((SMZZA - SMZZA1) / SMZZA1));
  250. *
  251. *==================================================================*
  252. * affichage des resultats *
  253. *==================================================================*
  254. *
  255. MESS ' RESULTATS ';
  256. MESS ' --------- ';
  257. *
  258. MESS ' La valeur cherchee est la contrainte verticale au point A,';
  259. ' elle est comparee a une valeur theorique obtenue analytiquement.';
  260. MESS ' Contrainte verticale theorique en A :' SMZZA1 'MPa';
  261. MESS ' Contrainte verticale calculee en A :' SMZZA 'MPa';
  262. MESS ' Soit un ecart de :' ERGZZA '%';
  263. *
  264. SI (K EGA 1);
  265. MESS ' MAILLAGE GROSSIER';
  266. SINON;
  267. MESS ' MAILLAGE FIN';
  268. FINSI;
  269. *
  270. MESS ' NOMBRE D ELEMENTS :' ELVOL1;
  271. MESS ' NOMBRE DE NOEUDS :' NOVOL1;
  272. MESS ' SOIT ' (NOVOL1 * 6) 'D.D.L.';
  273. *
  274. *==================================================================*
  275. * code fonctionnement *
  276. *==================================================================*
  277. * L'ecart maximum entre valeur theorique et calculee doit etre
  278. * inferieure a 2%.
  279. *
  280. SAUT 1 LIGNE;
  281. SI (ERGZZA <EG 2);
  282. ERRE 0;
  283. SINON;
  284. ERRE 5;
  285. FINSI;
  286. *
  287. *==================================================================*
  288. * Temps de calcul et fin *
  289. *==================================================================*
  290. TEMPS;
  291.  
  292. FIN;
  293.  
  294.  
  295.  
  296.  
  297.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales