Télécharger la plaquette Cast3M


fr en

Télécharger formation_debutant_2_thermique.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : formation_debutant_2_thermique.dgibi
  2. *
  3. ************************************************************************
  4. *      FORMATION DEBUTER AVEC CAST3M - CALCULS THERMO-MECANIQUES       *
  5. *                                                                      *
  6. * Modelisation du comportement thermo-mecanique d'une structure avec   *
  7. * une cavite                                                           *
  8. *                                                                      *
  9. * Ce fichier est la partie 2 sur 3 de la formation debutant a Cast3M   *
  10. *                                                                      *
  11. * Partie 2 : calculs thermiques                                        *
  12. *            restitution des objets                                    *
  13. *            conduction, convection, rayonnement                       *
  14. *            regimes stationnaires et transitoires                     *
  15. *            creation d'une procedure Gibiane                          *
  16. *            instructions conditionelles, gestion des erreurs          *
  17. *            sauvegarde des objets                                     *
  18. *                                                                      *
  19. ************************************************************************
  20.  
  21.  
  22.  
  23.  
  24. * RESTITUTION DES OBJETS CREES
  25. * ----------------------------
  26. OPTI 'REST' 'formation_debutant_1_maillage.sauv' ;
  28.  
  29.  
  30. * OBJET LOGIQUE POUR INDIQUER SI L'ON FAIT LES TRACES OU NON
  31. * ----------------------------------------------------------
  32. ITRAC    = FAUX ;
  33.  
  34.  
  35. * CARACTERISTIQUES DU MATERIAU
  36. * ----------------------------
  37. CONDUMAT = 210. ;
  38. CAPAMAT  = 900. ;
  39. RHOMAT   = 2700. ;
  40.  
  41.  
  42. * TEMPERATURE INITIALE ET DE REFERENCE
  43. * ------------------------------------
  44. T0       = 25. ;
  45.  
  46.  
  47.  
  48.  
  49. ************************************************************************
  50. * CHAPITRE 2 : THERMIQUE LINEAIRE STATIONNAIRE                         *
  51. ************************************************************************
  52.  
  53.  
  54. * MODELE THERMIQUE (CONDUCTION) A MATERIAU UNIFORME ET CONSTANT
  55. * -------------------------------------------------------------
  56. MOT      = MODE SU 'THERMIQUE' 'CONDUCTION' ;
  57. MAT      = MATE MOT 'K' CONDUMAT 'C' CAPAMAT 'RHO' RHOMAT 'TINI' T0 ;
  58.  
  59.  
  60. * CALCUL DE LA MATRICE DE CONDUCTIVITE
  61. * ------------------------------------
  62. CON      = COND MOT MAT ;
  63.  
  64.  
  65. * MATRICE DE BLOCAGE : TEMPERATURE IMPOSEE SUR LE TROU
  66. * ----------------------------------------------------
  67. BLT      = BLOQ CE   'T' ;
  68.  
  69.  
  70. * FLUX NODAUX ASSOCIES AU BLOCAGE
  71. * -------------------------------
  72. TMAX     = 250. ;
  73. FLT1     = DEPI BLT TMAX ;
  74.  
  75.  
  76. * FLUX IMPOSE SUR LA LIGNE GAUCHE
  77. * -------------------------------
  78. FLT2     = FLUX MOT LIGA -3.5E4 ;
  79.  
  80.  
  81. * CALCUL DU CHAMP DE TEMPERATURES PAR APPEL AU SOLVEUR
  82. * ----------------------------------------------------
  83. TCON1    = RESO (CON ET BLT) (FLT1 ET FLT2) ;
  84.  
  85.  
  86. * AFFICHAGE DU CHAMP DE TEMPERATURE
  87. * ---------------------------------
  88. LISO1    = PROG 0. 'PAS' (TMAX / 15.) TMAX ;
  89. SI ITRAC ;
  90.   TRAC TCON1 SU ;
  91.   TRAC TCON1 SU CSU ;
  92.   TRAC TCON1 SU CSU LISO1 ;
  93.   TRAC TCON1 SU CSU LISO1 'TITR' '[2] Temperature' ;
  94. FINSI ;
  95.  
  96.  
  97.  
  98.  
  99.  
  100.  
  101.  
  102. ************************************************************************
  103. * CHAPITRE 2.1 : THERMIQUE LINEAIRE STATIONNAIRE                       *
  104. *                AJOUT DE CONVECTION + SOURCE VOLUMIQUE                *
  105. ************************************************************************
  106.  
  107.  
  108. * MODELE DE CONVECTION
  109. * --------------------
  110. MOC      = MODE LHAUT 'THERMIQUE' 'CONVECTION' ;
  111. MAC      = MATE MOC 'H' 100. ;
  112.  
  113.  
  114. * PREMIER MEMBRE POUR LA CONVECTION
  115. * ---------------------------------
  116. CONH     = COND MOC MAC ;
  117.  
  118.  
  119. * SECOND MEMBRE POUR LA CONVECTION
  120. * --------------------------------
  121. CHTC     = MANU 'CHPO' LHAUT 'T' T0 ;
  122. FLH      = CONV MOC MAC CHTC ;
  123.  
  124.  
  125. * SECOND MEMBRE POUR LA SOURCE
  126. * ----------------------------
  127. X Y      = COOR SU ;
  128. PT1      = X POIN 'SUPERIEUR' 20.E-1 ;
  129. PT2      = (REDU Y PT1) POIN 'INFERIEUR' 5.E-1 ;
  130. ELSOU    = SU ELEM 'APPUYE' 'STRICTEMENT' PT2 ;
  131. FLS      = SOUR (REDU MOT ELSOU) 1.E5 ELSOU ;
  132.  
  133.  
  134. * CALCUL DU CHAMP DE TEMPERATURES PAR APPEL AU SOLVEUR
  135. * ----------------------------------------------------
  136. TCON2    = RESO (CON ET CONH ET BLT) (FLT1 ET FLT2 ET FLH ET FLS) ;
  137.  
  138.  
  139. * AFFICHAGE DU CHAMP DE TEMPERATURE
  140. * ---------------------------------
  141. SI ITRAC ;
  142.   TRAC TCON2 SU CSU LISO1 'TITR' '[2.1] Temperature' ;
  143. FINSI ;
  144.  
  145.  
  146.  
  147.  
  148.  
  149.  
  150.  
  151. ************************************************************************
  152. * CHAPITRE 3 : THERMIQUE LINEAIRE TRANSITOIRE                          *
  153. *              UTILISATION DE PASAPAS                                  *
  154. ************************************************************************
  155.  
  156.  
  157. * INSTANT FINAL DU CALCUL THERMIQUE
  158. * ---------------------------------
  159. TPSFIN   = 5.E4 ;
  160.  
  161.  
  162. * CHARGEMENT TEMPERATURE IMPOSEE
  163. * ------------------------------
  164. LIST1    = PROG 0. (0.1 * TPSFIN) TPSFIN ;
  165. LIST2    = PROG (T0 / TMAX) 1. 1. ;
  166. EVT1     = EVOL 'MANU' LIST1 LIST2 ;
  167. CHATIMP  = CHAR 'TIMP' FLT1 EVT1 ;
  168.  
  169.  
  170. * CHARGEMENT FLUX IMPOSE
  171. * ----------------------
  172. LIST3    = PROG 0. (0.2 * TPSFIN) (0.4 * TPSFIN) TPSFIN ;
  173. LIST4    = PROG 0. 0. 1. 1. ;
  174. EVT2     = EVOL 'MANU' LIST3 LIST4 ;
  175. CHAFIMP  = CHAR 'Q'    FLT2 EVT2 ;
  176.  
  177.  
  178. * CHARGEMENT CONVECTION
  179. * ---------------------
  180. LIST5    = PROG 0. TPSFIN ;
  181. LIST6    = PROG 1. 1. ;
  182. EVCTE    = EVOL 'MANU' LIST5 LIST6 ;
  183. CHACONV  = CHAR 'TECO' CHTC EVCTE ;
  184.  
  185.  
  186. * CHARGEMENT SOURCE VOLUMIQUE
  187. * ---------------------------
  188. CHASOUR  = CHAR 'Q'    FLS EVT2 ;
  189.  
  190.  
  191. * RASSEMBLEMENT DES CHARGEMENTS
  192. * -----------------------------
  193. CHAT      = CHATIMP ET CHAFIMP ET CHACONV ET CHASOUR ;
  194.  
  195.  
  196. * DEFINITION DE LA TABLE D'ARGUMENTS A FOURNIR EN DONNEE D'ENTREE A LA
  197. * PROCEDURE PASAPAS
  198. * --------------------------------------------------------------------
  199. TAB1                         = TABL ;
  200. TAB1 . 'MODELE'              = MOT ET MOC ;
  201. TAB1 . 'CARACTERISTIQUES'    = MAT ET MAC ;
  202. TAB1 . 'BLOCAGES_THERMIQUES' = BLT ;
  203. TAB1 . 'CHARGEMENT'          = CHAT ;
  204. TAB1 . 'TEMPS_CALCULES'      = PROG 0. 'PAS' (0.02 * TPSFIN) TPSFIN ;
  205.  
  206.  
  207. * APPEL A PASAPAS
  208. * ---------------
  209. PASAPAS TAB1 ;
  210.  
  211.  
  212. * POST TRAITEMENT
  213. * ---------------
  214. * EVOLUTION TEMPORELLE DE LE TEMPERATURE EN DEUX POINTS POUR VERIFIER
  215. * QUE L'ON A ATTEINT L'ETAT STATIONNAIRE
  216. PMIL     = SU POIN 'PROC' ((0.5 * LONG) (0.5 * HAUT)) ;
  217. EV1      = EVOL 'ROUG' 'TEMP' TAB1 'TEMPERATURES' 'T' PMIL ;
  218. EV2      = EVOL 'BLEU' 'TEMP' TAB1 'TEMPERATURES' 'T' PG ;
  219. SI ITRAC ;
  220.   DESS (EV1 ET EV2) 'TITR' '[3] Temperature vs Temps' ;
  221. FINSI ;
  222.  
  223. * BOUCLE SUR TOUS LES PAS DE TEMPS ET TRACE DU CHAMP DE TEMPERATURES
  224. N1       = DIME (TAB1 . 'TEMPERATURES') ;
  225. SI ITRAC ;
  226.   REPE B1 N1 ;
  227.     T_I      = TAB1 . 'TEMPERATURES' . (&B1 - 1) ;
  228.     TPS_I    = TAB1 . 'TEMPS' . (&B1 - 1) ;
  229.     PRC_I    = ENTI (100. * TPS_I / TPSFIN) ;
  230.     MOT_I    = CHAI '[3] Temperature au temps ' TPS_I '  (' PRC_I ' %)' ;
  231.     TRAC T_I SU CSU 'TITR' MOT_I LISO1 ;
  232.   FIN B1 ;
  233. FINSI ;
  234.  
  235. * VECTEUR FLUX DE CHALEUR ==> CREATION D'UNE PROCEDURE
  236. DEBP VECFLU  CHP1*'CHPOINT'  MOD1*'MMODEL'  MAT1*'MCHAML' ;
  237. * CALCUL DU GRADIENT DE T ET CHANGEMENT DU TYPE
  238.   G1       = GRAD CHP1 MOD1 ;
  239.   G2       = CHAN 'TYPE' G1 'CARACTERISTIQUES' ;
  240. * MULTIPLICATION DES CHAMPS ENTRE EUX
  241.   Q        = MAT1 * G2 (MOTS 'K' 'K') (MOTS 'T,X' 'T,Y') (MOTS 'QX' 'QY') ;
  242.   Q        = -1. * Q ;
  243. * CREATION D'UN OBJET VECTEUR
  244.   VEC1     = VECT Q MOD1 (MOTS 'QX' 'QY') 2.E-6 ;
  245. FINP VEC1 ;
  246.  
  247. * BOUCLE SUR TOUS LES PAS DE TEMPS ET TRACE VECTEUR FLUX DE CHALEUR
  248. SI ITRAC ;
  249.   REPE B1 N1 ;
  250.     T_I      = TAB1 . 'TEMPERATURES' . (&B1 - 1) ;
  251.     VF_I     = VECFLU T_I MOT MAT ;
  252.     TPS_I    = TAB1 . 'TEMPS' . (&B1 - 1) ;
  253.     PRC_I    = ENTI (100. * TPS_I / TPSFIN) ;
  254.     MOT_I    = CHAI '[3] Vecteur flux de chaleur au temps ' TPS_I '  (' PRC_I ' %)' ;
  255.     TRAC VF_I CSU 'TITR' MOT_I ;
  256.   FIN B1 ;
  257. FINSI ;
  258.  
  259. * VECTEUR FLUX ET CHAMP DE TEMPRATURE SOUS FORME DE LIGNES D'ISOVALEURS
  260. OPTI 'ISOV' 'LIGN' ;
  261. SI ITRAC ;
  262.   TRAC VF_I T_I SU CSU 15 'TITR' MOT_I ;
  263. FINSI ;
  264. OPTI 'ISOV' 'SURF' ;
  265.  
  266.  
  267.  
  268.  
  269.  
  270.  
  271.  
  272.  
  273.  
  274. ************************************************************************
  275. * CHAPITRE 4 : THERMIQUE NON LINEAIRE TRANSITOIRE                      *
  276. *              AJOUT DU RAYONNEMENT                                    *
  277. ************************************************************************
  278.  
  279.  
  280. * MODELE DE RAYONNEMENT SUR LA LIGNE DU HAUT
  281. * ET MATERIAU REPRESENTANT L'EMISSIVITE
  282. * ------------------------------------------
  283. MOR      = MODE LHAUT 'THERMIQUE' 'RAYONNEMENT' 'INFINI' ;
  284. MAR      = MATE MOR 'EMIS' 0.8 ;
  285.  
  286.  
  287. * CHARGEMENT DE RAYONNEMENT REPRESENTANT LA TEMPERATURE
  288. * EXTERIEURE (MAINTENUE)
  289. * -----------------------------------------------------
  290. CHTR     = MANU 'CHPO' LHAUT 1 'T' T0 ;
  291. CHARAY   = CHAR 'TERA' CHTR EVCTE ;
  292. CHAT     = CHAT ET CHARAY ;
  293.  
  294.  
  295. * REDEFINITION DE LA TABLE TAB1 POUR PASAPAS
  296. * ------------------------------------------
  297. TAB1                         = TABL ;
  298. TAB1 . 'MODELE'              = MOT ET MOC ET MOR ;
  299. TAB1 . 'CARACTERISTIQUES'    = MAT ET MAC ET MAR ;
  300. TAB1 . 'BLOCAGES_THERMIQUES' = BLT ;
  301. TAB1 . 'CHARGEMENT'          = CHAT ;
  302. TAB1 . 'TEMPS_CALCULES'      = PROG 0. 'PAS' (0.02 * TPSFIN) TPSFIN ;
  303. TAB1 . 'CELSIUS'             = VRAI ;
  304.  
  305.  
  306. * APPEL A PASAPAS
  307. * ---------------
  308. PASAPAS TAB1 ;
  309.  
  310.  
  311. * POST TRAITEMENT
  312. * ---------------
  313. * EVOLUTION TEMPORELLE DE LA TEMPERATURE
  314. EV11     = EVOL 'ROUG' 'TEMP' TAB1 'TEMPERATURES' 'T' PMIL ;
  315. EV22     = EVOL 'BLEU' 'TEMP' TAB1 'TEMPERATURES' 'T' PG ;
  316. TL       = TABL ;
  317. TL . 1   = 'TIRR' ;
  318. TL . 2   = 'TIRR' ;
  319. TL . 'TITRE' = TABL ;
  320. TL . 'TITRE' . 1 = 'PMIL cond seule' ;
  321. TL . 'TITRE' . 2 = 'PG   cond seule' ;
  322. TL . 'TITRE' . 3 = 'PMIL cond+conv+ray' ;
  323. TL . 'TITRE' . 4 = 'PG   cond+conv+ray' ;
  324. SI ITRAC ;
  325.   DESS (EV1 ET EV2 ET EV11 ET EV22) 'LEGE' TL 'TITR' '[4] Temperature vs Temps' ;
  326. FINSI ;
  327.  
  328. * BOUCLE SUR TOUS LES PAS DE TEMPS ET TRACE DU CHAMP DE TEMPERATURES
  329. N1       = DIME (TAB1 . 'TEMPERATURES') ;
  330. SI ITRAC ;
  331.   REPE B1 N1 ;
  332.     T_I      = TAB1 . 'TEMPERATURES' . (&B1 - 1) ;
  333.     TPS_I    = TAB1 . 'TEMPS' . (&B1 - 1) ;
  334.     PRC_I    = ENTI (100. * TPS_I / TPSFIN) ;
  335.     MOT_I    = CHAI '[4] Temperature au temps ' TPS_I ' (conv. + ray.)' '  (' PRC_I ' %)' ;
  336.     TRAC T_I SU CSU 'TITR' MOT_I LISO1 ;
  337.   FIN B1 ;
  338. FINSI ;
  339.  
  340. * BOUCLE SUR TOUS LES PAS DE TEMPS ET TRACE VECTEUR FLUX DE CHALEUR
  341. SI ITRAC ;
  342.   REPE B1 N1 ;
  343.     T_I      = TAB1 . 'TEMPERATURES' . (&B1 - 1) ;
  344.     VF_I     = VECFLU T_I MOT MAT ;
  345.     TPS_I    = TAB1 . 'TEMPS' . (&B1 - 1) ;
  346.     PRC_I    = ENTI (100. * TPS_I / TPSFIN) ;
  347.     MOT_I    = CHAI '[4] Vecteur flux de chaleur au temps ' TPS_I '  (' PRC_I ' %)' ;
  348.     TRAC VF_I CSU 'TITR' MOT_I ;
  349.   FIN B1 ;
  350. FINSI ;
  351.  
  352.  
  353. * SAUVEGARDE DES OBJETS CREES
  354. * ---------------------------
  355. OPTI 'SAUV' 'formation_debutant_2_thermique.sauv' ;
  357.  
  358.  
  359. FIN ;
  360.  
  361.  
  362.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales