7. Jeux de données

7.1. statique1.dgibi

Script Cast3M statique1.dgibi

  1* fichier : statique1.dgibi
  2************************************************************************
  3* Illustration de la methode de resolution d'un equilibre mecanique    *
  4* par minimisation iterative du residu.                                *
  5*                                                                      *
  6* On calcul la flexion simple d'une poutre au comportement elasto-     *
  7* plastique parfait en petits deplacements.                            *
  8*                                                                      *
  9************************************************************************
 10
 11* Pour visualiser les tracer, commentez la ligne ci-dessous :
 12opti trac psc ;
 13
 14* Options generales : 3D, hexahedre lineaire
 15opti dime 3 elem cub8 ;
 16
 17* Precision :
 18zprec1   = 1.e-4 ;
 19
 20*** Geometrie et maillage ***
 21* Dimensions de la poutre (Longuer, Epaisseur, Hauteur) :
 22l1       = 15. ;
 23e1       = 0.3 ;
 24h1       = 0.6 ;
 25
 26* Repere :
 27o1       = 0 0 0 ;
 28x1       = 1 0 0 ;
 29y1       = 0 1 0 ;
 30z1       = 0 0 1 ;
 31
 32* Maillage :
 33ly1      = o1  droi 4 (e1 * y1) ;
 34s1       = ly1 tran 8 (h1 * z1) ;
 35v1       = s1  volu tran 100 (l1 * x1) ;
 36s2       = v1  face 2 ;
 37trac qual cach v1
 38  titr (chai 'maillage de la poutre (nb noeuds =' (nbno v1) ')') ;
 39
 40*** Modele mecanique ***
 41* Modele & Caracteristiques materielles :
 42mo1      = mode v1 mecanique elastique plastique parfait ;
 43ma1      = mate mo1 youn 40.e9 nu 0.2 sigy 25.e6 rho 2.e3 ;
 44
 45* Conditions sur les deplacements :
 46A1       = bloq depl s1 ;
 47
 48* Forces volumiques et surfaciques  :
 49grav1    = manu chml mo1 fx 0. fy 0. fz -9.81 rigidites type scalaire ;
 50rho1     = (exco ma1 rho scal) chan type 'FOR. VOL' ;
 51Fv1      = cneq mo1 (rho1 * grav1) ;
 52Fs1      = forc s2 (0 0 -1.e4) ;
 53trac cach (vect Fv1 forc bleu 5.e-2) v1
 54  titr 'Forces nodales equivalentes volumiques' ;
 55trac cach (vect Fs1 forc vert 5.e-3) (aret v1 et s2)
 56  titr 'Forces nodales equivalentes surfaciques' ;
 57
 58*** Resolution :
 59* Rigidites :
 60Kel1     = rigi mo1 ma1 ;
 61Kel1     = Kel1 et A1 ;
 62
 63*** Resolution iterative par Minimisation du Residu ***
 64* On resout de facon iterative le champ de deplacement solution
 65* en controlant le critere sur l'equilibre des efforts.
 66* En dessous d'une valeur cible (zprec1), on sort : 
 67R1       = Fv1 + Fs1 ;
 68U1       = manu chpo V1 3 ux 0. uy 0. uz 0. ;
 69lsm1     = extr mo1 contraintes ;
 70repe b1 20 ;
 71  dDu1     = reso Kel1 R1 ;
 72  U1       = U1 + dDu1 ;
 73  Fr1      = reac A1 U1 ;
 74  eps1     = epsi line mo1 U1 ;
 75  comp1    = comp mo1 (eps1*0.) (eps1 et ma1) ;
 76  sig1     = exco comp1 lsm1 lsm1 ;
 77  bsg1     = bsig mo1 sig1 ;
 78  R1       = Fv1 + Fs1 + Fr1 - bsg1 ;
 79  si (&b1 ega 1) ;
 80    opti echo 0 ;
 81    mess ' Ite.     Critere Forces   Epse' ;
 82    Fref1    = maxi abs (Fv1 + Fs1 + Fr1) ;
 83  fins ;
 84  zcr1     = (maxi abs R1) / Fref1 ;
 85  epse1    = exco comp1 epse epse ;
 86  mess &B1 '     ' zcr1 '     ' (maxi epse1) ;
 87  si (zcr1 < zprec1) ;
 88    mess ' > Convergence a l iteration ' &B1 ;
 89    opti echo 1 ;
 90        quit b1 ;
 91  fins ;
 92fin b1 ;
 93epse1    = exco comp1 epse epse ;
 94*
 95* Deformees :
 96def0     = defo U1 (aret v1)  0. blan ;
 97def1     = defo U1 (enve v1) 20. roug ;
 98trac cach (def0 et def1) titr ' Deformee ';
 99
100* Contrainte SMxx sur deformee :
101niso1    = 14 ;
102sig1     = 1.e-6 * sig1 ;
103defsg1   = defo U1 v1 20. mo1 (exco sig1 smxx smxx) ;
104trac defsg1 titr ' Contrainte SMxx sur deformee (MPa) ' niso1 ;
105
106* Deformations inelastiques EIXX sur deformee :
107liso1    = prog 0. pas 0.1e-4 1.2e-4 ;
108defei1   = defo U1 v1 20. mo1 epse1 ;
109trac defei1 titr ' Deformation plastique cumulee sur deformee ' liso1 ;
110
111fin ;