Télécharger dependance.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : dependance.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. ********************************************************************
  5. * TEST DE CONDENSATION
  6. *
  7. * poutre des section rectangulaire en appui simples
  8. * face inferieure renforcee par une plaque en acier
  9. * un renfort interne de type poutre
  10. * un renfort interne de type barr
  11. *
  12. * les renforts sont disjoints du maillage massif
  13. *
  14. * comparaison des solutions obtenues par :
  15.  
  16. * rela accro / resou
  17. * dependance / resou
  18. * cmct / resou + mrem
  19. *
  20. * test de fonctionnement dans pasapas
  21. *
  22. *********************************************************************
  23. opti echo 1;
  24. graph='N' ;
  25. opti dime 3 elem cub8 ;
  26. * ajout de option epsilon lineaire pour la precision des test!
  27. OPTION epsilon lineaire;
  28. *
  29. * GEOMETRIE
  30. *
  31. long = 10.0;
  32. *---BETON
  33. h = 1.;
  34. h1= .9 ;
  35. *h1 = 1. - (1./6.1);
  36. pa=0.0 0. 0.0;
  37. pb=long 0. 0.0;
  38. pc=long 0. h ;
  39. pd=0.0 0. h;pn = 0. 0. (h - h1) ;
  40.  
  41. *---ARMATURE
  42. prof = 1. ;
  43. pm = long (prof/2) (h - h1) ;
  44. pn = 0. (prof/2) (h - h1) ;
  45. nb1 = 20;
  46. nb2 = 4 ;
  47. nb3=17 ;
  48. c1=pa droi nb1 pb;
  49. c2=pb droi nb2 pc;
  50. c3=pc droi nb1 pd;
  51. c4=pd droi nb2 pa;
  52. sur1=(dall c1 c2 c3 c4) ;
  53.  
  54.  
  55. sur1 = sur1 volu 2 tran (0 prof 0) ;
  56. d1 = d nb3 pm pn coul roug ;
  57. d2 = d1 plus ( 0 0 h1 ) ;
  58. finf = sur1 points plan pa pb (pa plus (0 1 0)) .01 ;
  59. finf = (( sur1 envel) elem appu stric finf ) ;
  60. fsup = finf plus (0 0 h) ;
  61. elim .1 sur1 fsup ;
  62. *----- on decolle la plaque pour pouvoir l ACCROCHER
  63. plaq = finf plus ( 0 0 0 ) coul bleu ;
  64.  
  65. 'SI' ( 'NEG' graph 'N' ) ;
  66. trac (1000 1000 1000 ) ( sur1 et d1) ;
  67. 'FINSI' ;
  68.  
  69. *
  70. * MODELE
  71. *------------------------- beton ---------------------------------
  72. Eb = 0.4e11 ;
  73. modb= 'MODE' sur1 mecanique elastique ;
  74. matb= 'MATE' modb youn Eb nu 0.3;
  75. ribe = rigi modb matb;
  76.  
  77. *----------------------- barre ----------------------------
  78. YOUCAB = 1495.D6/0.718D-2 ; ;
  79. TRACAB = EVOL MANU
  80. 'EPS' (1.D-2 * (PROG 0. .718 .804 .890 1.00 1.278 2.957))
  81. 'Pa' (1.D6 * (PROG 0. 1495. 1553. 1623. 1669. 1727. 1855.));
  82. mod1 = MODE d1 MECANIQUE ELASTIQUE ISOTROPE PLASTIQUE ISOTROPE BARR ;
  83. mat1= MATE mod1 YOUN youcab NU 0.3 SECT 0.04 TRAC tracab ALPH
  84. 12.5E-6 ;
  85. riba = rigi mod1 mat1 ;
  86.  
  87. *------------------- - poutre -----------------------
  88.  
  89. mod2= 'MODE' d2 mecanique elastique pout ;
  90. mat2=( 'MATE' mod2 youn Eb nu 0.0 INRY 10. INRZ 10. TORS 3.)
  91. et ( cara mod2 sect .02) ;
  92. ripo = rigi mod2 mat2 ;
  93.  
  94. *--------------------- coque -------------------------
  95.  
  96. *---- Courbe d'écrouissage de l'acier A42
  97. EPS1 = PROG 0. 0.002 0.018 0.02 0.036 0.05 0.068 0.084 0.102 ;
  98. SIG1 = PROG 0. 312. 325. 335. 400. 425. 450. 465. 475. ;
  99. SIG1 = SIG1*1.E6 ;
  100. EVSIG = EVOL MANU 'EP' EPS1 'SI' SIG1 ;
  101. *---- Module de Young de la Peau d'étanchéité
  102. YOUNT = 312.E6 / 0.002 ;
  103. mod3 = mode plaq MECANIQUE ELASTIQUE ISOTROPE
  104. PLASTIQUE ISOTROPE coq4 ;
  105. Mat3 = MATE mod3 YOUN YOUNT NU 0.3 EPAI 0.03 TRAC EVSIG ALPH
  106. 12.5E-6 ;
  107. rico = rigi mod3 mat3 ;
  108. *----------------------------------------------------------
  109. *
  110. * CONDITIONS AUX LIMITES
  111. *
  112. aa = sur1 points droite pa ( pa plus (0 1 0)) .01 ;
  113. bb = sur1 points droite pb ( pb plus (0 1 0)) .01 ;
  114. cl1 = bloq aa ux ;
  115. cl2 = bloq aa uz ;
  116. cl3 = bloq bb uz ;
  117. cl4 = bloquer uy ( pa et pb) ;
  118. clb = cl1 et cl2 et cl3 et cl4 ;
  119. *
  120. * on veut bloquer la rotation sur elle meme de la poutre
  121. *
  122. dp2 = d2 elem ( lect 1 pas 1 ( nb3 - 1)) ;
  123. pf = d2 point final ;
  124. conf pf ( sur1 point proche pf ) ;
  125. *
  126. clt = clb et ( bloquer RX pf ) ;
  127. *
  128.  
  129. racc = rela accro (plaq et d1 et dp2 ) sur1 ;
  130. radd = chan DEPE racc ;
  131.  
  132. * ------ concatenation des raideurs ------------
  133. rign = ribe et riba et ripo et rico ;
  134. riga = rign et racc et clt ;
  135. rigd = rign et radd et clt ;
  136. *
  137. * --- pression sur face superieure + force sur la plaque -----
  138. MOP = 'MODE' fsup 'CHARGEMENT' 'PRESSION' ;
  139. PRZ = 'PRES' MOP pres 1.e8 ;
  140. f1 = bsig mop PRZ ;
  141. f2 = force 1.E8 FZ plaq ;
  142. ff = f1 + f2 ;
  143. *-------------- solution par depend-------------------------
  144. dep2 = resou rigd ff ;
  145. *-------------- solution par accro -------------------------
  146. dep1 = resou riga ff ;
  147. *--------------------------------------------------------
  148. *------------- solution par cmct puis mrem ------------
  149. * --- condensation des matrices liees aux noeuds esclaves ---
  150. rige = cmct (rign et clt ) radd ;
  151. * --- condensation des la force liees aux noeuds esclaves -----
  152. racd radu = chan COND racc ;
  153. fad = f1 et ( radu * f2 ) ;
  154. * ----- solution reduite ---------------------------------------
  155. * dep30 = resou rige fad ;
  156. *-- remeontee a la solution complete --------------------------
  157. * on n'utilise plus tout cela, c'est intégré dans résou
  158. * dep3 = mrem dep30 (rign et clt et radd ) ff ;
  159. dep3 = resou rige fad ;
  160. *--------------------------------------------------------------
  161. mde1 = mini dep1 avec ( mots UZ) ;
  162. mde2 = mini dep2 avec ( mots UZ) ;
  163. mde3 = mini dep3 avec ( mots UZ) ;
  164. surd = (sur1 envel ) et d1 et d2 ;
  165.  
  166. * ----------- reactions aux appuis et liaisons ---------------------
  167. rea1 = reac (clt et racc ) dep1 ;
  168. rea2 = reac (clt et radd ) dep2 ;
  169. *----------examen des differences entre les deux methodes ----------
  170. aaa = rea1 - rea2 ;
  171. reamo1 = (psca rea1 rea1 ( mots FX FY FZ) ( mots FX FY FZ)) ** .5 ;
  172. reamo2 = (psca rea2 rea2 ( mots FX FY FZ) ( mots FX FY FZ)) ** .5 ;
  173. depmod = (psca dep1 dep1 ( mots UX UY UZ) ( mots UX UY UZ)) ** .5 ;
  174. si ( neg GRAPH N) ;
  175. av = maxi ( abs rea1 ) avec (mots FZ) ;
  176. amv = 4./av ;
  177. vr1 = vecteur rea1 amv FX FY FZ roug ;
  178. vr2 = vecteur rea2 amv FX FY FZ vert ;
  179. amp = .3/ ( maxi depmod) ;
  180. amd = 4./(maxi reamo1) ;
  181. vd1 = vecteur rea1 amd FX FY FZ roug ;
  182. vd2 = vecteur rea2 amd FX FY FZ vert ;
  183. titre 'UZ mini accro ' mde1 ' dependence ' mde2 'cmct' mde3 ;
  184. dde0 = defo surd dep1 0. blan ;
  185. dde1 = defo surd dep1 amp vr1 roug ;
  186. dde2 = defo surd dep2 amp vr2 vert ;
  187. trac ( dde1 et dde2 ) ;
  188. dur1 = defo surd dep1 amp vd1 roug ;
  189. dur2 = defo surd dep2 amp vd2 vert ;
  190. trac ( dur1 et dur2 ) ;
  191. vdif = vecteur aaa FX FY FZ amd vert ;
  192. titre ' difference sur reactions accro depen ' ;
  193. trac surd vdif ;
  194. finsi ;
  195. rdif = reamo1 - reamo2 ;
  196. a3= rdif point maxi ;
  197. av1 = (abs (maxi rdif)) /( extr reamo1 SCAL (a3 point 1 )) ;
  198. ruz = abs (((mde1 - mde2) * 100 ) / mde2 ) ;
  199.  
  200. mess ' differences relatives max sur la fleche maximum ' ruz '%' ;
  201. mess ' differences relatives max sur les reactions ' av1 '%' ;
  202. 'SI' (( ruz > 1.e-7) OU ( av1 > 1.e-7));
  203. erre 5 ;
  204. 'FINSI' ;
  205.  
  206. * suite uniquement pour tester que tout se passe correctement ds pasapas
  207.  
  208. evf = EVOL MANU 'Sec.' (prog 0. 1000.) 'Pa' (prog 1. 1. ) ;
  209. chforce = char meca f2 evf ;
  210. *
  211. chpress = char pres prz evf ;
  212.  
  213. TABMC = TABLE ;
  214. TABMC.MODELE = modb et mod1 et mod2 et mod3 et mop ;
  215. TABMC.BLOCAGES_MECANIQUES = radd et clt ;
  216. TABMC.CARACTERISTIQUES = matb et mat1 et mat2 et mat3 ;
  217. TABMC.CHARGEMENT = chpress et chforce ;
  218. evtt = prog 0. pas 1. 5.;
  219. TABMC.TEMPS_CALCULES = evtt ;
  220. TABMC.TEMPS_SAUVES = evtt ;
  221. PASAPAS TABMC ;
  222.  
  223. ttt = tabmc.'DEPLACEMENTS' ;
  224. i1 = index ttt ;nt = dime i1 ;
  225. dep = ttt . (i1.nt ) ;uref = -8.94153E-02 ;
  226. uymi = mini dep avec (mots UZ) ;
  227. * fleche attendue 5 iterations =-8.94153E-02 ;
  228. ruz = abs (((uref - uymi) * 100 ) / (abs uymi )) ;
  229. mess ' difference relative ' ruz '%' ;
  230.  
  231. 'SI' ( ruz > 5.e-1) ;
  232. erre 5 ;
  233. 'FINSI' ;
  234. 'FIN' ;
  235.  
  236.  
  237.  
  238.  
  239.  
  240.  
  241.  
  242.  
  243.  
  244.  
  245.  
  246.  
  247.  
  248.  
  249.  
  250.  
  251.  
  252.  
  253.  
  254.  
  255.  
  256.  
  257.  
  258.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales