Télécharger thme1.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : thme1.dgibi
  2. * Test Thme1.dgibi: Jeux de données *
  3. * --------------------------------- *
  4. * *
  5. complet = faux;
  6. *
  7. *************************************************
  8. * pour calcul complet mettre complet à : vrai;
  9. *************************************************
  10. *------------------------------------------------------
  11. *
  12. * Calcul thermo-mécanique ( mécanique et thermique
  13. * linéaire ). Utilisation de la procédure PASAPAS
  14. *
  15. *
  16. * |
  17. * |_____________________________________
  18. * | |
  19. * | T_initial = 20°C | x1 = 0.1 m
  20. * |_____________________________________| T1 = 500°C
  21. * | x0 = 0 m
  22. * | T0 = 20°C
  23. * Encastrement
  24. *
  25. * on étudie la diffusion thermique dans le barreau
  26. * et sa dilatation
  27. *
  28. * caracteristiques du barreau :
  29. *
  30. * l = 0.1m
  31. * K = 14.6
  32. * C = 460
  33. * RHO = 7800
  34. * ALPHA = 1E-5
  35. * YOUNG = 2.E11
  36. * NU = 0.00001
  37. *
  38. *
  39. * Mailles de 0.01 m de cote
  40. *
  41. * On compare les résultats à une solution analytique
  42. *
  43. *------------------------------------------------------
  44.  
  45. OPTION ECHO 1;
  46. OPTION DIME 2 ELEM QUA8 MODE PLAN DEFO;
  47. *
  48. *-------------------- Creation du maillage ------------
  49. *
  50. dens 1;
  51. PA = 0. 0. ;
  52. PB = 0.1 0. ;
  53. PC = 0.1 0.01 ;
  54. PD = 0. 0.01 ;
  55. pp8 = 0.08 0.;
  56. D1 = DROI 10 PA PB ;
  57. D2 = DROI 1 PB PC ;
  58. D3 = DROI 10 PC PD ;
  59. D4 = DROI 1 PD PA ;
  60. L1 = D1 ET D2 ET D3 ET D4;
  61. SU1 = SURF L1 PLANE ;
  62. pp8 = su1 point proc pp8;
  63. *
  64. *-------------------- Définition du modèle ------------
  65. *
  66. MOD1 = MODE SU1 THERMIQUE ISOTROPE CONS UN;
  67. MOD2 = MODE SU1 MECANIQUE ELASTIQUE ISOTROPE CONS DEUX;
  68. MOD = MOD1 ET MOD2 ;
  69. *
  70. *------------------- Définition des matériaux ---------
  71. *
  72. MAT1 = MATE MOD1 K 14.6 'C' 460. RHO 7800. ;
  73. MAT2 = MATE MOD2 ALPHA 1E-5 YOUN 2E+11 NU 0.00001;
  74. MAT = MAT1 ET MAT2 ;
  75. *
  76. *------------------- blocages mécaniques --------------
  77. *
  78. CL1 = BLOQ UY SU1 ;
  79. CL2 = BLOQ UX D4 ;
  80. CL_ME = CL1 ET CL2;
  81. *
  82. *------------------- blocages thermiques --------------
  83. *
  84. CL3 = BLOQ T D2;
  85. CL4 = BLOQ T D4;
  86. CL_TH = CL3 ET CL4;
  87. *
  88. *------------------- températures imposées ------------
  89. *
  90. TEM1 = DEPI CL3 500.;
  91. TEM2 = DEPI CL4 20.;
  92. EV1 = EVOL MANU x (PROG 0. 200.) y (prog 1. 1.);
  93. CHA = CHAR TIMP (TEM1 + TEM2) EV1;
  94. *
  95. *------------------- température initiale -------------
  96. *
  97. TEM0 = MANU CHPO SU1 1 T 20.;
  98. *
  99. *--------------- creation de la table pour pasapas ----
  100. *
  101. ta = table;
  102. ta.modele = mod;
  103. ta.caracteristiques = mat;
  104. ta.blocages_mecaniques = cl_me;
  105. ta.blocages_thermiques = cl_th;
  106. ta.temperatures = table;
  107. ta.temperatures . 0 = tem0;
  108. ta.chargement = cha;
  109. ta.procedure_thermique = LINEAIRE;
  110. ta.temps_calcules = prog 0. pas 5. 150.;
  111. *
  112. *
  113. *----------------------- Depouillement ----------------
  114. *
  115. ltref1 = prog 10. pas 10. 150.;
  116. a = (14.6 / 7800.)/460.;
  117. x = 0.08;
  118. er1 = 0.;
  119. er2 = 0.;
  120. nb = 0;
  121. tpr1 = prog;
  122. tpr2 = prog;
  123. tpr3 = prog;
  124. tep_th = prog;
  125. dep_th = prog;
  126. idim = 'DIME' ltref1 ;
  127. solteenr = prog
  128. 32.779 76.142 116.26 148.47
  129. 174.30 195.40 212.98 227.88
  130. 240.70 251.85 261.65 270.33
  131. 278.08 285.03 291.30 ;
  132. soldeenr = prog
  133. 4.51064E-07 3.18778E-06 7.26909E-06 1.18402E-05
  134. 1.65525E-05 2.12583E-05 2.58885E-05 3.04069E-05
  135. 3.47909E-05 3.90251E-05 4.30987E-05 4.70048E-05
  136. 5.07398E-05 5.43030E-05 5.76962E-05;
  137. repeter bou idim;
  138. ite = &bou;
  139. te = 'EXTR' ltref1 ite ;
  140. dep = PECHE ta deplacements te ;
  141. tem = PECHE ta temperatures te ;
  142. tep1 = extr tem T pp8;
  143. dep1 = extr dep UX pp8;
  144. tpr1 = tpr1 et (prog tep1);
  145. tpr2 = tpr2 et (prog dep1);
  146. tpr3 = tpr3 et (prog te);
  147. si complet;
  148. co1 = erf((0.1 - x)/(2 * (( a * te )**0.5)));
  149. co2 = erf(0.1/(2.*(( a * te )**0.5)));
  150. sol_te = 500. - ((500. - 20.)*co1/co2);
  151. sinon;
  152. sol_te = extr solteenr ite;
  153. finsi;
  154. tep_th = tep_th et (prog sol_te);
  155. si complet;
  156. mi = prog;
  157. mi1 = prog ;
  158. repeter bou2 21;
  159. ite2 = &bou2 - 1;
  160. te1 = x * ite2 / 20;
  161. mi = mi et (prog te1);
  162. y1 = erf((0.1 - te1)/(2.*(( a * te )**0.5)));
  163. mi1 = mi1 et (prog y1);
  164. fin bou2;
  165. ev5 = evol manu xx mi y mi1;
  166. res = extr (INTG ev5) 1;
  167. sol_de = 1E-5*(500. - 20.)/co2*((x * co2) - res);
  168. sinon;
  169. sol_de = extr soldeenr ite;
  170. finsi;
  171. dep_th = dep_th et (prog sol_de);
  172. si ((flot ite) > ((flot idim)/2) );
  173. er1 = er1 + (abs ((sol_te - tep1)/sol_te) * 100.);
  174. er2 = er2 + (abs ((sol_de - dep1)/sol_de) * 100.);
  175. nb = nb + 1;
  176. finsi;
  177. fin bou;
  178. *
  179. er1 = er1/nb;
  180. er2 = er2/nb;
  181. mess 'erreur sur la température :'er1'%';
  182. mess 'erreur sur le deplacement :'er2'%';
  183. *
  184. *lvar =text 'EVOLUTION DE LA TEMPERATURE AU POINT'x'm';
  185. *titre lvar;
  186. *ev_te = evol manu temps tpr3 temperature tpr1;
  187. *ev_tet = evol manu temps tpr3 temperature tep_th;
  188. *dess (ev_te et ev_tet);
  189. *lvar = text 'EVOLUTION DU DEPLACEMENT AU POINT'x'm';
  190. *titre lvar;
  191. *ev_de = evol manu temps tpr3 deplacement tpr2;
  192. *ev_det = evol manu temps tpr3 deplacement dep_th;
  193. *dess (ev_de et ev_det);
  194. *
  195. si ( er1 > 2. ) ;
  196. mess 'Résultat incorrect' ;
  197. erreur 5 ;
  198. finsi ;
  199. si ( er2 > 5. ) ;
  200. mess 'Résultat incorrect' ;
  201. erreur 5 ;
  202. finsi ;
  203. *
  204. fin;
  205.  
  206.  
  207.  
  208.  
  209.  
  210.  
  211.  
  212.  
  213.  
  214.  
  215.  
  216.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales