Télécharger solubilite_01.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : solubilite_01.dgibi
  2.  
  3. ************************************************************************
  4. ************************************************************************
  5.  
  6. ************************************************************************
  7. * Cas test : solubilite_01.dgibi
  8. * --------
  9. *
  10. * Categorie : Verification
  11. * ---------
  12. *
  13. * Description :
  14. * -----------
  15. *
  16. * Teste le MODELE 'CHANGEMENT_PHASE' 'SOLUBILITE' developpe en 2021
  17. *
  18. * Plaque 2D constituee de 2 SOUS-ZONES 'TRI3' et 'QUA4'
  19. * Le point P1 est soumis à un chargement oscillant sur les
  20. * quantites duales 'QL' et 'QGA'.
  21. * La quantite primale 'CL' a une limite de solubilite Sol1
  22. * Les quantites primales 'CL' et 'CG' diffusent en plus dans
  23. * le domaine avec un modele de DIFFUSION de FICK
  24. *
  25. * Validation : (Aucune actuellement)
  26. * ----------
  27. * Tests a developper (Conservation des especes), solution analytique,
  28. * etc.
  29. *
  30. ************************************************************************
  31.  
  32. 'OPTI' 'TRAC' 'PSC';
  33. 'OPTI' 'DIME' 2 'ELEM' 'QUA4' 'MODE' 'PLAN' ;
  34.  
  35. *************** Solubilite ************************
  36. Sol1 = 0.5 ;
  37. SrcQL = 2.E-5 ;
  38. SrcQG = 1.E-5 ;
  39.  
  40. *************** Geometrie *************************************************
  41. P1 = 0. 0. ;
  42. P2 = 5.e-3 0. ;
  43. P3 = 5.e-3 10.e-3 ;
  44. P4 = 0. 10.e-3 ;
  45.  
  46. n = 20 ;
  47. L23 = P2 'DROI' n P3 ;
  48. L41 = P4 'DROI' n P1 ;
  49. L14 ='INVE' L41 ;
  50.  
  51. PA ='POIN' L41 'PROC' (0. 2.5e-3) ;
  52.  
  53. n = 10 ;
  54. MQUA4 = ('INVE' L41) 'REGL' n L23 ;
  55. MTRI3 ='CHAN' 'TRI3' (L23 'REGL' n (L23 'PLUS' P2));
  56.  
  57. su1 = MQUA4 'ET' MTRI3;
  58.  
  59. **************** Modeles et caracteristiques *********************************
  60. moddi1 ='MODE' su1 'DIFFUSION' 'FICK' 'INCO' 'CL' 'QL' 'CONS' 'CON1' ;
  61. moddi2 ='MODE' su1 'DIFFUSION' 'FICK' 'INCO' 'CG' 'QGA' 'CONS' 'CON2' ;
  62. modph1 ='MODE' su1 'CHANGEMENT_PHASE' 'SOLUBILITE' 'INCO' 'CL' 'CG' 'QL' 'QGA' 'CONS' 'SOL1' ;
  63. modtot = moddi1 'ET' moddi2 'ET' modph1 ;
  64.  
  65. matdi1 ='MATE' moddi1 'K' 1.D-5 'CDIF' 5.D-2 ;
  66. matdi2 ='MATE' moddi2 'K' 2.D-5 'CDIF' 1.D-1 ;
  67. matph1 ='MATE' modph1 'SOLU' Sol1 ;
  68. mattot = matdi1 'ET' matdi2 'ET' matph1 ;
  69.  
  70. **************** CHARGEMENT *********************************
  71. srcdi1 ='MANU' 'CHPO' ('MANU' 'POI1' P1) 1 'QL' SrcQL ;
  72. srcdi2 ='MANU' 'CHPO' ('MANU' 'POI1' P1) 1 'QGA' SrcQG ;
  73.  
  74. ltps1 ='PROG' 0. 'PAS' 0.1 10. ;
  75. lqL = 5.D-2 * ('SIN' (ltps1*360./4.)) ;
  76. lqG =-1.5D-2 * (3.D0 * ('SIN' (ltps1*360./3.))) * (1. + (ltps1 / 50.) ) ;
  77.  
  78. Evdi1 ='EVOL' 'BLEU' 'MANU' 'TEMP' ltps1 'QL' lqL ;
  79. Evdi2 ='EVOL' 'ROUG' 'MANU' 'TEMP' ltps1 'QGA' lqG ;
  80.  
  81. chardi1 ='CHAR' 'QL' srcdi1 Evdi1 ;
  82. chardi2 ='CHAR' 'QGA' srcdi2 Evdi2 ;
  83. chartot = chardi1 'ET' chardi2 ;
  84.  
  85. **************** PASAPAS *********************************
  86. listT ='PROG' 0. 'PAS' 0.2 10. ;
  87. xtab ='TABL' ;
  88. xtab.'MODELE' = modtot ;
  89. xtab.'CARACTERISTIQUES' = mattot ;
  90. xtab.'CHARGEMENT' = chartot ;
  91. xtab.'CONCENTRATIONS' ='TABL' ;
  92. xtab.'CONCENTRATIONS'. 0 ='MANU' 'CHPO' su1 2 'CL' 0.25 'CG' 0.D0 'NATURE' 'DIFFUS' ;
  93.  
  94. xtab.'TEMPS_CALCULES' = listT ;
  95. xtab.'PRECISION' = 1.D-6 ;
  96. xtab.'CTOL' ='MANU' 'CHPO' su1 2 'CL' 1.D-6 'CG' 1.D-6 ;
  97. xtab.'PROCESSEURS' ='MONOPROCESSEUR' ;
  98.  
  99. PASAPAS xtab ;
  100.  
  101. **************** POST-TRAITEMENT *********************************
  102. *Chargement en P1
  103. TLEG ='TABL';
  104. TLEG.'TITRE' ='TABL';
  105. TLEG.'TITRE'. 1='CHAI' 'Liquide';
  106. TLEG.'TITRE'. 2='CHAI' 'Gaz' ;
  107. Tit1 ='CHAI' 'Chargement sur le point P1';
  108. 'DESS' (Evdi1 'ET' Evdi2) 'GRIL' 'TITR' Tit1 'LEGE' TLEG ;
  109.  
  110. *Evolution des concentrations en P1
  111. EVO_L ='EVOL' 'BLEU' 'TEMP' xtab 'CONCENTRATIONS' 'CL' P1 ;
  112. EVO_G ='EVOL' 'ROUG' 'TEMP' xtab 'CONCENTRATIONS' 'CG' P1 ;
  113. EVO_Som ='COUL' (EVO_L + EVO_G) 'VERT' ;
  114. Tit1 ='CHAI' 'Concentrations CL et CG';
  115. 'DESS' (EVO_L 'ET' EVO_G) 'GRIL' 'TITR' Tit1 'LEGE' TLEG ;
  116. Tit1 ='CHAI' 'Cumul des concentrations CL et CG';
  117. 'DESS' EVO_Som 'GRIL' 'TITR' Tit1 ;
  118.  
  119. *Evolution des reactions sur les blocages du modele de 'SOLUBILITE' en P1
  120. BLOSOL='PMAT' modph1 ;
  121. Ltps1 ='TABL' 'ESCLAVE' ;
  122. LREAL ='TABL' 'ESCLAVE' ;
  123. LREAG ='TABL' 'ESCLAVE' ;
  124. 'REPE' SURi ('DIME' xtab.'TEMPS') ;
  125. Tpsi = xtab.'TEMPS'. (&SURi - 1) ;
  126. Ci = xtab.'CONCENTRATIONS'. (&SURi - 1) ;
  127. REAi ='REDU' ('REAC' Ci BLOSOL) P1 ;
  128. Ltps1. &SURi = Tpsi ;
  129. 'SI' ('EXIS' REAi 'QL');
  130. LREAL. &SURi ='MAXI' ('EXCO' REAi 'QL' );
  131. 'SINO';
  132. LREAL. &SURi = 0.D0;
  133. 'FINS';
  134. 'SI' ('EXIS' REAi 'QGA');
  135. LREAG. &SURi ='MAXI' ('EXCO' REAi 'QGA' );
  136. 'SINO';
  137. LREAG. &SURi = 0.D0;
  138. 'FINS';
  139. 'FIN' SURi ;
  140. Ltps1 ='ETG' Ltps1 ;
  141. LREAL ='ETG' LREAL ;
  142. LREAG ='ETG' LREAG ;
  143.  
  144. EVO_RL ='EVOL' 'BLEU' 'MANU' 'TEMP' Ltps1 'Reac_L' LREAL ;
  145. EVO_RG ='EVOL' 'ROUG' 'MANU' 'TEMP' Ltps1 'Reac_G' LREAG ;
  146.  
  147. Tit1 ='CHAI' 'Reactions sur les blocages CL et CG';
  148. 'DESS' (EVO_RL 'ET' EVO_RG) 'GRIL' 'TITR' Tit1 'LEGE' TLEG ;
  149.  
  150. 'REPE' SURi ('DIME' xtab.'TEMPS') ;
  151. Ci ='EXCO' xtab.'CONCENTRATIONS'. (&SURi - 1) 'CL';
  152. Tpsi = xtab.'TEMPS'. (&SURi - 1) ;
  153. Titi ='CHAI' 'Concentration ''CL'' au temps :' Tpsi ;
  154. 'TRAC' Ci su1 'TITR' Titi ;
  155. 'FIN' SURi ;
  156.  
  157. 'REPE' SURi ('DIME' xtab.'TEMPS') ;
  158. Ci ='EXCO' xtab.'CONCENTRATIONS'. (&SURi - 1) 'CG';
  159. Tpsi = xtab.'TEMPS'. (&SURi - 1) ;
  160. Titi ='CHAI' 'Concentration ''CG'' au temps :' Tpsi ;
  161. 'TRAC' Ci su1 'TITR' Titi ;
  162. 'FIN' SURi ;
  163.  
  164. FIN ;
  165.  
  166.  
  167.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales