Télécharger la plaquette Cast3M


fr en

Télécharger channeldie4.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : channeldie4.dgibi
  2. *----------------------------------------------------------------------*
  3. *                  C H A N N E L D I E 4 . D G I B I                   *
  4. *----------------------------------------------------------------------*
  5. * Objet :                                                              
  6. * -------
  7. *
  8. *    Cas-test de validation des elements BBAR pour l'element tetraedre
  9. * quadratique.
  10. *
  11. *    Calcul elastique de la compression d'un lopin de metal place dans
  12. * une matrice l'empechant de se dilater lateralement (lopin coince dans
  13. * un "canal", d'ou "channel die").
  14. *
  15. *    Validation du calcul par comparaison a la solution analytique.
  16. *
  17. *    Un 2nd chargement en deplacement impose sur la face superieure,
  18. * non uniforme en espace (varaition quadratique), permet de valider
  19. * l'integration dans les elements en verifiant l'equilibre (F-Bsig).
  20. *
  21. *    Verification du fonctionnement de l'operateur MASSE.
  22. *
  23. *    Verification et validation de l'operateur KSIG en deplacements.
  24. *
  25. * Description :
  26. * -------------
  27. *
  28. * Type de calcul : Mecanique Elastique
  29. * Mode de calcul : 3D
  30. * Type d'element : TE10
  31. * Chargement     : Deplacement impose
  32. *
  33. *----------------------------------------------------------------------*
  34. opti dime 3 mode TRID elem TE10 ;
  35.  
  36. * Pour affichages, mettre ig1 a VRAI :
  37. ig1      = faux ;
  38.  
  39. *------------------------------ MAILLAGE ------------------------------*
  40.  
  41. * Points :
  42. p1       = 0. 0. 0. ;
  43. p2       = 100. 0. 0. ;
  44. p3       = 100. 100. 0. ;
  45. p4       = 0. 100. 0. ;
  46. p5       = 0. 0. 100. ;
  47.  
  48. * Contour base :
  49. ne1      = 5 ;
  50. li1      = d ne1 p1 p2 ;
  51. li2      = d ne1 p2 p3 ;
  52. li3      = d ne1 p3 p4 ;
  53. li4      = d ne1 p4 p1 ;
  54.  
  55. * Surface et Volume :
  56. sur1     = dall li1 li2 li3 li4 'PLAN' ;
  57. vol1     = volu tran sur1 p5 ne1 ;
  58. sur2     = vol1 face 2 ;
  59. sur3     = vol1 face 3 ;
  60. sur3     = sur3 chan tri6 ;
  61. vol1     = volu (sur1 et sur2 et sur3) ;
  62. list (vol1 elem type) ;
  63.  
  64. si ig1 ;
  65.   trac cach vol1 titr 'Maillage lopin' ;
  66. fins ;
  67.  
  68. *--------------------- MODELE / CARACTERISTIQUES ----------------------*
  69.  
  70. * Valeurs modules d'elasticite :
  71. ym1      = 1.5e11 ;
  72. nu1      = 0.499 ;
  73.  
  74. * Modele et caracteristiques mecaniques :
  75. mod1     = modele vol1 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' 'BBAR' ;
  76. mat1     = mate mod1 'YOUNG' 1.5e11 'NU' nu1 'RHO' 7.6e3 ;
  77.  
  78. * Matrice de raideur :
  79. rig1     = rigi mod1 mat1 ;
  80. mas1     = mass mod1 mat1 ;
  81.  
  82. *----------------------- CONDITIONS AUX LIMITES -----------------------*
  83.  
  84. * Definition des points d'interet :
  85. ptx0     = (vol1 coor 1) poin mini ;
  86. pty0     = (vol1 coor 2) poin mini ;
  87. ptz0     = sur1 ;
  88. ptz1     = sur2 ;
  89. clx0     = bloq ux ptx0 ;
  90. cly0     = bloq uy pty0 ;
  91. clz0     = bloq uz ptz0 ;
  92. clz1     = bloq uz ptz1 ;
  93. cl0      = clx0 et cly0 et clz0 et clz1 ;
  94.  
  95. * Affichages points CL :
  96. si ig1 ;
  97.   trac ((ptx0 coul roug) et (aret vol1)) titr 'Points Ux = 0' ;
  98.   trac ((pty0 coul roug) et (aret vol1)) titr 'Points Uy = 0' ;
  99.   trac ((ptz0 coul roug) et (ptz1 coul rouge) et (aret vol1)) titr 'Points Uz = 0 (surfaces bloquees par matrice)' ;
  100. fins ;
  101.  
  102. *----------------------------- CHARGEMENT -----------------------------*
  103.  
  104. * Deplacement impose essai channel die :
  105. Uy1      = -0.1 ;
  106. pty1     = (vol1 coor 2) poin maxi ;
  107. cly1     = bloq uy pty1 ;
  108. dcl1     = depi cly1 Uy1 ;
  109.  
  110. * Deplacement impose non homogene :
  111. ptx1     = (vol1 coor 1) poin maxi ;
  112. clx1     = bloq ux ptx1 ;
  113. chy1     = ptz1 coor 2 ;
  114. Uz1      = (((-0.01 * (chy1 - 100.)) ** 2) / -100.) nomc uz ;
  115. dcl2     = depi clz1 Uz1 ;
  116.  
  117. si ig1 ;
  118.   trac ((pty1 coul vert) et (aret vol1)) titr 'Points deplacement Uy impose essai channel die' ;
  119.   trac Uz1 ptz1 titr '2nd chargement : deplacement non homogene' ;
  120. fins ;
  121.  
  122. *---------------------------- DEPLACEMENTS ----------------------------*
  123.  
  124. * Solution analytique au point P3:
  125. UxAna1   = -1. * nu1 / (1. - nu1) * Uy1 ;
  126.  
  127. * Solution Castem au point P3: uycas.
  128. deptot   = reso (rig1 et cl0 et cly1) dcl1 ;
  129. dep2     = reso (rig1 et cl0 et cly1 et clx1) dcl2 ;
  130.  
  131. * deplacement Ux au point P3 :
  132. UxSim1   = extr deptot 'UX' p3 ;
  133.  
  134. * Deformee :
  135. def0     = defo deptot (aret vol1) 0. blan ; 
  136. def1     = defo deptot (     vol1) 100 roug ; 
  137. mot1     = chai format '(F7.4)' 'deformee (vue de dessus) : Ux =' UxSim1 ;
  138.  
  139. si ig1 ;
  140.   trac cach (def0 et def1) titr 'deformee (rouge)' ;
  141.   trac (0 0 1.e6) (def0 et def1) titr mot1 ;
  142. fins ;
  143.  
  144. opti oeil (1.e6 -1.e6 0.8e6) ;
  145.  
  146. * Calcul de l'erreur sur le déplacement.
  147. err1     = abs (( UxAna1 - UxSim1 ) / ( UxAna1 )) ;
  148.  
  149. *---------------------------- CONTRAINTES -----------------------------*
  150.  
  151. * Solution analytique: 
  152. syyana1  = ym1 / (1. - (nu1 * nu1)) * uy1 / 100. ;
  153. szzana1  = nu1 * syyana1 ;
  154. prana1   = syyana1 + szzana1 / 3. ;
  155.  
  156. * Solution Castem : pression maximale = maxpres1.
  157. sig1     = sigma mod1 deptot mat1 ;
  158.  
  159. * Validation KSIG avec BBAR :
  160. ksg1     = ksigm mod1 sig1 ;
  161. depto2   = reso (rig1 et ksg1 et cl0 et cly1) dcl1 ;
  162. err6     = maxi abs (deptot - depto2) avec (mots ux uy uz) ;
  163.  
  164. * Affichage :
  165. si ig1 ;
  166.   trac sig1 mod1 titr 'Champ de contrainte' ;
  167. fins ;
  168.  
  169. * Calcul de la pression :
  170. syySim1  = exco 'SMYY' sig1 'P' ;
  171. szzSim1  = exco 'SMZZ' sig1 'P' ;
  172. prSim1   = (syySim1 + szzSim1) / 3. ;
  173. syySim1  = mini syySim1 ;
  174. szzSim1  = mini szzSim1 ;
  175. prSim1   = mini prSim1 ;
  176.  
  177. * Calcul de l'erreur sur les contraintes :
  178. err2     = ((syyana1 - syySim1) / syyana1) + ((szzana1 - szzSim1) / szzana1) + ((prana1 - prSim1) / prana1) ;
  179. err2     = abs err2 ;
  180.  
  181. * Verification equilibre chargement non homogene :
  182. sig2     = sigm mod1 mat1 dep2 ;
  183. bsg2     = bsig mod1 sig2 ;
  184. rea2     = reac (cl0 et cly1 et clx1) dep2 ;
  185. res2     = rea2 - bsg2 ;
  186. err5     = (maxi abs res2) / (maxi abs rea2) ;
  187.  
  188. * Affichages solution chargement non homogene :
  189. si ig1 ;
  190.   trac (defo vol1 dep2 2.e3) cach titr ' Deformee chargement non homogene' ;
  191.   trac sig2 mod1 titr ' Contraintes chargement non homogene' ;
  192. fins ;
  193.  
  194. *----------------------------- VALIDATION -----------------------------*
  195.  
  196. * Affichages :
  197. opti echo 0 ; saut 1 lign ;
  198. mess (chai format '(F6.2)' ' > Erreur relative deplacement au point P3 =' err1) ;
  199. mess (chai format '(F6.2)' ' > Erreur relative contraintes et pression =' err2) ;
  200. opti echo 1 ; saut 1 lign ;
  201.  
  202. * Test de validation:
  203. err0     = maxi abs (prog err1 err2 err5 err6) ;
  204. prec0    = (vale prec) ** 0.5 * 10. ;
  205. list err0 ;
  206. list err1 ;
  207. list err2 ;
  208. list err5 ;
  209. list err6 ;
  210. list prec0 ;
  211.  
  212. si ( err0 >eg prec0 ) ;
  213.   erreur 5 ;
  214. finsi ;
  215.  
  216. fin;
  217.  
  218.  
  219.  
  220.  
  221.  
  222.  
  223.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales