Télécharger gatt_3d.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : gatt_3d.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. * Test gatt_3d.dgibi: Jeux de données
  6. * ---------------------------------------
  7. *
  8. 'OPTI' 'DIME' 3 'MODE' 'TRID' ;
  9. 'OPTI' 'ELEM' 'CU20' ;
  10. 'OPTI' 'TRAC' 'PSC' ;
  11. 'TEMPS' 'ZERO' ;
  12. L = 'MOT' LIST ; F = 'MOT' FIN ;
  13. *
  14. *******************************************************
  15. * TEST DE VALIDATION *
  16. * ------------------ *
  17. * MODELE GATT_MONERIE *
  18. * UO2 STANDARD COMPRESSIBLE AVEC COUPLAGE STATIQUE *
  19. * *
  20. * MAILLAGE: *
  21. * EPROUVETTE PART DE CAMEMBERT *
  22. * *
  23. * CHARGEMENT: *
  24. * DEPLACEMENT VERTICAL IMPOSE *
  25. * TRACTION - COMPRESSION *
  26. * TEMPERATURE CONSTANTE *
  27. * DENSITE DE FISSIONS CONSTANTE *
  28. * PRIMAIRE - MECANISMES 1 ET 2 - IRRADIATION *
  29. * DENSIFICATION - GONFLEMENT *
  30. *******************************************************
  31. *
  32. GRAPH = FAUX ;
  33. LISTCOUR = VRAI ;
  34. *
  35. NA = 1 ;
  36. NR = 1 ;
  37. H = 6.2e-3 ;
  38. D = 5.e-3 ;
  39. R = D/2. ;
  40. HS2 = H/2. ;
  41. *
  42. OO = 0. 0. 0. ;
  43. A1 = R 0. 0. ;
  44. A2 = R 0. HS2 ;
  45. A3 = 0. 0. HS2 ;
  46. *
  47. LB = 'DROIT' NR OO A1 ;
  48. LD = 'DROIT' NA A1 A2 ;
  49. LH = 'DROIT' NR A2 A3 ;
  50. LG = 'DROIT' NA A3 OO ;
  51. *
  52. SU1 = 'DALL' LB LD LH LG 'PLAN' ;
  53. *
  54. SU2 = SU1 'TOUR' 30. OO A3 ;
  55. VOL1 = 'VOLU' 1 SU1 SU2 ;
  56. 'ELIM' (D/1000.) VOL1 ;
  57. VOL1 = 'REGE' VOL1 ;
  58. SUA = 'POIN' ('COOR' 2 VOL1) 'INFERIEUR' (D/1000.) ;
  59. SUB = 'POIN' ('COOR' 3 VOL1) 'INFERIEUR' (D/1000.) ;
  60. SUH = 'POIN' ('COOR' 3 VOL1) 'SUPERIEUR' (HS2 - (D/1000.)) ;
  61. LG = VOL1 'POIN' 'DROIT' OO A3 (D/1000) ;
  62. *
  63. MODL1= MODE VOL1 MECANIQUE ELASTIQUE VISCOPLASTIQUE GATT_MONERIE ;
  64. *
  65. * ----------------------*
  66. * Materiau GATT_MONERIE *
  67. * ----------------------*
  68. TE1 = 1400. + 273. ;
  69. PO = 4.52E-2 ;
  70. DF1 = 1.E18 ;
  71. TA = @GATTPAR '/u2/castem/divers/fichier_gatt' ;
  72. *
  73. * fluage primaire rendu significatif pour UO2 standard
  74. TA.'KPUO' = 1E3 * TA.'KPUO' ;
  75. *
  76. MATREE = MATE MODL1 'YOUN' (TA.'YOUN') ;
  77. PP = 'MANU' 'CHML' MODL1 'T' TE1 'PORO' PO RIGIDITE ;
  78. EE = 'VARI' 'NUAG' MODL1 MATREE PP ;
  79. *
  80. MATR11 = 'MATE' MODL1 'YOUN' EE 'NU' 0.3 'RHO' 10950. 'ALPH' 0. ;
  81. *
  82. MATR12 = 'MATE' MODL1
  83. 'R' (TA.'R') 'DG0' (TA.'DG0') 'DG' (TA.'DG')
  84. 'K1' (TA.'K1') 'M1' (TA.'M1') 'Q1' (TA.'Q1') 'N1' (TA.'N1')
  85. 'K2' (TA.'K2') 'M2' (TA.'M2') 'Q2' (TA.'Q2') 'N2' (TA.'N2')
  86. 'OMEG' (TA.'OMEG') 'H' (TA.'H') 'Q' (TA.'Q') 'BETA' (TA.'BETA')
  87. 'K' (TA.'K') 'A' (TA.'A') 'Q3' (TA.'Q3') 'N3' (TA.'N3')
  88. 'CR' (TA.'CR') 'CR1' (TA.'CR1') 'CR2' (TA.'CR2') 'CR3' (TA.'CR3');
  89. *
  90. MATR13 = 'MATE' MODL1 'KP' (TA.'KPUO') 'AP' (TA.'AP')
  91. 'BP' (TA.'BP') 'QP' (TA.'QP') ;
  92. *
  93. MATR14 = 'MATE' MODL1
  94. 'ADEN' (TA.'ADEN') 'KGON' (TA.'KGON')
  95. 'POR0' (TA.'POR0') 'BUMI' (TA.'BUMI') 'EFIS' (TA.'EFIS') ;
  96. *
  97. * TYPE = 0. combustible UO2 sinon combustible AFA3GLAA
  98. * COMP = 0. combustible compressible sinon incompressible
  99. * DYN = 0. couplage statique sinon dynamique
  100. *
  101. MATR1 = MATR11 'ET' MATR12 'ET' MATR13 'ET' MATR14 ;
  102. *
  103. * -----------------------------------------------------*
  104. * Conditions aux limites + deplacement impose sur CLZH *
  105. * -----------------------------------------------------*
  106. CLZB = 'BLOQ' UZ SUB ;
  107. CLZH = 'BLOQ' UZ SUH ;
  108. CLXG = 'BLOQ' UX LG ;
  109. CLYG = 'BLOQ' UY SUA ;
  110. CLT = CLZB 'ET' CLZH 'ET' CLXG 'ET' CLYG ;
  111. *
  112. TMIL = 1.E6 ;
  113. TFIN = 2.E6 ;
  114. *
  115. RHO0 = 1. - TA.'POR0' ;
  116. AKBU = TA.'EFIS'*270./238./10950./RHO0*DF1 ;
  117. * CE QUI SUIT EST VRAI CAR LE FLUX DE FISSIONS EST CONSTANT
  118. TBU = (TA.'BUMI' / AKBU) - 1. ;
  119. TTBU = ('ENTI' (TBU/10000.)) * 10000. ;
  120. *-------------------*
  121. * Instants calcules *
  122. *-------------------*
  123. 'SI' LISTCOUR ;
  124. *--------------
  125. LIST1 = 'PROG' 0 'PAS' 50 300 'PAS' 100 1000 'PAS' 1000 10000
  126. 'PAS' 10000. TTBU
  127. TBU (TTBU+10000.) (TTBU+20000.)
  128. 'PAS' 10000. TMIL ;
  129. 'SINON' ;
  130. *--------
  131. LIST1 = 'PROG' 0 'PAS' 50 300 'PAS' 100 1000 'PAS' 1000 10000
  132. 'PAS' 10000. TTBU
  133. TBU (TTBU+10000.) (TTBU+20000.)
  134. 'PAS' 10000. TMIL
  135. 'PAS' 100. (TMIL + ((TFIN - TMIL) / 200.))
  136. 'PAS' 1000. (TMIL + ((TFIN - TMIL) / 20.))
  137. 'PAS' 2000. (TMIL + ((TFIN - TMIL) / 4.))
  138. 'PAS' 10000. TFIN ;
  139. 'FINSI' ;
  140. *--------
  141. * --------------------------*
  142. * Chargement en temperature *
  143. * --------------------------*
  144. CHTEMP = 'MANU' 'CHPO' VOL1 1 'T' 1. ;
  145. EVT = 'EVOL' 'MANU' ('PROG' 0. (2.*TFIN))
  146. ('PROG' TE1 TE1) ;
  147. CHARTEMP = 'CHAR' 'T' CHTEMP EVT ;
  148. * ---------------------------------*
  149. * Chargement en densite de fission *
  150. * ---------------------------------*
  151. CHFISS = 'MANU' 'CHPO' VOL1 1 'DFIS' 1. ;
  152. EVF = 'EVOL' 'MANU' ('PROG' 0. (2.*TFIN))
  153. ('PROG' DF1 DF1) ;
  154. CHARFISS = 'CHAR' 'DFIS' CHFISS EVF ;
  155. * ---------------------------------*
  156. * Chargement en deplacement impose *
  157. * ---------------------------------*
  158. DEPZ = 'DEPI' CLZH 1 ;
  159. DELTAZ = HS2/200. ;
  160. EVEPS = 'EVOL' 'MANU'
  161. ('PROG' 0. TMIL TFIN (2.*TFIN))
  162. ('PROG' 0. DELTAZ 0. 0.) ;
  163. CHARMECA = 'CHAR' 'DIMP' DEPZ EVEPS ;
  164. *
  165. CHARTOT = CHARMECA 'ET' CHARTEMP 'ET' CHARFISS ;
  166. * ---------------------------------------*
  167. * Variables internes initiales 'PORO'=PO *
  168. * ---------------------------------------*
  169. VAR00 = 'ZERO' MODL1 'VARINTER' ;
  170. VAR01 = 'MANU' 'CHML' MODL1 'PORO' PO
  171. 'TYPE' 'VARIABLES INTERNES' 'STRESSES' ;
  172. VAR0 = VAR00 + VAR01 ;
  173. *
  174. *
  175. TAB1 = TABLE ;
  176. TAB1.'TEMPERATURES' = TABLE ;
  177. TAB1.'VARIABLES_INTERNES'= TABLE ;
  178. TAB1.'BLOCAGES_MECANIQUES' = CLT ;
  179. TAB1.'MODELE' = MODL1 ;
  180. TAB1.'CHARGEMENT' = CHARTOT ;
  181. TAB1.'TEMPERATURES' . 0 = CHTEMP ;
  182. TAB1.'VARIABLES_INTERNES' . 0 = VAR0 ;
  183. TAB1.'CARACTERISTIQUES' = MATR1 ;
  184. TAB1.'TEMPS_CALCULES' = LIST1 ;
  185. TAB1.'TEMPS_SAUVES' = LIST1 ;
  186. *
  187. TMASAU = TABLE ;
  188. tab1 . 'MES_SAUVEGARDES' = TMASAU ;
  189. TMASAU .'DEFTO' = VRAI ;
  190. TMASAU .'DEFIN' = VRAI ;
  191. *
  192. PASAPAS TAB1 ;
  193. *
  194. AP = TA.'AP' ;
  195. BP = TA.'BP' ;
  196. N1 = TA.'N1' ;
  197. N2 = TA.'N2' ;
  198.  
  199. * Facteurs multiplicatifs dus au dopage par le Chrome
  200. WC1 = 'TANH' ( (TA.'CR' - TA.'CR2') / TA.'CR3' ) ;
  201. WC1 = 1. + ( 0.5 * TA.'CR1' * (1. + WC1) ) ;
  202. CV = 180. / PI ;
  203. WC2 = 1. - ( 'COS' (CV * TA.'DG' / TA.'DG0') ) ;
  204. WC2 = 2. * (TA.'DG0'**TA.'M2') * WC2 ;
  205.  
  206. BUMI = TA.'BUMI' ;
  207. AKEVD = AKBU*TA.'KGON' ;
  208. ADEN = TA.'ADEN' ;
  209. KGON = TA.'KGON' ;
  210. * -------------------------------------------------------------------*
  211. * Calcul de la cte AAAA intervenant ds le calcul de la def. de dens. *
  212. * -------------------------------------------------------------------*
  213. BUMAX0=60.D0*BUMI ;
  214. CRIT=1.D-10 ;
  215. 'REPE' BLOC 100 ;
  216. BUMAX = BUMI* ('EXP' (1. - (ADEN/(KGON*BUMAX0)))) ;
  217. BUMAX = (0.2*BUMAX) + (0.8*BUMAX0) ;
  218. TEST='ABS' ((BUMAX-BUMAX0)/BUMAX0) ;
  219. 'SI' ('<' TEST CRIT) ;
  220. 'QUIT' BLOC ;
  221. 'FINS' ;
  222. BUMAX0=BUMAX ;
  223. 'FIN' BLOC ;
  224. AAAA = (-1.D0*RHO0*(ADEN-(KGON*BUMAX))) /
  225. ((1.D0+ADEN)*(LOG(BUMAX/BUMI))) ;
  226. *
  227. * -----------------------*
  228. * Controle des resultats *
  229. * -----------------------*
  230. SS = TAB1 . 'CONTRAINTES' ;
  231. VV = TAB1 . 'VARIABLES_INTERNES' ;
  232. IN = TAB1 . 'DEFORMATIONS_INELASTIQUES' ;
  233. NCONT = ('DIME' (TAB1 . 'CONTRAINTES')) - 1 ;
  234. *
  235. T1 = 0. ;
  236. SMZZ1 = 0. ;
  237. FF1 = TA.'POR0' ;
  238. ERMAX1 = 0. ;
  239. ERMAX2 = 0. ;
  240. *
  241. LTT = 'PROG' ;
  242. LDFF = 'PROG' ;
  243. LEVFF = 'PROG' ;
  244. LEVP3 = 'PROG' ;
  245. LEVTH = 'PROG' ;
  246. LEVCALC = 'PROG' ;
  247. *
  248. 'REPE' BLOC NCONT ;
  249. *
  250. * -------------------------------------
  251. * VITESSE DE DEFORMATION THEORIQUE EVTH
  252. * -------------------------------------
  253. T2 = 'EXTR' (TAB1.'TEMPS_SAUVES') (&BLOC + 1) ;
  254. EVTH = DELTAZ / HS2 / TMIL ;
  255. 'SI' (> T2 (TMIL+0.1)) ;
  256. EVTH = -1. * DELTAZ / HS2 / (TFIN - TMIL) ;
  257. 'FINS' ;
  258. * ----------------------------------------------------
  259. * SMZZ EST PREPONDERANTE DEVANT LES AUTRES CONTRAINTES
  260. * ----------------------------------------------------
  261. SMZZ = 'MAXI' ('EXCO' SS.&BLOC 'SMZZ') ;
  262. SSM = SMZZ / 3. ;
  263. SSEQ = 'ABS' SMZZ ;
  264. * Deviateur des contraintes
  265. SSPRIM1 = -1. * SMZZ / 3 ;
  266. SSPRIM2 = -1. * SMZZ / 3 ;
  267. SSPRIM3 = 2. * SMZZ / 3 ;
  268. * ---------------------------------------------
  269. * DEFORMATION VISCO-PLASTIQUE EQUIVALENTE EVPEQ
  270. * ---------------------------------------------
  271. EVXX = 'MAXI' ('EXCO' IN.&BLOC 'EIXX') ;
  272. EVYY = 'MAXI' ('EXCO' IN.&BLOC 'EIYY') ;
  273. EVZZ = 'MAXI' ('EXCO' IN.&BLOC 'EIZZ') ;
  274. EVH = (EVXX+EVYY+EVZZ) / 3. ;
  275. EVPEQ = ((EVXX - EVH)**2) + ((EVYY - EVH)**2) + ((EVZZ - EVH)**2) ;
  276. EVPEQ = ((2./3.) * EVPEQ)**0.5 ;
  277. * ------------------------------------------
  278. * VITESSE DE DEFORMATION VISCO-PLASTIQUE EVP
  279. * ------------------------------------------
  280. *-- fluage primaire
  281. *
  282. 'SI' ('<' EVPEQ 1E-10) ; EVPEQ = 1E-10 ; 'FINSI' ;
  283. *
  284. EVP01 = 1.5 * TA.'KPUO' *
  285. ('EXP' (-1.*TA.'QP'/(TA.'R'*TE1))) *
  286. ( (SSEQ**(AP-1)) / (EVPEQ**BP) ) * SSPRIM1 ;
  287. *
  288. EVP02 = 1.5 * TA.'KPUO' *
  289. ('EXP' (-1.*TA.'QP'/(TA.'R'*TE1))) *
  290. ( (SSEQ**(AP-1)) / (EVPEQ**BP) ) * SSPRIM2 ;
  291. *
  292. EVP03 = 1.5 * TA.'KPUO' *
  293. ('EXP' (-1.*TA.'QP'/(TA.'R'*TE1))) *
  294. ( (SSEQ**(AP-1)) / (EVPEQ**BP) ) * SSPRIM3 ;
  295. *
  296. *-- fluage secondaire (2 mecanismes)
  297. *
  298. PP = 'MAXI' ('EXCO' VV.&BLOC 'PORO') ;
  299. *
  300. A1 = (N1* (PP**(-1./N1) - 1.)**(-2.*N1/(N1+1.))) ;
  301. B1 = (1. + (2.*PP/3.))/ ((1. - PP) **(2.*N1/(N1+1.))) ;
  302. AB1 = (9. * A1) / ( (4.*B1) + A1 ) ;
  303. BA1 = B1 / ( B1 + (A1/4.) ) ;
  304. *
  305. GSSEQ = ((BA1 * (SSEQ**2)) + (AB1 * (SSM**2))) ** 0.5 ;
  306. *
  307. A2 = (N2* (PP**(-1./N2) - 1.)**(-2.*N2/(N2+1.))) ;
  308. B2 = (1. + (2.*PP/3.))/ ((1. - PP) **(2.*N2/(N2+1.))) ;
  309. *
  310. EVP11 = 0.5 * (TA.'K1' * (TA.'DG'**TA.'M1') * WC1 *
  311. ('EXP' (-1.*TA.'Q1'/(TA.'R'*TE1))) *
  312. (((A1*((1.5*SSM)**2)) + (B1*(SSEQ ** 2)))**((N1-1.)/2.)) *
  313. ((A1*1.5*SSM) + (3.*B1*SSPRIM1))) ;
  314. *
  315. EVP21 = 0.5 * (TA.'K2' * WC2 * ('EXP' (-1.*TA.'Q2'/(TA.'R'*TE1))) *
  316. (((A2*((1.5*SSM)**2)) + (B2*(SSEQ ** 2)))**((N2-1.)/2.)) *
  317. ((A2*1.5*SSM) + (3.*B2*SSPRIM1))) ;
  318. *
  319. EVP12 = 0.5 * (TA.'K1' * (TA.'DG'**TA.'M1') * WC1 *
  320. ('EXP' (-1.*TA.'Q1'/(TA.'R'*TE1))) *
  321. (((A1*((1.5*SSM)**2)) + (B1*(SSEQ ** 2)))**((N1-1.)/2.)) *
  322. ((A1*1.5*SSM) + (3.*B1*SSPRIM2))) ;
  323. *
  324. EVP22 = 0.5 * (TA.'K2' * WC2 * ('EXP' (-1.*TA.'Q2'/(TA.'R'*TE1))) *
  325. (((A2*((1.5*SSM)**2)) + (B2*(SSEQ ** 2)))**((N2-1.)/2.)) *
  326. ((A2*1.5*SSM) + (3.*B2*SSPRIM2))) ;
  327. *
  328. EVP13 = 0.5 * (TA.'K1' * (TA.'DG'**TA.'M1') * WC1 *
  329. ('EXP' (-1.*TA.'Q1'/(TA.'R'*TE1))) *
  330. (((A1*((1.5*SSM)**2)) + (B1*(SSEQ ** 2)))**((N1-1.)/2.)) *
  331. ((A1*1.5*SSM) + (3.*B1*SSPRIM3))) ;
  332. *
  333. EVP23 = 0.5 * (TA.'K2' * WC2 * ('EXP' (-1.*TA.'Q2'/(TA.'R'*TE1))) *
  334. (((A2*((1.5*SSM)**2)) + (B2*(SSEQ ** 2)))**((N2-1.)/2.)) *
  335. ((A2*1.5*SSM) + (3.*B2*SSPRIM3))) ;
  336. *
  337. PSI1 = TA.'K1' * WC1 * (TA.'DG'**TA.'M1')/(N1+1.) *
  338. ('EXP' (-1.*TA.'Q1'/(TA.'R'*TE1))) *
  339. (((A1*((1.5*SSM)**2)) + (B1*(SSEQ ** 2)))**((N1+1.)/2.)) ;
  340. *
  341. PSI2 = TA.'K2' * WC2/(N2+1.) * ('EXP' (-1.*TA.'Q2'/(TA.'R'*TE1))) *
  342. (((A2*((1.5*SSM)**2)) + (B2*(SSEQ ** 2)))**((N2+1.)/2.)) ;
  343. *
  344. EVPC1 = 0.5 * TA.'BETA' / TA.'H' * TA.'Q' * TA.'OMEG' *
  345. (GSSEQ**(-1.*TA.'Q' - 2.)) *
  346. (1. -
  347. (('TANH' ((TE1 - (TA.'OMEG' * (GSSEQ**(-1.*TA.'Q')))) / TA.'H'))**2))
  348. * (PSI2 - PSI1) * ( ((AB1*SSM)/3.) + (1.5*BA1*SSPRIM1) ) ;
  349. *
  350. EVPC2 = 0.5 * TA.'BETA' / TA.'H' * TA.'Q' * TA.'OMEG' *
  351. (GSSEQ**(-1.*TA.'Q' - 2.)) *
  352. (1. -
  353. (('TANH' ((TE1 - (TA.'OMEG' * (GSSEQ**(-1.*TA.'Q')))) / TA.'H'))**2))
  354. * (PSI2 - PSI1) * ( ((AB1*SSM)/3.) + (1.5*BA1*SSPRIM2) ) ;
  355. *
  356. EVPC3 = 0.5 * TA.'BETA' / TA.'H' * TA.'Q' * TA.'OMEG' *
  357. (GSSEQ**(-1.*TA.'Q' - 2.)) *
  358. (1. -
  359. (('TANH' ((TE1 - (TA.'OMEG' * (GSSEQ**(-1.*TA.'Q')))) / TA.'H'))**2))
  360. * (PSI2 - PSI1) * ( ((AB1*SSM)/3.) + (1.5*BA1*SSPRIM3) ) ;
  361. *
  362. TETA = 0.5 * TA.'BETA' *
  363. (1. +
  364. ('TANH' ((TE1 - (TA.'OMEG' * (GSSEQ**(-1.*TA.'Q')))) / TA.'H'))) ;
  365. *
  366. EVP1 = EVP01 + ((1. - TETA) * EVP11) + (TETA * EVP21) + EVPC1 ;
  367. EVP2 = EVP02 + ((1. - TETA) * EVP12) + (TETA * EVP22) + EVPC2 ;
  368. EVP3 = EVP03 + ((1. - TETA) * EVP13) + (TETA * EVP23) + EVPC3 ;
  369. * -------------------------------------
  370. * VITESSE DE DEFORMATION ELASTIQUE EVEL
  371. * -------------------------------------
  372. DSMZZ = (SMZZ - SMZZ1) / (T2 - T1) ;
  373. EVEL = DSMZZ / ('MAXI' EE) ;
  374. * ----------------------------------
  375. * VITESSE DE DEFORMATION IRRADIATION
  376. * ----------------------------------
  377. EVIR1 = 1.5 * TA.'A' * DF1 * (SSEQ **(TA.'N3' - 1.)) *
  378. ('EXP' (-1.*TA.'Q3'/(TA.'R'*TE1))) * SSPRIM1 ;
  379. EVIR2 = 1.5 * TA.'A' * DF1 * (SSEQ **(TA.'N3' - 1.)) *
  380. ('EXP' (-1.*TA.'Q3'/(TA.'R'*TE1))) * SSPRIM2 ;
  381. EVIR3 = 1.5 * TA.'A' * DF1 * (SSEQ **(TA.'N3' - 1.)) *
  382. ('EXP' (-1.*TA.'Q3'/(TA.'R'*TE1))) * SSPRIM3 ;
  383. * ------------------------------------
  384. * VITESSE DE DEFORMATION DENSIFICATION
  385. * ------------------------------------
  386. * CE QUI SUIT EST VRAI CAR LE FLUX DE FISSIONS EST CONSTANT
  387. BU = AKBU * T2 ;
  388. 'SI' (BU '>' BUMI) ;
  389. NUMER = (RHO0 * RHO0 * AKEVD) - (RHO0 * AAAA * AKEVD) +
  390. (RHO0 * AAAA * AKEVD * ('LOG' (BU / BUMI))) -
  391. (RHO0 * AAAA / T2) ;
  392. DENOM = (RHO0 + (AAAA * ('LOG' (BU / BUMI)))) *
  393. (RHO0 + (AAAA * ('LOG' (BU / BUMI)))) ;
  394. EVD = -1. * (AKEVD - (NUMER/DENOM)) / 3. ;
  395. 'SINO' ;
  396. EVD = 0. ;
  397. 'FINS' ;
  398. * ---------------------------------
  399. * VITESSE DE DEFORMATION GONFLEMENT
  400. * ---------------------------------
  401. * CE QUI SUIT EST VRAI CAR LE FLUX DE FISSIONS EST CONSTANT
  402. EVG = AKEVD/3. ;
  403. * -------------------------------
  404. * VITESSE DE DEFORMATION SELON ZZ
  405. * -------------------------------
  406. EVCALC = ((1.+(TA.'K'*DF1))*EVP3) + EVEL + EVIR3 + EVD + EVG ;
  407. ECART1 = (EVCALC - EVTH) / EVTH ;
  408. ERMAX1 = 'MAXI' ('PROG' ('ABS' ECART1) ERMAX1) ;
  409. * -------------------
  410. * VITESSE DE POROSITE
  411. * -------------------
  412. FF = 'MAXI' ('EXCO' (VV . &BLOC) 'PORO') ;
  413. DFF = (FF - FF1) / (T2 - T1) ;
  414. EVFF = (3.*EVD) +
  415. ((1. - FF) * (1.+(TA.'K'*DF1))*(EVP1+EVP2+EVP3)) +
  416. ((1. - FF) * (EVIR1 + EVIR2 + EVIR3)) ;
  417. ECART2 = ('ABS' (DFF - EVFF)) / FF ;
  418. ERMAX2 = 'MAXI' ('PROG' ('ABS' ECART2) ERMAX2) ;
  419. *
  420. LTT = LTT 'ET' ('PROG' T2) ;
  421. LEVP3 = LEVP3 'ET' ('PROG' EVP3) ;
  422. LEVCALC = LEVCALC 'ET' ('PROG' EVCALC) ;
  423. LEVTH = LEVTH 'ET' ('PROG' EVTH) ;
  424. LDFF = LDFF 'ET' ('PROG' DFF) ;
  425. LEVFF = LEVFF 'ET' ('PROG' EVFF) ;
  426. *
  427. FF1 = FF ;
  428. SMZZ1 = SMZZ ;
  429. T1 = T2 ;
  430. *
  431. 'FIN' BLOC ;
  432. *
  433. 'SI' ( ERMAX1 '&lt;EG' 0.05 );
  434. 'ERRE' 0;
  435. 'SINO';
  436. 'MESS' 'ERREUR MAXIMALE VITESSE DEFORMATION :'
  437. ERMAX1 '> 0.05 ' ;
  438. 'ERRE' 5;
  439. 'FINS';
  440. *
  441. 'SI' ( ERMAX2 '&lt;EG' 0.05 );
  442. 'ERRE' 0;
  443. 'SINO';
  444. 'MESS' 'ERREUR MAXIMALE POROSITE :'
  445. ERMAX2 '> 0.05 ' ;
  446. 'ERRE' 5;
  447. 'FINS';
  448. *
  449. 'SI' GRAPH ;
  450. 'TITR' 'Tridimensionnel : Vitesses de Deformation' ;
  451. EVEVP = 'EVOL' 'MANU' LTT 'Temps' LEVP3 'Vitesse';
  452. EVEVC = 'EVOL' 'MANU' LTT 'Temps' LEVCALC 'Vitesse';
  453. EVEVTH = 'EVOL' 'MANU' LTT 'Temps' LEVTH 'Vitesse' ;
  454. TAD = TABLE ;
  455. TAD . 1 = 'TIRC' ;
  456. TAD . 3 = 'TIRR' ;
  457. TAD . 'TITRE' = TABLE ;
  458. TAD . 'TITRE' . 1 = 'Viscoplastique Analytique' ;
  459. TAD . 'TITRE' . 2 = 'Totale Calculee' ;
  460. TAD . 'TITRE' . 3 = 'Totale Analytique' ;
  461. 'DESS' (EVEVP 'ET' EVEVC 'ET' EVEVTH) TAD 'LEGE' ;
  462. *
  463. 'TITR' 'Tridimensionnel : Vitesses de variation de la porosite' ;
  464. EVDFF = 'EVOL' 'MANU' LTT 'Temps' LDFF 'Vitesse' ;
  465. EVEVFF = 'EVOL' 'MANU' LTT 'Temps' LEVFF 'Vitesse' ;
  466. TAF = TABLE ;
  467. TAF . 2 = 'TIRR' ;
  468. TAF . 'TITRE' = TABLE ;
  469. TAF . 'TITRE' . 1 = 'Calculee' ;
  470. TAF . 'TITRE' . 2 = 'Analytique' ;
  471. 'DESS' (EVDFF 'ET' EVEVFF) TAF 'LEGE' ;
  472. 'FINS' ;
  473. *
  474. 'FIN';
  475.  
  476.  
  477.  
  478.  
  479.  
  480.  
  481.  
  482.  
  483.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales