Télécharger amor.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : amor.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. ************************************************************************
  6. * Test de frontiere LYSMER et KULHEMEYER
  7. ************************************************************************
  8. *
  9. * Dans ce test, une onde de compression est generee par une impulsion
  10. * a une extremite d'une barre maille en elements massifs 3D. Cette onde
  11. * est absorbée lorsqu'elle arrive a l'autre extremite de la barre munie
  12. * de la frontiere absorbante de Lysmer et Kulhemeyer.
  13. *
  14. * L'absorption est totale si la direction de propagation de l'onde est
  15. * perpendiculaire a la frontiere, ce qui est le cas ici.
  16. *
  17. * F. WANG DM2S/SEMT/EMSI 02/2014
  18. ************************************************************************
  19. * Pour les traces, mettre IG1 a VRAI ; *
  20. IG1 = FAUX ;
  21. * *
  22. OPTI DIME 3 ELEM CUB8 ;
  23.  
  24. NE = 80 ;
  25. DIS = 80. ;
  26. DX = DIS / NE ;
  27.  
  28. P0 = 0 0 0 ;
  29. P1 = 0 5 0 ;
  30. L1 = DROI 1 P0 P1 ;
  31. S1 = TRAN 1 L1 (0 0 5) ;
  32. SOL = VOLU NE S1 TRAN (DIS 0 0) ;
  33. S2 = FACE 2 SOL ;
  34. TITR 'MAILLAGE 3D D UNE BARRE' ;
  35. ELIM SOL 0.001 ;
  36. 'SI' IG1 ;
  37. TRAC SOL ;
  38. 'FINS' ;
  39.  
  40. NU1 = 1./3. ;
  41. VS = 400. ;
  42. VP = 800. ;
  43. RHO1 = 2500 ;
  44. G1 = VS*VS*RHO1 ;
  45. E1 = 2*(1 + NU1)*G1 ;
  46.  
  47. MOD_S = MODE SOL MECANIQUE ELASTIQUE ISOTROPE CUB8 ;
  48. MAT_S = MATE MOD_S YOUN E1 NU NU1 RHO RHO1 ;
  49. MAS_S = MASS MOD_S MAT_S ;
  50. RIG_S = RIGI MOD_S MAT_S ;
  51.  
  52. * APPEL AMOR
  53.  
  54. AMO_S = AMOR S2 MOD_S MAT_S ;
  55.  
  56. CL1 = BLOQ UZ UY SOL ;
  57.  
  58. TITR 'FORCE APPLIQUEE A UNE EXTREMITE' ;
  59. DT = 0.0125 / 2 ;
  60. NT = 300 ;
  61. L_TIM = 'PROG' 0.0 'PAS' DT 'NPAS' NT ;
  62. L_FOR = 'PROG' 0. 1.E5 0. -1.E5 297 * 0. ;
  63. EV_FOR = 'EVOL' 'MANU' 'TEMPS(S)' L_TIM 'FORCE(N)' L_FOR ;
  64. 'SI' IG1 ;
  65. DESS EV_FOR ;
  66. 'FINS' ;
  67.  
  68. MODP = 'MODE' S1 'CHARGEMENT' 'PRESSION' ;
  69. MATP = 'MATE' MODP 'PRES' 1.0 ;
  70. PP = 'PRES' MODP MATP ;
  71. P_S1 = 'PRES' 'MASS' MOD_S 1.0 S1 ;
  72. F_S1 = 'EXCO' 'FX' P_S1 'FX' ;
  73. CHA1 = CHAR F_S1 EV_FOR ;
  74.  
  75. *-----------------------------------------------------------------------
  76. * TABLE POUR LA PROCEDURE DYNAMIQUE
  77. *-----------------------------------------------------------------------
  78.  
  79. CH_DEPI = MANU CHPO 3 SOL UX 0.0 UY 0.0 UZ 0.0 ;
  80. CH_VITI = MANU CHPO 3 SOL UX 0.0 UY 0.0 UZ 0.0 ;
  81.  
  82. TAB_DYN = TABLE ;
  83. TAB_DYN.'DEPL' = CH_DEPI ;
  84. TAB_DYN.'VITE' = CH_VITI ;
  85. TAB_DYN.'RIGI' = RIG_S ET CL1 ;
  86. TAB_DYN.'MASS' = MAS_S ;
  87. TAB_DYN.'AMOR' = AMO_S ;
  88. TAB_DYN.'CHAR' = CHA1 ;
  89. TAB_DYN.'FREQ' = 250 ;
  90. TAB_DYN.'DEBU' = 0.0 ;
  91. NB_PAS = ENTI (0.3 / 0.001) ;
  92. TAB_DYN.'INST' = PROG 0. PAS 0.001 NPAS (NB_PAS - 1) ;
  93. RESU = DYNAMIC TAB_DYN ;
  94. TEMPS ;
  95.  
  96. *-----------------------------------------------------------------------
  97. * POST-TRAITEMENT
  98. *-----------------------------------------------------------------------
  99.  
  100. POI = TABLE ;
  101. POI.1 = P0 ;
  102. POI.2 = SOL POIN PROC (40 0 0) ;
  103. POI.3 = SOL POIN PROC (80 0 0) ;
  104.  
  105. NP = DIME POI ;
  106. L_TEM = PROG NB_PAS * 0.0 ;
  107. L_ENR = PROG NB_PAS * 0.0 ;
  108. L_D = TABLE ;
  109.  
  110. I = 1 ;
  111. REPE B1 NP ;
  112. L_D.I = PROG NB_PAS * 0.0 ;
  113.  
  114. I = I + 1 ;
  115. FIN B1 ;
  116.  
  117. I_TEM = 0 ;
  118. REPETER B2 NB_PAS ;
  119. I_TEM = I_TEM + 1 ;
  120. TEM_I = RESU.I_TEM.'TEMP' ;
  121. REMP L_TEM I_TEM TEM_I ;
  122.  
  123. CHD_I = RESU.I_TEM.'DEPL' ;
  124. EPS_I = EPSI MOD_S CHD_I ;
  125. SIG_I = SIGM MOD_S MAT_S CHD_I ;
  126. ENR_I = ENER MOD_S EPS_I SIG_I ;
  127. ENR_I = INTG MOD_S ENR_I ;
  128. I = 1 ;
  129. REPE B2_1 NP ;
  130. REMP L_D.I I_TEM (EXTR CHD_I POI.I UX) ;
  131. REMP L_ENR I_TEM ENR_I ;
  132. I = I + 1 ;
  133. FIN B2_1 ;
  134.  
  135. FIN B2 ;
  136.  
  137. EV_DEP = TABLE ;
  138.  
  139. I = 1 ;
  140. REPE B3 NP ;
  141. Z_I = COOR 1 POI.I ;
  142.  
  143. TITRE 'DEPLACEMENT POINT' I ' Z =' Z_I ' M' ;
  144. EV_DEP.I = EVOL MANU 'TEMPS (S)' L_TEM 'DEPL (M)' L_D.I ;
  145. I = I + 1 ;
  146. FIN B3 ;
  147.  
  148. TITR 'DEPLACEMENTS DES POINTS A 0, 40 ET 80 M' ;
  149. 'SI' IG1 ;
  150. DESS ((COUL ROUG EV_DEP.1) ET (COUL VERT EV_DEP.2) ET
  151. (COUL BLEU EV_DEP.3)) MIMA ;
  152. 'FINS' ;
  153.  
  154. TITRE 'EVOLUTION D ENERGIE DE DEFORMATION DANS LA BARRE' ;
  155. EV_ENR = EVOL ROSE MANU 'TEMPS (S)' L_TEM 'ENERGIE' L_ENR ;
  156. 'SI' IG1 ;
  157. DESS EV_ENR MIMA ;
  158. 'FINS' ;
  159.  
  160. E_MAX = MAXI L_ENR ;
  161. E_FIN = EXTR L_ENR (DIME L_ENR) ;
  162. E_RES = E_FIN / E_MAX ;
  163. *
  164. * CODE FONCTIONNEMENT
  165. *
  166. SI (E_RES < 1.E-4) ;
  167. MESS 'TAUX D ENERGIE RESIDUELLE = ' E_RES ;
  168. SINON ;
  169. ERRE 5 ;
  170. FINSI ;
  171. * *
  172. FIN ;
  173.  
  174.  
  175.  
  176.  
  177.  
  178.  
  179.  
  180.  
  181.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales