Télécharger poudre3.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : poudre3.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. ************************************************************
  6. * *
  7. * Cas test pour la loi poudre_A *
  8. * *
  9. * par Christophe DELLIS (CEREM) *
  10. * *
  11. ************************************************************
  12. *
  13. * cas dense
  14. *
  15. *
  16. *opti echo 0 ;
  17. *
  18. option dime 2 elem qua8 mode axis ;
  19. *
  20. * parametres du maillage
  21. *
  22. rayon_1 = 10.0 ;
  23. *
  24. haute_1 = 15.0 ;
  25. *
  26. * definition des coordonnees des points
  27. *
  28. xa0 = 0.0 ;
  29. ya0 = 0.0 ;
  30. *
  31. xa1 = rayon_1 ;
  32. ya1 = ya0 ;
  33. *
  34. xa2 = xa1 ;
  35. ya2 = ya1 + haute_1 ;
  36. *
  37. xa3 = 0.0 ;
  38. ya3 = ya2 ;
  39. *
  40. * definition des densites
  41. *
  42. dena0 = 10.0 ;
  43. dena1 = 10.0 ;
  44. dena2 = 10.0 ;
  45. dena3 = 10.0 ;
  46. *
  47. * definition des points
  48. *
  49. densite dena0 ;
  50. a0 = xa0 ya0 ;
  51. *
  52. densite dena1 ;
  53. a1 = xa1 ya1 ;
  54. *
  55. densite dena2 ;
  56. a2 = xa2 ya2 ;
  57. *
  58. densite dena3 ;
  59. a3 = xa3 ya3 ;
  60. *
  61. * definition des lignes
  62. *
  63. la0a1 = a0 droi 2 a1 ;
  64. la1a2 = a1 droi 2 a2 ;
  65. la2a3 = a2 droi 2 a3 ;
  66. la3a0 = a3 droi 2 a0 ;
  67. *
  68. la3a2 = inve la2a3 ;
  69. la2a1 = inve la1a2 ;
  70. *
  71. * lignes pour les conditions limites
  72. *
  73. l_symz = la0a1 ;
  74. l_symx = la3a0 ;
  75. l_ext1 = la1a2 ;
  76. l_ext2 = la2a3 ;
  77. *
  78. * definition des surfaces
  79. *
  80. elmat1 = surf ( la0a1 et la1a2 et la2a3 et la3a0 ) plan ;
  81. *
  82. piece_1 = coul elmat1 bleu ;
  83. *
  84. tot = piece_1 ;
  85. elim (tot et a2) 0.001 ;
  86. *
  87. *
  88. ************************************************************
  89. * *
  90. * calcul *
  91. * *
  92. ************************************************************
  93. *
  94. T0TEMPE = 925.0 ;
  95. T1TEMPE = 925.0 ;
  96. T0TEMPS = 0.0 ;
  97. T1TEMPS = 1200.0 ;
  98. T2TEMPS = 2400.0 ;
  99. T3TEMPS = 3600.0 ;
  100. *
  101. *******************************************
  102. * Champ-point de temperature
  103. *******************************************
  104. *
  105. clth0001 = BLOQ 'T' (l_ext1 et l_ext2) ;
  106. p_bloth1 = DEPI clth0001 1. ;
  107. p_temps1 = prog T0TEMPS T1TEMPS T2TEMPS T3TEMPS ;
  108. p_theta1 = prog T0TEMPE T1TEMPE T1TEMPE T0TEMPE ;
  109. ev_ther1 = EVOL MANU TEMPS p_temps1 'T' p_theta1 ;
  110. ch_ther1 = CHAR TIMP p_bloth1 ev_ther1 ;
  111. *
  112. ************************************************************
  113. * *
  114. * materiau *
  115. * *
  116. ************************************************************
  117. P1MODEL = MODE piece_1 MECANIQUE ELASTIQUE
  118. VISCOPLASTIQUE POUDRE_A CONS DEUX;
  119. *
  120. V1YOUNG = 118.0E+03 ;
  121. V1NU = 0.33 ;
  122. V1ALPHA = 10.0E-20 ;
  123. V1A = 7.76e-15 ;
  124. V1N = 4.55 ;
  125. V1QSRT = 0.0 ;
  126. V1RHOR = 1.0 ;
  127. V1F0 = 0.1098 ;
  128. V1F1 = 1.0168 ;
  129. V1F2 = -0.2591 ;
  130. V1F3 = 0.0 ;
  131. V1F4 = 0.0 ;
  132. V1F5 = 0.66 ;
  133. V1C0 = 2.10851 ;
  134. V1C1 = 1.21767 ;
  135. V1C2 = -0.43081 ;
  136. V1C3 = 0.0 ;
  137. V1C4 = 0.0 ;
  138. V1C5 = 50.0 ;
  139. *
  140. P1MATER = MATER P1MODEL YOUNG V1YOUNG NU V1NU ALPHA V1ALPHA
  141. A V1A N V1N QSRT V1QSRT F0 V1F0 F1 V1F1 F2 V1F2 F3 V1F3
  142. F4 V1F4 F5 V1F5 C0 V1C0 C1 V1C1 C2 V1C2 C3 V1C3 C4 V1C4
  143. C5 V1C5 RHOR V1RHOR ;
  144. *
  145. P2MODEL = MODE piece_1 THERMIQUE ISOTROPE CONS UN ;
  146. *
  147. P2MATER = MATER P2MODEL 'C' 460 'K' 14.6 'RHO' 4.54 ;
  148. *
  149. ************************************************************
  150. * *
  151. * chargement *
  152. * *
  153. ************************************************************
  154. *
  155. p0bloca = bloque uz l_symz ;
  156. p1bloca = bloque ur l_symx ;
  157. *
  158. p_bloca = p0bloca et p1bloca ;
  159. *
  160. t0pres = 0.0 ;
  161. t1pres = 100.0 ;
  162. *
  163. li_tps = prog t0temps t1temps t2temps t3temps ;
  164. li_pres = prog t0pres t1pres t1pres t0pres ;
  165. ev_pres = evol manu temps li_tps pression li_pres ;
  166. *dess ev_pres titr 'Evolution du chargement en pression' nclk ;
  167. *
  168. p2force = pres mass p1model 1.0 l_ext1 ;
  169. p3force = pres mass p1model 1.0 l_ext2 ;
  170. titr 'Force appliquees' ;
  171. vec1 = vect (p2force et p3force) 'FR' 'FZ' 0.1;
  172. *trac vec1 piece_1 nclk ;
  173. *
  174. p2charg = char p2force ev_pres 'MECA';
  175. p3charg = char p3force ev_pres 'MECA';
  176. *
  177. p_charg = p2charg et p3charg ;
  178. *
  179. ************************************************************
  180. * *
  181. * calcul *
  182. * *
  183. ************************************************************
  184. *
  185. p_model = p1model et p2model ;
  186. p_mater = p1mater et p2mater ;
  187. *
  188. * Initialisation de la table pour la procedure PASAPAS
  189. *
  190. TAB1 = TABLE ;
  191. TAB1 . 'CHARGEMENT' = (p_charg et ch_ther1) ;
  192. TAB1 . 'MODELE' = p_model ;
  193. TAB1 . 'CARACTERISTIQUES' = p_mater ;
  194. TAB1 . 'BLOCAGES_MECANIQUES' = p_bloca ;
  195. TAB1 . 'BLOCAGES_THERMIQUES' = clth0001 ;
  196. TAB1 . 'TEMPS_CALCULES' = PROG 0.0
  197. PAS 50.0 2400.0 ;
  198. TAB1 . 'TEMPS_SAUVES' = PROG 2400.0 ;
  199. TAB1 . 'MAXITERATION' = 49 ;
  200. TAB1 . 'MAXISOUSPAS' = 500 ;
  201. TAB1 . 'MOVA' = 'MOT' 'VHOR' ;
  202. TAB1 . 'PRECISION' = 1.0E-4 ;
  203. TAB1 . 'TALPHA_REFERENCE' = 20.0 ;
  204. TAB1 . 'PROCEDURE_THERMIQUE' = 'MOT' 'LINEAIRE' ;
  205. *
  206. PASAPAS TAB1 ;
  207. *
  208. ************************************************************
  209. * *
  210. * Test de validation *
  211. * *
  212. ************************************************************
  213. *
  214. ind1 = index (TAB1 . 'VARIABLES_INTERNES') ;
  215. nb1 = dime ind1 ;
  216. *
  217. * densite finale
  218. *
  219. vm1 = TAB1 . 'VARIABLES_INTERNES' .(ind1.nb1) ;
  220. vm2 = exco VHOR vm1 ;
  221. vm3 = redu vm2 piece_1 ;
  222. rhof1 = maxi vm3 ;
  223. *
  224. * Calcul theorique analytique de la densite finale :
  225. *
  226. rhof2 = 1.0 ;
  227. *
  228. *
  229. erho1 = abs ((rhof1 - rhof2 )/rhof2);
  230. *
  231. * Ecriture des erreurs a l'ecran :
  232. *
  233. opti echo 0 ;
  234. sauter 3 lignes ;
  235. mess 'Erreur sur la densite finale: ' erho1 ;
  236. sauter 3 lignes ;
  237.  
  238. *
  239. si ( (erho1 ) >eg 0.05 ) ;
  240. mess '---------RESULTATS INCORRECTS-------------' ;
  241. sauter 3 lignes ;
  242. erreur 5;
  243. sinon ;
  244. mess '---------RESULTATS CORRECTS-------------' ;
  245. sauter 3 lignes ;
  246. finsi ;
  247. *
  248. fin ;
  249.  
  250.  
  251.  
  252.  
  253.  
  254.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales