Télécharger la plaquette Cast3M


fr en

Télécharger diffusion_sous_contraintes_01.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  diffusion_sous_contraintes_01.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. ************************************************************************
  6. *             CAS TEST diffusion_sous_contraintes_01.dgibi             *
  7. ************************************************************************
  8. *   NOTA : Ce cas-test ne valide aucun resultat analytique
  9. *          Il permet d'enrichir la base des cas-tests pour les utilisateurs
  10. *          Il incombe aux utilisateurs de valider et qualifier leur
  11. *          domaine de simulation.
  12. *
  13. *   DESCRIPTION :
  14. *   Ce cas-test simule la diffusion d'une espece chimique dans un gradient
  15. *   de potentiel elastique (calcul mecanique couple a la diffusion)
  16. *   La piece est une eprouvette entaillee afin de generer un fort champ
  17. *   de contrainte en pointe d'entaille.
  18. *
  19. *   - 2D PLAN
  20. *   - ELEMENTS FINIS TESTES : 'QUA4'
  21. *   - Regime transitoire pour la diffusion
  22. *
  23. *   - Utilisation de la procedure CHARTHER pour appliquer le flux du au
  24. *     gradient de potentiel elastique
  25. *   - Utilisation de l'operateur SORET pour calculer le flux lui-meme
  26. *   - Convergence DIFFUSION-MECANIQUE activee car la diffusion est
  27. *     influencee par la mecanique.
  28. ************************************************************************
  29. 'OPTI' 'DIME' 2 'ELEM' 'QUA4';
  30. 'OPTI' 'DEBU' 1;
  31. 'OPTI' 'TRAC' 'PSC';
  32.  
  33.  
  34. 'DEBP' CHARTHER PRECED TPS1;
  35. ************************************************************************
  36. * Dans la procedure CHARTHER (appel dans TRANSNON a chaque iterations)
  37. * permet d'ajouter une flux de diffusion du a un gradient d'energie
  38. * potetielle elastique dans le materiau
  39. *   - Le flux vaut JH=-CH.KD.grad(EPS(elas):SIG)
  40. *   - Le flux nodal integre QH est renvoye comme second membre dans 
  41. *     l'indice 'ADDI_SECOND'
  42. ************************************************************************
  43.  
  44.   SIG    = PRECED.'ESTIMATION'.'CONTRAINTES';
  45.   EPS    ='ELAS' MOD1 SIG MAT1;
  46.  
  47.   ENECHM ='ENER' MOD1 EPS SIG ;
  48.   ENE    ='CHAN' 'CHPO' MOD1 ENECHM ;
  49.  
  50. * Pour les besoins de SORE, on met 'T' comme nom de composante 
  51.   ENE    ='NOMC' 'T' ENE;  
  52.   CH     ='EXCO' TH_COUR 'CH' 'CH';
  53.  
  54.   RIGDM ='SORE'  MOD2  MATLOC COEF ENE  ;
  55.  
  56.   TAA='TABL';
  57.   TAA.'ADDI_SECOND'=RIGDM * CH;
  58. 'FINP' TAA ;
  59. ************************************************************************
  60.  
  61. * MAILLAGE 
  62.  LX = 1. ;
  63.  LY = 1. ;
  64.  A0 = 0.2;
  65.  
  66.  NBEX = 50;
  67.  NBEY = 50;
  68.  NBA0 ='ENTI' 'SUPE' (NBEY*A0/LY) ;
  69.  
  70.  P1 = 0. 0. ;
  71.  P2 = P1 'PLUS' (LX 0.);
  72.  P3 = P2 'PLUS' (0. A0);
  73.  
  74.  P4 = P3 'PLUS' (0. (LY-A0));
  75.  
  76.  P5 = P1 'PLUS' (0. LY);
  77.  P6 = P1 'PLUS' (0. A0);
  78.  
  79.  
  80.  L1 ='DROI' P1 NBEX P2;
  81.  L2 ='DROI' P6 NBEX P3;
  82.  L3 ='DROI' P5 NBEX P4;
  83.  
  84.  S1 ='REGL' L1  NBA0         L2 'COUL' BLEU;
  85.  S2 ='REGL' L2 (NBEY - NBA0) L3 'COUL' VERT;
  86.  PIECE=S1 'ET' S2 ;
  87.  
  88.  LSUP= 'COTE' 2 S2                     'COUL' 'JAUN' ;
  89.  LDRO=('COTE' 2 S1) 'ET'   LSUP        'COUL' 'CYAN' ;
  90.  LGAU=('COTE' 4 S1) 'ET' ('COTE' 4 S2) 'COUL' 'TURQ' ;
  91.  
  92. *TRAC 'QUAL' (S1 ET S2 ET LSUP ET LGAU);
  93.  
  94.  
  95. * MODELE & MATERIAU
  96.  MOD1  ='MODE' PIECE 'MECANIQUE' 'ELASTIQUE' 'CONS' 'MEC1';
  97.  MOD2  ='MODE' PIECE 'DIFFUSION' 'INCO' 'CH' 'QH' 'CONS' 'DIF1';
  98.  MODTOT= MOD1 'ET' MOD2;
  99.  
  100.  MAT1  ='MATE' MOD1 'YOUN' 90.E9 'NU' 0.3 ;
  101.  MAT2  ='MATE' MOD2 'KD' 5.D-3 'CDIF' 1. ;
  102.  MATTOT= MAT1 'ET' MAT2 ;
  103.  
  104. * Pour une utilisation dans CHARTHER avec SORET
  105.  DM    = 2.D-13 ;
  106.  MATLOC='MATE'  MOD2 'KD' DM           ;
  107.  COEF  ='MANU' 'CHML' MOD2 'SCAL' 1.D0 ;
  108.  
  109. * BLOCAGES
  110.  BLO1  ='BLOQ' 'UX'   LGAU ;
  111.  BLO2  ='BLOQ' 'UY'   LGAU ;
  112.  BLO3  ='BLOQ' 'UX'   LSUP ;
  113.  BLOTOT= BLO1 'ET' BLO2 'ET' BLO3;
  114.  
  115. * CHARGEMENT
  116.  DEPI1='DEPI' BLO1 (-1*LX/10);
  117.  
  118.  EVO1   ='EVOL' 'MANU' 'TEMP' ('PROG' 0. 0.5 1.) 'AMPL' ('PROG' 0. 1. 1.);
  119.  CHADEP1='CHAR' 'DIMP' DEPI1 EVO1;
  120.  CHATOT = CHADEP1;
  121.  
  122. * CONDITIONS INITIALES
  123.  CHPCH0 ='MANU' 'CHPO' PIECE 1 'CH' 1. 'NATU' 'DIFFUS';
  124.  
  125.  LTPS1  ='PROG' 0. 'PAS' 0.05 1. ;
  126.  
  127. * PASAPAS
  128.  TA1='TABL';
  129.  TA1.MODELE             = MODTOT ;
  130.  TA1.CARACTERISTIQUES   = MATTOT ;
  131.  TA1.BLOCAGES_MECANIQUES= BLOTOT ;
  132.  TA1.CHARGEMENT         = CHATOT ;
  133.  TA1.TEMPS_CALCULES     = LTPS1  ;
  134.  
  135.  TA1.PROCEDURE_CHARTHER = VRAI   ;
  136.  TA1.CONVERGENCE_MEC_THE= VRAI   ;
  137.  
  138.  TA1.CONCENTRATIONS     ='TABL' ;
  139.  TA1.CONCENTRATIONS. 0  = CHPCH0 ;
  140.  
  141.  PASAPAS TA1 ;
  142.  
  143.  DIM1 ='DIME' TA1.'TEMPS' - 1;
  144.  
  145. 'TRAC' ('LOG' TA1.CONCENTRATIONS. DIM1) PIECE ;
  146.  EVO1 ='EVOL' 'BLEU' 'TEMP' TA1 'CONCENTRATIONS' P3;
  147. 'DESS' EVO1;
  148. 'FIN';
  149.  
  150.  
  151.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales