Télécharger orth6.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : orth6.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * CAS TEST DU 91/06/13 PROVENANCE : TEST
  5. SAUT PAGE;
  6.  
  7. *****************************************************************
  8. * TEST ORTH6 *
  9. * PLAQUE CARREE ORTHOTROPE ENCASTREE *
  10. * *
  11. * Test V.P.C.S. numero SSLS33/90 *
  12. * Groupe : Statique lineaire *
  13. * Structure assemblee *
  14. * *
  15. *****************************************************************
  16. *
  17. OPTION ECHO 0;
  18. *
  19. OPTION DIME 2 ELEM QUA4;
  20. *
  21. GRAPH = 'N';
  22. * GRAPH = 'O';
  23.  
  24. SAUT PAGE;
  25. SI (NEG GRAPH 'N') ;
  26. OPTI ECHO 1 ;
  27. OPTI TRAC PSC ;
  28. SINO ;
  29. OPTI ECHO 0 ;
  30. FINSI ;
  31.  
  32. *----------------------------------------------------------------*
  33. * geometrie : maillage *
  34. *----------------------------------------------------------------*
  35. *
  36. PA = 0.5 0.5;
  37. PB = -0.5 0.5;
  38. PC = -0.5 -0.5;
  39. PD = 0.5 -0.5;
  40. PE = 0. 0.;
  41. *
  42. D1 = PA DROIT 10 PB;
  43. D2 = PB DROIT 10 PC;
  44. D3 = PC DROIT 10 PD;
  45. D4 = PD DROIT 10 PA;
  46. *
  47. SUR1 = DALLAGE D1 D2 D3 D4 PLAN;
  48. SUR = SUR1 ET PE;
  49. *
  50. ELIM SUR 0.001;
  51. *
  52. SI (NEG GRAPH 'N');
  53. TITRE 'ORTH6 : PLAQUE CARREE ORTHOTROPE';
  54. TRACE SUR 'QUAL';
  55. FINSI ;
  56. *
  57. NBNOSUR = NBNO SUR1;
  58. NBELSUR = NBEL SUR1;
  59. *
  60. *----------------------------------------------------------------*
  61. * calcul de la rigidite *
  62. *----------------------------------------------------------------*
  63. *
  64. MOD = MODE SUR1 MECANIQUE ELASTIQUE ORTHOTROPE QUA4;
  65. *
  66. DIR1 = (COS 30.) (SIN 30.);
  67. MAT = MATE MOD DIRE DIR1 YG1 2.5737E10 YG2 7.377E9 YG3 7.377E9
  68. NU12 0.31 NU13 0.31 NU23 0.31 G12 2.319E9;
  69.  
  70. * verification graphique de l'orientation :
  71. * 2D massif => 2 vecteurs : V1 et V2
  72. v12 = VLOC MOD MAT;
  73. ve12 = VECT v12 MOD (mots 'V1X' 'V1Y' 'V2X' 'V2Y') 0.02
  74. (mots 'AZUR' 'BRON');
  75. SI (NEG GRAPH 'N');
  76. TITRE 'ORTH6 : V1(AZUR) V2 (JAUNE)';
  77. TRACE ve12 SUR ;
  78. FINSI ;
  79.  
  80. RI = RIGI MOD MAT ;
  81. *
  82. *----------------------------------------------------------------*
  83. * conditions aux limites *
  84. *----------------------------------------------------------------*
  85. *
  86. CL = BLOQUE DEPL ROTA D2;
  87. RIG = RI ET CL;
  88. *
  89. *----------------------------------------------------------------*
  90. * chargement *
  91. *----------------------------------------------------------------*
  92. *
  93. FTOT = 1.E6;
  94. NBNOD4 = NBNO D4;
  95. F5 = FTOT / ((2 * NBNOD4) - 2);
  96. F50 = F5 0.;
  97. I = 1;
  98. NBI = NBNOD4 - 1;
  99. CHA = FORC (0. 0.) (D4 POIN 1);
  100. REPETER BLOC1 NBI;
  101. CHA1 = FORC F50 (D4 POIN I);
  102. CHA2 = FORC F50 (D4 POIN (I+1));
  103. CHA = CHA ET CHA1 ET CHA2;
  104. I = I + 1;
  105. FIN BLOC1;
  106. *
  107. *----------------------------------------------------------------*
  108. * resolution : calcul elastique *
  109. *----------------------------------------------------------------*
  110. *
  111. * Champs de deplacements
  112. *
  113. DE = RESO RIG CHA;
  114. *
  115. * Contraintes : interpolation aux noeuds du maillage
  116. *
  117. CHAM1 = SIGM MOD MAT DE;
  118. CHAM2 = CHAN NOEUD MOD CHAM1;
  119. CHPO1 = CHAN CHPO MOD CHAM2;
  120. *
  121. * Trace facultatif du champ de déplacement.
  122. *
  123. SI (NEG GRAPH 'N');
  124. TITR 'ORTH6 : Deplacements UX';
  125. TRAC CACH SUR1 (EXCO DE UX);
  126. TITR 'ORTH6 : Deplacements UY';
  127. TRAC CACH SUR1 (EXCO DE UY);
  128. FINSI;
  129. *
  130. *----------------------------------------------------------------*
  131. * extraction des resultats *
  132. *----------------------------------------------------------------*
  133. *
  134. UA = EXTR DE UX PA; UA1 = 1.10E-4;
  135. ERGUA = 100 * (ABS ((UA1 - UA) / UA1));
  136. *
  137. UD = EXTR DE UX PD; UD1 = 9.95E-5;
  138. ERGUD = 100 * (ABS ((UD1 - UD) / UD1));
  139. *
  140. UE = EXTR DE UX PE; UE1 = 4.77E-5;
  141. ERGUE = 100 * (ABS ((UE1 - UE) / UE1));
  142. *
  143. VA = EXTR DE UY PA; VA1 = -1.31E-4;
  144. ERGVA = 100 * (ABS ((VA1 - VA) / VA1));
  145. *
  146. VD = EXTR DE UY PD; VD1 = -7.17E-5;
  147. ERGVD = 100 * (ABS ((VD1 - VD) / VD1));
  148. *
  149. VE = EXTR DE UY PE; VE1 = -4.98E-5;
  150. ERGVE = 100 * (ABS ((VE1 - VE) / VE1));
  151. *
  152. SMXXE = EXTR CHPO1 SMXX PE;
  153. SMXXE = SMXXE / 1.E6;
  154. SMXXE1 = 1.02;
  155. ERGXX = 100 * (ABS ((SMXXE1 - SMXXE) / SMXXE1));
  156. *
  157. SMYYE = EXTR CHPO1 SMYY PE;
  158. SMYYE = SMYYE / 1.E6;
  159. SMXYE = EXTR CHPO1 SMXY PE;
  160. SMXYE = SMXYE / 1.E6;
  161. *
  162. *----------------------------------------------------------------*
  163. * affichage des resultats *
  164. *----------------------------------------------------------------*
  165. *
  166. * Trace facultatif de la deformees
  167. *
  168. SI (NEG GRAPH 'N');
  169. TITR ' PLAQUE CARREE ORTHOTROPE : DEFORMEE .';
  170. AMPVEC = 1E-6;
  171. VECT1= VECT CHA AMPVEC FX FY ROUGE;
  172. REA2 = REAC DE RIG;
  173. VECT2= VECT REA2 1e-6 FX FY BLEU;
  174. DEF0 = DEFO SUR DE 0.;
  175. DEF1 = DEFO SUR DE 30. (VECT1 ET VECT2) VERT;
  176. TRAC (DEF0 ET DEF1);
  177. FINSI;
  178. *
  179. MESS 'Resultats : test orth6.dgibi';
  180. MESS '----------------------------';
  181. MESS ' Deplacements';
  182. MESS ' ------------';
  183. *
  184. MESS ' Point A :';
  185. MESS ' ---------';
  186. MESS ' Deplacement theorique horizontal : ' UA1 'm';
  187. MESS ' Deplacement calcule horizontal : ' UA 'm';
  188. MESS ' Soit un ecart de : ' ERGUA '%';
  189. MESS ' Deplacement theorique vertical : ' VA1 'm';
  190. MESS ' Deplacement calcule vertical : ' VA 'm';
  191. MESS ' Soit un ecart de : ' ERGVA '%';
  192. *
  193. MESS ' Point D :';
  194. MESS ' ---------';
  195. MESS ' Deplacement theorique horizontal : ' UD1 'm';
  196. MESS ' Deplacement calcule horizontal : ' UD 'm';
  197. MESS ' Soit un ecart de : ' ERGUD '%';
  198. MESS ' Deplacement theorique vertical : ' VD1 'm';
  199. MESS ' Deplacement calcule vertical : ' VD 'm';
  200. MESS ' Soit un ecart de : ' ERGVD '%';
  201. *
  202. MESS ' Point E :';
  203. MESS ' ---------';
  204. MESS ' Deplacement theorique horizontal : ' UE1 'm';
  205. MESS ' Deplacement calcule horizontal : ' UE 'm';
  206. MESS ' Soit un ecart de : ' ERGUE '%';
  207. MESS ' Deplacement theorique vertical : ' VE1 'm';
  208. MESS ' Deplacement calcule vertical : ' VE 'm';
  209. MESS ' Soit un ecart de : ' ERGVE '%';
  210. *
  211. MESS ' Contraintes au point E';
  212. MESS ' ----------------------';
  213. *
  214. MESS ' Contrainte theorique horizontale : ' SMXXE1 'MPa';
  215. MESS ' Contrainte calculee horizontale : ' SMXXE 'MPa';
  216. MESS ' Soit un ecart de : ' ERGXX '%';
  217. MESS ' Contrainte calculee verticale : ' SMYYE 'MPa';
  218. MESS ' Contrainte calculee de cisaillement : ' SMXYE 'MPa';
  219. *
  220. MESS ' Maillage : ';
  221. MESS ' ---------- ';
  222. MESS ' Nombre de noeuds : ' NBNOSUR;
  223. MESS ' Nombre d elements : ' NBELSUR 'QUA4';
  224. *----------------------------------------------------------------*
  225. * code fonctionnement *
  226. *----------------------------------------------------------------*
  227. *
  228. ERGMAX = MAXI ( PROG ERGUA ERGUD ERGUE ERGVA ERGVD ERGVD ERGXX);
  229. *
  230. * Il y a erreur si un des pourcentages ERG* est suprieur 1.%
  231. *
  232. SI (ERGMAX <EG 1.0);
  233. ERRE 0 ;
  234. SINO;
  235. ERRE 5 ;
  236. FINSI;
  237. *
  238. TEMPS;
  239.  
  240. FIN;
  241.  
  242.  
  243.  
  244.  
  245.  
  246.  
  247.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales