Télécharger mistral_D3d.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : mistral_D3d.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. * Test mistral_D3d.dgibi: Jeux de donnees *
  6. * --------------------------------------- *
  7. * *
  8. opti echo 0 ;
  9. opti dime 3 mode tridim elem cu20 ;
  10. * ajout de option epsilon lineaire pour la precision des test!
  11. OPTION epsilon lineaire;
  12.  
  13. *
  14. *******************************************************
  15. * TEST DE VALIDATION *
  16. * ------------------ *
  17. * MODELE MISTRAL *
  18. * ELASTICITE ET PLASTICITE INSTANTANEE *
  19. * *
  20. * MAILLAGE: *
  21. * EPROUVETTE CUBIQUE *
  22. * *
  23. * CHARGEMENT: *
  24. * DEPLACEMENT IMPOSE MONOTONE CROISSANT *
  25. *******************************************************
  26. *
  27. * Geometrie
  28. *
  29. * ------------------------------------------
  30. XX = 1. ; YY = 1. ; ZZ = 1. ;
  31. * ------------------------------------------
  32. *
  33. PB00 = 0 0 0 ; PB10 = XX 0 0 ;
  34. PB11 = XX YY 0 ; PB01 = 0 YY 0 ;
  35. VECZ = 0 0 ZZ ;
  36. *
  37. LBX0 = droi 1 PB00 PB10 ;
  38. LBY1 = droi 1 PB10 PB11 ;
  39. LBX1 = droi 1 PB11 PB01 ;
  40. LBY0 = droi 1 PB01 PB00 ;
  41. *
  42. * Maillage
  43. *
  44. PLB = dall LBX0 LBY1 LBX1 LBY0 plan ;
  45. EPROU = PLB volu 1 tran VECZ ;
  46. PLH = face 2 EPROU ;
  47. PL0YZ = EPROU poin plan PB00 PB01 VECZ 1E-3 ;
  48. PLX0Z = EPROU poin plan PB00 PB10 VECZ 1E-3 ;
  49. * trac EPROU ;
  50. *
  51. * Modele et materiau
  52. *
  53. MOD3 = mode EPROU mecanique elastique orthotrope
  54. viscoplastique mistral ;
  55. *
  56. * ------------------------------------------------------------
  57. VEC1 = 1. 1. 0. ; VEC2 = -1. 1. 0. ; TETA = 45. ;
  58. SENSIP1 = -2 ; SENSIP2 = 1 ; ICBASE = 0 ;
  59. fichier = '/u/castem/divers/mimatD3d_par' ;
  60. PDILT E1 E2 E3 NU12 NU23 NU13 MU12 MU23 MU13
  61. PNBRE PCOHI PECOU PEDIR PRVCE PECRX PDVDI PCROI PINCR
  62. = @mistpar fichier SENSIP1 SENSIP2 ;
  63. * ------------------------------------------------------------
  64. MAT3 = mate MOD3 'YG1 ' E1 'YG2 ' E2 'YG3 ' E3
  65. 'NU12' NU12 'NU23' NU23 'NU13' NU13
  66. 'G12 ' MU12 'G13 ' MU13 'G23 ' MU23
  67. 'ALP1' 0. 'ALP2' 0. 'ALP3' 0.
  68. 'DILT' PDILT 'NBRE' PNBRE 'COHI' PCOHI 'ACOU' PECOU 'EDIR' PEDIR
  69. 'RVCE' PRVCE 'ECRX' PECRX 'DVDI' PDVDI 'CROI' PCROI 'INCR' PINCR
  70. 'SIP1' SENSIP1 'SIP2' SENSIP2 'IBAS' ICBASE
  71. 'DIRECTION' VEC1 VEC2 'INCLINE' TETA ;
  72. *
  73. * Conditions aux limites
  74. *
  75. CLB = bloq uz PLB ;
  76. CLH = bloq uz PLH ;
  77. CLYZ = bloq ux PL0YZ ;
  78. CLXZ = bloq uy PLX0Z ;
  79. CL = CLB et CLH et CLYZ et CLXZ ;
  80. *
  81. * Chargement
  82. *
  83. * -------------------------------------------------------
  84. T1 = 100. ; DT1 = 10. ;
  85. EPSZZ1 = 0.02 ;
  86. TT1 = 300. ;
  87. PHIT0 = 0. ;
  88. * -------------------------------------------------------
  89. TEMPS = prog 0. T1 ;
  90. TEMPSCAL = prog 0. pas DT1 T1 ;
  91. *
  92. DEPZ = depi CLH ZZ ;
  93. EVEPS = evol manu TEMPS (prog 0. EPSZZ1) ;
  94. CHADE = char dimp DEPZ EVEPS ;
  95. *
  96. TT = manu chpo EPROU 1 'T' 1. ;
  97. EVTT = evol manu TEMPS (prog TT1 TT1) ;
  98. CHTT = char 'T' TT EVTT ;
  99. *
  100. PHI = manu chpo EPROU 1 'FI' 1. ;
  101. EVFI = evol manu TEMPS (prog 0. 0.) ;
  102. CHFI = char 'FI' PHI EVFI ;
  103. *
  104. CHA = CHADE et CHTT et CHFI ;
  105. *
  106. * Valeurs initiales
  107. *
  108. VINT0 = zero MOD3 'VARINTER' ;
  109. FIT0 = manu chml MOD3 'FIT ' PHIT0 type 'SCALAIRE' 'STRESSES' ;
  110. VINT0 = VINT0 + FIT0 ;
  111. *
  112. * Calcul
  113. *
  114. TAB = TABLE ;
  115. TAB.'VARIABLES_INTERNES' = TABLE ;
  116. TAB.'BLOCAGES_MECANIQUES' = CL ;
  117. TAB.'CARACTERISTIQUES' = MAT3 ;
  118. TAB.'MODELE' = MOD3 ;
  119. TAB.'CHARGEMENT' = CHA ;
  120. TAB.'VARIABLES_INTERNES' . 0 = VINT0 ;
  121. TAB.'TEMPS_CALCULES' = TEMPSCAL ;
  122. *
  123. PASAPAS TAB ;
  124. *
  125. * Traitement des resultats
  126. *
  127. SIG = TAB.'CONTRAINTES' ;
  128. DEP = tab.'DEPLACEMENTS' ;
  129. VI = tab.'VARIABLES_INTERNES' ;
  130. NT = dime TEMPSCAL-1 ;
  131. * ----------------
  132. ERMAX = 0.005 ;
  133. * ----------------
  134. *
  135. SIGT = SIG.NT ;
  136. SIGT_PO = chang chpo MOD3 SIGT ;
  137. SIGXX = extr SIGT_PO SMXX PB00 ;
  138. SIGYY = extr SIGT_PO SMYY PB00 ;
  139. SIGZZ = extr SIGT_PO SMZZ PB00 ;
  140. SIGXY = extr SIGT_PO SMXY PB00 ;
  141. SIGXZ = extr SIGT_PO SMXZ PB00 ;
  142. SIGYZ = extr SIGT_PO SMYZ PB00 ;
  143. *
  144. DEPT = DEP.NT ;
  145. EPSIT = epsi DEPT MOD3 ;
  146. EPSIT_PO = chang chpo MOD3 EPSIT ;
  147. EPSXX = extr EPSIT_PO EPXX PB00 ;
  148. EPSYY = extr EPSIT_PO EPYY PB00 ;
  149. EPSZZ = extr EPSIT_PO EPZZ PB00 ;
  150. EPSXY = (extr EPSIT_PO GAXY PB00)/2. ;
  151. EPSXZ = (extr EPSIT_PO GAXZ PB00)/2. ;
  152. EPSYZ = (extr EPSIT_PO GAYZ PB00)/2. ;
  153. *
  154. VIT = VI.NT ;
  155. VIT_PO = chang chpo MOD3 VIT ;
  156. EPSP11 = extr VIT_PO EP01 PB00 ;
  157. EPSP22 = extr VIT_PO EP02 PB00 ;
  158. EPSP33 = extr VIT_PO EP03 PB00 ;
  159. EPSP12 = extr VIT_PO EP04 PB00 ;
  160. EPSP13 = extr VIT_PO EP05 PB00 ;
  161. EPSP23 = extr VIT_PO EP06 PB00 ;
  162. *
  163. mess ;
  164. mess 'SIGXX SIGYY SIGZZ : ' SIGXX SIGYY SIGZZ ;
  165. mess 'SIGXY SIGXZ SIGYZ : ' SIGXY SIGXZ SIGYZ ;
  166. mess ;
  167. mess 'EPSXX EPSYY EPSZZ : ' EPSXX EPSYY EPSZZ ;
  168. mess 'EPSXY EPSXZ EPSYZ : ' EPSXY EPSXZ EPSYZ ;
  169. mess ;
  170. mess 'EPSP11 EPSP22 EPSP33 : ' EPSP11 EPSP22 EPSP33 ;
  171. mess 'EPSP12 EPSP13 EPSP23 : ' EPSP12 EPSP13 EPSP23 ;
  172. mess ;
  173. *
  174. * -----------------------------------------------------
  175. SIGZZ1 = 486970389. ;
  176. EPSP331 = 0.01513029 ;
  177. YOUNGX = 1.E11 ; YOUNGY = 1.E11 ; YOUNGZ = 1.E11 ;
  178. POISYZ = 0.2 ; POISZX = 0.4 ;
  179. * -----------------------------------------------------
  180. EPSEZZ1 = SIGZZ1/YOUNGZ ;
  181. EPSEXX1 = (-1.)*(POISZX/YOUNGZ)*SIGZZ1 ;
  182. EPSEYY1 = (-1.)*(POISYZ/YOUNGY)*SIGZZ1 ;
  183. EPSP111 = (-0.6)*EPSP331 ;
  184. EPSP221 = (-0.4)*EPSP331 ;
  185. EPSXX1 = EPSEXX1 + EPSP111 ;
  186. EPSYY1 = EPSEYY1 + EPSP221 ;
  187. EPSZZ1 = EPSEZZ1 + EPSP331 ;
  188. *
  189. ERSIGZZ = ABS(SIGZZ/SIGZZ1 - 1.) ;
  190. *
  191. EREPSXX = EPSXX/EPSXX1 - 1. ;
  192. EREPSYY = EPSYY/EPSYY1 - 1. ;
  193. EREPSZZ = EPSZZ/EPSZZ1 - 1. ;
  194. P_ER = prog EREPSXX EREPSYY EREPSZZ ;
  195. EREPSMA = maxi P_ER 'ABS' ;
  196. *
  197. EREPSP11 = EPSP11/EPSP111 - 1. ;
  198. EREPSP22 = EPSP22/EPSP221 - 1. ;
  199. EREPSP33 = EPSP33/EPSP331 - 1. ;
  200. P_ER = prog EREPSP11 EREPSP22 EREPSP33 ;
  201. EREPSPMA = maxi P_ER 'ABS' ;
  202. *
  203. si (ERSIGZZ > ERMAX) ;
  204. mess ;
  205. mess 'ABS(erreur relative) sur la contrainte > ' ERMAX ;
  206. mess ERSIGZZ ;
  207. finsi ;
  208. si (EREPSMA > ERMAX) ;
  209. mess ;
  210. mess 'ABS(erreur relative) sur une deformation totale > ' ERMAX ;
  211. mess EREPSXX EREPSYY EREPSZZ ;
  212. finsi ;
  213. si (EREPSPMA > ERMAX) ;
  214. mess ;
  215. mess 'ABS(erreur relative) sur une deformation plastique > ' ERMAX ;
  216. mess EREPSP11 EREPSP22 EREPSP33 ;
  217. mess ;
  218. finsi ;
  219. P_ER = prog ERSIGZZ EREPSMA EREPSPMA ;
  220. ERMA = maxi P_ER ;
  221. si (ERMA > ERMAX) ;
  222. ERRE 5 ;
  223. finsi ;
  224.  
  225. fin ;
  226.  
  227.  
  228.  
  229.  
  230.  
  231.  
  232.  
  233.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales