Télécharger la plaquette Cast3M


fr en

Télécharger formation_pasapas_2_initial.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : formation_pasapas_2_initial.dgibi
  2. ************************************************************************
  3. *              FORMATION AVANCEE SUR LA PROCEDURE PASAPAS              *
  4. *                                                                      *
  5. * Rupture d'une plaque trouee en traction                              *
  6. * Comportement elastique lineaire                                      *
  7. *                                                                      *
  8. * Ce fichier constitue la mise donnee initiale du probleme et realise  *
  9. * - le maillage                                                        *
  10. * - la definition du modele et des parametres materiaux                *
  11. * - la definition du chargement                                        *
  12. * - la resolution avec PASAPAS                                         *
  13. * - le post traitement (contraintes, courbe force/deplacement)         *
  14. *                                                                      *
  15. ************************************************************************
  16.  
  17.  
  18. ** Options generales
  19. OPTI 'DIME' 2 'ELEM' 'QUA8' 'MODE' 'PLAN' 'DEFO' 'ECHO' 0 ;
  20. ITRAC = FAUX ;
  21.  
  22.  
  23. ** Parametres geometriques
  24. L1 = 1. ;
  25. R1 = 0.15 ;
  26.  
  27.  
  28. ** Maillage
  29. DENS1 = R1 / 15. ;
  30. DENS2 = L1 / 15. ;
  31. P0 = 0. 0. ;
  32. P1 = R1 0. ;
  33. P2 = 0. R1 ;
  34. P3 = L1 0. ;
  35. P4 = L1 L1 ;
  36. P5 = 0. L1 ;
  37. CER = CERC 20 P1 P0 P2 ;
  38. LID = DROI 10 P3 P4 ;
  39. LIH = DROI 10 P4 P5 ;
  40. S1 = REGL CER (LID ET LIH) 'DINI' DENS1 'DFIN' DENS2 ;
  41. LIG = S1 COTE 2 ;
  42. LIB = S1 COTE 4 ;
  43. CS1 = CONT S1 ;
  44.  
  45.  
  46. ** Modele et materiau
  47. MO = MODE S1 'MECANIQUE' 'ELASTIQUE' ;
  48. MA = MATE MO 'YOUN' 200.E9 'NU' 0.3 ;
  49.  
  50.  
  51. ** Blocages mecaniques
  52. BL1 = BLOQ 'UY' LIB ;
  53. BL2 = BLOQ 'UX' LIG ;
  54. BL3 = BLOQ 'UY' LIH ;
  55. BL  = BL1 ET BL2 ET BL3 ;
  56.  
  57.  
  58. ** Chargement en deplacement impose
  59. UMAX = L1 / 20. ;
  60. F1 = DEPI BL3 UMAX ;
  61. EV1 = EVOL 'MANU' (PROG 0. 1.) (PROG 0. 1.) ;
  62. CH = CHAR 'DIMP' F1 EV1 ;
  63.  
  64.  
  65. ** Resolution
  66. TAB1                         = TABL ;
  67. TAB1 . 'MODELE'              = MO ;
  68. TAB1 . 'CARACTERISTIQUES'    = MA ;
  69. TAB1 . 'BLOCAGES_MECANIQUES' = BL ;
  70. TAB1 . 'CHARGEMENT'          = CH ;
  71. TAB1 . 'TEMPS_CALCULES'      = PROG 0.1 'PAS' 0.1 1. ;
  72. TAB1 . 'GRANDS_DEPLACEMENTS' = VRAI ;
  73. PASAPAS TAB1 ;
  74.  
  75.  
  76. ** Post-traitement (deformees, contraintes, reaction aux appuis, courbe force/deplacement)
  77. TT = TAB1 . 'TEMPS' ;
  78. TU = TAB1 . 'DEPLACEMENTS' ;
  79. TS = TAB1 . 'CONTRAINTES' ;
  80. TR = TAB1 . 'REACTIONS' ;
  81. LISO = PROG 0. 'PAS' 4.E9 4.E10 ;
  82. DEF0 = DEFO CS1 (TU . 0) 0. 'ROUG' ;
  83. LTPS = PROG 0. ;
  84. LDEP = PROG 0. ;
  85. LFOR = PROG 0. ;
  86. NT1 = (DIME TT) - 1 ;
  87. REPE B1 NT1 ;
  88. * instant
  89.   TPS1 = TT . &B1 ;
  90.   LTPS = LTPS ET TPS1 ;
  91. * contraintes
  92.   SG1 = TS . &B1 ;
  93.   SP1 = EXCO 'SI11' (PRIN SG1 MO) ;
  94. * deplacements
  95.   U1 = TU . &B1 ;
  96.   UY1 = EXTR U1 'UY' P5 ;
  97.   LDEP = LDEP ET UY1 ;
  98. * reactions
  99.   R1 = TR . &B1 ;
  100.   VEC1 = VECT R1 5.E-10 'FORC' 'ROSE' ;
  101.   RES1 = MAXI 'ABS' (RESU (REDU R1 LIB)) ;
  102.   LFOR = LFOR ET RES1 ;
  103. * deformees
  104.   DEF1 = DEFO S1 U1 1. VEC1 SP1 MO ;
  105. * traces
  106.   TIT1 = CHAI 'Contraintes au temps ' TPS1 ;
  107.   SI ITRAC ;
  108.     TRAC (DEF1 ET DEF0) 'TITR' TIT1 LISO ;
  109.   FINSI ;
  110. FIN B1 ;
  111. * courbe force vs deplacement
  112. EVFC = EVOL 'MANU' 'Deplacement' LDEP 'Force' LFOR ;
  113. SI ITRAC ;
  114.   DESS EVFC 'TITR' 'Force vs Deplacement' ;
  115. FINSI ;
  116.  
  117.  
  118. FIN ;
  119.  
  120.  
  121.  
  122.  
  123.  
  124.  
  125.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales