Télécharger la plaquette Cast3M


fr en

Télécharger formation_pasapas_3_initial.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : formation_pasapas_3_initial.dgibi
  2. ************************************************************************
  3. *              FORMATION AVANCEE SUR LA PROCEDURE PASAPAS              *
  4. *                                                                      *
  5. * Chauffage d'une plaque par une source de chaleur variable            *
  6. * dependante de la temperature                                         *
  7. *                                                                      *
  8. * Ce fichier constitue la mise donnee initiale du probleme et realise  *
  9. * - le maillage                                                        *
  10. * - la definition du modele et des parametres materiaux                *
  11. * - la definition du chargement (convection + source constante)        *
  12. * - la resolution avec PASAPAS                                         *
  13. * - le post traitement                                                 *
  14. ************************************************************************
  15.  
  16.  
  17. ** Options generales
  18. OPTI 'DIME' 2 'ELEM' 'QUA8' 'ECHO' 0 ;
  19. ITRAC = FAUX ;
  20.  
  21.  
  22. ** Parametres geometriques, materiaux, conditions aux limites
  23. TPSMAX   = 1.E5 ;
  24. L        = 1. ;
  25. R        = 0.25 ;
  26. CP       = 128. ;
  27. RHO      = 19300. ;
  28. T_INI    = 20. ;
  29. T_EXT    = 20. ;
  30. LAMBDA   = 317. ;
  31. HCONV    = 150. ;
  32. VSOUR    = 4.E6 ;
  33.  
  34.  
  35. ** Maillage
  36. OPTI 'DENS' (R/5.) ;
  37. P0       = 0. 0. ;
  38. P1       = L 0. ;
  39. LBAS     = DROI P0 P1 ;
  40. S1       = LBAS TRAN (0. L) ;
  41. CHX      = S1 COOR 1 ;
  42. PTX      = CHX POIN 'EGINFE' (R + 1.E-8) ;
  43. EL1      = S1 ELEM 'APPU' 'STRI' PTX ;
  44. CHY      = EL1 COOR 2 ;
  45. PTY      = CHY POIN 'EGINFE' (R + 1.E-8) ;
  46. MAIL1    = EL1 ELEM 'APPU' 'STRI' PTY ;
  47. MAIL2    = DIFF S1 MAIL1 ;
  48. MAILT    = MAIL1 ET MAIL2 ;
  49. LDROITE  = S1 COTE 2 ;
  50. LHAUT    = S1 COTE 3 ;
  51. LEXT     = LDROITE ET LHAUT ;
  52. P2       = MAILT 'POIN' 'PROC' (L L) ;
  53. SI ITRAC ;
  54.   TRAC 'FACE' ((MAIL1 COUL 'ROUG') ET (MAIL2 COUL 'BLEU')) 'TITR' 'Maillage (zone source en rouge)' ;
  55. FINSI ;
  56.  
  57.  
  58. ** Modeles et materiaux
  59. MOD_THER = MODE MAILT 'THERMIQUE' 'CONDUCTION' ;
  60. MAT_THER = MATE MOD_THER 'K' LAMBDA 'C' CP 'RHO' RHO 'TINI' T_INI ;
  61. * sous-modele reduit au maillage de la source (pour l'operateur SOUR)
  62. MOD1     = REDU MOD_THER MAIL1 ;
  63.  
  64. MOD_CONV = MODE LEXT 'THERMIQUE' 'CONVECTION' ;
  65. MAT_CONV = MATE MOD_CONV 'H' HCONV 'TC' T_EXT ;
  66.  
  67.  
  68. ** Chargements thermiques
  69. EV1      = EVOL 'MANU' (PROG 0. TPSMAX) (PROG 1. 1.) ;
  70. CHFL1    = SOUR MOD1 VSOUR MAIL1 ;
  71. CHA1     = CHAR 'Q' CHFL1 EV1 ;
  72.  
  73.  
  74. **Resolution avec PASAPAS
  75. TAB1                         = TABL ;
  76. TAB1 . 'MODELE'              = MOD_THER ET MOD_CONV ;
  77. TAB1 . 'CARACTERISTIQUES'    = MAT_THER ET MAT_CONV ;
  78. TAB1 . 'CHARGEMENT'          = CHA1 ;
  79. TAB1 . 'TEMPS_CALCULES'      = PROG 0. 'PAS' (TPSMAX / 50.) TPSMAX ;
  80.  
  81.  
  82. ** Appel a la procedure PASAPAS
  83. PASAPAS TAB1 ;
  84.  
  85.  
  86. ** Post-traitement
  87. NBOU1 = DIME (TAB1 . 'TEMPS_CALCULES') ;
  88. T_MAX = 1800. ;
  89. LIS1 = PROG T_INI 'PAS' ((T_MAX - T_INI) / 20.) T_MAX ;
  90. REPE BOU1 NBOU1 ;
  91.   I        = &BOU1 - 1 ;
  92. * temps
  93.   TEMPS_I  = TAB1 . 'TEMPS' . I ;
  94.   P100     = ENTI (100. * TEMPS_I / TPSMAX) ;
  95. * temperatures au temps i
  96.   TEMP_I   = TAB1 . 'TEMPERATURES' . I ;
  97.   SI ITRAC ;
  98.     TRAC TEMP_I MAILT LIS1 'TITR' (CHAI 'Temperature au temps' TEMPS_I ' (' P100 '%)') ;
  99.   FINSI ;
  100. FIN BOU1 ;
  101. * courbes d'evolution temporelles des temperatures aux coins de la piece
  102. EVTP0 = EVOL 'ROUG' 'TEMP' TAB1 'TEMPERATURES' 'T' P0 ;
  103. EVTP2 = EVOL 'BLEU' 'TEMP' TAB1 'TEMPERATURES' 'T' P2 ;
  104. TL = TABL ;
  105. TL . 'TITRE' = TABL ;
  106. TL . 'TITRE' . 1 = 'Coin inf. gauche' ;
  107. TL . 'TITRE' . 2 = 'Coin sup. droite' ;
  108. SI ITRAC ;
  109.   DESS (EVTP0 ET EVTP2) 'LEGE' 'SE' TL 'TITR' 'Temperature aux coins vs Temps' 'YBOR' 0. 2000. ;
  110. FINSI ;
  111.  
  112. FIN ;
  113.  
  114.  
  115.  
  116.  
  117.  
  118.  
  119.  
  120.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales