Télécharger fsi6.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : fsi6.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * CAS TEST DU 91/10/04 PROVENANCE : PETI
  5.  
  6. *******************************************
  7. * Test fsi6.dgibi: jeux de données *
  8. * --------------------------------- *
  9. *******************************************
  10.  
  11. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  12. * SINON SI GRAPH DIFFERENT DE N TOUS
  13. * LES GRAPHIQUES SONT AFFICHES
  14.  
  15. GRAPH = 'N' ;
  16.  
  17. SAUT PAGE;
  18. SI (NEG GRAPH 'N') ;
  19. OPTI ECHO 1 ;
  20. OPTI TRAC PSC ;
  21. SINO ;
  22. OPTI ECHO 0 ;
  23. FINSI ;
  24.  
  25. SAUT PAGE;
  26. *******************************************
  27. * *
  28. * TEST FSI6 *
  29. * *
  30. * PARALLELEPIPEDIQUE FLUID VOLUME WITH *
  31. * FREE SURFACE *
  32. * *
  33. * Calculation of the sloshing frequency *
  34. * of a parallelpipedique fluid volume *
  35. * Height (h) 0.1m length (a) 2m *
  36. * Breadth (b) 1.58m *
  37. * *
  38. * P2 *
  39. * _________________ *
  40. * / /| *
  41. * / / | *
  42. * / b / | *
  43. * / / | *
  44. * / a / | *
  45. * P1 /_________________/ / *
  46. * | | / *
  47. * | | / *
  48. * | h | / *
  49. * |_________________|/ *
  50. * *
  51. * *
  52. * *
  53. * *
  54. * The boundary conditions are *
  55. * *
  56. * dp | *
  57. * ---- | = 0. *
  58. * dz | h = 0. *
  59. * *
  60. * dp | *
  61. * ---- | = 0. *
  62. * dx | x = 0 , a *
  63. * *
  64. * dp | *
  65. * ---- | = 0. *
  66. * dy | y = 0 , b *
  67. *******************************************
  68.  
  69. TEMPS;
  70.  
  71. OPTI ELEM CUB8;
  72. OPTI EPSI LINEAIRE;
  73.  
  74. *=========================================*
  75. * geometry *
  76. *=========================================*
  77.  
  78. * Dimensions en metres
  79.  
  80. * Points
  81.  
  82. P1 = 0. 0. 0. ;
  83. P2 = 0. 1.58114 0. ;
  84. EYE = 5. -3. 3. ;
  85.  
  86. S1 =P1 D 15 P2 ;
  87.  
  88. FRSUR = S1 TRAN 15 (2. 0. 0.) ;
  89. WATER = FRSUR VOLU TRAN 2 (0. 0. -0.1) ;
  90.  
  91. * OPTIO FOR TRACE
  92.  
  93. SI (NEG GRAPH 'N');
  94. TITR ' FSI6 : MAILLAGE';
  95. TRAC QUAL WATER CACH EYE ;
  96. FINSI;
  97.  
  98. *=========================================*
  99. * MODE - materiau - rigidite - masse *
  100. *=========================================*
  101.  
  102. MODLIQ1=MODE WATER LIQUIDE LCU8;
  103. MODLIQ2=MODE FRSUR LIQUIDE LSU4;
  104.  
  105. MATLIQ = MATE (MODLIQ1 ET MODLIQ2)
  106. RHO 1.E3 RORF 1.E3
  107. CSON 1435. CREF 1435.
  108. LCAR 1.0 G 9.81 ;
  109.  
  110. RIG1 = RIGI (MODLIQ1 ET MODLIQ2) MATLIQ ;
  111. MAS1 = MASS (MODLIQ1 ET MODLIQ2) MATLIQ ;
  112.  
  113. *=========================================*
  114. * boundary conditions *
  115. *=========================================*
  116.  
  117. * No explicit boundary condition
  118. * the boundary conditions are natural
  119.  
  120. * Theoritical value of frequency
  121.  
  122. FRE1 = TABL ;
  123. FRE1.1 = 0.2476;
  124. FRE1.2 = 0.3132;
  125. FRE1.3 = 0.3993;
  126. FRE1.4 = 0.4952;
  127. LIST1 = PROG FRE1.1 FRE1.2 FRE1.3 FRE1.4 ;
  128.  
  129. *=========================================*
  130. * calculation of the frequencies *
  131. * and *
  132. * extraction of some results *
  133. *=========================================*
  134.  
  135. * Use of the operator VIBR. (option PROC)
  136. RESUL = VIBR PROC LIST1 RIG1 MAS1 ;
  137.  
  138. *=========================================*
  139. * results *
  140. *=========================================*
  141.  
  142. MESS ' RESULTATS ';
  143. MESS ' --------- ';
  144.  
  145. FRE2 = TABL;
  146. MOD = TABL;
  147. DEF = TABL;
  148. ERG = TABL;
  149.  
  150. I = 0;
  151. REPETER BLOC1 (dime LIST1);
  152. I = I + 1;
  153. FRE2.I = RESUL . MODES . I . FREQUENCE;
  154. ERG.I = 100 *
  155. (ABS ((FRE1.I - FRE2.I) / FRE1.I));
  156. MESS ' MODE ' I ;
  157. MESS ' ----------';
  158. MESS 'Frequence theorique :' FRE1.I 'Hz';
  159. MESS 'Frequence calculee :' FRE2.I 'Hz';
  160. MESS ' Soit un ecart de : ' ERG.I '%';
  161.  
  162. * mode shape extraction and optional trace
  163. SI (NEG GRAPH 'N');
  164. MOD.I= RESUL . MODES . I . DEFORMEE_MODALE;
  165. DEF0 = DEFO FRSUR MOD.I 0.;
  166. DEF.I= DEFO FRSUR MOD.I VERT;
  167. DEPZ = EXCO MOD.I 'UZ';
  168. TRAC CACH (DEF.I ET DEF0) EYE CACH ;
  169. TRAC DEPZ FRSUR
  170. (DEFO FRSUR MOD.I NOIR) ;
  171. FINSI;
  172. FIN BLOC1;
  173.  
  174. *=========================================*
  175. * code validation *
  176. *=========================================*
  177.  
  178. ERGMAX = MAXI
  179. (PROG ERG.1 ERG.2 ERG.3 ERG.4 ) ;
  180.  
  181. SI (ERGMAX <EG 5.0);
  182. ERRE 0;
  183. SINON;
  184. ERRE 5;
  185. FINSI;
  186.  
  187. TEMPS;
  188.  
  189. FIN;
  190.  
  191.  
  192.  
  193.  
  194.  
  195.  
  196.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales