Exemples de jeux de données Cast3M

************************************************************************
*          Exemple de calcul thermo-mécanique avec des coques          *
*                                                                      *
* On modélise une plaque trouée encastrée sur les bords et soumise à   *
* une élévation de température sur le trou. La dilatation contrariée   *
* induit des contraintes et la flexion de la plaque                    *
************************************************************************
 
 
** Options générales
OPTI 'DIME' 3 'MODE' 'TRID' 'ELEM' 'TRI6' ;
itrac = FAUX ;
ray = 0.1 ;
lon = 1. ;
epa = 0.01 ;
 
** Maillage
p0 = 0. 0. 0. ;
pz = 0. 0. 1. ;
p1 = ray 0. 0. ;
ce = CERC 20 'ROTA' 360. p1 p0 pz 'ELIM' ;
p2 = lon lon 0. ;
p3 = lon (-1. * lon) 0. ;
p4 = -1. * (lon lon 0.) ;
p5 = (-1. * lon) lon 0. ;
ld = DROI 10 p2 p3 ;
lb = DROI 10 p3 p4 ;
lg = DROI 10 p4 p5 ;
lh = DROI 10 p5 p2 ;
co = ld ET lb ET lg ET lh ;
mail = SURF (co ET ce) 'PLAN' ;
 
** Modèles
mot = MODE mail 'THERMIQUE' 'COQ6' ;
mat = MATE mot 'K' 50. 'C' 500. 'RHO' 7800. 'TINI' 0. 'EPAI' epa ;
mom = MODE mail 'MECANIQUE' 'COQ6' ;
mam = MATE mom 'YOUN' 200.E9 'NU' 0.3 'ALPH' 5.E-5 'TREF' 0. 'TALP' 0. 'EPAI' epa ;
 
** Blocages
clt1 = BLOQ 'TINF' 'T' 'TSUP' co ;
clt2 = BLOQ 'TINF' 'T' 'TSUP' ce ;
clm = BLOQ 'DEPL' co ;
 
** Chargement
ft = DEPI clt2 200. ;
ev = EVOL 'MANU' (PROG 0. 2.5E4 5.E4 10.E4) (PROG 0. 1. 0. 0.) ;
cha = CHAR 'TIMP' ft ev ;
 
** Résolution
t                         = TABL ;
t . 'MODELE'              = mot ET mom ;
t . 'CARACTERISTIQUES'    = mat ET mam ;
t . 'BLOCAGES_THERMIQUES' = clt1 ET clt2 ;
t . 'BLOCAGES_MECANIQUES' = clm ;
t . 'CHARGEMENT'          = cha ;
t . 'TEMPS_CALCULES'      = PROG 1.E3 'PAS' 1.E3 10.E4 ;
PASAPAS t ;
 
** Post-traitement
tt = t . 'TEMPS' ;
tp = t . 'TEMPERATURES' ;
td = t . 'DEPLACEMENTS' ;
* 1) tracé de la température sur la configuration déformée à chaque instant
nt = DIME tt ;
REPE bt nt ;
  tpsi = tt . (&bt - 1) ;
  defi = DEFO mail (td . (&bt - 1)) 100. ;
  ti = EXCO 'T' (tp . (&bt - 1)) ;
  titi = CHAI 'Temperatures au temps' ' ' tpsi ;
  SI itrac ;
    TRAC ti mail defi 'TITR' titi ;
  FINSI ;
FIN bt ;
* 2) évolutions temporelles de T et UZ en quelques points
lcoul = MOTS 'DEFA' 'ROUG' 'ORAN' 'JAUN' 'VERT' 'OLIV' 'TURQ' 'BLEU' 'VIOL' ;
ncour = DIME lcoul ;
tvst = VIDE 'EVOLUTION' ;
uvst = VIDE 'EVOLUTION' ;
tleg = TABL ;
tleg . 'TITRE' = TABL ;
REPE bcour ncour ;
  couli = EXTR lcoul &bcour ;
  xi = ray + ((lon - ray) * (((FLOT &bcour) - 1.)) / ((FLOT ncour) - 1.)) ;
  pti = mail POIN 'PROC' (xi 0. 0.) ;
  tvst = tvst ET (EVOL couli 'TEMP' t 'TEMPERATURES' 'T'  pti) ;
  uvst = uvst ET (EVOL couli 'TEMP' t 'DEPLACEMENTS' 'UZ' pti) ;
  tleg . 'TITRE' . &bcour = CHAI 'En x =' xi ;
FIN bcour ;
SI itrac ;
  DESS tvst 'TITR' 'Temperature VS temps' 'LEGE' tleg ;
  DESS uvst 'TITR' 'Deplacement VS temps' 'LEGE' tleg ;
FINSI ;
 
FIN ;