Télécharger pressugQ.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : pressugQ.dgibi
  2. *---------------------------------------------------------
  3. * Cas test analogue a pressu.dgibi testant QUAF MSOMMET
  4. *
  5. *
  6. * Le maillage correspond à une enceinte cylindrique
  7. * d'environ 10 m3 avec un mur en contact avec la
  8. * paroi verticale (10 cm d'acier)
  9. * Tout le volume est initialement a 1bar et 40oC
  10. * et la température du mur est mise à 60oC
  11. * au début du calcul. On calcule la pressurisation
  12. * de cette enceinte sur 50 secondes en injectant un débit
  13. * de 50g/s de vapeur à 150oC. Ce test (un peu long)
  14. * verifie le demarrage de la condensation a 20"
  15. * verifie l'evolution moyenne de la temprature gaz
  16. * verifie la pression max a 50"
  17. * verifie la vitesse max a 50" (Convection naturelle)
  18. * verifie la masse d'eau a 50"
  19. * Auteurs : E. Studer, J.P. Magnaud Novembre 1999
  20. * revisite Mars 2001
  21. *--------------------------------------------------------
  22. COMPLET = FAUX ;
  23. *COMPLET = VRAI ;
  24. GRAPH = VRAI ;
  25. GRAPH = FAUX ;
  26.  
  27. 'SI' COMPLET ;
  28.  
  29. nbit=100;
  30. DT0 = 1. ;
  31. n1 = 1 ; n2 = 4 ; n3 = 4 ;
  32. n4 = 8 ; nn = 2 ;
  33.  
  34. 'SINON' ;
  35.  
  36. nbit= 5 ;
  37. DT0 = 5. ;
  38. n1 = 1 ; n2 = 2 ; n3 = 4 ;
  39. n4 = 4 ; nn = 1 ;
  40.  
  41. 'FINSI' ;
  42.  
  43. *--------------------------------------------------------
  44. * Definition du maillage de l'enceinte cylindrique
  45. *
  46. 'OPTI' 'DIME' 3 'ELEM' 'CU20' ;
  47. 'OPTI' 'TRAC' 'X' ;
  48.  
  49. ri = 1.052 ; sp = 0.10 ; hc = 4.163 ;
  50.  
  51.  
  52.  
  53. epsi = 1.000e-2 ; ;
  54.  
  55. p0 = 0.000 0.000 0.000 ;
  56. px = -1000.000 0.000 0.000 ;
  57. py = 0.000 -1000.000 0.000 ;
  58. pz = 0.000 0.000 1000.000 ;
  59. cd = 0.000 0.000 -20.000 ;
  60. ph0 = 0.000 0.000 hc ;
  61. phx = ri 0.000 hc ;
  62. phy = 0.000 ri hc ;
  63.  
  64. fg1 = 0.25 ;
  65. fg2 = fg1 * (2.0 ** 0.5) / 2. ;
  66.  
  67. p1 = (ri*fg1) 0.000 0.000 ;
  68. p2 = (ri*fg2) (ri*fg2) 0.000 ;
  69. p3 = 0.000 (ri*fg1) 0.000 ;
  70. p4 = ri 0.000 0.000 ;
  71. p5 = 0.000 ri 0.000 ;
  72. p6 = (ri+sp) 0.000 0.000 ;
  73. p7 = 0.000 (ri+sp) 0.000 ;
  74.  
  75. * Hauteur de l'enceinte
  76. h1 = 4.163 ;
  77. * Vecteur de translation
  78. v1 = 0. 0. h1 ;
  79.  
  80. l1 = 'DROI' p0 p1 n1 ;
  81. l2 = 'DROI' p1 p2 n1 ;
  82. l3 = 'DROI' p2 p3 n1 ;
  83. l4 = 'DROI' p3 p0 n1 ;
  84. l5 = 'CERC' p4 p0 p5 (2*n1) ;
  85. l6 = 'CERC' p6 p0 p7 (2*n1) ;
  86.  
  87. basf0= 'DALL' l1 l2 l3 l4 'PLAN' ;
  88. basf1=('REGL' (l2 'ET' l3) l5 n2) ;
  89. l44= cote 2 basf1;
  90. ax4= (inve l4) et l44 ;
  91. l11= cote 4 basf1;
  92. ax1= l11 et (inve l1) ;
  93.  
  94. basf = basf0 'ET' ('REGL' (l2 'ET' l3) l5 n2) ;
  95. 'ELIM' basf epsi ;
  96. basf = basf 'ET' ('SYME' basf 'DROI' p0 p3) ;
  97. ax11 = ('SYME' ax1 'DROI' p0 p3) 'ET' (inve ax1) ;
  98. 'ELIM' basf epsi ;
  99. basf = basf 'ET' ('SYME' basf 'DROI' p0 p1) ;
  100. ax44 = (inve ax4) 'ET' ('SYME' ax4 'DROI' p0 p4) ;
  101. 'ELIM' basf epsi ;
  102.  
  103. basm = 'REGL' l5 l6 n3 ;
  104. basm = basm 'ET' ('SYME' basm 'DROI' p0 p3) ;
  105. 'ELIM' basm epsi ;
  106. basm = basm 'ET' ('SYME' basm 'DROI' p0 p1) ;
  107. 'ELIM' basm epsi ;
  108.  
  109. * Creation du volume
  110.  
  111. dx = ri / 2. ;
  112. nz1 = ('ENTIER' ( h1 / dx ))*nn ;
  113.  
  114. bas = basf 'VOLU' nz1 'TRAN' v1 ;
  115. mbas = basm 'VOLU' nz1 'TRAN' v1 ;
  116. mbas = mbas 'COUL' 'ROUG' ;
  117. plan1 = ax11 'TRAN' nz1 v1 ;
  118. plan4 = ax44 'TRAN' nz1 v1 ;
  119. 'ELIM' (bas et plan1 et plan4) epsi ;
  120.  
  121. mt = bas ;
  122. wall = mbas ;
  123. elim (mt et wall) epsi ;
  124.  
  125. * Localisation d'une brèche éventuelle au bas de l'enceinte
  126.  
  127. pjg = 'POIN' basf 'PROC' (0.000 0.000 0.000) ;
  128. jg = ('ELEM' basf 'APPUIE' 'LARGEMENT' pjg) 'COUL' 'VERT' ;
  129.  
  130. *--------------------------------------------------------------------
  131. * Fin de la définition du maillage
  132. *--------------------------------------------------------------------
  133.  
  134. *--------------------------------------------------------------------
  135. * Début de l'initialisation de la procédure ENCEINTE : table RXT
  136. *--------------------------------------------------------------------
  137.  
  138. rxt = 'TABLE' ;
  139. rxt.'VERSION'= 'V0' ;
  140.  
  141. *-- Nom du volume fluide
  142. rxt.'vtf' = mt ;
  143. rxt.'epsi' = epsi ;
  144.  
  145. rxt.'DISCR' = 'QUAF' ;
  146. rxt.'KPRE' = 'MSOMMET';
  147. *-- Definition des murs de l'enceinte : ici un seul mur
  148. *-- en ACIER dont on traitera la thermique dans l'épaisseur
  149. *-- et que l'on initialise a 40oC
  150.  
  151. *-- On definit d'abort la matériau ACIER avec sa conductivite
  152. *-- thermique LAMBDA (W/m/K) et le produit ro*Cp (J/m3/K)
  153. rxt.'THERMP' = VRAI ;
  154. rxt.'vtp' = wall ;
  155. rxt.'LAMBDA' = 15. ;
  156. rxt.'ROCP' = 3.9E6 ;
  157. rxt.'Tp0' = 60. ;
  158. rxt.'ECHAN' = 10. ;
  159.  
  160. *-- Conditions initiales dans l'enceinte de test
  161. rxt.'TF0' = 40.0 ;
  162. rxt.'PT0' = 1.00000e5 ;
  163. rxt.'Yvap0' = 0.0023 ;
  164.  
  165. *-- On positionne une brèche
  166. rxt.'breche' = jg ;
  167. rxt.'diru1' = 0 0 1 ;
  168.  
  169. *-- On definit un point interne au maillage pour imposer la valeur de
  170. *-- la pression
  171. rxt.'pi' = (0.0 0.0 0.5) ;
  172.  
  173. *-- On indique que le calcul comporte de la vapeur d'eau
  174. rxt.'VAPEUR' = VRAI ;
  175.  
  176. *-- On active le recalcul automatique du préconditionnement
  177. *-- toutes les 5 itérations
  178. rxt.'FRPREC' = 5 ;
  179. rxt.'DETMAT' = VRAI ;
  180.  
  181. *-- Definition du scenario thermohydraulique
  182. rxt.'scenario' = table ;
  183.  
  184. *-- Conditions a la breche (Obligatoire pour l'instant)
  185. rxt.'scenario'.'t' = prog 0.0 1000.0 ;
  186. rxt.'scenario'.'qeau' = prog 0.050 0.050 ;
  187. rxt.'scenario'.'qair' = prog 0.000 0.000 ;
  188. rxt.'scenario'.'tinj' = prog 150.0 150.0 ;
  189.  
  190. *-- On impose le pas de temps (s)
  191. rxt.'DT0' = DT0 ;
  192.  
  193. *-- On impose la viscosite turbulente (m2/s)
  194. rxt.'MODTURB'='NUTURB' ;
  195. rxt.'NUT' = 1.e-2 ;
  196.  
  197. *-- On lance le calcul sur 20 itérations d'une seconde
  198. rxt.'GRAPH'=GRAPH ;
  199.  
  200. EXECRXT 2 rxt ;
  201. EXECRXT (nbit - 2) rxt ;
  202.  
  203.  
  204. list rxt.TIC.'Tfm' ;
  205. list rxt.TIC.'PT' ;
  206. list rxt.TIC.'Qc' ;
  207. list rxt.TIC.'LMAXU';
  208.  
  209. ltfm=Prog 40.000 52.602 58.480 64.050
  210. 68.963 73.355;
  211. lPT =Prog 1.00000E+05 1.02838E+05 1.11084E+05 1.15491E+05
  212. 1.18771E+05 1.23861E+05;
  213. Lqc =Prog 0.0000 0.0000 0.0000 0.0000
  214. 0.0000 0.0000;
  215. Lmaxu=Prog 0.0000 0.66429 1.8613 2.3843
  216. 2.3962 2.2940;
  217.  
  218. tic=rxt.'TIC' ;
  219. ERtf=somm( abs (ltfm - tic.'Tfm') )/ 80. ;
  220. ERPT=somm( abs (lPT - tic.'PT' ) ) /1.e5 ;
  221. ERQc=somm( abs (lqc - tic.'Qc' ) ) ;
  222. ERum=somm( abs (Lmaxu - tic.'LMAXU' ) )/2. ;
  223.  
  224. Mess 'ERtf=' ERtf 'ERPT=' ERPT 'ERQc=' ERQc 'ERum=' ERum ;
  225.  
  226. Si (ERtf '>' 2.e-2) ; erreur 5 ; Finsi ;
  227. Si (ERPT '>' 1.e-2) ; erreur 5 ; Finsi ;
  228. Si (ERQc '>' 1.e-2) ; erreur 5 ; Finsi ;
  229. Si (ERum '>' 5.e-2) ; erreur 5 ; Finsi ;
  230.  
  231. Si GRAPH ;
  232.  
  233. $vtf=rxt.'GEO'.'$vtf' ;
  234. mt =doma $vtf maillage ;
  235. Mpl1=chan 'QUAF' plan1 ;
  236. Mpl4=chan 'QUAF' plan4 ;
  237. ELIM (mt et Mpl1 et Mpl4) epsi ;
  238. $mpl1= mode Mpl1 'NAVIER_STOKES' MACRO ;
  239. $mpl4= mode Mpl4 'NAVIER_STOKES' MACRO ;
  240. plan1= doma $mpl1 maillage ;
  241. plan4= doma $mpl4 maillage ;
  242. plan=plan1 et plan4 ;
  243.  
  244. paroif = rxt.'GEO'.'paroif';
  245. rho=rxt.'TIC'.'RHO';
  246. rvp=rxt.'TIC'.'RVP';
  247. tf=rxt.'TIC'.'TF';
  248. un=rxt.'TIC'.'UN' ;
  249. un1=redu un plan ;
  250. ung= vect un1 1. ux uy uz jaune ;
  251. trace ung plan ;
  252. opti isov suli ;
  253. trace rho plan 'TITRE'' Rho' ;
  254. trace rvp plan 'TITRE'' Rvp' ;
  255. trace tf plan 'TITRE'' Tf ' ;
  256.  
  257. trace rho paroif 'TITRE'' Rho' ;
  258. trace rvp paroif 'TITRE'' Rvp' ;
  259. trace Tf paroif 'TITRE'' Tf ' ;
  260. Fcond = tic.'Fcondw';
  261. trace Fcond paroif 'TITRE' ' Flux de condensation Kg / m**2 ' ;
  262.  
  263. axe = p0 d nz1 (p0 plus v1) ;
  264. axe = chan axe 'QUAF' ;
  265. elim (axe et mt) epsi ;
  266.  
  267. evr= evol 'CHPO' rho axe ;
  268. dess evr 'TITRE' ' Rho axe ';
  269.  
  270. evt = evol 'CHPO' Tf axe ;
  271. dess evt 'TITRE' ' Température axe ';
  272.  
  273. evvp= evol 'CHPO' rvp axe ;
  274. dess evvp 'TITRE' ' rvp axe ';
  275.  
  276.  
  277.  
  278. 'FINSI' ;
  279.  
  280.  
  281.  
  282.  
  283.  
  284. 'FIN' ;
  285.  
  286.  
  287.  
  288.  
  289.  
  290.  
  291.  
  292.  
  293.  
  294.  
  295.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales