Télécharger gdcis.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : gdcis.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *======================================================================*
  5. * MODELE HYPERELASTIQUE GORNET-DESMORAT INCOMPRESSIBLE *
  6. * EN GRANDES TRANSFORMATIONS - CONTRAINTES PLANES *
  7. * *
  8. * TEST DE VALIDATION DU MODELE : CISAILLEMENT DANS LA DIRECTION X *
  9. * COMPARAISON AVEC LA SOLUTION ANALYTIQUE *
  10. * *
  11. * Contribution de Laurent Gornet - Ecole Centrale de Nantes (2010) *
  12. *======================================================================*
  13. * Pour plus d'informations, voir la presentation de L. Gornet lors *
  14. * du Club Cast3m 2009, disponible sur le site Web de Cast3m. *
  15. *======================================================================*
  16. * Exemple d'utilisation d'un modele UMAT en grandes transformations *
  17. * *
  18. * Note : Actuellement en grandes deformations dans PASAPAS, le modele *
  19. * ne peut contenir que des modeles de type UMAT. On ne peut *
  20. * pas melanger les derivees objectives et les modeles de C3m. *
  21. *======================================================================*
  22.  
  23. 'OPTION' 'DIME' 2 'MODE' 'PLAN' 'CONT' 'ECHO' 0;
  24. option epsilon 'UTILISATEUR';
  25. *
  26. * Mettre VRAI si l'on souhaite divers traces.
  27. GRAPH = FAUX ;
  28. *GRAPH = VRAI ;
  29. title = 'CHAINE' 'GORNET-DESMORAT - ' 'CISAILLEMENT SIMPLE XY' ;
  30.  
  31. *======================================================================*
  32. * Geometrie - Maillage *
  33. *======================================================================*
  34. * Longueur (direction x) de la plaque/membrane :
  35. Lg_x = 1.8 ;
  36. * Largeur (direction y) de la plaque/membrane :
  37. Lg_y = 1. ;
  38. * Nombre d'elements selon les directions x et y :
  39. Nel_x = 5 ;
  40. Nel_y = 2 ;
  41. *
  42. *Nel_x = 50 ;
  43. *Nel_y = 20 ;
  44. 'OPTION' 'ELEM' 'QUA4' ;
  45. *
  46. P1 = 0. 0. ;
  47. P2 = Lg_x 0. ;
  48. P3 = Lg_x Lg_y ;
  49. P4 = 0. Lg_y ;
  50. *
  51. L1 = 'DROITE' Nel_x P1 P2 ;
  52. L2 = 'DROITE' Nel_y P2 P3 ;
  53. L3 = 'DROITE' Nel_x P3 P4 ;
  54. L4 = 'DROITE' Nel_y P4 P1 ;
  55. *
  56. SU = 'DALLER' L1 L2 L3 L4 ;
  57. 'SI' GRAPH ;
  58. 'TRACER' SU 'TITRE' ('CHAINE' title ' - MAILLAGE') ;
  59. 'FINSI' ;
  60.  
  61. *======================================================================*
  62. * Modele - Materiau - Caracteristiques (en Pa) *
  63. *======================================================================*
  64. 'SI' (('NEG' ('VALEUR' 'DIME') 2) 'OU'
  65. ('NEG' ('VALEUR' 'MODE') 'PLANCONT')) ;
  66. 'MESS' 'Ce modele ne fonctionne qu en 2D CONTRAINTES PLANES' ;
  67. 'ERREUR' 5 ;
  68. 'FINSI' ;
  69. *
  70. * Ne pas oublier de definir les parametres lies a l'elasticite.
  71. * Meme si ce n'est pas utilise dans le modele, cela est utile pour
  72. * l'operateur de convergence mecanique de PASAPAS-INCREME.
  73. *
  74. LCMAT = MOTS 'YOUN' 'NU ' 'H1' 'H2' 'H3' ;
  75. MO = MODE SU 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'
  76. 'NON_LINEAIRE' 'UTILISATEUR'
  77. 'NUME_LOI' 33 'C_MATERIAU' LCMAT ;
  78. * Pour calculer le module d'Young, on utilise les
  79. * Coefficients du modele de Mooney-Rivlin (en MPa) :
  80. C1 = 0.183 ; C2 = 0.0034 ;
  81. *
  82. * On fixe le coefficient de Poisson XNU a une valeur proche de 0.5
  83. * du fait de l'incompressibilite inherente au modele.
  84. * Le module de Young YOU est alors connu, car, pour ce modele, le
  85. * module de cisaillement MU vaut : MU = YOU/(2*(1+XNU)) = 2.(C1+C2)
  86. * Il s'agit de la valeur initiale et de la borne inferieure dans le cas
  87. * de la traction. En fonction du niveau de deformation atteinte en
  88. * traction, il faut augmenter cette valeur afin de pouvoir faire
  89. * converger les calculs (module tangent en fin de calculs).
  90. * Prendre des valeurs superieures n'entraine pas de modification des
  91. * resultats, cela modifie seulement le nombre d'iterations mecaniques.
  92. *
  93. XNU = 0.499 ;
  94. YOUini = 3.*(2.*(C1+C2)) ; YOU = 100. * YOUini ;
  95. *
  96. *Parametres du modèle GD : essais Treloar/Kawabata MPa
  97. H1 = 0.142236 ;
  98. H2 = 1.5854659E-2 ;
  99. H3 = 3.4946541E-4 ;
  100. *
  101. MA = MATE MO 'YOUN' YOU 'NU ' XNU 'H1' H1 'H2' H2 'H3' H3 ;
  102.  
  103. *======================================================================*
  104. * Conditions aux limites - Traction suivant UY *
  105. *======================================================================*
  106. CTOT = 'CONTOUR' SU ;
  107. BL1 = 'BLOQUER' 'UX ' CTOT ;
  108. BL2 = 'BLOQUER' 'UY ' CTOT ;
  109. BLTOT = BL1 'ET' BL2 ;
  110. *
  111. * Definition des instants du chargement :
  112. t_deb = 0. ; t_fin = 10. ;
  113. L_tps = 'PROG' t_deb t_fin ;
  114. * Cisaillement suivant X :
  115. UX_deb = 0. ; UX_fin = 3. * Lg_y ;
  116. L_UX = 'PROG' UX_deb UX_fin ;
  117. EV_xy = 'EVOL' 'MANU' 'TEMPS' L_tps 'LAMX' L_UX ;
  118. chp_y = 'NOMC' 'UX ' ('COORD' 2 CTOT) ;
  119. FF_xy = 'DEPIMP' BL1 chp_y ;
  120. CHARTOT = 'CHARGEMENT' 'DIMP' FF_xy EV_xy ;
  121.  
  122. *======================================================================*
  123. * Initialisation de la table pour appel a PASAPAS *
  124. *======================================================================*
  125. TAB1 = 'TABLE' ;
  126. TAB1.'MODELE' = MO ;
  127. TAB1.'CARACTERISTIQUES' = MA ;
  128. TAB1.'BLOCAGES_MECANIQUES' = BLTOT ;
  129. TAB1.'CHARGEMENT' = CHARTOT ;
  130. *TAB1.'PRECISION' = 1.E-6 ;
  131. *TAB1.'FTOL' = 1.E-5 ;
  132. *TAB1.'MTOL' = 1.E-5 ;
  133. TAB1.'CONVERGENCE_FORCEE' = FAUX ;
  134. TAB1.'GRANDS_DEPLACEMENTS' = VRAI ;
  135. TAB1.'TEMPS_CALCULES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  136. TAB1.'TEMPS_SAUVES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  137. *
  138. L_abs = TAB1.'TEMPS_SAUVES' ;
  139. n_abs = 'DIMENSION' L_abs ;
  140. *
  141. PASAPAS TAB1 ;
  142. *
  143. * Quelques traces de controle apres calculs
  144. 'SI' GRAPH ;
  145. Defo_0 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 0. ;
  146. Defo_1 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 1. 'VERT' ;
  147. 'TRACER' (Defo_0 'ET' Defo_1)
  148. 'TITRE' ('CHAINE' title ' - DEFORMEES INITIALE ET FINALE') ;
  149. 'TRACER' MO (TAB1.'CONTRAINTES'.(n_abs-1))
  150. 'TITRE' ('CHAINE' title ' - CONTRAINTES EN FIN DE CALCUL') ;
  151. 'FINSI' ;
  152. *
  153. *======================================================================*
  154. * Construction de la solution analytique *
  155. *======================================================================*
  156. * Definitions :
  157. * - Cisaillement selon xy : Cisx = UX/Lg_y
  158. * - Densite d'energie de deformation hyperelastique : W(I1,I2)
  159. * - I1, I2 : trois invariants du tenseur de Cauchy-Green droit
  160. * Dans le cas du modele GD : Incompressible
  161. * Les contraintes de Cauchy sont calculables analytiquement :
  162. * - SCxx = 2.(Cisx**2).dW/dI1
  163. * - SCyy = -2.(Cisx**2).dW/dI2
  164. * - SCxy = 2.Cisx.(dW/dI1 + dW/dI2)
  165. * - SCzz = 0 (hypothese des contraintes planes)
  166. *
  167. Cisx = ('IPOL' L_abs L_tps L_UX) / Lg_y ;
  168. L_z1 = Cisx * Cisx ;
  169. *LG
  170. L_Un = 'PROG' n_abs '*' 1. ;
  171. L_tr = L_Un * 3.;
  172. I1 = L_z1 + L_tr ;
  173. I2 = I1;
  174. ************************************************************************
  175. dWI1= H1 * (exp (H3 *((I1 - L_tr)**2)));
  176. dWI2= 3 * H2 * L_Un / (I2**0.5);
  177. ************************************************************************
  178. SCxx_th = 2.*dWI1*L_z1 ;
  179. SCyy_th = -2.*dWI2*L_z1 ;
  180. SCxy_th = 2.*(dWI1+dWI2)*Cisx ;
  181.  
  182. *======================================================================*
  183. * Comparaison des resultats avec la solution analytique *
  184. *======================================================================*
  185. * La comparaison s'effectue entre les valeurs moyennes des contraintes
  186. * calculees et les solutions analytiques correspondantes.
  187. * On ne cherche pas a verifier l'uniformite du champ de contraintes.
  188. * (Faire le calcul en mettant GRAPH a VRAI et voir les isovaleurs !)
  189. *
  190. TabD = TAB1.'DEPLACEMENTS' ;
  191. TabS = TAB1.'CONTRAINTES' ;
  192. Confini = 'FORM' ;
  193. ChmUn = 'MANU' 'CHML' MO 'SCAL' 1. ;
  194. *
  195. SCxx = 'PROG' 0. ;
  196. SCyy = 'PROG' 0. ;
  197. SCxy = 'PROG' 0. ;
  198. 'REPETER' Boucle (n_abs - 1) ;
  199. 'FORM' (TabD.&Boucle) ;
  200. VolSU = 'INTG' MO ChmUn ;
  201. SCxx = SCxx 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXX')/VolSU)) ;
  202. SCyy = SCyy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYY')/VolSU)) ;
  203. SCxy = SCxy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXY')/VolSU)) ;
  204. 'FORM' Confini ;
  205. 'FIN' Boucle ;
  206. *
  207. * LG gam Cisx
  208. L_abs = Cisx;
  209. *
  210. 'SI' GRAPH ;
  211. tlege = 'TABLE' ;
  212. tlege. 1 = 'MARQ CROI' ;
  213. tlege.'TITRE' = 'TABLE' ;
  214. tlege.'TITRE'. 1 = 'Numerique' ;
  215. tlege.'TITRE'. 2 = 'Analytique' ;
  216. Evxx = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXX' SCxx ;
  217. Evxx_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXX' SCxx_th ;
  218. 'DESSIN' (Evxx 'ET' Evxx_th) 'LEGE' tlege
  219. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XX (MPa)') ;
  220. Evyy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYY' SCyy ;
  221. Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYY' SCyy_th ;
  222. 'DESSIN' (Evyy 'ET' Evyy_th) 'LEGE' tlege
  223. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY YY (MPa)') ;
  224. Evxy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXY' SCxy ;
  225. Evxy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXY' SCxy_th ;
  226. 'DESSIN' (Evxy 'ET' Evxy_th) 'LEGE' tlege
  227. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (MPa)');
  228. 'FINSI' ;
  229. *
  230. * Tests de bon fonctionnement :
  231. r_xx = 'MAXIMUM' ('ABS' (SCxx - SCxx_th)) ;
  232. r_yy = 'MAXIMUM' ('ABS' (SCyy - SCyy_th)) ;
  233. r_xy = 'MAXIMUM' ('ABS' (SCxy - SCxy_th)) ;
  234. *
  235. MESS ' RESULTATS : ' title ;
  236. MESS ' ------------------------------------------------- ';
  237. 'SAUTER' 1 'LIGNE' ;
  238. 'MESS' ' Tests de bon fonctionnement :' ;
  239. 'MESS' ' -------------------------------' ;
  240. 'MESS' ' Comparaison effectuee sur les contraintes de Cauchy' ;
  241. 'MESS' ' Ecart maximal absolu entre la valeur moyenne calculee' ;
  242. 'MESS' ' et la '
  243. 'solution analytique associee' ;
  244. 'MESS' ' Composante XX : ' r_xx ' MPa' ;
  245. 'MESS' ' Composante YY : ' r_yy ' MPa' ;
  246. 'MESS' ' Composante XY : ' r_xy ' MPa' ;
  247. 'SAUTER' 1 'LIGNE' ;
  248. * Ecart relatif maximal tolere
  249. Sigref = 1.E-3 ;
  250. 'SI' ('>EG' ('MAXIMUM' ('PROG' r_xx r_yy r_xy)) Sigref) ;
  251. 'MESS' ' ---------------------' ;
  252. 'MESS' ' ECHEC DU CAS-TEST !' ;
  253. 'MESS' ' ---------------------' ;
  254. 'ERREUR' 5 ;
  255. 'SINON' ;
  256. 'MESS' ' ----------------------' ;
  257. 'MESS' ' SUCCES DU CAS-TEST !' ;
  258. 'MESS' ' ----------------------' ;
  259. 'FINSI' ;
  260. 'SAUTER' 1 'LIGNE' ;
  261. 'FIN' ;
  262.  
  263.  
  264.  
  265.  
  266.  
  267.  
  268.  
  269.  
  270.  
  271.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales