Télécharger fluage_fibre_polynomial_3.dgibi

Retour à la liste

Numérotation des lignes :

  1. ************************************************************************
  2. * Comparaison du modele de fluage polynomial : *
  3. * - modele poutre a fibre VS modele massif *
  4. * - chargement uniaxial, traction puis compression *
  5. * - en deplacement impose *
  6. ************************************************************************
  7.  
  8.  
  9.  
  10. ** Options generales
  11. OPTI 'DIME' 3 'ELEM' 'CU20' 'ECHO' 0 ;
  12. itrac = FAUX ;
  13.  
  14.  
  15. ** Parametres geometrie (poutre a section rectangulaire)
  16. a = 0.05 ;
  17. b = 0.02 ;
  18. l = 1. ;
  19. se = a * b ;
  20.  
  21.  
  22. ** Nombres d'elements
  23. nea = 1 ;
  24. neb = 1 ;
  25. nel = 1 ;
  26.  
  27.  
  28. ** Parametres materiau
  29. yo = 1.E8 ;
  30. nu = 0.3 ;
  31. af0 = 1.E-6 ;
  32. af1 = 1.E-12 ;
  33. af2 = 1.6 ;
  34. af3 = 1.E-10 ;
  35. af4 = 0.8 ;
  36. af5 = 2.E-9 ;
  37. af6 = 0.2 ;
  38.  
  39.  
  40. ** Parametres chargement
  41. utrac = 0.01 ;
  42. tl = 25. ;
  43.  
  44.  
  45. ** Maillage et modele volumique
  46. p0 = 0. 0. 0. ;
  47. p1 = 0. a 0. ;
  48. l1 = DROI nea p0 p1 ;
  49. s1 = l1 TRAN neb (0. 0. b) ;
  50. p2 = s1 POIN 'PROC' (0. 0. b) ;
  51. v1 = s1 VOLU 'TRAN' nel (l 0. 0.) ;
  52. env1 = ENVE v1 ;
  53. are1 = ARET v1 ;
  54. p3 = v1 POIN 'PROC' (l 0. 0.) ;
  55. s2 = v1 FACE 2 ;
  56. mov = MODE v1 'MECANIQUE' 'ELASTIQUE' 'FLUAGE' 'POLYNOMIAL' ;
  57. mav = MATE mov 'YOUN' yo 'NU' nu 'AF0' af0 'AF1' af1 'AF2' af2 'AF3' af3 'AF4' af4 'AF5' af5 'AF6' af6 ;
  58.  
  59.  
  60. ** Maillage et modele de section
  61. OPTI 'ELEM' 'CUB8' ;
  62. lig1 = DROI nea ((-0.5 * a) (-0.5 * b) 0.) ((0.5 * a) (-0.5 * b) 0.) ;
  63. s3 = lig1 TRAN neb (0. b 0.) ;
  64. s3 = SURF (CONT s3) 'PLAN' ;
  65. mos = MODE s3 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' 'POLYNOMIAL' 'QUAS' 'TRIS' ;
  66. mas = MATE mos 'YOUN' yo 'NU' nu 'AF0' af0 'AF1' af1 'AF2' af2 'AF3' af3 'AF4' af4 'AF5' af5 'AF6' af6 'SMAX' (yo / 1000.) 'ALPY' 0.66 'ALPZ' 0.66 ;
  67.  
  68.  
  69. ** Maillage et modele de poutre TIMO
  70. lf = DROI nel p0 p3 ;
  71. mop = MODE lf 'MECANIQUE' 'ELASTIQUE' 'SECTION' 'PLASTIQUE' 'SECTION' 'TIMO' ;
  72. map = MATE mop 'MODS' mos 'MATS' mas 'VECT' (0. 1. 0.) ;
  73.  
  74.  
  75. ** Conditions aux limites
  76. tl0 = 1.E-5 ;
  77. tl2 = 2. * tl ;
  78. tl3 = 3. * tl ;
  79. tl4 = 4. * tl ;
  80. evcha = EVOL 'MANU' (PROG 0. tl0 tl (tl + tl0) tl2 (tl2 + tl0) tl3 (tl3 + tl0) tl4)
  81. (PROG 0. 0.999 1. 0.001 0. -0.999 -1. -0.001 0.) ;
  82.  
  83. * pour le modele volumique
  84. * encastrement
  85. bl1 = (BLOQ 'UX' s1) ET (BLOQ 'UY' 'UZ' p0) ET (BLOQ 'UZ' p1) ;
  86. * deplacement impose
  87. bl2 = BLOQ 'UX' s2 ;
  88. bl1 = bl1 ET bl2 ;
  89. ft = DEPI bl2 utrac ;
  90. chaft = CHAR 'DIMP' ft evcha ;
  91.  
  92. * pour le modele TIMO
  93. * encastrement
  94. bl1p = BLOQ 'DEPL' 'ROTA' p0 ;
  95. * deplacement impose
  96. bl2p = BLOQ 'UX' p3 ;
  97. bl1p = bl1p ET bl2p ;
  98. ftp = DEPI bl2p utrac ;
  99. chaftp = CHAR 'DIMP' ftp evcha ;
  100.  
  101.  
  102. ** Resolution
  103. xpas = tl / 20. ;
  104. ltc = PROG tl0 'PAS' xpas tl
  105. (tl + tl0) 'PAS' xpas tl2
  106. (tl2 + tl0) 'PAS' xpas tl3
  107. (tl3 + tl0) 'PAS' xpas tl4 ;
  108.  
  109. tv = TABL ;
  110. tv . 'MODELE' = mov ;
  111. tv . 'CARACTERISTIQUES' = mav ;
  112. tv . 'BLOCAGES_MECANIQUES' = bl1 ;
  113. tv . 'CHARGEMENT' = chaft ;
  114. tv . 'TEMPS_CALCULES' = ltc ;
  115. PASAPAS tv ;
  116. itp1 = TEMP 'ENTI' 'HORL' ;
  117.  
  118. tp = TABL ;
  119. tp . 'MODELE' = mop ;
  120. tp . 'CARACTERISTIQUES' = map ;
  121. chmsg0 = ZERO mos 'CONTRAIN' ;
  122. chmvi0 = ZERO mos 'VARINTER' ;
  123. tp . 'VARIABLES_INTERNES' = TABL ;
  124. tp . 'VARIABLES_INTERNES' . 0 = MANU 'CHML' mop 'VONS' chmsg0 'VAIS' chmvi0 'TYPE' 'VARIABLES INTERNES' 'STRESSES' ;
  125. tp . 'BLOCAGES_MECANIQUES' = bl1p ;
  126. tp . 'CHARGEMENT' = chaftp ;
  127. tp . 'TEMPS_CALCULES' = ltc ;
  128. PASAPAS tp ;
  129. itp11 = TEMP 'ENTI' 'HORL' ;
  130.  
  131. MESS 'Temps horloge : ' ;
  132. MESS (CHAI '- modele massif :' ' ' itp1) ;
  133. MESS (CHAI '- modele poutre :' ' ' itp11) ;
  134.  
  135.  
  136. ** Post traitement
  137. n1 = DIME (tv . 'TEMPS') ;
  138. ltps = PROG ;
  139. * deplacements de l'extremite
  140. luv = EXTR (EVOL 'TEMP' tv 'DEPLACEMENTS' 'UX' p3) 'ORDO' ;
  141. lup = EXTR (EVOL 'TEMP' tp 'DEPLACEMENTS' 'UX' p3) 'ORDO' ;
  142. * force de reaction a l'encastrement
  143. lfv = PROG ;
  144. REPE b1 n1 ;
  145. i1 = &b1 - 1 ;
  146. ltps = ltps ET (tv . 'TEMPS' . i1) ;
  147. fv = 0. ;
  148. SI (NEG i1 0) ;
  149. fv = MAXI (EXCO 'FX' (RESU (REDU (tv . 'REACTIONS' . i1) s1))) ;
  150. FINSI ;
  151. lfv = lfv ET fv ;
  152. FIN b1 ;
  153. lfp = EXTR (EVOL 'TEMP' tp 'REACTIONS' 'FX' p0) 'ORDO' ;
  154. * defomration inelastique
  155. lev = PROG ;
  156. lep = PROG ;
  157. vol1 = MESU v1 ;
  158. REPE b1 n1 ;
  159. i1 = &b1 - 1 ;
  160. tps1 = tv . 'TEMPS' . i1 ;
  161. lev = lev ET ((INTG mov (tv . 'VARIABLES_INTERNES' . i1) 'EPSE') / vol1) ;
  162. uv = tv . 'DEPLACEMENTS' . i1 ;
  163. up = tp . 'DEPLACEMENTS' . i1 ;
  164. tabv = TABL ;
  165. tabv . 'DEPLACEMENTS' = TABL ;
  166. tabv . 'DEPLACEMENTS' . 1 = up ;
  167. tabv . 'VONS' = TABL ;
  168. tabv . 'VONS' . 1 = EXCO (tp . 'VARIABLES_INTERNES' . i1) 'VONS' ;
  169. tabv . 'VAIS' = TABL ;
  170. tabv . 'VAIS' . 1 = EXCO (tp . 'VARIABLES_INTERNES' . i1) 'VAIS' ;
  171. mail1 = POUT2MAS mop map 'GAUSS' tabv ;
  172. vips = tabv . 'VAIS_3D' . 1 ;
  173. mobid = MODE mail1 'MECANIQUE' ;
  174. cham1 = CHAN 'CHAM' mobid vips ;
  175. epsep = (INTG mobid cham1 'EPSE') * l / (NBEL lf) / se ;
  176. lep = lep ET epsep ;
  177. FIN b1 ;
  178.  
  179.  
  180. ** Analyse/trace des resultats
  181. tleg = TABL ;
  182. tleg . 1 = MOT 'MARQ LOSA NOLI' ;
  183. tleg . 2 = MOT 'MARQ ROND NOLI' ;
  184. tleg . 'TITRE' = TABL ;
  185. tleg . 'TITRE' . 1 = 'Modele 3D massif' ;
  186. tleg . 'TITRE' . 2 = 'Modele poutre fibre' ;
  187. MESS 'Ecart relatif max.' ;
  188. evuv = EVOL 'VERT' 'MANU' 'Temps' ltps 'Deplacement' luv ;
  189. evup = EVOL 'ROUG' 'MANU' 'Temps' ltps 'Deplacement' lup ;
  190. difu = (MAXI (ABS (lup - luv))) / (MAXI (ABS luv)) ;
  191. MESS '-- deplacement :' difu ;
  192. SI itrac ;
  193. DESS (evuv ET evup) 'TITR' 'Deplacement vs. Temps' 'LEGE' tleg ;
  194. FINSI ;
  195. evfv = EVOL 'VERT' 'MANU' 'Temps' ltps 'Force' lfv ;
  196. evfp = EVOL 'ROUG' 'MANU' 'Temps' ltps 'Force' lfp ;
  197. diff = (MAXI (ABS (lfp - lfv))) / (MAXI (ABS lfv)) ;
  198. MESS '-- effort :' diff ;
  199. SI itrac ;
  200. DESS (evfv ET evfp) 'TITR' 'Force vs. Temps' 'LEGE' tleg ;
  201. FINSI ;
  202. evev = EVOL 'VERT' 'MANU' 'TEMPS' ltps 'EPSE' lev ;
  203. evep = EVOL 'ROUG' 'MANU' 'TEMPS' ltps 'ESPE' lep ;
  204. dife = (MAXI (ABS (lep - lev))) / (MAXI (ABS lev)) ;
  205. MESS '-- def. fluage :' dife ;
  206. SI itrac ;
  207. DESS (evev ET evep) 'TITR' 'Deformation non lin. (EPSE) vs Temps' 'LEGE' tleg ;
  208. FINSI ;
  209.  
  210.  
  211. ** Erreur si l'ecart relatif est trop eleve
  212. lerr = PROG difu diff dife ;
  213. errmax = MAXI lerr ;
  214. SI (errmax > 2.E-3) ;
  215. MESS 'Echec du cas test !' ;
  216. ERRE 5 ;
  217. SINON ;
  218. MESS 'Succes du cas test !' ;
  219. FINSI ;
  220.  
  221.  
  222. FIN ;
  223.  
  224.  
  225.  
  226.  
  227.  
  228.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales