Télécharger thgdep2.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : thgdep1.dgibi
  2. IG1 = FAUX ;
  3. *----------------------------------------------------------------------*
  4. * Cas-test de calcul thermomecanique en grands deplacements, avec *
  5. * convergence thermique-mécanique. *
  6. * On teste egalement la reprise en prolongeant la liste des temps. *
  7. * Dans ce cas, le dernier PAS calculé au 1er appel de PASAPAS est *
  8. * recalcule au 2e appel, ce qui decale les indices de la table. *
  9. *----------------------------------------------------------------------*
  10. 'OPTI' 'DIME' 2 'ELEM' 'QUA4' ;
  11. * *
  12. O1 = 0. 0. ;
  13. X1 = 1. 0. ;
  14. Y1 = 0. 1. ;
  15. * *
  16. L1 = O1 'DROI' 5 X1 ;
  17. S1 = L1 'TRAN' 3 Y1 ;
  18. L2 = S1 'COTE' 2 ;
  19. L3 = S1 'COTE' 3 ;
  20. L4 = S1 'COTE' 4 ;
  21. 'SI' IG1 ;
  22. 'TRAC' 'QUAL' S1 ;
  23. 'FINS' ;
  24. * *
  25. MODT1 = 'MODE' S1 'THERMIQUE' ;
  26. MODM1 = 'MODE' S1 'MECANIQUE' ;
  27. * *
  28. MATT1 = 'MATE' MODT1 'K' 100. 'RHO' 0. 'C' 1. ;
  29. MATM1 = 'MATE' MODM1 'YOUN' 2.E9 'NU' 0.25 'ALPH' 1.E-6 ;
  30. * *
  31. MOD1 = MODT1 'ET' MODM1 ;
  32. MAT1 = MATT1 'ET' MATM1 ;
  33. * *
  34. CLM1 = ('BLOQ' L1 'UY') 'ET' ('BLOQ' L4 'UX') ;
  35. CLT1 = 'BLOQ' L1 'T' ;
  36. *
  37. F1 = 'PRES' 'MASS' MODM1 L3 (-1.E8) ;
  38. Q1 = 'FLUX' MODT1 L3 300. ;
  39. QREF1 = 'FLUX' MODT1 L3 1. ;
  40. * *
  41. LTPS1 = 'PROG' 0. 1.0 2. ;
  42. LAMP1 = 'PROG' 0. 0.5 1. ;
  43. EV1 = 'EVOL' 'MANU' 'TEMP' LTPS1 'AMPL' LAMP1 ;
  44. * *
  45. CGM1 = 'CHAR' 'MECA' F1 EV1 ;
  46. CGT1 = 'CHAR' 'Q' Q1 EV1 ;
  47. * *
  48. TAB1 = 'TABL' ;
  49. TAB1 . 'MODELE' = MOD1 ;
  50. TAB1 . 'CARACTERISTIQUES' = MAT1 ;
  51. TAB1 . 'BLOCAGES_MECANIQUES' = CLM1 ;
  52. TAB1 . 'BLOCAGES_THERMIQUES' = CLT1 ;
  53. TAB1 . 'CHARGEMENT' = CGM1 'ET' CGT1 ;
  54. TAB1 . 'TEMPS_CALCULES' = 'PROG' 0. 1. ;
  55. TAB1 . 'GRANDS_DEPLACEMENTS' = VRAI ;
  56. TAB1 . 'RELAXATION_THETA' = 1. ;
  57. TAB1 . 'CONVERGENCE_MEC_THE' = VRAI ;
  58. * *
  59. PASAPAS TAB1 ;
  60. * *
  61. CHT1 = TAB1 . 'TEMPERATURES' . 1 ;
  62. DEP1 = TAB1 . 'DEPLACEMENTS' . 1 ;
  63. * *
  64. UXM1 = 'MINI' ('EXCO' DEP1 'UX') ;
  65. UYM1 = 'MAXI' ('EXCO' DEP1 'UY') ;
  66. TM1 = 'MAXI' ('ENLE' CHT1 'LX') ;
  67. FLU1 = ('MAXI' ('TIRE' CGT1 'Q' 1.)) / ('MAXI' QREF1) ;
  68. TREF1 = FLU1 / ('EXTR' MATT1 'K' 1 1 1) * (1. + UYM1) / (1. + UXM1) ;
  69. ERR1 = 'ABS' (TM1 - TREF1) ;
  70. * *
  71. TAB1 . 'TEMPS_CALCULES' = LTPS1 ;
  72. * *
  73. PASAPAS TAB1 ;
  74. * *
  75. IFIN1 = ('DIME' TAB1 . 'TEMPERATURES') - 1 ;
  76. CHT2 = TAB1 . 'TEMPERATURES' . IFIN1 ;
  77. DEP2 = TAB1 . 'DEPLACEMENTS' . IFIN1 ;
  78. * *
  79. UXM2 = 'MINI' ('EXCO' DEP2 'UX') ;
  80. UYM2 = 'MAXI' ('EXCO' DEP2 'UY') ;
  81. TM2 = 'MAXI' ('ENLE' CHT2 'LX') ;
  82. FLU2 = ('MAXI' ('TIRE' CGT1 'Q' 2.)) / ('MAXI' QREF1) ;
  • TREF2 = FLU2 / ('EXTR' MATT1 'K' 1 1 1) * (1. + UYM2) / (1. + UXM2) ;
  • ERR2 = 'ABS' (TM2 - TREF2) ;
  • * *
  • 'SI' ((ERR1 > 1.E-4) 'OU' (ERR2 > 1.E-4)) ;
  • 'ERRE' 5 ;
  • 'SINO' ;
  • 'OPTI' 'ECHO' 0 ;
  • 'SAUT' 1 'LIGN' ;
  • 'MESS' ' ****** Erreur max. = ' ('MAXI' ('PROG' err1 err2)) ;
  • 'MESS' ' ' ;
  • 'MESS' ('CHAI' ' -'
  • '----------------------------- TEST REUSSI ----------------------------'
  • '-') ;
  • 'FINS' ;
  • 'FIN' ;
  • 'OPTI' 'ECHO' 1 ;
  •  
  •  
  •  
  •  
  • © Cast3M 2003 - Tous droits réservés.
    Mentions légales