Télécharger flam3.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : flam3.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * COMPARAISON DES CALCULS DE FLAMBAGE D'UN TUBE
  5. * SOUS PRESSION INTERNE (TUBE DE SACLAY)
  6. OPTI DIME 3 ELEM QUA4 ECHO 1;
  7. OPTI EPSI LINEAIRE;
  8. MESS ' COMPARAISON DES CALCULS DE FLAMBAGE';
  9. MESS 'D UN TUBE SOUS PRESSION INTERNE MODéLISé';
  10. MESS ' AVEC COQ3 ET COQ4 (TUBE DE SACLAY)';
  11. L = 10. ;
  12. T = .01 ;
  13. R = .5 ;
  14. E = 2E11 ;
  15. NV = 30 ;
  16. NH = 8 ;
  17. ************************
  18. P1 = R 0 0 ;
  19. P2 = R 0 L ;
  20. L1 = P1 D NV P2 ;
  21. AX1 = 0 0 0 ;
  22. AX2 = 0 0 L;
  23. SURF4 = ROTA L1 AX1 AX2 NH 90. ;
  24. SURF3 = CHAN 'TRI3' SURF4;
  25. SURF8 = CHAN 'QUADRATIQUE' SURF4 ;
  26. * MODéLES, MATéRIAUX ET RIGIDITé
  27. MODL3 = MODE SURF3 MECANIQUE COQ3;
  28. MODL4 = MODE SURF4 MECANIQUE COQ4;
  29. MODL8 = MODE SURF8 MECANIQUE COQ8;
  30. MAT3 = MATE MODL3 YOUN E NU .30 RHO 8000 EPAI T ;
  31. MAT4 = MATE MODL4 YOUN E NU .30 RHO 8000 EPAI T ;
  32. MAT8 = MATE MODL8 YOUN E NU .30 RHO 8000 EPAI T ;
  33. *
  34. MOP1 = 'MODE' SURF3 'CHARGEMENT' 'PRESSION' COQ3 ;
  35. MOP2 = 'MODE' SURF4 'CHARGEMENT' 'PRESSION' COQ4 ;
  36. MOP3 = 'MODE' SURF8 'CHARGEMENT' 'PRESSION' COQ8 ;
  37. MAP1 = 'PRES' MOP1 'PRES' -100. ;
  38. MAP2 = 'PRES' MOP2 'PRES' -100. ;
  39. MAP3 = 'PRES' MOP3 'PRES' -100. ;
  40. MAP3B = 'CARA' MOP3 'EPAI' T ;
  41. MODL3 = MODL3 ET MOP1 ; MAT3 = MAT3 ;
  42. MODL4 = MODL4 ET MOP2 ; MAT4 = MAT4 ;
  43. MODL8 = MODL8 ET MOP3 ; MAT8 = MAT8 ;
  44. *
  45. RIG3 = RIGI MODL3 MAT3 ;
  46. RIG4 = RIGI MODL4 MAT4 ;
  47. RIG8 = RIGI MODL8 MAT8 ;
  48. I1 = PI*(R**3)*T ;
  49. S1 = 2*PI*R*T ;
  50. * CONDITION AUX LIMITES
  51. LL41 = COTE 2 SURF4 ;
  52. BL41 = SYMT DEPL ROTA (0 0 0) (1 0 0) (0 1 0) SURF4 .01 ;
  53. BL42 = SYMT DEPL ROTA AX1 AX2 P1 SURF4 .01 ;
  54. BL43 = SYMT DEPL ROTA AX1 AX2 (0 1 0) SURF4 .01;
  55. F4 = 'BSIG' MOP2 MAP2 ;
  56. LL31 = COTE 2 SURF4 ;
  57. BL31 = SYMT DEPL ROTA (0 0 0) (1 0 0) (0 1 0) SURF3 .01 ;
  58. BL32 = SYMT DEPL ROTA AX1 AX2 P1 SURF3 .01 ;
  59. BL33 = SYMT DEPL ROTA AX1 AX2 (0 1 0) SURF3 .01;
  60. F3 = 'BSIG' MOP1 MAP1 ;
  61. BL81 = SYMT DEPL ROTA (0 0 0) (1 0 0) (0 1 0) SURF8 .01 ;
  62. BL82 = SYMT DEPL ROTA AX1 AX2 P1 SURF8 .01 ;
  63. BL83 = SYMT DEPL ROTA AX1 AX2 (0 1 0) SURF8 .01;
  64. F8 = 'BSIG' MOP3 MAP3 MAP3B ;
  65. * CALCULS éLASTIQUES
  66. DEP3 = RESO (RIG3 ET BL31 ET BL32 ET BL33) F3 ;
  67. SIG3 = SIGM MODL3 MAT3 DEP3 ;
  68. KSIG3 = KSIG MODL3 MAT3 SIG3 FLAM ;
  69. DEP4 = RESO (RIG4 ET BL41 ET BL42 ET BL43) F4 ;
  70. SIG4 = SIGM MODL4 MAT4 DEP4 ;
  71. KSIG4 = KSIG MODL4 MAT4 SIG4 FLAM ;
  72. DEP8 = RESO (RIG8 ET BL81 ET BL82 ET BL83) F8 ;
  73. SIG8 = SIGM MODL8 MAT8 DEP8 ;
  74. KSIG8 = KSIG MODL8 MAT8 SIG8 FLAM ;
  75. * CONDITIONS AUX LIMITES POUR LE CALCUL DE FLAMBAGE
  76. BL33 = ANTI DEPL ROTA AX1 AX2 (0 1 0) SURF3 .01;
  77. PP0 = POIN SURF3 PROCHE (0 R L) ;
  78. BL34 = BLOQ UX PP0 ;
  79. RIGT3 = RIG3 ET BL31 ET BL32 ET BL33 ET BL34 ;
  80. BL43 = ANTI DEPL ROTA AX1 AX2 (0 1 0) SURF4 .01;
  81. PP0 = POIN SURF4 PROCHE (0 R L) ;
  82. BL44 = BLOQ UX PP0 ;
  83. RIGT4 = RIG4 ET BL41 ET BL42 ET BL43 ET BL44 ;
  84. BL83 = ANTI DEPL ROTA AX1 AX2 (0 1 0) SURF8 .01;
  85. PP0 = POIN SURF8 PROCHE (0 R L) ;
  86. BL84 = BLOQ UX PP0 ;
  87. RIGT8 = RIG8 ET BL81 ET BL82 ET BL83 ET BL84 ;
  88. * CALCUL DE FLAMBAGE
  89. KP3 = KP MOP1 (MANU CHPO SURF3 1 P -100.) FLAM ;
  90. TAB3 = VIBR PROCHE (PROG 79.) RIGT3
  91. ((1*KP3) ET (-1*KSIG3) ) ;
  92. KP4 = KP MOP2 (MANU CHPO SURF4 1 P -100.) FLAM ;
  93. TAB4 = VIBR PROCHE (PROG 79.) RIGT4
  94. ((1*KP4) ET (-1*KSIG4) ) ;
  95. KP8 = KP MOP3 (MANU CHPO SURF8 1 P -100.) FLAM ;
  96. TAB8 = VIBR PROCHE (PROG 79.) RIGT8
  97. ((1*KP8) ET (-1*KSIG8) ) ;
  98. DEP3 = TAB3.MODES. 1 .DEFORMEE_MODALE ;
  99. DEP4 = TAB4.MODES. 1 .DEFORMEE_MODALE ;
  100. DEP8 = TAB8.MODES. 1 .DEFORMEE_MODALE ;
  101. DEF3 = DEFO DEP3 SURF3 1. ROUGE ;
  102. DEF4 = DEFO DEP4 SURF4 1. VERT ;
  103. DEF8 = DEFO DEP8 SURF8 1. BLEU ;
  104. DEF0 = DEFO DEP3 SURF3 0. ;
  105. *TRAC (DEF3 ET DEF4 ET DEF0) ;
  106. F3 = TAB3.MODES. 1 .FREQUENCE ;
  107. LL3 = (2*PI*F3)**2 ;
  108. F4 = TAB4.MODES. 1 .FREQUENCE ;
  109. LL4 = (2*PI*F4)**2 ;
  110. F8 = TAB8.MODES. 1 .FREQUENCE ;
  111. LL8 = (2*PI*F8)**2 ;
  112. PCOQ3 = LL3*100 ;
  113. PCOQ4 = LL4*100 ;
  114. PCOQ8 = LL8*100 ;
  115. PTH = PI**2*E*R*T/4/L/L ;
  116. ERR3 = ABS (100.*(PTH - PCOQ3)/PCOQ3);
  117. ERR4 = ABS (100.*(PTH - PCOQ4)/PCOQ4);
  118. ERR8 = ABS (100.*(PTH - PCOQ8)/PCOQ8);
  119. MESS 'CALCUL THéORIQUE : ' PTH;
  120. MESS 'CALCUL NUMéRIQUE (COQ3) : ' PCOQ3;
  121. MESS 'ERREUR : ' ERR3 '%';
  122. MESS 'CALCUL NUMéRIQUE (COQ4) : ' PCOQ4;
  123. MESS 'ERREUR : ' ERR4 '%';
  124. MESS 'CALCUL NUMéRIQUE (COQ8) : ' PCOQ8;
  125. MESS 'ERREUR : ' ERR8 '%';
  126. *------------------ CODE DE BON FONCTIONNEMENT -------------------------
  127. SI ((ERR3 < 5) ET (ERR4 < 5) ET (ERR8 < 8));
  128. ERRE 0;
  129. SINON;
  130. ERRE 5;
  131. FINSI;
  132. FIN;
  133.  
  134.  
  135.  
  136.  
  137.  
  138.  
  139.  
  140.  
  141.  
  142.  
  143.  
  144.  
  145.  
  146.  
  147.  
  148.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales