Télécharger Contact2Djeufaible.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : Contact2Djeufaible.dgibi
  2. *---------------------------------------------------------------------*
  3. * Ce cas-test est une adaptation du cas-test Contact2D avec l'ajout*
  4. * d'un jeu entre les deux objets. Il permet de tester la gestion du *
  5. * contact faible par PASAPAS. *
  6. * Il simule la mise en contact, en deplacements imposes, d'un carre *
  7. * sur une surface rigide. Le probleme est traite en 2D, contraintes *
  8. * planes. On impose le deplacement de l'arete sup. du carre. Sa base *
  9. * entre en contact, le carre est mis en compression. On compare la *
  10. * solution EF a la solution analytique. *
  11. *---------------------------------------------------------------------*
  12. * *
  13. **'OPTI' ECHO 0 ;
  14. * *
  15. 'OPTI' 'DIME' 2 'ELEM' QUA4 'MODE' 'PLAN' 'CONT' ;
  16. * *
  17. * Si TRACes desires, mettre IG1 a VRAI : *
  18. IG1 = FAUX ;
  19. * *
  20. *---------------------------------------------------------------------*
  21. * MAILLAGE *
  22. *---------------------------------------------------------------------*
  23. * *
  24. S1 = -10. 0.9998 ;
  25. S2 = 10. 0.9998 ;
  26. NLS1 = 5 ;
  27. LS1 = S1 'DROI' NLS1 S2 ;
  28. * *
  29. M1 = -5. 1. ;
  30. M2 = 5. 1. ;
  31. NLM1 = 7 ;
  32. LM1 = M1 'DROI' NLM1 M2 ;
  33. SM1 = LM1 'TRAN' NLM1 (0. 10.) ;
  34. * *
  35. * Maillages de contact : *
  36. * *
  37. MCONT1 = ('IMPO' 'MAIL' 'FAIB' LM1 ('INVE' LS1)) 'COUL' 'JAUN' ;
  38. chjeu1 = 'MANU' 'CHML' MCONT1 'JEU' 1e-4 ;
  39. *list MCONT1;
  40. * *
  41. * Traces : *
  42. * *
  43. 'SI' IG1 ;
  44. 'TITR' 'Maillages' ;
  45. 'TRAC' 'FACE' (LS1 'ET' SM1 'ET' MCONT1) ;
  46. 'FINS' ;
  47. * *
  48. *---------------------------------------------------------------------*
  49. * MODELES / CARACTERISTIQUES *
  50. *---------------------------------------------------------------------*
  51. * *
  52. MODM1 = 'MODE' SM1 'MECANIQUE' 'ELASTIQUE' ;
  53. MATM1 = 'MATE' MODM1 'YOUN' 1.E3 'NU' 0.3 ;
  54. * *
  55. *---------------------------------------------------------------------*
  56. * C.L. / CHARGEMENT *
  57. *---------------------------------------------------------------------*
  58. * *
  59. * Deplacements imposes : *
  60. * *
  61. LM3 = SM1 'COTE' 3 ;
  62. LM4 = SM1 'COTE' 4 ;
  63. CLLM3 = 'BLOQ' LM3 'UY' ;
  64. CLLM4 = 'BLOQ' LM4 'UX' ;
  65. CLS1 = 'BLOQ' LS1 'DEPL' ;
  66. CL0 = CLLM3 'ET' CLLM4 'ET' CLS1 ;
  67. * *
  68. UY0 = -0.0002 ;
  69. DCLLM3 = 'DEPI' CLLM3 UY0 ;
  70. * *
  71. 'SI' IG1 ;
  72. 'TITR' 'Deplacement impose au bord superieur du carre.' ;
  73. 'TRAC' ('VECT' (DCLLM3 'NOMC' 'UY') 1. 'UX' 'UY' 'VERT')
  74. (LS1 'ET' SM1) ;
  75. 'FINS' ;
  76. * *
  77. * Chargements : *
  78. * *
  79. LTPS1 = 'PROG' 0. 1. ;
  80. EV1 = 'EVOL' 'MANU' 'TEMPS' LTPS1 ('PROG' 0. 1.) ;
  81. * *
  82. CHARU1 = 'CHAR' 'DIMP' DCLLM3 EV1 ;
  83. CHAR0 = CHARU1 ;
  84. MODCONTA= model MCONT1 contact unilateral;
  85. MATCONTA= 'MATE' MODCONTA 'JEU' chjeu1;
  86. * *
  87. *---------------------------------------------------------------------*
  88. * RESOLUTION *
  89. *---------------------------------------------------------------------*
  90. * *
  91. * Construction de la table PASAPAS : *
  92. * *
  93. TAB1 = 'TABL' ;
  94. TAB1 . 'TEMPS_CALCULES' = LTPS1 ;
  95. TAB1 . 'MODELE' = MODM1 et modconta;
  96. TAB1 . 'CARACTERISTIQUES' = MATM1 'ET' MATCONTA ;
  97. TAB1 . 'BLOCAGES_MECANIQUES' = CL0 ;
  98. TAB1 . 'CHARGEMENT' = CHAR0 ;
  99. *TAB1 . 'CONTACT' = MCONT1 ;
  100. *TAB1 . 'GRANDS_DEPLACEMENTS' = FAUX ;
  101. * *
  102. * Resolution : *
  103. * *
  104. TAB2 = PASAPAS TAB1 ;
  105. * *
  106. *---------------------------------------------------------------------*
  107. * DEPOUILLEMENT *
  108. *---------------------------------------------------------------------*
  109. * *
  110. DEP1 = (TAB2 . 'DEPLACEMENTS' . 1) 'ENLE' 'LX' ;
  111. * *
  112. * Deformee : *
  113. * *
  114. DEFO0 = 'DEFO' (SM1 'ET' LS1) DEP1 0. 'VERT' ;
  115. DEFO1 = 'DEFO' (SM1 'ET' LS1) DEP1 1. 'ROUG' ;
  116. * *
  117. 'SI' IG1 ;
  118. 'TITR' 'Maillages non deforme (vert) et deforme (rouge).' ;
  119. 'TRAC' (DEFO0 'ET' DEFO1) ;
  120. 'FINS' ;
  121. * *
  122. * Definition des deplacements solutions et comparaison avec la *
  123. * solution EF : *
  124. * *
  125. EPXX1 = ((-1. * UY0) - 0.0001) * 0.1 * 0.3;
  126. UXSM1 = (('COOR' 1 SM1) + 5.) * EPXX1 ;
  127. SOLUX1 = UXSM1 'NOMC' 'UX' ;
  128. EPYY1 = ((-1. * UY0) - 0.0001) * 0.1 ;
  129. UYSM1 = ((('COOR' 2 SM1) - 1.) * EPYY1) + 0.0001;
  130. SOLUY1 = (-1. * UYSM1) 'NOMC' 'UY' ;
  131. SOLU1 = SOLUX1 'ET' SOLUY1 ;
  132. ERR1 = 'MAXI' ('ABS' ((SOLU1 - DEP1) / ('MAXI' 'ABS' (SOLU1)))) ;
  133. * *
  134. 'SI' IG1 ;
  135. 'TITR' 'Champ de deplacements.' ;
  136. 'TRAC' ('CHAN' 'CHAM' DEP1 MODM1 'NOEUDS') MODM1 ;
  137. 'FINS' ;
  138. * *
  139. * Comparaison des champs de contraintes : *
  140. * *
  141. EPS1 = 'EPSI' MODM1 SOLU1 ;
  142. SIG1 = 'ELAS' MODM1 EPS1 MATM1 ;
  143. SIG2 = TAB2 . 'CONTRAINTES' . 1 ;
  144. ERR2 = 'MAXI' ('ABS' ((SIG1 - SIG2) / ('MAXI' 'ABS' (SIG1)))) ;
  145. * *
  146. 'SI' IG1 ;
  147. 'TITR' 'Champ de contraintes.' ;
  148. 'TRAC' SIG2 MODM1 ;
  149. 'FINS' ;
  150. * *
  151. * Visualisations des reactions : *
  152. * *
  153. 'SI' IG1 ;
  154. REAC1 = TAB2 . 'REACTIONS' . 1 ;
  155. VR1 = 'VECT' REAC1 0.8E-2 'FX' 'FY' 'ROUG' ;
  156. 'TITR' 'Forces de reaction.' ;
  157. 'TRAC' VR1 (LS1 'ET' SM1) ;
  158. 'FINS' ;
  159. * *
  160. LERR0 = 'PROG' ERR1 ERR2 ;
  161. ERR0 = 'MAXI' LERR0 ;
  162. ERRMAX1 = 1.E-3 ;
  163. * *
  164. 'OPTI' 'ECHO' 0 ;
  165. 'SAUT' 1 'LIGN' ;
  166. '------------------------ RESULTAT CAS-TEST ------------------------' ;
  167. 'SAUT' 1 'LIGN' ;
  168. 'Ecart relatif a la solution calculee sur les deplacements' ;
  169. 'et les contraintes :' ;
  170. 'MESS'
  171. '-----------------------------------------------------------' ;
  172. 'MESS' ;
  173. 'MESS' ' MAX. ERREUR =' ERR0 ;
  174. 'SAUT' 1 'LIGN' ;
  175. 'SI' (ERR0 '<EG' ERRMAX1) ;
  176. 'MESS' '==> Erreur relative inferieure a' ERRMAX1 ':' ;
  177. 'MESS' '' ;
  178. 'MESS' ' __________________' ;
  179. 'MESS' ' | |' ;
  180. 'MESS' ' | TEST REUSSI ! |' ;
  181. 'MESS' ' |________________|' ;
  182. 'SAUT' 1 'LIGN' ;
  183. 'SINO' ;
  184. 'MESS' '==> Erreur relative superrieure a' ERRMAX1 ':' ;
  185. 'MESS' '' ;
  186. 'MESS' ' __________________' ;
  187. 'MESS' ' | |' ;
  188. 'MESS' ' | ERREUR ! |' ;
  189. 'MESS' ' |________________|' ;
  190. 'SAUT' 1 'LIGN' ;
  191. 'ERRE' 5 ;
  192. 'FINS' ;
  193. '-------------------------- FIN CAS-TEST ---------------------------' ;
  194. * *
  195. 'FIN' ;
  196. 'OPTI' 'ECHO' 1 ;
  197.  
  198.  
  199.  
  200.  
  201.  
  202.  
  203.  
  204.  
  205.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales