Télécharger vibr2.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : vibr2.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Test vibr2.dgibi: Jeux de données *
  5. * --------------------------------- *
  6. * *
  7.  
  8. *******************************************************
  9. * Test vibr2.dgibi: jeux de données *
  10. * --------------------------------- *
  11. *******************************************************
  12.  
  13. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  14. * SINON SI GRAPH DIFFERENT DE N TOUS
  15. * LES GRAPHIQUES SONT AFFICHES
  16.  
  17. GRAPH = 'N' ;
  18.  
  19. SAUT PAGE;
  20. SI (NEG GRAPH 'N') ;
  21. OPTI ECHO 1 ;
  22. OPTI TRAC PSC ;
  23. SINO ;
  24. OPTI ECHO 0 ;
  25. FINSI ;
  26.  
  27. SAUT PAGE;
  28. *********************************************************************
  29. * VIBR2
  30. *********************************************************************
  31. * *
  32. * Mots-clés : Vibrations, calcul modal, axisymetrique *
  33. * *
  34. * TEST VIBR2 *
  35. * *
  36. * CAS TEST DU 91/06/13 PROVENANCE : TEST *
  37. * *
  38. * SPHERE EPAISSE : VIBRATION RADIALE UNIFORME *
  39. * *
  40. * Test NAFEMS , test numero fv42 *
  41. * *
  42. * On se propose de calculer les frequences et *
  43. * modes propres d'une sphere epaisse. On ne s'inte- *
  44. * resse qu'aux modes de vibration radiale uniforme. *
  45. * *
  46. * On ne maille qu'un secteur de la sphere et l'on *
  47. * travaille en mode axisymetrique. *
  48. * *
  49. * Pour obtenir les conditions aux limites corres- *
  50. * pondantes, on utilise l'operateur RELA (les noeuds *
  51. * ayant le meme rayon ont le meme deplacement radial) *
  52. * *
  53. *********************************************************************
  54.  
  55. OPTI MODE AXIS;
  56. OPTI ELEM QUA8;
  57.  
  58. *-----------------------------------------------------*
  59. * geometrie - maillage *
  60. *-----------------------------------------------------*
  61. *
  62. ALPHA = 5.; COSALPHA = COS ALPHA; SINALPHA = SIN ALPHA;
  63. *
  64. P0 = 0. 0.;
  65. P1 = 1.8 ( 1.8 * SINALPHA);
  66. P2 = 1.8 (-1.8 * SINALPHA);
  67. P3 = 6.0 (-6.0 * SINALPHA);
  68. P4 = 6.0 ( 6.0 * SINALPHA);
  69. *
  70. D23 = P2 DROI 5 P3;
  71. *
  72. SUR1 = D23 ROTA 1 (2 * ALPHA) P0;
  73. D41 = COTE 3 SUR1;
  74. *
  75. ELIM (SUR1 ET D23 ET D41) 0.001;
  76. *
  77. SI (NEG GRAPH 'N');
  78. TITR 'VIBR2 : MAILLAGE';
  79. TRAC 'QUAL' SUR1;
  80. FINSI;
  81. *
  82. *-----------------------------------------------------*
  83. * MODE - materiau - rigidite - masse *
  84. *-----------------------------------------------------*
  85. *
  86. MOD1 = MODE SUR1 MECANIQUE QUA8;
  87.  
  88. MAT1 = MATE MOD1 YOUN 2.E11 NU 0.3 RHO 8E3;
  89. RIG1 = RIGI MOD1 MAT1;
  90. MAS1 = MASS MOD1 MAT1;
  91. *
  92. *-----------------------------------------------------*
  93. * conditions aux limites *
  94. *-----------------------------------------------------*
  95. DIR1 = (-1 * SINALPHA) (-1 * COSALPHA);
  96. DIR2 = (-1 * SINALPHA) COSALPHA;
  97. *
  98. CL1 = BLOQ DEPL DIRECTION DIR1 D23;
  99. CL2 = BLOQ DEPL DIRECTION DIR2 D41;
  100. CLI1 = CL1 ET CL2;
  101. *
  102. DIR3 = COSALPHA (-1 * SINALPHA);
  103. DIR4 = COSALPHA SINALPHA;
  104. *
  105. LIST1 = LECT 27 22 17 23 18 24 19 25 20 26 21;
  106. LIST2 = LECT 1 6 2 7 3 8 4 9 5 10 11;
  107. *
  108. I = 0;
  109. REPETER BLOC1 11;
  110. I = I + 1;
  111. J = EXTR LIST1 I;
  112. K = EXTR LIST2 I;
  113. CL3 = RELA 1 DEPL DIRECTION DIR4 (NOEUD J)
  114. - 1 DEPL DIRECTION DIR3 (NOEUD K);
  115. CLI1 = CLI1 ET CL3;
  116. FIN BLOC1;
  117. *
  118. LIST1 = LECT 27 17 18 19 20 21;
  119. LIST2 = LECT 28 12 13 14 15 16;
  120. *
  121. I = 0;
  122. REPETER BLOC2 6;
  123. I = I + 1;
  124. J = EXTR LIST1 I;
  125. K = EXTR LIST2 I;
  126. CL4 = RELA 1 DEPL DIRECTION DIR4 (NOEUD J)
  127. - 1 UR (NOEUD K);
  128. CLI1 = CLI1 ET CL4;
  129. FIN BLOC2;
  130. *
  131. RIG1 = RIG1 ET CLI1;
  132. *
  133. *-----------------------------------------------------*
  134. * calcul des frequences propres *
  135. *-----------------------------------------------------*
  136. *
  137. * Utilisation de l'operateur VIBR.
  138. *
  139. FRE1 = TABLE;
  140. FRE1.1 = 369.91;
  141. FRE1.2 = 838.03;
  142. FRE1.3 = 1451.2;
  143. FRE1.4 = 2117.0;
  144. FRE1.5 = 2795.8;
  145. *
  146. LIST1 = PROG FRE1.1 FRE1.2 FRE1.3 FRE1.4 FRE1.5;
  147. *
  148. RESUL = VIBR PROC LIST1 RIG1 MAS1;
  149. *
  150. *-----------------------------------------------------*
  151. * extraction des resultats
  152. *-----------------------------------------------------*
  153. *
  154. MESS ' RESULTATS FV42.DGIBI';
  155. MESS ' --------------------';
  156. MESS ' SPHERE EN VIBRATION RADIALE';
  157. *
  158. FRE2 = TABLE; ERG = TABLE;
  159. DEP = TABLE; DEF = TABLE; EVO = TABLE;
  160. *
  161. I = 0;
  162. REPETER BLOC3 5;
  163. *
  164. I = I + 1;
  165. FRE2.I = RESUL . MODES . I . FREQUENCE;
  166. ERG.I = 100 * (ABS ((FRE1.I - FRE2.I) / FRE1.I));
  167. MESS ' MODE ' I;
  168. MESS ' ----------';
  169. MESS ' Frequence propre theorique :' FRE1.I 'Hz';
  170. MESS ' Frequence propre calculee :' FRE2.I 'Hz';
  171. MESS ' Soit un ecart de : ' ERG.I '%';
  172. *
  173. * Trace facultatif des modes propres
  174. *
  175. SI (NEG GRAPH 'N');
  176. DEP.I = RESUL . MODES . I . DEFORMEE_MODALE;
  177. DEF0 = DEFO SUR1 DEP.I 0. NOIR;
  178. DEF.I = DEFO SUR1 DEP.I VERT;
  179. TITR ' Mode propre : Deplacement radial';
  180. TRAC (DEF0 ET DEF.I);
  181. EVO.I = EVOL BLEU CHPO DEP.I UR D23;
  182. DESSIN EVO.I;
  183. FINSI;
  184. *
  185. FIN BLOC3;
  186. *
  187. *-----------------------------------------------------*
  188. * code fonctionnement *
  189. *-----------------------------------------------------*
  190. *
  191. ERGMAX = MAXI (PROG ERG.1 ERG.2 ERG.3 ERG.4 ERG.5);
  192. *
  193. SI (ERGMAX <EG 2.);
  194. ERRE 0;
  195. SINON;
  196. ERRE 5;
  197. FINSI;
  198. *
  199. TEMPS;
  200. *
  201. FIN;
  202.  
  203.  
  204.  
  205.  
  206.  
  207.  
  208.  
  209.  
  210.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales