Télécharger gdep5.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : gdep5.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Description :
  5. * Traction simple en deplacement impose.
  6. * Eprouvette en forme de pave droit, 3 elements
  7. * Calcul lineaire elastique en Grands deplacements,
  8. * option Lagrangien Reactualise.
  9. *
  10. * Validation :
  11. * La courbe contrainte-deformation issue du calcul doit etre egale a
  12. * celle fourunie dans les caracteristiques du modele.
  13. *
  14. ************************************************************************
  15.  
  16. ** Options generales
  17. OPTI 'DIME' 3 'ELEM' 'CUB8' ;
  18.  
  19. * Mettre igraph a VRAI pour visualiser
  20. igraph = faux ;
  21.  
  22.  
  23. ** Courbe de traction conventionnelle
  24. ym1 = 210.e9 ;
  25. nu1 = 0.3 ;
  26. ht1 = 1.e9 ;
  27. lec = PROG 0. 2.e-3 0.2 ;
  28. lsc = prog 0. (ym1*2.e-3) ((0.2-2.e-3)*ht1+(ym1*2.e-3)) ;
  29. cc = EVOL 'TURQ' 'MANU' lec lsc ;
  30.  
  31. ** Courbe de traction rationnelle
  32. ler = LOG (1. + lec) ;
  33. lsr = lsc * (1 + lec) ;
  34. cr = EVOL 'VERT' 'MANU' ler lsr ;
  35.  
  36. si igraph ;
  37. tl = TABL ;
  38. tl . 'TITRE' = TABL ;
  39. tl . 'TITRE' . 1 = 'Courbe conventionnelle ' ;
  40. tl . 'TITRE' . 2 = 'Courbe rationnelle ' ;
  41. tl . 1 = mot 'MARQ CARR TIRR' ;
  42. tl . 2 = mot 'MARQ TRIA TIRR' ;
  43. dess (cc et cr) lege tl titr
  44. ' Courbes traction conventionnelle et rationnelle' ;
  45. fins ;
  46.  
  47.  
  48. ** Maillage
  49. p1 = 0. 0. 0. ;
  50. p2 = 1. 0. 0. ;
  51. l12 = DROI 1 p1 p2 ;
  52. s1 = l12 TRAN 1 (0. 1. 0.) ;
  53. v1 = s1 VOLU 'TRAN' 3 (0. 0. 3.) ;
  54. s2 = v1 FACE 2 ;
  55.  
  56. si igraph ;
  57. trac qual V1 titr
  58. ' Traction simple : deplacement bloque-impose sur S1-S2 ' ;
  59. fins ;
  60.  
  61.  
  62. ** Modele et materiau (plasticite isotrope avc courbe de traction)
  63. yor = (EXTR lsr 2) / (EXTR ler 2) ;
  64. mo1 = MODE v1 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' 'ISOTROPE' ;
  65. ma1 = MATE mo1 'YOUN' yor 'NU' 0.3 'TRAC' cr ;
  66.  
  67.  
  68. ** Blocages et chargement (deplacement UZ de la face sup.)
  69. bl1 = BLOQ 'UZ' s2 ;
  70. bl2 = (BLOQ 'UZ' s1) ET (BLOQ 'UX' 'UY' p1) ET (BLOQ 'UY' p2) ;
  71. bl = bl1 ET bl2 ;
  72. ev1 = EVOL 'MANU' (PROG 0. 1.) (PROG 0. 1.) ;
  73. * Avec un deplacement de 3., on a un dL/L de 100 % au temps 1
  74. f1 = DEPI bl1 3. ;
  75. cha = CHAR 'DIMP' f1 ev1 ;
  76.  
  77.  
  78. ** Resolution : lagrangien reactualise avec materiau courbe rationnelle
  79. t1 = TABL 'PASAPAS' ;
  80. t1 . 'MODELE' = mo1 ;
  81. t1 . 'CARACTERISTIQUES' = ma1 ;
  82. t1 . 'BLOCAGES_MECANIQUES' = bl ;
  83. t1 . 'CHARGEMENT' = cha ;
  84. t1 . 'MES_SAUVEGARDES' = TABL ;
  85. t1 . 'MES_SAUVEGARDES' . 'DEFTO' = VRAI ;
  86. t1 . 'GRANDS_DEPLACEMENTS' = VRAI ;
  87. t1 . 'LAGRANGIEN' = MOT 'REACTUALISE' ;
  88. t1 . 'TEMPS_CALCULES' = PROG 0. pas 2.e-3 0.2 ;
  89. PASAPAS t1 ;
  90.  
  91.  
  92. ** Post traitement (courbe contrainte / deformation)
  93. * On reconstruit la courbe Svmis Vs. Eeq et F(U) :
  94. ntps1 = dime t1.temps - 1 ;
  95. leeq1 = prog 0 ;
  96. lsvm1 = prog 0 ;
  97. luz1 = prog 0 ;
  98. lfz1 = prog 0 ;
  99. repe bp1 ntps1 ;
  100. sigi1 = t1.contraintes.&bp1 ;
  101. epsi1 = elas mo1 ma1 sigi1 ;
  102. eeqi1 = t1.variables_internes.&bp1 exco epse epzz ;
  103. eeqi1 = eeqi1 + epsi1 ;
  104. leeq1 = leeq1 et (prog (maxi abs eeqi1)) ;
  105. lsvm1 = lsvm1 et (prog (maxi abs (vmis mo1 sigi1))) ;
  106. fzi1 = (((t1.reactions.&bp1 redu s2) resu) exco fz fz) maxi abs ;
  107. lfz1 = lfz1 et (prog fzi1) ;
  108. uzi1 = (t1.deplacements.&bp1 redu s2 exco uz) maxi abs ;
  109. luz1 = luz1 et (prog uzi1) ;
  110. fin bp1 ;
  111. evr = EVOL 'ROSE' 'MANU' leeq1 lsvm1 ;
  112.  
  113. * On construit la courbe rationnelle a partir de la reponse F(U)
  114. lepzz1 = luz1 / (mesu V1 / (mesu S1)) ;
  115. lun1 = prog (dime lepzz1)*1. ;
  116. lepzz1 = log (lun1 + lepzz1) ;
  117. lfz1 = lfz1 * (lun1 + lepzz1) / (mesu S1) ;
  118. evr2 = EVOL 'ORAN' 'MANU' lepzz1 lfz1 ;
  119.  
  120. si igraph ;
  121. tl = TABL ;
  122. tl . 'TITRE' = TABL ;
  123. tl . 'TITRE' . 1 = 'Courbe fournie ' ;
  124. tl . 'TITRE' . 2 = 'Szz(Ezz) PASAPAS ' ;
  125. tl . 'TITRE' . 3 = 'Szz(Ezz) de F(U) ' ;
  126. tl . 1 = mot 'TIRR MARQ TRIA' ;
  127. tl . 2 = mot 'TIRL' ;
  128. tl . 3 = mot 'TIRC' ;
  129. DESS (cr ET evr et evr2) 'LEGE' tl
  130. titr ' Comparaison courbes calculees-fournie ' ;
  131. fins ;
  132.  
  133. ** Validation :
  134. * Erreur sur la contrainte :
  135. lepc1 = extr evr absc ;
  136. lsmc1 = extr evr ordo ;
  137. lsmr1 = ipol cr lepc1 ;
  138. err1 = maxi abs (lsmc1 - lsmr1) / (maxi abs lsmr1) ;
  139. *
  140. * Erreur sur l'integrale sous la courbe :
  141. evrr1 = evol manu lepc1 lsmr1 ;
  142. err2 = intg (evrr1 - evr) / (intg cr) maxi abs ;
  143. err0 = prog err1 err2 maxi ;
  144.  
  145.  
  146. ** Message / Sortie en erreur :
  147. opti echo 0 ;
  148. mess ' ' ;
  149. mess ' RESULTATS ' ;
  150. mess ' --------- ' ;
  151. mess ' *** Erreur relative max. sur la contrainte : ' (100.* err1) ' %';
  152. mess ' *** Erreur relative max. sur l energie : ' (100.* err2) ' %';
  153. mess ' ' ;
  154. opti echo 1 ;
  155. *
  156. si (err0 > 1.e-2) ;
  157. opti echo 0 ;
  158. mess ' ' ;
  159. mess ' > TEST ECHOUE :( ' ;
  160. mess ' ' ;
  161. opti echo 1 ;
  162. erre 5 ;
  163. sino ;
  164. opti echo 0 ;
  165. mess ' ' ;
  166. mess ' > TEST REUSSI :) ' ;
  167. mess ' ' ;
  168. opti echo 1 ;
  169. fins ;
  170. *
  171. FIN ;
  172.  
  173.  
  174.  
  175.  
  176.  
  177.  
  178.  
  179.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales