Télécharger vibr14_3d.dgibi

Retour à la liste

Numérotation des lignes :

  1. *
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. * VIBR14_3D
  6. *
  7. * Objectif : Calcul des modes propres d'un tube mince orthotrope
  8. * axisymetrique encastre - encastre
  9. * Elements : coque mince DKT
  10. * Creation : BP, 2017-03-01
  11. * Reference : Intercomparaison avec modele 2D Fourier CAST3M
  12. *
  13. ************************************************************************
  14. *
  15. * DIMENSION dans le plan (XOY)
  16. *
  17. * solide
  18. * Y
  19. * Y=L | . . . D __ B
  20. * | | |
  21. * | | |
  22. * | | |
  23. * | | |
  24. * | | |
  25. * | | |
  26. * | | |
  27. * | . . . |__| -----> X
  28. * O C A
  29. * R=Ri R=Re
  30. *
  31. * | |
  32. * <-->
  33. * t
  34. *
  35. * la coque mince est definie sur Rmoy=(Re+Ri)/2
  36. *
  37. *
  38. * ORTHOTROPIE dans le plan (Y,Theta)
  39. *
  40. * Y
  41. * |
  42. * V2 beta |
  43. * \ |
  44. * \ |
  45. * \ |
  46. * \ |
  47. * \ |
  48. * \|
  49. * Z-------------+X
  50. *
  51. ************************************************************************
  52.  
  53. GRAPH = FAUX ;
  54. * GRAPH = VRAI ;
  55.  
  56. ************************************************************************
  57. * OPTIONS ET DONNEES
  58. ************************************************************************
  59.  
  60. * options
  61. OPTI DIME 3 MODE TRID ELEM CUB8 EPSI LINEAIRE;
  62. OPTI TRAC PSC POTR HELVETICA_16 EPTR 15;
  63.  
  64. * geometrie
  65. L = 0.3048;
  66. t = 0.254E-3;
  67. Re = 0.0762;
  68. Ri = Re - t;
  69. Rmoy = (Ri + Re) / 2.;
  70.  
  71. * nombre d elements selon Z et R
  72. ncirc = 2**8; nz = 20; nR = 1;
  73. * ncirc = 2**8; nz = 40; nR = 1;
  74. * ncirc = 2**9; nz = 80; nR = 1;
  75.  
  76. * materiau
  77. Ey1 = 206.E9;
  78. nu12 = 0.3;
  79. rho1 = 7850.;
  80. Ey2 = Ey1 / 10.;
  81. G12 = Ey2 / (2. * (1. + nu12));
  82. mess Ey1 Ey2 G12;
  83. beta=30.;
  84.  
  85. * nombre de modes calcules
  86. nmod = 2*4;
  87. * nmod = 2*7;
  88.  
  89.  
  90. ************************************************************************
  91. * MAILLAGE
  92. ************************************************************************
  93.  
  94. p0 = 0. 0. 0.;
  95. vaxe = 0. 1. 0.;
  96. vx = 1. 0. 0.;
  97. vz = 0. 0. 1. ;
  98.  
  99. * MAILLAGE COQUE MINCE
  100.  
  101. p1 = Rmoy 0. 0.;
  102. p2 = Rmoy L 0.;
  103. d12 = p1 droi nZ p2;
  104. OPTI ELEM TRI3;
  105. mesh3 = ROTA d12 360. ncirc p0 vaxe;
  106. ELIM mesh3 (1.E-3 * t);
  107. OPTI ELEM CUB8;
  108.  
  109. * recup
  110. y3 = COOR mesh3 2;
  111. py1 = POIN y3 EGINFE 1.E-6;
  112. py2 = POIN y3 EGSUPE (L - 1.E-6);
  113. p4 = poin py2 'PROCH' ( 0. L (-1.*Rmoy));
  114. p6 = poin py2 'PROCH' ((-1.*Rmoy) L 0. );
  115. p8 = poin py2 'PROCH' ( 0. L Rmoy );
  116. cy2 = (cer3 p2 p4 p6 (ncirc/2)) et (cer3 p6 p8 p2 (ncirc/2));
  117. cy2 = cy2 coul BRUN;
  118. elim cy2 py2 1.E-8;
  119. cyMIL = cy2 moin (0. (0.5*L) 0.);
  120. elim cyMIL mesh3 1.E-8;
  121. cyMIL2 = cy2 moin (0. (0.25*L) 0.);
  122. elim cyMIL2 mesh3 1.E-8;
  123.  
  124. * chpoints angulaires
  125. cos1 = (coor mesh3 3) / Rmoy;
  126. sin1 = (coor mesh3 1) / Rmoy;
  127. cosMIL = (coor cyMIL 3) / Rmoy;
  128. sinMIL = (coor cyMIL 1) / Rmoy;
  129. cosMIL2 = (coor cyMIL2 3) / Rmoy;
  130. sinMIL2 = (coor cyMIL2 1) / Rmoy;
  131.  
  132.  
  133.  
  134. ************************************************************************
  135. * MODELEs ET MATERIAUx
  136. ************************************************************************
  137.  
  138. * coque mince dkt
  139. mod3 = MODE mesh3 'MECANIQUE' 'ELASTIQUE' 'ORTHOTROPE' 'DKT';
  140. mat3 = MATE mod3 'YG1' Ey1 'YG2' Ey2 'NU12' nu12 'G12' G12
  141. 'RHO' rho1 'EPAI' t
  142. 'DIRE' vaxe 'INCL' beta ;
  143.  
  144. * verification graphique de l'orientation des fibres
  145. v3 = chan (VLOC mod3 mat3) 'GRAVITE' mod3;
  146. SI GRAPH;
  147. xv3 = 0.1 / nZ;
  148. vv3 = vect v3 xv3 mod3 (mots V1X V1Y V1Z V2X V2Y V2Z V3X V3Y V3Z)
  149. (mots 'BLEU' 'BRON' 'ROUG');
  150. vv3_1 = vect v3 xv3 mod3 (mots V1X V1Y V1Z )
  151. (mots 'BLEU' );
  152. TRAC (0. 2. -10.) vv3_1 mesh3 'BOIT' py2 'CACH';
  153. TRAC (0. 2. -10.) vv3 mesh3 'BOIT' py2 'CACH';
  154. FINSI;
  155.  
  156. ************************************************************************
  157. * MATRICES
  158. ************************************************************************
  159.  
  160. * coque mince dkt
  161. cl3 = BLOQ 'DEPL' (py1 et py2);
  162. K3 = RIGI mod3 mat3;
  163. M3 = MASS mod3 mat3;
  164. Ktot3 = K3 et cl3;
  165.  
  166.  
  167. ************************************************************************
  168. * ANALYSE MODALE
  169. ************************************************************************
  170. SI GRAPH;
  171. mopost = mots 'TABL' 'DEFO';
  172. SINO;
  173. mopost = mots 'TABL' ;
  174. FINSI;
  175.  
  176. * coque mince dkt
  177. TMOD_3 = VIBR 'IRAM' 300. nmod Ktot3 M3 ;
  178. POSTVIBR TMOD_3 mopost;
  179.  
  180.  
  181.  
  182. ************************************************************************
  183. * TEST DE BON FONCTIONNEMENT
  184. ************************************************************************
  185. * REM : On teste que les harmoniques de Fourier sont 6, 7, 5 et 8.
  186. nHref = lect 6 7 5 8;
  187. nHjj = lect;
  188.  
  189. * boucles sur les modes
  190. I= -1 ;
  191. REPE BMOD 4; I = I + 2;
  192. phi1 = TMOD_3 . 'MODES' . I . 'DEFORMEE_MODALE';
  193. phi1MIL = REDU phi1 cyMIL;
  194. phi1MIL = (cosMIL * (exco phi1MIL 'UZ' 'SCAL'))
  195. + (sinMIL * (exco phi1MIL 'UX' 'SCAL'));
  196. ev1MIL = EVOL CHPO phi1MIL 'SCAL' cyMIL;
  197. s1MIL = EXTR ev1MIL 'ABSC';
  198. u1MIL = EXTR ev1MIL 'ORDO';
  199. u1moy = ((mini u1MIL) + (maxi u1MIL)) / 2.;
  200. s1moy = IPOL u1moy u1MIL s1MIL 'TOUS';
  201. nH1 = (DIME s1moy) / 2;
  202. nHjj = nHjj et nH1;
  203. FIN BMOD ;
  204.  
  205. list nHjj;
  206.  
  207. nHdiff = nHjj - nHref;
  208.  
  209. SI ((maxi nHdiff 'ABS') >eg 1);
  210. ERRE 5;
  211. SINON;
  212. ERRE 0;
  213. FINSI;
  214.  
  215. FIN ;
  216.  
  217.  
  218.  
  219.  
  220.  
  221.  
  222.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales