Télécharger pressupp.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : pressupp.dgibi
  2. *---------------------------------------------------------
  3. * Pressurisation d'une enceinte type Phébus
  4. *
  5. * Le maillage correspond à une enceinte cylindrique
  6. * d'environ 10 m3 avec un mur en contact avec la
  7. * paroi verticale (10 cm d'acier)
  8. * Tout le volume est initialement a 1bar et 40oC
  9. * et la température du mur est mise à 60oC
  10. * au début du calcul. On calcule la pressurisation
  11. * de cette enceinte sur 50 secondes en injectant un débit
  12. * de 50g/s de vapeur à 150oC. Ce test (un peu long)
  13. * verifie le demarrage de la condensation a 20"
  14. * verifie l'evolution moyenne de la temprature gaz
  15. * verifie la pression max a 50"
  16. * verifie la vitesse max a 50" (Convection naturelle)
  17. * verifie la masse d'eau a 50"
  18. * Auteurs : E. Studer Novembre 1999
  19. * revisite Mars 2001
  20. *--------------------------------------------------------
  21. COMPLET = FAUX ;
  22. *COMPLET = VRAI ;
  23. GRAPH = VRAI ;
  24. GRAPH = FAUX ;
  25. 'OPTI' 'TRAC' 'X' ;
  26. *'OPTI' 'TRAC' 'PSC' ;
  27.  
  28. 'SI' COMPLET ;
  29.  
  30. nbit=100;
  31. DT0 = 1. ;
  32. n1 = 1 ; n2 = 4 ; n3 = 4 ;
  33. n4 = 8 ; nn = 2 ;
  34.  
  35. 'SINON' ;
  36.  
  37. nbit= 5 ;
  38. DT0 = 10. ;
  39. n1 = 1 ; n2 = 2 ; n3 = 4 ;
  40. n4 = 4 ; nn = 1 ;
  41.  
  42. 'FINSI' ;
  43.  
  44. *--------------------------------------------------------
  45. * Definition du maillage de l'enceinte cylindrique
  46. *
  47. 'OPTI' 'DIME' 3 'ELEM' 'CU20' ;
  48.  
  49. ri = 1.052 ; sp = 0.10 ; hc = 4.163 ;
  50.  
  51.  
  52.  
  53. epsi = 1.000e-2 ; ;
  54.  
  55. p0 = 0.000 0.000 0.000 ;
  56. px = -1000.000 0.000 0.000 ;
  57. py = 0.000 -1000.000 0.000 ;
  58. pz = 0.000 0.000 1000.000 ;
  59. cd = 0.000 0.000 -20.000 ;
  60. ph0 = 0.000 0.000 hc ;
  61. phx = ri 0.000 hc ;
  62. phy = 0.000 ri hc ;
  63.  
  64. fg1 = 0.25 ;
  65. fg2 = fg1 * (2.0 ** 0.5) / 2. ;
  66.  
  67. p1 = (ri*fg1) 0.000 0.000 ;
  68. p2 = (ri*fg2) (ri*fg2) 0.000 ;
  69. p3 = 0.000 (ri*fg1) 0.000 ;
  70. p4 = ri 0.000 0.000 ;
  71. p5 = 0.000 ri 0.000 ;
  72. p6 = (ri+sp) 0.000 0.000 ;
  73. p7 = 0.000 (ri+sp) 0.000 ;
  74.  
  75. * Hauteur de l'enceinte
  76. h1 = 4.163 ;
  77. * Vecteur de translation
  78. v1 = 0. 0. h1 ;
  79.  
  80. l1 = 'DROI' p0 p1 n1 ;
  81. l2 = 'DROI' p1 p2 n1 ;
  82. l3 = 'DROI' p2 p3 n1 ;
  83. l4 = 'DROI' p3 p0 n1 ;
  84. l5 = 'CERC' p4 p0 p5 (2*n1) ;
  85. l6 = 'CERC' p6 p0 p7 (2*n1) ;
  86.  
  87. basf0= 'DALL' l1 l2 l3 l4 'PLAN' ;
  88. basf1=('REGL' (l2 'ET' l3) l5 n2) ;
  89. l44= cote 2 basf1;
  90. ax4= (inve l4) et l44 ;
  91. l11= cote 4 basf1;
  92. ax1= l11 et (inve l1) ;
  93.  
  94. basf = basf0 'ET' ('REGL' (l2 'ET' l3) l5 n2) ;
  95. 'ELIM' basf epsi ;
  96. basf = basf 'ET' ('SYME' basf 'DROI' p0 p3) ;
  97. ax11 = ('SYME' ax1 'DROI' p0 p3) 'ET' (inve ax1) ;
  98. 'ELIM' basf epsi ;
  99. basf = basf 'ET' ('SYME' basf 'DROI' p0 p1) ;
  100. ax44 = (inve ax4) 'ET' ('SYME' ax4 'DROI' p0 p4) ;
  101. 'ELIM' basf epsi ;
  102.  
  103. basm = 'REGL' l5 l6 n3 ;
  104. basm = basm 'ET' ('SYME' basm 'DROI' p0 p3) ;
  105. 'ELIM' basm epsi ;
  106. basm = basm 'ET' ('SYME' basm 'DROI' p0 p1) ;
  107. 'ELIM' basm epsi ;
  108.  
  109. * Creation du volume
  110.  
  111. dx = ri / 2. ;
  112. nz1 = ('ENTIER' ( h1 / dx ))*nn ;
  113.  
  114. bas = basf 'VOLU' nz1 'TRAN' v1 ;
  115. mbas = basm 'VOLU' nz1 'TRAN' v1 ;
  116. mbas = mbas 'COUL' 'ROUG' ;
  117. plan1 = ax11 'TRAN' nz1 v1 ;
  118. plan4 = ax44 'TRAN' nz1 v1 ;
  119. 'ELIM' (bas et plan1 et plan4) epsi ;
  120.  
  121. mt = bas ;
  122. wall = mbas ;
  123. elim (mt et wall) epsi ;
  124.  
  125. * Localisation d'une brèche éventuelle au bas de l'enceinte
  126.  
  127. pjg = 'POIN' basf 'PROC' (0.000 0.000 0.000) ;
  128. jg = ('ELEM' basf 'APPUIE' 'LARGEMENT' pjg) 'COUL' 'VERT' ;
  129.  
  130. *--------------------------------------------------------------------
  131. * Fin de la définition du maillage
  132. *--------------------------------------------------------------------
  133.  
  134. *--------------------------------------------------------------------
  135. * Début de l'initialisation de la procédure ENCEINTE : table RXT
  136. *--------------------------------------------------------------------
  137.  
  138. rxt = 'TABLE' ;
  139. rxt.'VERSION'= 'V0' ;
  140.  
  141. *-- Nom du volume fluide
  142. rxt.'vtf' = mt ;
  143. rxt.'epsi' = epsi ;
  144.  
  145. rxt.'TCPT' = FAUX ;
  146. rxt.'TKPR' = VRAI ;
  147. rxt.'TRESOU' = FAUX ;
  148. rxt.'IMPARA' = FAUX ;
  149. * rxt.'TRrvap' = FAUX ;
  150.  
  151. *-- Definition des murs de l'enceinte : ici un seul mur
  152. *-- en ACIER dont on traitera la thermique dans l'épaisseur
  153. *-- et que l'on initialise a 40oC
  154.  
  155. *-- On definit d'abort la matériau ACIER avec sa conductivite
  156. *-- thermique LAMBDA (W/m/K) et le produit ro*Cp (J/m3/K)
  157. rxt.'THERMP' = VRAI ;
  158. rxt.'vtp' = wall ;
  159. rxt.'LAMBDA' = 15. ;
  160. rxt.'ROCP' = 3.9E6 ;
  161. rxt.'Tp0' = 60. ;
  162. rxt.'ECHAN' = 10. ;
  163.  
  164. *-- Conditions initiales dans l'enceinte de test
  165. rxt.'TF0' = 40.0 ;
  166. rxt.'PT0' = 1.00000e5 ;
  167. rxt.'Yvap0' = 0.0023 ;
  168.  
  169. *-- On positionne une brèche
  170. rxt.'breche' = jg ;
  171. rxt.'diru1' = 0 0 1 ;
  172.  
  173. *-- On definit un point interne au maillage pour imposer la valeur de
  174. *-- la pression
  175. rxt.'pi' = (0.0 0.0 0.5) ;
  176.  
  177. *-- On indique que le calcul comporte de la vapeur d'eau
  178. rxt.'VAPEUR' = VRAI ;
  179.  
  180. *-- On active le recalcul automatique du préconditionnement
  181. *-- toutes les 5 itérations
  182. rxt.'FRPREC' = 5 ;
  183. rxt.'DETMAT' = VRAI ;
  184. *rxt.'TRTF' = FAUX ;
  185.  
  186. *-- Definition du scenario thermohydraulique
  187. rxt.'scenario' = table ;
  188.  
  189. *-- Conditions a la breche (Obligatoire pour l'instant)
  190. rxt.'scenario'.'t' = prog 0.0 1000.0 ;
  191. rxt.'scenario'.'qeau' = prog 0.050 0.050 ;
  192. rxt.'scenario'.'qair' = prog 0.000 0.000 ;
  193. rxt.'scenario'.'tinj' = prog 150.0 150.0 ;
  194.  
  195. *-- On impose le pas de temps (s)
  196. rxt.'DT0' = DT0 ;
  197.  
  198. *-- On impose la viscosite turbulente (m2/s)
  199. rxt.'MODTURB'='NUTURB' ;
  200. rxt.'NUT' = 1.e-2 ;
  201.  
  202. *-- On lance le calcul sur 20 itérations d'une seconde
  203. rxt.'GRAPH'=GRAPH ;
  204.  
  205. EXECRXT 2 rxt ;
  206. EXECRXT (nbit - 2) rxt ;
  207. *EXECRXT nbit rxt ;
  208.  
  209.  
  210. list rxt.TIC.'Tfm' ;
  211. list rxt.TIC.'PT' ;
  212. list rxt.TIC.'Qc' ;
  213. list rxt.TIC.'LMAXU';
  214.  
  215.  
  216. Ltfm=Prog
  217. 40.000 65.434 73.516 81.090 86.291
  218. 89.532 ;
  219. LPT=Prog
  220. 1.00000E+05 1.04578E+05 1.21342E+05 1.30318E+05 1.36229E+05
  221. 1.42995E+05;
  222. Lqc= Prog
  223. 0.0000 0.0000 0.0000 1.46999E-03 5.27545E-03
  224. 8.56995E-03 ;
  225. Lmaxu=Prog
  226. 0.0000 0.81320 0.85322 1.5357 1.8768
  227. 1.9459;
  228.  
  229.  
  230. tic=rxt.'TIC' ;
  231. ERtf=somm( abs (ltfm - tic.'Tfm') )/ 80. ;
  232. ERPT=somm( abs (lPT - tic.'PT' ) ) /1.e5 ;
  233. ERQc=somm( abs (lqc - tic.'Qc' ) ) ;
  234. ERum=somm( abs (Lmaxu - tic.'LMAXU' ) )/2. ;
  235.  
  236. Mess 'ERtf=' ERtf 'ERPT=' ERPT 'ERQc=' ERQc 'ERum=' ERum ;
  237.  
  238. Si (ERtf '>' 1.e-4) ; erreur 5 ; Finsi ;
  239. Si (ERPT '>' 1.e-3) ; erreur 5 ; Finsi ;
  240. Si (ERQc '>' 1.e-4) ; erreur 5 ; Finsi ;
  241. Si (ERum '>' 1.e-2) ; erreur 5 ; Finsi ;
  242.  
  243. Si GRAPH ;
  244.  
  245. $vtf=rxt.'GEO'.'$vtf' ;
  246. mt =doma $vtf maillage ;
  247. Mpl1=chan 'QUAF' plan1 ;
  248. Mpl4=chan 'QUAF' plan4 ;
  249. ELIM (mt et Mpl1 et Mpl4) epsi ;
  250. $mpl1= mode Mpl1 'NAVIER_STOKES' MACRO ;
  251. $mpl4= mode Mpl4 'NAVIER_STOKES' MACRO ;
  252. plan1= doma $mpl1 maillage ;
  253. plan4= doma $mpl4 maillage ;
  254. plan=plan1 et plan4 ;
  255.  
  256. paroif = rxt.'GEO'.'paroif';
  257. rho=rxt.'TIC'.'RHO';
  258. rvp=rxt.'TIC'.'RVP';
  259. tf=rxt.'TIC'.'TF';
  260. un=rxt.'TIC'.'UN' ;
  261. un1=redu un plan ;
  262. ung= vect un1 1. ux uy uz jaune ;
  263. trace ung plan ;
  264. opti isov suli ;
  265. trace rho plan 'TITRE'' Rho' ;
  266. trace rvp plan 'TITRE'' Rvp' ;
  267. trace tf plan 'TITRE'' Tf ' ;
  268.  
  269. trace rho paroif 'TITRE'' Rho' ;
  270. trace rvp paroif 'TITRE'' Rvp' ;
  271. trace Tf paroif 'TITRE'' Tf ' ;
  272. Fcond = tic.'Fcondw';
  273. trace Fcond paroif 'TITRE' ' Flux de condensation Kg / m**2 ' ;
  274.  
  275. axe = p0 d nz1 (p0 plus v1) ;
  276. axe = chan axe 'QUAF' ;
  277. elim (axe et mt) epsi ;
  278.  
  279. evr= evol 'CHPO' rho axe ;
  280. dess evr 'TITRE' ' Rho axe ';
  281.  
  282. evt = evol 'CHPO' Tf axe ;
  283. dess evt 'TITRE' ' Température axe ';
  284.  
  285. evvp= evol 'CHPO' rvp axe ;
  286. dess evvp 'TITRE' ' rvp axe ';
  287.  
  288.  
  289.  
  290. 'FINSI' ;
  291.  
  292.  
  293.  
  294.  
  295.  
  296. 'FIN' ;
  297.  
  298.  
  299.  
  300.  
  301.  
  302.  
  303.  
  304.  
  305.  
  306.  
  307.  
  308.  
  309.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales