Télécharger elas2.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : elas2.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. *******************************************************
  6. * Test elas2.dgibi: Jeux de données *
  7. * --------------------------------- *
  8. *******************************************************
  9.  
  10. * GRAPH = FAUX => PAS DE GRAPHIQUE AFFICHE
  11. * GRAPH = VRAI => LES GRAPHIQUES SONT AFFICHES dans un postscript
  12. GRAPH = FAUX ;
  13.  
  14. SAUT PAGE;
  15. SI GRAPH ;
  16. OPTI ECHO 1 ;
  17. OPTI TRAC PSC ;
  18. SINO ;
  19. OPTI ECHO 0 ;
  20. FINSI ;
  21.  
  22. *______________________________________________________
  23. * TEST ELAS2
  24. *
  25. * Un cylindre est pincé à une de ses extrémités,
  26. * l'autre extrémité étant encastrée.
  27. *
  28. * Pour des raisons de symétrie seul 1/4 de la structure
  29. * a est modélisé.
  30. *
  31. * Les conditions aux limites sont imposées pour
  32. * respecter les symétries.
  33. * Une force ponctuelle est appliquée diametralement.
  34. *
  35. * Le déplacement en X d'un point de la base est comparé
  36. * au déplacement théorique (déplacement nul puisque
  37. * encastré).
  38. * Le déplacement en Z du point d'application de force
  39. * est comparé à la valeur théorique (-1.140)
  40. *______________________________________________________
  41.  
  42. OPTION DIME 3 ELEM TRI3 ;
  43. TITRE 'CYLINDRE PINCE A BORDS ENCASTRES' ;
  44. TEMPS ;
  45. *-----------------------------------------------------
  46. * DEFINITION DE LA GEOMETRIE
  47. *-----------------------------------------------------
  48. P1=7 0 0 ;P2=0 0 7 ;C1=0 0 0 ;VECT=0 70 0 ;
  49. LIG1=C 6 P1 C1 P2 ;SURF=LIG1 TRAN 30 VECT ;
  50. LIG1 LIG2 LIG3 LIG4=COTE SURF ;P3=LIG2 POIN FINA ;
  51. *
  52. OEIL1 = 100 100 100;
  53. SI(GRAPH);
  54. TRAC OEIL1 SURF 'QUAL';
  55. FINSI;
  56. *-----------------------------------------------------
  57. * DEFINITION DU MODELE
  58. *-----------------------------------------------------
  59. MOD1=MODE SURF MECANIQUE ELASTIQUE DKT ;
  60. MAT1=MATE MOD1 YOUN 3.E7 NU 0.3 ;
  61. EPEE=CARA MOD1 EPAI 0.1 ;
  62. MAT1=MAT1 ET EPEE;
  63. *-----------------------------------------------------
  64. *** CALCUL RIGIDITE ET MASSE ;
  65. *-----------------------------------------------------
  66. *
  67. RIG1=RIGI MOD1 MAT1;
  68. *
  69. *-----------------------------------------------------
  70. * CONDITIONS AUX LIMITES
  71. *-----------------------------------------------------
  72. *bp ENC1=BLOQ LIG4 UZ ;ENC2=BLOQ LIG4 RX ;ENC3=BLOQ LIG4 RY ;
  73. *bp, 2020-11-12 : on teste la syntaxe de BLOQ avec LISTMOTS
  74. ENC1a3 = BLOQ (MOTS 'UZ' 'RX' 'RY') (MOTS 'FZ' 'MX' 'MY') LIG4;
  75. ENC4=BLOQ LIG2 UX ;ENC5=BLOQ LIG2 RY ;ENC6=BLOQ LIG2 RZ ;
  76. ENC7=BLOQ LIG3 UY ;ENC8=BLOQ LIG3 RX ;ENC9=BLOQ LIG3 RZ ;
  77. ENC10=BLOQ LIG1 DEPL ROTA ;
  78. *bp ENC11=ENC1 ET ENC2 ET ENC3 ET ENC4 ET ENC5 ET ENC6 ET ENC7 ET ENC8 ET ENC9 ET ENC10 ;
  79. ENC11=ENC1a3 ET ENC4 ET ENC5 ET ENC6 ET ENC7 ET ENC8 ET ENC9 ET ENC10 ;
  80. *------------------------------------------------------
  81. * FORCES
  82. *------------------------------------------------------
  83. F1=0 0 -2500 ;
  84. EFOR=FORC F1 P3 ;
  85. RIG2=RIG1 ET ENC11;
  86. *------------------------------------------------------
  87. * RESOLUTION ET RESULTATS
  88. *------------------------------------------------------
  89. DE1 = RESOU RIG2 EFOR;
  90. D1X = EXTR DE1 UX P1 ;
  91. D3Z = EXTR DE1 UZ P3 ;
  92.  
  93. DEFO1= DEFO SURF DE1;
  94. DZ = EXCO DE1 UZ;
  95. SI (GRAPH) ;
  96. LIST DE1;
  97. TRAC OEIL1 'CACH' DEFO1 DZ;
  98. FINSI;
  99.  
  100. *------------------------------------------------------
  101. * SORTIE DES RESULTATS
  102. *------------------------------------------------------
  103. SAUT PAGE ;
  104. MESS ' DEPLACEMENT EN X DE LA BASE VALEUR THEORIQUE : 0.00' ;
  105. MESS ' DEPLACEMENT EN X DE LA BASE VALEUR CALCULEE : ' D1X ;
  106. SAUT 2 LIGNE ;
  107. MESS ' DEPLACEMENT EN Z THEORIQUE : -1.140' ;
  108. MESS ' DEPLACEMENT EN Z CALCULE : ' D3Z ;
  109. TEMPS ;
  110. * CODE FONCTIONNEMENT
  111. DZREF=-1.14;
  112. RESI1=ABS((D3Z-DZREF)/DZREF);
  113. SI( RESI1 <EG 6E-4 );
  114. ERRE 0;
  115. SINO;
  116. ERRE 5;
  117. FINSI;
  118.  
  119. DXREF= 0.0;
  120. RESI2= ABS D1X;
  121. SI( RESI2 <EG DXREF);
  122. ERRE 0;
  123. SINO;
  124. ERRE 5;
  125. FINSI;
  126.  
  127. FIN;
  128.  
  129.  
  130.  
  131.  
  132.  
  133.  
  134.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales