Télécharger TirantLAB.dgibi

Retour à la liste

Numérotation des lignes :

  1.  
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. * CAS TEST DU 13/11/14 PROVENANCE : TEST
  6. SAUT PAGE;
  7. *
  8. *******************************************************
  9. * *
  10. * TEST ELEMENT COAXIAL COS2 POUR MODELE DE LIAISON *
  11. * ACIER-BETONEN REGIME LINEAIRE *
  12. * *
  13. * TIRANT 3 m SECTION CARRE 0.1 * 0.1 *
  14. * *
  15. * *
  16. * Le tirant est maille en 3D a l'aide d'elements *
  17. * massif CUB8. L'acier est maille a l'aide d'elements*
  18. * barre. Le tirant est soumise sous un chargemet *
  19. * monotone. *
  20. *******************************************************
  21. *
  22.  
  23.  
  24. OPTI ECHO 0;
  25. ***parametres
  26. xp1 = 3.;
  27. xp2 = xp1 + 0.1;
  28. yp1 = 0.1;
  29. yp2 = yp1/2.;
  30. nelx = 100;
  31. nely = 1;
  32. nelz = 1;
  33. *
  34. opti dime 3 elem cub8;
  35. ***geometrie et maillage
  36. b1 = 0. 0. 0.;
  37. b2 = xp1 0. 0.;
  38. lib1 = b1 droi nelx b2 ;
  39. sb1 = lib1 tran nely (0. yp1 0.) ;
  40. vol1 = sb1 volu tran nelz (0. 0. yp1) ;
  41. a1 = 0. yp2 yp2; a2 = xp1 yp2 yp2;
  42. PA1 = (-0.1 yp2 yp2) ;
  43. PA2 = (xp2 yp2 yp2) ;
  44. *
  45. lia1 = droi nelx a1 a2 ;
  46. lia2 = lia1 plus (0. 0. 0.);
  47. *
  48. D1 = DROI 1 PA1 A1 ;
  49. D2 = DROI 1 A2 PA2 ;
  50. ACI = D1 et D2 et LIA1 ;
  51. *
  52. acibet = racc lia1 lia2 1.e-4;
  53. vtot = vol1 et acibet;
  54. ***loi d adherence
  55. pulo1 = prog 0. 1.;
  56. pulo2 = prog 0. 1.e11;
  57. *
  58. pulop = evol manu pulo1 pulo2;
  59. *
  60. ***materiaux
  61. ***acier
  62. yga = 210.e9;
  63. nua = 0.3;
  64. secc1 = 7.854e-5;
  65. secc2 = 7.854e-5;
  66. ***beton
  67. ygb = 30.e9;
  68. nub = 0.2;
  69. ***model
  70. ***acier
  71. moa= model aci mecanique elastique isotrope barre;
  72. maa = mate moa young yga nu nua SECT secc1;
  73. ***beton
  74. mob = model vol1 mecanique elastique isotrope;
  75. mab =MATE mob youn ygb nu nub;
  76. ***beton acier
  77. moab = model acibet mecanique elastique isotrope plastique
  78. liaison_acbe cos2;
  79. maab = mate moab 'PULO' pulop 'KN' 1e15 'KS' 1.e11 'SECT' secc2 ;
  80. *
  81. motot = moa et mob et moab;
  82. matot = maa et mab et maab;
  83. ***conditions aux limites
  84. cl1 = rela accro lia2 vol1;
  85. cl2 = bloqu UZ sb1;
  86. cl3 = bloqu depl PA1;
  87. cl4 = bloqu ux PA2;
  88. cl5 = bloqu uz pa2;
  89. cl6 = bloqu uy pa2;
  90. pp1 = 0. 0. 0.;
  91. pp2 = 1. 0. 0.;
  92. pp3 = 1. 0. yp1;
  93. sy1 = vol1 poin plan pp1 pp2 pp3 1.e-4;
  94. cl7 = bloq uy sy1;
  95. *
  96. cltot = cl1 et cl2 et cl3 et cl4 et cl5 et cl6 et cl7;
  97. ***chargement
  98. evo1 = evol manu (prog 0. 1.) (prog 0. 2.e-3);
  99. for1 = depi cl4 1.;
  100. char1 = chargement (for1 ) evo1 dimp;
  101. ***table
  102. tab1 = table;
  103. tab1.modele = motot;
  104. tab1.caracteristiques = matot;
  105. tab1.blocages_mecaniques = cltot;
  106. tab1.chargement= char1;
  107. tab1.'PRECISION' = 1.e-5;
  108. tab1.temps_calcules =
  109. prog 0. pas 0.5 1.;
  110. *
  111. pasapas tab1;
  112. *
  113. *********************
  114. ***post traitement***
  115. *********************
  116. ***force
  117. rr0 = reac cl4 tab1.deplacements.1;
  118. rr1 = resu rr0;
  119. fff = extr rr1 'FX' (poin ( extr rr0 mail ) initial );
  120. *
  121. errf = abs(fff - 33.75e3)/33.75e3;
  122. *
  123. si (> errf 1e-3);
  124. erreur (5);
  125. finsi;
  126.  
  127. fin;
  128.  
  129.  
  130.  
  131.  
  132.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales