Télécharger dpressu.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : dpressu.dgibi
  2. *---------------------------------------------------------
  3. * Cas test de recette de TONUS multiD version 1.0
  4. *
  5. * Depressurisation d'une enceinte type Phébus
  6. *
  7. * Le maillage correspond à une enceinte cylindrique
  8. * d'environ 10 m3 avec un mur en contact avec la
  9. * paroi verticale (10 cm d'acier)
  10. * Tout le volume est initialement a 1.86bar et 90oC
  11. * et la température du mur est mise à 40oC
  12. * au début du calcul. On calcule la depressurisation
  13. * de cette enceinte sur 50 secondes en n'injectant pas de
  14. * vapeur. La temperature d injection est de 90oC.
  15. * Ce test (un peu long)
  16. * verifie le demarrage de la condensation "
  17. * verifie l'evolution moyenne de la temprature gaz
  18. * verifie la pression max a 50"
  19. * verifie la vitesse max a 50" (Convection naturelle)
  20. * Auteurs : E. Studer, J.P. Magnaud Novembre 1999
  21. * revisite Avril 2002
  22. * Ce test peut utiliser la procedure enceinte
  23. * 1/ il faut l'avoir (ce n'est pas donne a tout le monde)
  24. * 2/ faire enceinte = mot 'ENCEINTE' ;
  25. *--------------------------------------------------------
  26. COMPLET = FAUX ;
  27. *COMPLET = VRAI ;
  28. GRAPH = VRAI ;
  29. GRAPH = FAUX ;
  30.  
  31. 'SI' COMPLET ;
  32.  
  33. nbit=100;
  34. DT0 = 1. ;
  35. n1 = 1 ; n2 = 4 ; n3 = 4 ;
  36. n4 = 8 ; nn = 2 ;
  37.  
  38. 'SINON' ;
  39.  
  40. nbit= 5 ;
  41. DT0 = 10. ;
  42. n1 = 1 ; n2 = 2 ; n3 = 4 ;
  43. n4 = 4 ; nn = 1 ;
  44.  
  45. 'FINSI' ;
  46.  
  47. *--------------------------------------------------------
  48. * Definition du maillage de l'enceinte cylindrique
  49. *
  50. 'OPTI' 'DIME' 3 'ELEM' 'CU20' ;
  51.  
  52. ri = 1.052 ; sp = 0.10 ; hc = 4.163 ;
  53.  
  54.  
  55.  
  56. epsi = 1.000e-2 ; ;
  57.  
  58. p0 = 0.000 0.000 0.000 ;
  59. px = -1000.000 0.000 0.000 ;
  60. py = 0.000 -1000.000 0.000 ;
  61. pz = 0.000 0.000 1000.000 ;
  62. cd = 0.000 0.000 -20.000 ;
  63. ph0 = 0.000 0.000 hc ;
  64. phx = ri 0.000 hc ;
  65. phy = 0.000 ri hc ;
  66.  
  67. fg1 = 0.25 ;
  68. fg2 = fg1 * (2.0 ** 0.5) / 2. ;
  69.  
  70. p1 = (ri*fg1) 0.000 0.000 ;
  71. p2 = (ri*fg2) (ri*fg2) 0.000 ;
  72. p3 = 0.000 (ri*fg1) 0.000 ;
  73. p4 = ri 0.000 0.000 ;
  74. p5 = 0.000 ri 0.000 ;
  75. p6 = (ri+sp) 0.000 0.000 ;
  76. p7 = 0.000 (ri+sp) 0.000 ;
  77.  
  78. * Hauteur de l'enceinte
  79. h1 = 4.163 ;
  80. * Vecteur de translation
  81. v1 = 0. 0. h1 ;
  82.  
  83. l1 = 'DROI' p0 p1 n1 ;
  84. l2 = 'DROI' p1 p2 n1 ;
  85. l3 = 'DROI' p2 p3 n1 ;
  86. l4 = 'DROI' p3 p0 n1 ;
  87. l5 = 'CERC' p4 p0 p5 (2*n1) ;
  88. l6 = 'CERC' p6 p0 p7 (2*n1) ;
  89.  
  90. basf0= 'DALL' l1 l2 l3 l4 'PLAN' ;
  91. basf1=('REGL' (l2 'ET' l3) l5 n2) ;
  92. l44= cote 2 basf1;
  93. ax4= (inve l4) et l44 ;
  94. l11= cote 4 basf1;
  95. ax1= l11 et (inve l1) ;
  96.  
  97. basf = basf0 'ET' ('REGL' (l2 'ET' l3) l5 n2) ;
  98. 'ELIM' basf epsi ;
  99. basf = basf 'ET' ('SYME' basf 'DROI' p0 p3) ;
  100. ax11 = ('SYME' ax1 'DROI' p0 p3) 'ET' (inve ax1) ;
  101. 'ELIM' basf epsi ;
  102. basf = basf 'ET' ('SYME' basf 'DROI' p0 p1) ;
  103. ax44 = (inve ax4) 'ET' ('SYME' ax4 'DROI' p0 p4) ;
  104. 'ELIM' basf epsi ;
  105.  
  106. basm = 'REGL' l5 l6 n3 ;
  107. basm = basm 'ET' ('SYME' basm 'DROI' p0 p3) ;
  108. 'ELIM' basm epsi ;
  109. basm = basm 'ET' ('SYME' basm 'DROI' p0 p1) ;
  110. 'ELIM' basm epsi ;
  111.  
  112. * Creation du volume
  113.  
  114. dx = ri / 2. ;
  115. nz1 = ('ENTIER' ( h1 / dx ))*nn ;
  116.  
  117. bas = basf 'VOLU' nz1 'TRAN' v1 ;
  118. mbas = basm 'VOLU' nz1 'TRAN' v1 ;
  119. mbas = mbas 'COUL' 'ROUG' ;
  120. plan1 = ax11 'TRAN' nz1 v1 ;
  121. plan4 = ax44 'TRAN' nz1 v1 ;
  122. 'ELIM' (bas et plan1 et plan4) epsi ;
  123.  
  124. mt = bas ;
  125. wall = mbas ;
  126. elim (mt et wall) epsi ;
  127.  
  128. * Localisation d'une brèche éventuelle au bas de l'enceinte
  129.  
  130. pjg = 'POIN' basf 'PROC' (0.000 0.000 0.000) ;
  131. jg = ('ELEM' basf 'APPUIE' 'LARGEMENT' pjg) 'COUL' 'VERT' ;
  132.  
  133. *--------------------------------------------------------------------
  134. * Fin de la définition du maillage
  135. *--------------------------------------------------------------------
  136.  
  137. *--------------------------------------------------------------------
  138. * Début de l'initialisation de la procédure ENCEINTE : table RXT
  139. *--------------------------------------------------------------------
  140.  
  141. rxt = 'TABLE' ;
  142. rxt.'VERSION'= 'V0' ;
  143.  
  144. *-- Nom du volume fluide
  145. rxt.'vtf' = mt ;
  146. rxt.'epsi' = epsi ;
  147.  
  148. *-- Definition des murs de l'enceinte : ici un seul mur
  149. *-- en ACIER dont on traitera la thermique dans l'épaisseur
  150. *-- et que l'on initialise a 40oC
  151.  
  152. *-- On definit d'abort la matériau ACIER avec sa conductivite
  153. *-- thermique LAMBDA (W/m/K) et le produit ro*Cp (J/m3/K)
  154. rxt.'THERMP' = VRAI ;
  155. rxt.'vtp' = wall ;
  156. rxt.'LAMBDA' = 15. ;
  157. rxt.'ROCP' = 3.9E6 ;
  158. rxt.'Tp0' = 40. ;
  159. rxt.'ECHAN' = 10. ;
  160.  
  161. *-- Conditions initiales dans l'enceinte de test
  162. rxt.'TF0' = 90.0 ;
  163. rxt.'PT0' = 1.86076e5 ;
  164. rxt.'Yvap0' = 0.2728 ;
  165.  
  166. *-- On positionne une brèche
  167. * rxt.'breche' = jg ;
  168. * rxt.'diru1' = 0 0 1 ;
  169.  
  170. *-- On definit un point interne au maillage pour imposer la valeur de
  171. *-- la pression
  172. rxt.'pi' = (0.0 0.0 0.5) ;
  173.  
  174. *-- On indique que le calcul comporte de la vapeur d'eau
  175. rxt.'VAPEUR' = VRAI ;
  176.  
  177. *-- On active le recalcul automatique du préconditionnement
  178. *-- toutes les 5 itérations
  179. rxt.'FRPREC' = 5 ;
  180. rxt.'DETMAT' = VRAI ;
  181.  
  182. *-- Definition du scenario thermohydraulique
  183. * rxt.'scenario' = table ;
  184.  
  185. *-- Conditions a la breche (Obligatoire pour l'instant)
  186. * rxt.'scenario'.'t' = prog 0.0 1000.0 ;
  187. * rxt.'scenario'.'qeau' = prog 0.000 0.000 ;
  188. * rxt.'scenario'.'qair' = prog 0.000 0.000 ;
  189. * rxt.'scenario'.'tinj' = prog 90.0 90.0 ;
  190.  
  191. *-- On impose le pas de temps (s)
  192. rxt.'DT0' = DT0 ;
  193.  
  194. *-- On impose la viscosite turbulente (m2/s)
  195. rxt.'MODTURB'='NUTURB' ;
  196. rxt.'NUT' = 1.e-2 ;
  197.  
  198. *-- On lance le calcul sur 20 itérations d'une seconde
  199. rxt.'GRAPH'=GRAPH ;
  200.  
  201. EXECRXT 2 rxt ;
  202. EXECRXT (nbit - 2) rxt ;
  203.  
  204.  
  205. list rxt.TIC.'Tfm' ;
  206. list rxt.TIC.'PT' ;
  207. list rxt.TIC.'Qc' ;
  208. list rxt.TIC.'LMAXU';
  209.  
  210. 'SI' (NON COMPLET) ;
  211.  
  212. ltfm=Prog 90.000 82.759 65.078 60.441 55.834
  213. 51.594;
  214. lPT =Prog 1.86076E+05 1.83833E+05 1.73088E+05 1.55608E+05
  215. 1.49734E+05 1.46982E+05;
  216. Lqc =Prog 0.0000 7.74979E-02 5.06072E-02 3.66336E-02
  217. 3.16894E-02 2.84774E-02;
  218. Lmaxu=Prog 0.0000 0.0000 0.30666 0.29694 0.38583
  219. 0.27822;
  220.  
  221. tic=rxt.'TIC' ;
  222. ERtf=SOMM( abs (ltfm - tic.'Tfm') )/ 80. ;
  223. ERPT=SOMM( abs (lPT - tic.'PT' ) ) /1.e5 ;
  224. ERQc=SOMM( abs (lqc - tic.'Qc' ) ) ;
  225. ERum=SOMM( abs (Lmaxu - tic.'LMAXU' ) )/2. ;
  226.  
  227. Mess 'ERtf=' ERtf 'ERPT=' ERPT 'ERQc=' ERQc 'ERum=' ERum ;
  228.  
  229. Si (ERtf '>' 1.e-4) ; erreur 5 ; Finsi ;
  230. Si (ERPT '>' 1.e-4) ; erreur 5 ; Finsi ;
  231. Si (ERQc '>' 1.e-4) ; erreur 5 ; Finsi ;
  232. Si (ERum '>' 1.e-3) ; erreur 5 ; Finsi ;
  233.  
  234. 'FINSI' ;
  235.  
  236. Si GRAPH ;
  237.  
  238. $vtf=rxt.'GEO'.'$vtf' ;
  239. mt =doma $vtf maillage ;
  240. Mpl1=chan 'QUAF' plan1 ;
  241. Mpl4=chan 'QUAF' plan4 ;
  242. ELIM (mt et Mpl1 et Mpl4) epsi ;
  243. $mpl1= mode Mpl1 'NAVIER_STOKES' MACRO ;
  244. $mpl4= mode Mpl4 'NAVIER_STOKES' MACRO ;
  245. plan1= doma $mpl1 maillage ;
  246. plan4= doma $mpl4 maillage ;
  247. plan=plan1 et plan4 ;
  248.  
  249. paroif = rxt.'GEO'.'paroif';
  250. rho=rxt.'TIC'.'RHO';
  251. rvp=rxt.'TIC'.'RVP';
  252. tf=rxt.'TIC'.'TF';
  253. un=rxt.'TIC'.'UN' ;
  254. un1=redu un plan ;
  255. ung= vect un1 1. ux uy uz jaune ;
  256. trace ung plan ;
  257. opti isov suli ;
  258. trace rho plan 'TITRE'' Rho' ;
  259. trace rvp plan 'TITRE'' Rvp' ;
  260. trace tf plan 'TITRE'' Tf ' ;
  261.  
  262. trace rho paroif 'TITRE'' Rho' ;
  263. trace rvp paroif 'TITRE'' Rvp' ;
  264. trace Tf paroif 'TITRE'' Tf ' ;
  265. Fcond = tic.'Fcondw';
  266. trace Fcond paroif 'TITRE' ' Flux de condensation Kg / m**2 ' ;
  267.  
  268. axe = p0 d nz1 (p0 plus v1) ;
  269. axe = chan axe 'QUAF' ;
  270. elim (axe et mt) epsi ;
  271.  
  272. evr= evol 'CHPO' rho axe ;
  273. dess evr 'TITRE' ' Rho axe ';
  274.  
  275. evt = evol 'CHPO' Tf axe ;
  276. dess evt 'TITRE' ' Température axe ';
  277.  
  278. evvp= evol 'CHPO' rvp axe ;
  279. dess evvp 'TITRE' ' rvp axe ';
  280.  
  281.  
  282. 'FINSI' ;
  283.  
  284.  
  285. 'FIN' ;
  286.  
  287.  
  288.  
  289.  
  290.  
  291.  
  292.  
  293.  
  294.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales