Télécharger ricbet_3d.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : ricbet_3d.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *******************************************************
  5. * Cas test de l'implantation numerique du modele
  6. * RICBET LOCAL/NON LOCAL 3D
  7. *******************************************************
  8. * Développé par :
  9. * Benjamin Richard
  10. * Contact :
  11. * Benjamin.Richard@lmt.ens-cachan.fr
  12. * Institution :
  13. * CEA\DEN\DANS\DM2S\SEMT\EMSI
  14. * LMT\ENS Cachan
  15. *******************************************************
  16. * Les cas de charges sont entrés :
  17. * - 1 : Traction monotone
  18. * - 2 : Compression monotone
  19. * - 3 : Traction cyclique
  20. * - 4 : Compression cyclique
  21. * - 5 : Traction/compression cyclique
  22. * - 6 : Compression/traction
  23. * - 7 : Traction/Compression/Traction 1
  24. * - 8 : Traction/Compression/Traction 2
  25. *******************************************************
  26. graph = 'N';
  27.  
  28. * Choix du cas de charge-
  29. ncas = 1;
  30.  
  31. * Test du fichier compatible avec le non local
  32. * nloc0 = 0; Cas local
  33. * nloc0 = 1; Cas non local
  34.  
  35. nloc0 = 0;
  36.  
  37. * Calcul élastiques (pour référence avant fissuration)
  38. * nelas = 1; cas non lineaire
  39. * nelas = 0; cas lineaire
  40.  
  41. nelas = 1;
  42. *******************************************************
  43.  
  44. *
  45. *-------------- Options de calcul ---------------------
  46. *
  47. OPTION DIME 3 ELEM CUB8;
  48.  
  49. *
  50. *-------------- Definition de la geometrie ------------
  51. *
  52. P1 = 0. 0. 0.;
  53. P2 = 1. 0. 0.;
  54. P3 = 1. 1. 0.;
  55. P4 = 0. 1. 0.;
  56. P5 = 0. 0. 1. ;
  57.  
  58. L1 = P1 DROIT 1 P2 ;
  59. L2 = P2 DROIT 1 P3 ;
  60. L3 = P3 DROIT 1 P4 ;
  61. L4 = P4 DROIT 1 P1 ;
  62.  
  63. LTOT = L1 ET L2 ET L3 ET L4 ;
  64. SURF1 = SURF LTOT PLANE;
  65. VOLTO =VOLU SURF1 1 TRANS P5;
  66. SURF2= FACE VOLTO 2;
  67.  
  68. VOLTOT = VOLTO;
  69.  
  70. *
  71. *------- Définition des conditions aux limites --------
  72. *----------- et des déplacements imposés --------------
  73. *
  74. CL = BLOQ SURF1 UZ;
  75. CLL = BLOQ P1 'DEPL';
  76. CL1 = BLOQ SURF2 Uz;
  77. CL2 = bloq (noeud 3) UY;
  78. cl=cl et cl2;
  79.  
  80. D1 = DEPI CL1 1;
  81.  
  82. *
  83. *----- Définition du modèle ---------------------------
  84. *
  85. SI (EGA nelas 1);
  86. MOD1=MODE VOLTOT MECANIQUE ELASTIQUE ISOTROPE ENDOMMAGEMENT RICBET;
  87. SINON;
  88. MOD1=MODE VOLTOT MECANIQUE ELASTIQUE ISOTROPE;
  89. FINSI;
  90. EBETON = 34100E6;
  91. NUBETON = 0.16;
  92. LC = 0.020;
  93. FTN = 3.80E+6;
  94.  
  95. * Young modulus
  96. youngn = EBETON;
  97.  
  98. * Poisson ratio
  99. nun = NUBETON;
  100.  
  101. * Brittleness in tension
  102. aldin = 6.0e-3;
  103.  
  104. * Hardening modulus 1
  105. gam1n = 5.0e9;
  106.  
  107. * Hardening modulus 2
  108. a1n = 8.0e-6;
  109.  
  110. * Closure stress
  111. srefn = -3e6;
  112.  
  113. * Compression strength (initial)
  114. fcn = 6e6;
  115.  
  116. * Asymptotic stress in compression
  117. sigun = -4e6;
  118.  
  119. * Yield surface 1
  120. afn = 0.7;
  121.  
  122. * Yield surface 2
  123. bfn = 0.3;
  124.  
  125. * Plastic potential 1
  126. agn = 0.6;
  127.  
  128. * Plastic potential 2
  129. bgn = 0.45;
  130.  
  131. * Yield hardening 1
  132. acn = 3.2e10;
  133.  
  134. * Yield hardening 1
  135. bcn = 700.0;
  136.  
  137. SI (EGA nelas 1);
  138. mat1 =MATE mod1 YOUN youngn NU nun
  139. FT ftn GAM1 gam1n
  140. A1 a1n ALDI aldin
  141. SREF srefn AF afn BF bfn
  142. AG agn BG bgn AC acn BC bcn
  143. SIGU sigun FC fcn;
  144. SINON;
  145. mat1 =MATE mod1 YOUN youngn NU nun;
  146. FINSI;
  147.  
  148.  
  149.  
  150.  
  151. *
  152. *----- Définition des cas de charge -------------------
  153. *
  154.  
  155. SI (EGA ncas 1) ;
  156. LI1 = PROG 0. 1. ;
  157. LI2 = PROG 0. 1.0e-3;
  158. LIS1 = PROG 0. PAS 0.01 1.;
  159. FINSI;
  160.  
  161. SI (EGA ncas 2) ;
  162. LI1 = PROG 0. 1.;
  163. LI2 = PROG 0. -1;
  164. LIS1 = PROG 0. PAS 1.E-4 6.0E-3;
  165. FINSI;
  166.  
  167. SI (EGA ncas 3) ;
  168. LI1 = PROG 0. 1. 2. 3. 4. 5.;
  169. LI2 = PROG 0. 1.5e-4 9.5e-6 2.0E-4 3.0E-5 2.5E-4;
  170. LIS1 = PROG 0. PAS 0.02 5.;
  171. FINSI;
  172.  
  173. SI (EGA ncas 4) ;
  174. LI1 = PROG 0. 1. 2. 3. 4. 5.;
  175. LI2 = PROG 0. -3.0e-3 -1.5e-4 -5.0E-3 -3.5E-4 -10.0E-3;
  176. LIS1 = PROG 0. PAS 0.02 5.;
  177. FINSI;
  178.  
  179. SI (EGA ncas 5) ;
  180. LI1 = PROG 0. 1. 2. 3. 4. 5. 6. 7.;
  181. LI2 = PROG 0. 1.3e-4 -3.0e-3 -1.5E-4 -5.0E-3 -3.5E-4 -8.0E-3 1.0E-3;
  182. LIS1 = PROG 0. PAS 0.005 7;
  183. FINSI;
  184.  
  185. SI (EGA ncas 6) ;
  186. LI1 = PROG 0. 1. 2.;
  187. LI2 = PROG 0. -2.0e-3 5.0e-4;
  188. LIS1 = PROG 0. PAS 0.005 2;
  189. FINSI;
  190.  
  191. SI (EGA ncas 7) ;
  192. LI1 = PROG 0. pas 1. 11.;
  193. LI2 = PROG 0. 5.0e-4 -5.0e-4 6.0e-4 -5.0e-4
  194. 7.0e-4 -5.0e-4 8.0e-4 -5.0e-4
  195. 9.0e-4 -5.0e-4 10.0e-4;
  196. LIS1 = PROG 0. PAS 0.01 11;
  197. FINSI;
  198.  
  199. SI (EGA ncas 8) ;
  200. LI1 = PROG 0. 1. 2. 3. 4. 5.;
  201. LI2 = PROG 0. 3.e-4 -1.e-5 5.0E-4 -5E-3 -4.0E-3;
  202. LIS1 = PROG 0. PAS 0.02 2;
  203. FINSI;
  204.  
  205.  
  206. EV = EVOL MANU LI1 LI2 ;
  207. CHA1 = CHAR 'DIMP' D1 EV ;
  208.  
  209. *
  210. *----------- Calcul par l'operateur PASAPAS ------------
  211. *
  212. LC = 1.0e-10;
  213. CO1 = CONNEC mod1 LC NORMAL;
  214.  
  215. TAB1 = TABLE ;
  216. TAB1.'BLOCAGES_MECANIQUES' = CL ET CLL ET CL1;
  217. TAB1.'MODELE' = MOD1;
  218. TAB1.'MOVA' = 'D ';
  219. TAB1.'CHARGEMENT' = CHA1;
  220. TAB1.'CARACTERISTIQUES' = MAT1;
  221. TAB1.'TEMPS_CALCULES' = LIS1;
  222.  
  223. SI (EGA nloc0 1);
  224. TAB1.NON_LOCAL='MOT' 'MOYE' ;
  225. TAB1.LVIAM=(MOTS EPTI);
  226. TAB1.LCAR=LC;
  227. TAB1.CONN = CO1;
  228. FINSI;
  229.  
  230. PASAPAS TAB1 ;
  231.  
  232. dd=dime tab1.deplacements;
  233.  
  234. *
  235. *----------- Courbe effort-deplacement -----------------
  236. *
  237. si (ega graph 'O');
  238. ev2=@global tab1 CL1 EV fz;
  239. @excel1 ev2 'loi_beton-RL5.txt';
  240. DESS EV2;
  241. finsi;
  242.  
  243. ee=tab1.variables_internes.(dd-1);
  244. aa=extr ee 'D ' 1 1 1;
  245. list aa;
  246. message 'erreur relative';
  247.  
  248. err = (aa - 0.99020) / 0.99020;
  249. list err;
  250.  
  251. si (> err 1.0E-3);
  252. erreur(5);
  253. finsi;
  254.  
  255. fin;
  256.  
  257.  
  258.  
  259.  
  260.  
  261.  
  262.  
  263.  
  264.  
  265.  
  266.  
  267.  
  268.  
  269.  
  270.  
  271.  
  272.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales