Télécharger la plaquette Cast3M


fr en

Télécharger raff01.dgibi

Retour à la liste

Numérotation des lignes : 

  1. *******************************************************************
  2. *              raff01.dgibi
  3. *******************************************************************
  4. *
  5. * Calcul en mecanique de la rupture avec un maillage raffine par 
  6. * l'opérateur RAFF.
  7. *
  8. * d'une plaque elastique en traction en 2D déformations planes
  9. * avec fissure horizontale 
  10. * test avec des éléments QUA4 QUA6 TRI3 et TRI6
  11. * 
  12. *    ^ ^ ^ ^ ^ ^ ^
  13. *    | | | | | | |
  14. *    -------------    
  15. *   |             |<  
  16. *   |             |   
  17. *   |             |
  18. *   |             |   
  19. *   |             |
  20. *   |             |
  21. *   |             |
  22. *   |             |<
  23. *    ---------====
  24. *    ^       ^
  25. *      Dimentions du quart de plaque:
  26. *        l1= 0.1 m
  27. *        l2 = 0.2 m
  28. *      Longueur de la demi-fissure :
  29. *        a=0.03 m
  30. *    
  31. *création : gg, le 15.03.2017                              
  32. *
  33. * Comparaison des facteurs d'intensite de contraintes simules
  34. * avec ceux obtenu par un calcul sur un maillage convergé 
  35. * ( mailles de 6 E-4 m en pointe de fissure )
  36.  
  37. ********************************************************************
  38. *OPTI DIME 2 ELEM QUA4 MODE PLAN DEFO TRAC PSC FTRAC tailleplaque ;
  39.  
  40. OPTI DIME 2 ELEM QUA4 MODE PLAN DEFO TRAC X;
  41. *---------------------------------------------------
  42. * Option de trace
  43. *graph = vrai;
  44. graph = faux;
  45.  
  46. complet = vrai;
  47. *complet = faux;
  48.  
  49. *----------------------------------------------------*
  50. * Données
  51. *----------------------------------------------------*
  52.  
  53. * Données géométriques 
  54. l1=0.1;
  55. l2=0.2;
  56. *abssice du front de fissure
  57. X0=0.7;
  58. * Données Materiaux
  59. E1= 7.2E10;
  60. nu1= 0.4;
  61. * Donnée de chargement 
  62. pre1=-500;
  63.  
  64. *coefficient de dilatation deformée
  65. XAMP = 1.E7 ;
  66. *Densitée des maillages
  67. DENS1 = 0.0100001 ;
  68. DENS2 = (DENS1/8)*1.0001 ;
  69. *Parametre RAFF Distance maillage fin
  70. *DMIN = l1*0.15;
  71. DMIN = (2**0.5)*dens1;
  72.  
  73.  
  74. *Parametre RAFF Distance maillage large
  75. *DMAX = DMIN+(l1*0.2) ;
  76. DMAX = DMIN+ (2 * DENS1) ;
  77.  
  78.  
  79. * Definition des points
  80.  
  81. P1 = 0. 0. ;
  82. P2 = (l1*X0) (l2*0.) ;
  83. P3 = l1 0. ;
  84. P4 = l1 l2 ;
  85. P5 = 0. l2 ;
  86.  
  87. * Valeur théorique de KI
  88. * (obtenu avec un calcul overkill) DENS=0.005
  89. FIC0SIF = 163.31;
  90. FIC0GTH = 162.34;
  91. *----------------------------------------------------*
  92.  
  93. *----------------------------------------------------*
  94. ERRKI= TABL;
  95. KI=TABL;
  96. LSTERR=TABL;
  97. LSTKI=TABL;
  98. *Boucle sur les types d'éléments
  99. ELE1= TABL;
  100. ELE1.1='QUA4';
  101. si complet;
  102.  ELE1.2='QUA8';
  103.  ELE1.3='TRI3';
  104.  ELE1.4='TRI6';
  105. finsi;
  106.  
  107. I=0;
  108. REPETER ELEMENT1 (dime ELE1) ;
  109.  
  110. I = I+1 ;
  111. OPTI ELEM (ELE1.I);
  112. MESS ELE1.I;
  113.  
  114. ERRKI.I = TABL;
  115. KI.I = TABL;
  116.  
  117. *----------------------------------------------------*
  118. *Definition du maillage grossier
  119. NL11A = ENTI 'PROCH' (l1*X0/DENS1);
  120. NL11B = ENTI 'PROCH' (l1*(1-X0)/DENS1);
  121. NL12 = ENTI 'PROCH' (l2/DENS1);
  122. NL13 = ENTI 'PROCH' (l1/DENS1) ;
  123. L11A = DROITE NL11A P1 P2 ;
  124. L11B = DROITE NL11B P2 P3 ;
  125. L12 = DROITE NL12 P3 P4 ;
  126. L13 = DROITE NL13 P4 P5 ;
  127. L14 = DROITE NL12 P5 P1 ;
  128.  
  129. SURF1 = DALL (L11A ET L11B) L12 L13 L14 ;
  130.  
  131. si (graph);
  132.   TRAC SURF1 TITR 'Surf1' ;
  133. finsi;
  134.  
  135. *Modele
  136. MOD1 = MODE SURF1 MECANIQUE ELASTIQUE ;
  137.  
  138. *Materiau
  139. MAT1 = MATE MOD1 YOUN E1 NU nu1 ;
  140.  
  141. *Conditions aux limites
  142. CL1 = BLOQUE UY L11A ; 
  143. CL2 = BLOQUE UX L12 ;
  144. CLT1 = CL1 ET CL2 ;
  145.  
  146. *Chargement
  147. F1 = PRES 'MASS' MOD1 pre1 . L13 ;
  148. * F1 = DEPI CL3 0.02 ;
  149.  
  150. *Rigidite
  151. RIG0 = RIGI MOD1 MAT1 ;
  152. RIG1 = RIG0 et CLT1 ;
  153.  
  154. *Resolution
  155. RES1 = RESO RIG1 F1 ;
  156.  
  157. si (graph);
  158.  
  159. *Deformee
  160.   DEF0 = DEFO 0. SURF1 RES1 'GRIS';
  161.   DEF1 = DEFO XAMP SURF1 RES1 'BLEU';
  162.  
  163.   TRAC (DEF0 et DEF1) TITR 'Deformee1';
  164. *Deplacement Uy le complet de la lèvre de la fissure
  165.   DEPF1 = EVOL 'ROUG' 'CHPO' RES1 UY L11B ;
  166.   DESS DEPF1 TITR 'Deplacement Uy ';
  167.  
  168. *Contraintes
  169.  
  170.   SIG1 = SIGM MOD1 MAT1 RES1 'LINE' ;
  171.   TRAC 'TITR' 'Contrainte xx force' (EXCO SMXX SIG1) MOD1 ;
  172.  
  173.   TRAC 'TITR' 'Contrainte yy force' (EXCO SMYY SIG1) MOD1 ;
  174.  
  175.   TRAC 'TITR' 'Contrainte xy force' (EXCO SMXY SIG1) MOD1 ;
  176.  
  177.  
  178. *Contrainte normale de traction le long de l'axe horizontal (lig+levre)
  179.   SIGP1 = CHAN 'CHPO' SIG1 MOD1 ;
  180.   SNT1 = EVOL 'ROUG' 'CHPO' SIGP1 SMYY (L11A ET L11B) ;
  181.   DESS SNT1 TITR 'Contrainte normale';
  182. finsi;
  183.  
  184. *Facteur d'intensité de contraintes G_THETA
  185. FIC1 = TABLE ;
  186. FIC1 . 'OBJECTIF' = MOT 'J' ;
  187. FIC1 . 'COUCHE' = ENTI 'PROCH' 1 ;
  188. FIC1 . 'LEVRE_SUPERIEURE' = L11B ;
  189. FIC1 . 'FRONT_FISSURE' = P2 ;
  190. FIC1 . 'SOLUTION_RESO' = RES1 ;
  191. FIC1 . 'MODELE' = MOD1 ;
  192. FIC1 . 'CARACTERISTIQUES' = MAT1 ;
  193. FIC1 . 'CHARGEMENTS_MECANIQUES' = F1 ;
  194. FIC1 . 'BLOCAGES_MECANIQUES' = CLT1 ;
  195. G_THETA FIC1 ;
  196.  
  197. *En contraines planes :
  198. * FIC1GTH= ((FIC . RESULTATS) * (E1))**0.5 ;
  199. *En déformations planes :
  200. FIC1GTH = ((FIC1 . RESULTATS) * (E1/(1-(nu1*nu1))))**0.5 ;
  201. mess 'Facteur Intensité de Contraintes maillage régulier grossier:';
  202. mess FIC1SIF;
  203. mess FIC1GTH;
  204.  
  205. ERRKI.I.1 = ABS((FIC1GTH - FIC0GTH)/FIC0GTH);
  206. KI.I.1 =FIC1GTH;
  207. *----------------------------------------------------*
  208.  
  209. si (complet);
  210. *----------------------------------------------------*
  211. *Definition du maillage fin
  212.   NL21A = ENTI 'PROCH' (l1*X0/DENS2);
  213.   NL21B = ENTI 'PROCH' (l1*(1-X0)/DENS2);
  214.   NL22 = ENTI 'PROCH' (l2/DENS2);
  215.   NL23 = ENTI 'PROCH' (l1/DENS2) ;
  216.   L21A = DROITE NL21A P1 P2 ;
  217.   L21B = DROITE NL21B P2 P3 ;
  218.   L22 = DROITE NL22 P3 P4 ;
  219.   L23 = DROITE NL23 P4 P5 ;
  220.   L24 = DROITE NL22 P5 P1 ;
  221.  
  222.   SURF2 = DALL (L21A ET L21B) L22 L23 L24 ;
  223.  
  224.   si (graph);
  225.     TRAC SURF2 TITR 'Surf2';
  226.   finsi;
  227. *Modele
  228.   MOD2 = MODE SURF2 MECANIQUE ELASTIQUE ;
  229.  
  230. *Materiau
  231.   MAT2 = MATE MOD2 YOUN E1 NU nu1 ;
  232.  
  233. *Conditions aux limites
  234.   CL3 = BLOQUE UY L21A ; 
  235.   CL4 = BLOQUE UX L22 ;
  236.   CLT2 = CL3 ET CL4 ;
  237.  
  238. *Chargement
  239.   F2 = PRES 'MASS' MOD2 pre1 . L23 ;
  240. * F2 = DEPI CL3 0.02 ;
  241.  
  242. *Rigidite
  243.   RIG0 = RIGI MOD2 MAT2 ;
  244.   RIG2 = RIG0 et CLT2 ;
  245.  
  246. *Resolution
  247.   RES2 = RESO RIG2 F2 ;
  248.  
  249.   si (graph);
  250. *Deformee
  251.     DEF20 = DEFO 0. SURF2 RES2 'GRIS';
  252.     DEF21 = DEFO XAMP SURF2 RES2 'BLEU';
  253.     TRAC (DEF20 et DEF21) TITR 'Deformee2';
  254.  
  255. *Deplacement Uy le long de la lèvre de la fissure
  256.     DEPF2 = EVOL 'ROUG' 'CHPO' RES2 UY L21B ;
  257.     DESS DEPF2 TITR 'Deplacement Uy ';
  258.  
  259. *Contraintes
  260.     SIG2 = SIGM MOD2 MAT2 RES2 'LINE' ;
  261.     TRAC 'TITR' 'Contrainte xx force' (EXCO SMXX SIG2) MOD2 ;
  262.  
  263.     TRAC 'TITR' 'Contrainte yy force' (EXCO SMYY SIG2) MOD2 ;
  264.  
  265.     TRAC 'TITR' 'Contrainte xy force' (EXCO SMXY SIG2) MOD2 ;
  266.  
  267.  
  268. *Contrainte normale de traction le long de l'axe horizontal (lig+levre)
  269.     SIGP2 = CHAN 'CHPO' SIG1 MOD1 ;
  270.     SNT2 = EVOL 'ROUG' 'CHPO' SIGP2 SMYY (L21A ET L21B) ;
  271.     DESS SNT2 TITR 'Contrainte normale';
  272.   finsi;
  273.  
  274. *Facteur d'intensité de contraintes G_THETA
  275.   FIC2 = TABLE ;
  276.   FIC2 . 'OBJECTIF' = MOT 'J' ;
  277.   FIC2 . 'COUCHE' = ENTI 'PROCH' 8 ;
  278.   FIC2 . 'LEVRE_SUPERIEURE' = L21B ;
  279.   FIC2 . 'FRONT_FISSURE' = P2 ;
  280.   FIC2 . 'SOLUTION_RESO' = RES2 ;
  281.   FIC2 . 'MODELE' = MOD2 ;
  282.   FIC2 . 'CARACTERISTIQUES' = MAT2 ;
  283.   FIC2 . 'CHARGEMENTS_MECANIQUES' = F2 ;
  284.   FIC2 . 'BLOCAGES_MECANIQUES' = CLT2 ;
  285.   G_THETA FIC2 ;
  286.  
  287. *En contraines planes :
  288. *  FIC2GTH= ((FIC . RESULTATS) * (E1))**0.5 ;
  289. *En déformations planes :
  290.   FIC2GTH = ((FIC2 . RESULTATS) * (E1/(1-(nu1*nu1))))**0.5 ;
  291.   mess 'Facteur Intensité de Contraintes maillage régulier raffiné :';
  292.   mess FIC2SIF;
  293.   mess FIC2GTH;
  294.   ERRKI.I.2 = ABS((FIC2GTH - FIC0GTH)/FIC0GTH);
  295.   KI.I.2 = FIC2GTH;
  296. *----------------------------------------------------*
  297. finsi;
  298.  
  299. *----------------------------------------------------*
  300. *Definition du maillage avec RAFF
  301.  
  302. *Distance à la pointe de fissure
  303. X Y = COOR SURF1 ;
  304. DPF = (((X-(l1*X0))*(X-(l1*X0)))+(Y*Y))**0.5 ;
  305.  
  306. * Raff maillage
  307. AFF = (((DENS1-DENS2)*(DPF-DMIN))/(DMAX-DMIN)) + DENS2 ;
  308. DENS3 = BORN AFF 'SCAL' 'COMPRIS' (DENS1*1.001) (DENS2*1.001) ;
  309. SURF3 = RAFF SURF1 DENS3 ;
  310.  
  311. si (graph);
  312.   TRAC SURF3 TITR 'Surf3';
  313. finsi;
  314.  
  315. *opti donn 5;
  316.  
  317. MAILL = SURF3 ;
  318.  
  319. *Modele
  320. MOD3 = MODE MAILL MECANIQUE ELASTIQUE ;
  321.  
  322. *Materiau
  323. MAT3 = MATE MOD3 YOUN E1 NU nu1 ;
  324.  
  325. *Contours du maillage pour CL et chargement
  326. CT = CONT MAILL ;
  327. XC YC = COOR CT ;
  328. PTCL0 = YC POIN 'MINI' ;
  329. XC0 YC0 = COOR PTCL0 ;
  330. PTCL1 = XC0 POIN 'INFERIEUR' (l1*X0 + 1E-10) ;
  331. SEGCL1 = CT ELEM 'APPUYE' PTCL1 ;
  332.  
  333. PTCL2 = XC POIN 'SUPERIEUR' (l1- 1E-10) ;
  334.  
  335. PTCL3 = YC POIN 'MAXI' ;
  336. SEGCL3 = CT ELEM 'APPUYE' PTCL3 ;
  337.  
  338. *Fissure
  339. PTFISS = (DIFF PTCL0 PTCL1) ET P2 ;
  340. CT = CONT MAILL ;
  341. LFISS = CT ELEM 'APPUYE' PTFISS ;
  342.  
  343. *Conditions aux limites
  344. CL5 = BLOQUE UY PTCL1 ; 
  345. CL6 = BLOQUE UX PTCL2 ;
  346. CLT3 = CL5 ET CL6 ;
  347.  
  348. *Chargement
  349. F3 = PRES 'MASS' MOD3 pre1 SEGCL3 ;
  350.  
  351. *Rigidite
  352. RIG0 = RIGI MOD3 MAT3 ;
  353. REL0 = RELA MOD3 ;
  354.  
  355.  
  356. RIG3 = RIG0 et REL0 et CLT3 ;
  357.  
  358. list rig3;
  359.  
  360. * opti donn 5;
  361. *Resolution
  362. RES3 = RESO RIG3 F3 ;
  363.  
  364. si (graph);
  365. *Deformee
  366.   DEF30 = DEFO 0. SURF3 RES3 'GRIS';
  367.   DEF31 = DEFO XAMP SURF3 RES3 'BLEU';
  368.   TRAC (DEF30 et DEF31) TITR 'Deformee3';
  369.  
  370. *Deplacement Uy le long de la lèvre de la fissure
  371.   DEPF3 = EVOL 'ROUG' 'CHPO' RES3 UY LFISS ;
  372.   DESS DEPF3 TITR 'Deplacement Uy ';
  373.  
  374. *Contraintes
  375.   SIG3 = SIGM MOD3 MAT3 RES3 'LINE' ;
  376.   TRAC 'TITR' 'Contrainte xx force' (EXCO SMXX SIG3) MOD3 ;
  377.  
  378.   TRAC 'TITR' 'Contrainte yy force' (EXCO SMYY SIG3) MOD3 ;
  379.  
  380.   TRAC 'TITR' 'Contrainte xy force' (EXCO SMXY SIG3) MOD3 ;
  381.  
  382.  
  383. *Contrainte normale de traction le long de l'axe horizontal (lig+levre)
  384.   SIGP3 = CHAN 'CHPO' SIG3 MOD3 ;
  385.   SNT3 = EVOL 'ROUG' 'CHPO' SIGP3 SMYY SEGCL1 ;
  386.   DESS SNT3 TITR 'Contrainte normale';
  387. finsi;
  388.  
  389. *Facteur d'intensité de contraintes G_THETA
  390. FIC3 = TABLE ;
  391. FIC3 . 'OBJECTIF' = MOT 'J' ;
  392. FIC3 . 'COUCHE' = ENTI 'PROCH' 8 ;
  393. FIC3 . 'LEVRE_SUPERIEURE' = LFISS ;
  394. FIC3 . 'FRONT_FISSURE' = P2 ;
  395. FIC3 . 'SOLUTION_RESO' = RES3 ;
  396. FIC3 . 'MODELE' = MOD3 ;
  397. FIC3 . 'CARACTERISTIQUES' = MAT3 ;
  398. FIC3 . 'CHARGEMENTS_MECANIQUES' = F3 ;
  399. FIC3 . 'BLOCAGES_MECANIQUES' = CLT3 ;
  400. G_THETA FIC3 ;
  401.  
  402. *En contraines planes :
  403. * FIC2GTH= ((FIC . RESULTATS) * (E1))**0.5 ;
  404.  
  405. *En déformations planes :
  406. FIC3GTH = ((FIC3 . RESULTATS) * (E1/(1-(nu1*nu1))))**0.5 ;
  407. mess 'Facteur Intensité de Contraintes maillage régulier raffiné :';
  408. mess FIC3SIF;
  409. mess FIC3GTH;
  410. ERRKI.I.3 = ABS((FIC3GTH - FIC0GTH)/FIC0GTH);
  411. KI.I.3 = FIC3GTH;
  412.  
  413. si (complet);
  414.   LSTERR.I = PROG ERRKI.I.1 ERRKI.I.2 ERRKI.I.3 ;
  415.   LSTKI.I = PROG KI.I.1 KI.I.2 KI.I.3 ;
  416. sinon;
  417.   LSTERR.I = PROG ERRKI.I.1 ERRKI.I.3 ;
  418.   LSTKI.I = PROG KI.I.1 KI.I.3 ;
  419. finsi;
  420.  
  421. SI  (ERRKI.I.3 < (3.0E-2));
  422.   'MESS' ' ----------------------' ;
  423.   'MESS' '  SUCCES DU CAS-TEST !' ;
  424.   'MESS' ' ----------------------' ;
  425.   Erre 0;
  426. Sinon;
  427.   'MESS' ' ---------------------' ;
  428.   'MESS' '  ECHEC DU CAS-TEST !' ;
  429.   'MESS' ' ---------------------' ;
  430.   Erre 5;
  431. finsi;
  432. *opti donne 5;
  433.  
  434. FIN ELEMENT1;
  435.  
  436. si (graph);
  437.   EVOLERR1 = EVOL 'MANU' 'Erreur' LSTERR.1 'Erreur' LSTERR.2;
  438.  
  439.   EVOLERR2 = EVOL 'MANU' 'Erreur' LSTERR.3 'Erreur' LSTERR.4 ;
  440.  
  441.   @EXCEL1 EVOLERR1 'ERREURS_QUA' ;
  442.   @EXCEL1 EVOLERR2 'ERREURS_TRI' ;
  443.   EVOLKI1 = EVOL 'MANU' 'Erreur' LSTKI.1 'Erreur' LSTKI.2;
  444.  
  445.   EVOLKI2 = EVOL 'MANU' 'Erreur' LSTKI.3 'Erreur' LSTKI.4 ;
  446.  
  447.   @EXCEL1 EVOLKI1 'KI_QUA' ;
  448.   @EXCEL1 EVOLKI2 'KI_TRI' ;
  449. finsi;
  450.  
  451. FIN ;
  452.  
  453.  
  454.  
  455.  
  456.  
  457.  
  458.  
  459.  
  460.  
  461.  
  462.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales