Télécharger la plaquette Cast3M


fr en

Télécharger fluage_fibre_polynomial_2.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : fluage_fibre_polynomial_2.dgibi
  2. ************************************************************************
  3. * Comparaison du modele de fluage polynomial :                         *
  4. * - modele poutre a fibre VS modele massif                             *
  5. * - chargement uniaxial, traction puis compression                     *
  6. * - en force imposee                                                   *
  7. ************************************************************************
  8.  
  9.  
  10.  
  11. ** Options generales
  12. OPTI 'DIME' 3 'ELEM' 'CU20' 'ECHO' 0 ;
  13. itrac = FAUX ;
  14.  
  15.  
  16. ** Parametres geometrie (poutre a section rectangulaire)
  17. a = 0.05 ;
  18. b = 0.02 ;
  19. l = 1. ;
  20. se = a * b ;
  21.  
  22.  
  23. ** Nombres d'elements
  24. nea = 1 ;
  25. neb = 1 ;
  26. nel = 1 ;
  27.  
  28.  
  29. ** Parametres materiau
  30. yo = 1.E8 ;
  31. nu = 0.3 ;
  32. af0 = 1.E-6 ;
  33. af1 = 1.E-12 ;
  34. af2 = 1.6 ;
  35. af3 = 1.E-10 ;
  36. af4 = 0.8 ;
  37. af5 = 2.E-9 ;
  38. af6 = 0.2 ;
  39.  
  40.  
  41. ** Parametres chargement
  42. ftrac = 500. ;
  43. tl = 25. ;
  44.  
  45.  
  46. ** Maillage et modele volumique
  47. p0 = 0. 0. 0. ;
  48. p1 = 0. a 0. ;
  49. l1 = DROI nea p0 p1 ;
  50. s1 = l1 TRAN neb (0. 0. b) ;
  51. p2 = s1 POIN 'PROC' (0. 0. b) ;
  52. v1 = s1 VOLU 'TRAN' nel (l 0. 0.) ;
  53. env1 = ENVE v1 ;
  54. are1 = ARET v1 ;
  55. p3 = v1 POIN 'PROC' (l 0. 0.) ;
  56. s2 = v1 FACE 2 ;
  57. mov = MODE v1 'MECANIQUE' 'ELASTIQUE' 'FLUAGE' 'POLYNOMIAL' ;
  58. mav = MATE mov 'YOUN' yo 'NU' nu  'SMAX' 0. 'AF0' af0 'AF1' af1 'AF2' af2 'AF3' af3 'AF4' af4 'AF5' af5 'AF6' af6 ;
  59.  
  60.  
  61. ** Maillage et modele de section
  62. OPTI 'ELEM' 'CUB8' ;
  63. lig1 = DROI nea ((-0.5 * a) (-0.5 * b) 0.) ((0.5 * a) (-0.5 * b) 0.) ;
  64. s3 = lig1 TRAN neb (0. b 0.) ;
  65. s3 = SURF (CONT s3) 'PLAN' ;
  66. mos = MODE s3 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' 'POLYNOMIAL' 'QUAS' 'TRIS' ;
  67. mas = MATE mos 'YOUN' yo 'NU' nu 'AF0' af0 'AF1' af1 'AF2' af2 'AF3' af3 'AF4' af4 'AF5' af5 'AF6' af6 'SMAX' (yo / 1000.) 'ALPY' 0.66 'ALPZ' 0.66 ;
  68.  
  69.  
  70. ** Maillage et modele de poutre TIMO
  71. lf = DROI nel p0 p3 ;
  72. mop = MODE lf 'MECANIQUE' 'ELASTIQUE' 'SECTION' 'PLASTIQUE' 'SECTION' 'TIMO' ;
  73. map = MATE mop 'MODS' mos 'MATS' mas 'VECT' (0. 1. 0.) ;
  74.  
  75.  
  76. ** Conditions aux limites
  77. tl0 = 1.E-5 ;
  78. tl2 = 2. * tl ;
  79. tl3 = 3. * tl ;
  80. tl4 = 4. * tl ;
  81. evcha = EVOL 'MANU' (PROG 0. tl0   tl (tl + tl0) tl2 (tl2 + tl0) tl3 (tl3 + tl0) tl4)
  82.                     (PROG 0. 0.999 1. 0.001      0.  -0.999      -1. -0.001      0.) ;
  83.  
  84. * pour le modele volumique
  85. * encastrement
  86. bl1 = (BLOQ 'UX' s1) ET (BLOQ 'UY' 'UZ' p0) ET (BLOQ 'UZ' p1) ;
  87. * force imposee
  88. ft = FSUR 'MASS' mov s2 ((ftrac / (a * b)) 0. 0.) ;
  89. chaft = CHAR 'MECA' ft evcha ;
  90.  
  91. * pour le modele TIMO
  92. * encastrement
  93. bl1p  = BLOQ 'DEPL' 'ROTA' p0 ;
  94. * force imposee
  95. ftp = FORC (ftrac 0. 0.) p3 ;
  96. chaftp = CHAR 'MECA' ftp evcha ;
  97.  
  98.  
  99. ** Resolution
  100. xpas = tl / 20. ;
  101. ltc  = PROG       tl0  'PAS' xpas tl
  102.            (tl  + tl0) 'PAS' xpas tl2
  103.            (tl2 + tl0) 'PAS' xpas tl3
  104.            (tl3 + tl0) 'PAS' xpas tl4 ;
  105.  
  106. tv  = TABL ;
  107. tv  . 'MODELE' = mov ;
  108. tv  . 'CARACTERISTIQUES' = mav ;
  109. tv  . 'BLOCAGES_MECANIQUES' = bl1 ;
  110. tv  . 'CHARGEMENT' = chaft ;
  111. tv  . 'TEMPS_CALCULES' = ltc ;
  113. PASAPAS tv ;
  114. itp1 = TEMP 'HORL' ;
  115.  
  116. tp = TABL ;
  117. tp . 'MODELE' = mop ;
  118. tp . 'CARACTERISTIQUES' = map ;
  119. chmsg0 = ZERO mos 'CONTRAIN' ;
  120. chmvi0 = ZERO mos 'VARINTER' ;
  121. tp . 'VARIABLES_INTERNES' = TABL ;
  122. tp . 'VARIABLES_INTERNES' . 0 = MANU 'CHML' mop 'VONS' chmsg0 'VAIS' chmvi0 'TYPE' 'VARIABLES INTERNES' 'STRESSES' ;
  123. tp . 'BLOCAGES_MECANIQUES' = bl1p ;
  124. tp . 'CHARGEMENT' = chaftp ;
  125. tp . 'TEMPS_CALCULES'  = ltc ;
  127. PASAPAS tp ;
  128. itp11 = TEMP 'HORL' ;
  129.  
  130. MESS 'Temps horloge : ' ;
  131. MESS (CHAI '- modele massif :' ' ' itp1) ;
  132. MESS (CHAI '- modele poutre :' ' ' itp11) ;
  133.  
  134.  
  135. ** Post traitement
  136. n1 = DIME (tv . 'TEMPS') ;
  137. ltps = PROG ;
  138. * deplacements de l'extremite
  139. luv = EXTR (EVOL 'TEMP' tv 'DEPLACEMENTS' 'UX' p3) 'ORDO' ;
  140. lup = EXTR (EVOL 'TEMP' tp 'DEPLACEMENTS' 'UX' p3) 'ORDO' ;
  141. * force de reaction a l'encastrement
  142. lfv = PROG ;
  143. REPE b1 n1 ;
  144.   i1 = &b1 - 1 ;
  145.   ltps = ltps ET (tv . 'TEMPS' . i1) ;
  146.   fv = 0. ;
  147.   SI (NEG i1 0) ;
  148.     fv = MAXI (EXCO 'FX' (RESU (REDU (tv . 'REACTIONS' . i1) s1))) ;
  149.   FINSI ;
  150.   lfv = lfv ET fv ;
  151. FIN b1 ;
  152. lfp = EXTR (EVOL 'TEMP' tp 'REACTIONS' 'FX' p0) 'ORDO' ;
  153. * defomration inelastique
  154. lev = PROG ;
  155. lep = PROG ;
  156. vol1 = MESU v1 ;
  157. REPE b1 n1 ;
  158.   i1 = &b1 - 1 ;
  159.   tps1 = tv . 'TEMPS' . i1 ;
  160.   lev = lev ET ((INTG mov (tv . 'VARIABLES_INTERNES' . i1) 'EPSE') / vol1) ;
  161.   uv = tv . 'DEPLACEMENTS' . i1 ;
  162.   up = tp . 'DEPLACEMENTS' . i1 ;
  163.   tabv = TABL ;
  164.   tabv . 'DEPLACEMENTS' = TABL ;
  165.   tabv . 'DEPLACEMENTS' . 1 = up ;
  166.   tabv . 'VONS' = TABL ;
  167.   tabv . 'VONS' . 1 = EXCO (tp . 'VARIABLES_INTERNES' . i1) 'VONS' ;
  168.   tabv . 'VAIS' = TABL ;
  169.   tabv . 'VAIS' . 1 = EXCO (tp . 'VARIABLES_INTERNES' . i1) 'VAIS' ;
  170.   mail1 = POUT2MAS mop map 'GAUSS' tabv ;
  171.   vips = tabv . 'VAIS_3D' . 1 ;
  172.   mobid = MODE mail1 'MECANIQUE' ;
  173.   cham1 = CHAN 'CHAM' mobid vips ;
  174.   epsep = (INTG mobid cham1 'EPSE') * l / (NBEL lf) / se ;
  175.   lep = lep ET epsep ;
  176. FIN b1 ;
  177.  
  178.  
  179. ** Analyse/trace des resultats
  180. tleg = TABL ;
  181. tleg . 1 = MOT 'MARQ LOSA NOLI' ;
  182. tleg . 2 = MOT 'MARQ ROND NOLI' ;
  183. tleg . 'TITRE' = TABL ;
  184. tleg . 'TITRE' . 1 = 'Modele 3D massif' ;
  185. tleg . 'TITRE' . 2 = 'Modele poutre fibre' ;
  186. MESS 'Ecart relatif max.' ;
  187. evuv = EVOL 'VERT' 'MANU' 'Temps' ltps 'Deplacement' luv ;
  188. evup = EVOL 'ROUG' 'MANU' 'Temps' ltps 'Deplacement' lup ;
  189. difu = (MAXI (ABS (lup - luv))) / (MAXI (ABS luv)) ;
  190. MESS '-- deplacement :' difu ;
  191. SI itrac ;
  192.   DESS (evuv ET evup) 'TITR' 'Deplacement vs. Temps' 'LEGE' tleg ;
  193. FINSI ;
  194. evfv = EVOL 'VERT' 'MANU' 'Temps' ltps 'Force' lfv ;
  195. evfp = EVOL 'ROUG' 'MANU' 'Temps' ltps 'Force' lfp ;
  196. diff = (MAXI (ABS (lfp - lfv))) / (MAXI (ABS lfv)) ;
  197. MESS '-- effort      :' diff ;
  198. SI itrac ;
  199.   DESS (evfv ET evfp) 'TITR' 'Force vs. Temps' 'LEGE' tleg ;
  200. FINSI ;
  201. evev = EVOL 'VERT' 'MANU' 'TEMPS' ltps 'EPSE' lev ;
  202. evep = EVOL 'ROUG' 'MANU' 'TEMPS' ltps 'ESPE' lep ;
  203. dife = (MAXI (ABS (lep - lev))) / (MAXI (ABS lev)) ;
  204. MESS '-- def. fluage :' dife ;
  205. SI itrac ;
  206.   DESS (evev ET evep) 'TITR' 'Deformation non lin. (EPSE) vs Temps' 'LEGE' tleg ;
  207. FINSI ;
  208.  
  209.  
  210. ** Erreur si l'ecart relatif est trop eleve
  211. lerr = PROG difu diff dife ;
  212. errmax = MAXI lerr ;
  214. SI (errmax > 1.E-4) ;
  215.   MESS 'Echec du cas test !' ;
  216.   ERRE 5 ;
  217. SINON ;
  218.   MESS 'Succes du cas test !' ;
  219. FINSI ;
  220.  
  221.  
  222. FIN ;
  223.  
  224.  
  225.  
  226.  
  227.  
  228.  
  229.  
  230.  
  231.  
  232.  
  233.  
  234.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales