Télécharger fsi1.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : fsi1.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * CAS TEST DU 91/10/16 PROVENANCE : PETI
  5. * Test fsi1.dgibi: Jeux de données *
  6. * --------------------------------- *
  7. * *
  8.  
  9. *******************************************
  10. * Test fsi1.dgibi: jeux de données *
  11. * --------------------------------- *
  12. *******************************************
  13.  
  14. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  15. * SINON SI GRAPH DIFFERENT DE N TOUS
  16. * LES GRAPHIQUES SONT AFFICHES
  17.  
  18. GRAPH = 'N' ;
  19.  
  20. SAUT PAGE;
  21. SI (NEG GRAPH 'N') ;
  22. OPTI ECHO 1 ;
  23. OPTI TRAC PSC ;
  24. SINO ;
  25. OPTI ECHO 0 ;
  26. FINSI ;
  27.  
  28. SAUT PAGE;
  29. *******************************************
  30. * *
  31. * TEST FSI1 *
  32. * *
  33. * CYLINDRICAL FLUID CAVITY WITH FREE *
  34. * SURFACE *
  35. * *
  36. * Calculation of the frequencies of free *
  37. * surface mode,for m = 1, of cylindrical *
  38. * water volume of radius 1.43m and height *
  39. * 1.039m *
  40. * *
  41. * *
  42. * P8___________ P5 *
  43. * | | *
  44. * | | *
  45. * | | *
  46. * | | *
  47. * |__________| *
  48. * P7 P6 *
  49. * *
  50. * The boundary conditions are *
  51. * *
  52. * dp | *
  53. * ---- | = 0 *
  54. * dz | h = 0. *
  55. * *
  56. * dp | *
  57. * ---- | = 0 *
  58. * dr | r = R *
  59. *******************************************
  60.  
  61. TEMPS;
  62.  
  63. OPTI MODE FOUR 1;
  64. OPTI ELEM QUA4;
  65. OPTI EPSI LINEAIRE;
  66.  
  67. *=========================================*
  68. * geometry *
  69. *=========================================*
  70.  
  71. * Dimensions en metres
  72.  
  73. * Points
  74.  
  75. P5 = 1.43 1.039 ;
  76. P6 = 1.43 0.0 ;
  77. P7 = 0. 0. ;
  78. P8 = 0. 1.039 ;
  79.  
  80. N1 = 10 ;
  81. S4 = P6 D N1 P5 ; S5 =P7 D N1 P6 ;
  82. S6 = P7 D N1 P8 ; S7 =P8 D N1 P5 ;
  83.  
  84. WATER = DALL S4 S5 S6 S7 PLAN ;
  85.  
  86. * OPTIO FOR TRACE
  87.  
  88. SI (NEG GRAPH 'N');
  89. TITR ' FSI1 : MAILLAGE';
  90. TRAC QUAL (WATER ET (0 0));
  91. FINSI;
  92.  
  93. *=========================================*
  94. * MODE - materiau - rigidite - masse *
  95. *=========================================*
  96.  
  97. MODLIQ1=MODE WATER LIQUIDE LQU4 ;
  98. MODLIQ2=MODE S7 LIQUIDE LSU2 ;
  99.  
  100. MATLIQ = MATE (MODLIQ1 ET MODLIQ2)
  101. RHO 1.E3 RORF 1.E3 CSON 1435.
  102. CREF 1435. LCAR 1 G 10.0 ;
  103.  
  104. RIG1 = RIGI (MODLIQ1 ET MODLIQ2) MATLIQ ;
  105. MAS1 = MASS (MODLIQ1 ET MODLIQ2) MATLIQ ;
  106.  
  107. *=========================================*
  108. * boundary conditions *
  109. *=========================================*
  110.  
  111. * No explicit boundary condition
  112. * the boundary conditions are natural
  113. *=========================================*
  114. * Theoritical values of frequencies
  115.  
  116. FRE1 = TABLE;
  117. FRE1.1 = 0.5278;
  118. FRE1.2 = 0.9621;
  119. FRE1.3 = 1.2170;
  120. LIST1 = PROG FRE1.1 FRE1.2 FRE1.3 ;
  121.  
  122. * Theoritical values of mode shapes
  123.  
  124. S7PRE = TABLE ;
  125. S7PRE.1 = prog 0.0 .15755 .31110 .45677
  126. .59091 .71018 .81166 .89292
  127. .95212 .98801 1.0000 ;
  128. S7PRE.2 = prog 0.0 .45137 .80878 1.0000
  129. .99098 .79310 .45945
  130. 7.13120E-02 -.28176
  131. -.52329 -.60741 ;
  132. S7PRE.3 = prog 0.0 .67298 1.0000 .83272
  133. .29951 -.27942 -.58584
  134. -.48679 -9.75875E-02
  135. .30721 .47269 ;
  136.  
  137. *=========================================*
  138. * calculation of the frequencies *
  139. * and *
  140. * extraction of some results *
  141. *=========================================*
  142.  
  143. * Use of the operator VIBR. (option PROC)
  144.  
  145. RESUL = VIBR PROC LIST1 RIG1 MAS1 ;
  146.  
  147. *=========================================*
  148. * results *
  149. *=========================================*
  150.  
  151. MESS ' RESULTATS ';
  152. MESS ' --------- ';
  153.  
  154. FRE2 = TABL;
  155. MOD = TABL;
  156. DEF = TABL;
  157. ERG = TABL;
  158.  
  159. S70 = CHAN 'POI1' S7 ;
  160.  
  161. I = 0;
  162. REPETER BLOC1 3;
  163. I = I + 1;
  164. FRE2.I = TIRE RESUL FREQ RANG I;
  165. ERG.I = 100 *
  166. (ABS ((FRE1.I - FRE2.I) / FRE1.I));
  167.  
  168. MOD.I = TIRE RESUL DEPL RANG I;
  169. PRE1 = REDU MOD.I S7 ;
  170. PRE2 = EXCO 'P' PRE1 'P' ;
  171. CHP1 = MANU CHPO S70 1 P S7PRE.I ;
  172. CHP2 = (PRE2 / (MAXI PRE2 ABS));
  173. CHP3 = (CHP1 - CHP2 ) ;
  174. CHP4 = (CHP1 + CHP2 ) ;
  175.  
  176. MESS ' MODE ' I ;
  177. MESS ' ----------';
  178. MESS 'Frequence theorique :' FRE1.I 'Hz';
  179. MESS 'Frequence calculee :' FRE2.I 'Hz';
  180. MESS ' Soit un ecart de : ' ERG.I '%';
  181.  
  182. * mode shape extraction and optional trace
  183.  
  184. SI (NEG GRAPH 'N');
  185. DEF0 = DEFO S7 MOD.I 0.;
  186. DEF.I = DEFO S7 MOD.I BLEU;
  187. TRAC (DEF.I ET DEF0);
  188. FINSI;
  189. FIN BLOC1;
  190.  
  191. *=========================================*
  192. * code validation *
  193. *=========================================*
  194.  
  195. ERGMAX = MAXI (PROG ERG.1 ERG.2 ERG.3 );
  196. *
  197. SI (ERGMAX <EG 5.);
  198. ERRE 0;
  199. SINON;
  200. ERRE 5;
  201. FINSI;
  202.  
  203. TEMPS;
  204.  
  205. FIN;
  206.  
  207.  
  208.  
  209.  
  210.  
  211.  
  212.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales