Télécharger gd2trac.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : gd2trac.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *======================================================================*
  5. * MODELE HYPERELASTIQUE GORNET-DESMORAT INCOMPRESSIBLE *
  6. * EN GRANDES TRANSFORMATIONS - CONTRAINTES PLANES *
  7. * *
  8. * TEST DE VALIDATION DU MODELE : TRACTION BIAXIALE DANS LE PLAN X,Y *
  9. * COMPARAISON AVEC LA SOLUTION ANALYTIQUE *
  10. * *
  11. * Contribution de Laurent Gornet - Ecole Centrale de Nantes (2010) *
  12. *======================================================================*
  13. * Pour plus d'informations, voir la presentation de L. Gornet lors *
  14. * du Club Cast3m 2009, disponible sur le site Web de Cast3m. *
  15. *======================================================================*
  16. * Exemple d'utilisation d'un modele UMAT en grandes transformations *
  17. * *
  18. * Note : Actuellement en grandes deformations dans PASAPAS, le modele *
  19. * ne peut contenir que des modeles de type UMAT. On ne peut *
  20. * pas melanger les derivees objectives et les modeles de C3m. *
  21. *======================================================================*
  22.  
  23. 'OPTION' 'DIME' 2 'MODE' 'PLAN' 'CONT' 'ECHO' 0 ;
  24. option epsilon 'UTILISATEUR';
  25. *
  26. * Mettre VRAI si l'on souhaite divers traces.
  27. GRAPH = FAUX ;
  28. *GRAPH = VRAI ;
  29. *
  30. title = 'CHAINE' 'GORNET-DESMORAT- ' 'TRACTION BIAXIALE XY' ;
  31.  
  32.  
  33. *======================================================================*
  34. * Geometrie - Maillage *
  35. *======================================================================*
  36. * Longueur (direction x) de la plaque/membrane :
  37. Lg_x = 1. ;
  38. * Largeur (direction y) de la plaque/membrane :
  39. Lg_y = 0.5 ;
  40. * Nombre d'elements selon les directions x et y :
  41. Nel_x = 5 ;
  42. Nel_y = 3 ;
  43. *
  44. *Nel_x = 50 ;
  45. *Nel_y = 30 ;
  46. *
  47. 'OPTION' 'ELEM' 'QUA8' ;
  48. *
  49. P1 = 0. 0. ;
  50. P2 = Lg_x 0. ;
  51. P3 = Lg_x Lg_y ;
  52. P4 = 0. Lg_y ;
  53. *
  54. L1 = 'DROITE' Nel_x P1 P2 ;
  55. L2 = 'DROITE' Nel_y P2 P3 ;
  56. L3 = 'DROITE' Nel_x P3 P4 ;
  57. L4 = 'DROITE' Nel_y P4 P1 ;
  58. *
  59. SU = 'DALLER' L1 L2 L3 L4 ;
  60. 'SI' GRAPH ;
  61. 'TRACER' SU 'TITRE' ('CHAINE' title ' - MAILLAGE') ;
  62. 'FINSI' ;
  63.  
  64. *======================================================================*
  65. * Modele - Materiau - Caracteristiques (en MPa) *
  66. *======================================================================*
  67. 'SI' (('NEG' ('VALEUR' 'DIME') 2) 'OU'
  68. ('NEG' ('VALEUR' 'MODE') 'PLANCONT')) ;
  69. 'MESS' 'Ce modele ne fonctionne qu en 2D CONTRAINTES PLANES' ;
  70. 'ERREUR' 5 ;
  71. 'FINSI' ;
  72. *
  73. * Ne pas oublier de definir les parametres lies a l'elasticite.
  74. * Meme si ce n'est pas utilise dans le modele, cela est utile pour
  75. * l'operateur de convergence mecanique de PASAPAS-INCREME.
  76. *
  77. *
  78. LCMAT = MOTS 'YOUN' 'NU ' 'H1' 'H2' 'H3' ;
  79. MO = MODE SU 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'
  80. 'NON_LINEAIRE' 'UTILISATEUR'
  81. 'NUME_LOI' 33 'C_MATERIAU' LCMAT ;
  82. * Pour calculer le module d'Young, on utilise les
  83. * Coefficients du modele de Mooney-Rivlin (en MPa) :
  84. C1 = 0.183 ; C2 = 0.0034 ;
  85. *
  86. * On fixe le coefficient de Poisson XNU a une valeur proche de 0.5
  87. * du fait de l'incompressibilite inherente au modele.
  88. * Le module de Young YOU est alors connu, car, pour ce modele, le
  89. * module de cisaillement MU vaut : MU = YOU/(2*(1+XNU)) = 2.(C1+C2)
  90. * Il s'agit de la valeur initiale et de la borne inferieure dans le cas
  91. * de la traction. En fonction du niveau de deformation atteinte en
  92. * traction, il faut augmenter cette valeur afin de pouvoir faire
  93. * converger les calculs. Prendre des valeurs superieures n'entraine pas
  94. * de modification des resultats, cela modifie seulement le nombre
  95. * d'iterations mecaniques.
  96. * Par ex. : pour 1000 %, il faut multiplier par 30 la valeur initiale.
  97. * Si l'on se contente de 10., les calculs s'arretent vers 900 %.
  98. *
  99. XNU = 0.499 ;
  100. YOUini = 3.*(2.*(C1+C2)) ; YOU = 20000.* YOUini ;
  101. *
  102. *Parametres du modèle GD : essais Treloar/Kawabata MPa
  103. H1 = 0.142236 ;
  104. H2 = 1.5854659E-2 ;
  105. H3 = 3.4946541E-4 ;
  106. *
  107. MA = MATE MO 'YOUN' YOU 'NU ' XNU 'H1' H1 'H2' H2 'H3' H3 ;
  108.  
  109. *======================================================================*
  110. * Conditions aux limites - Chargement bi-axe *
  111. *======================================================================*
  112. BL1 = 'BLOQUER' 'UY ' L1 ;
  113. BL2 = 'BLOQUER' 'UY ' L3 ;
  114. BL4 = 'BLOQUER' 'UX ' L4 ;
  115. BL3 = 'BLOQUER' 'UX ' L2 ;
  116. BLTOT = BL1 'ET' BL2 'ET' BL3 'ET' BL4 ;
  117. *
  118. * Definition des instants du chargement :
  119. t_deb = 0. ; t_fin = 10. ;
  120. L_tps = 'PROG' t_deb t_fin ;
  121. * Deplacement suivant X :
  122. FF_x = 'DEPIMP' BL3 1. ;
  123. L_UX = 'PROG' 0. (5. * Lg_x) ;
  124. L_UX = 'PROG' 0. (8. * Lg_x) ;
  125. EV_x = 'EVOL' 'MANU' 'TEMPS' L_tps 'LAMX' L_UX ;
  126. CHAR_x = 'CHARGEMENT' 'DIMP' FF_x EV_x ;
  127. * Deplacement suivant Y :
  128. L_UY = 'PROG' 0. ( 2. * Lg_y) ;
  129. L_UY = 'PROG' 0. ( 6. * Lg_y) ;
  130. FF_y = 'DEPIMP' BL2 1. ;
  131. EV_y = 'EVOL' 'MANU' 'TEMPS' L_tps 'LAMY' L_UY ;
  132. CHAR_y = 'CHARGEMENT' 'DIMP' FF_y EV_y ;
  133. *
  134. CHARTOT = CHAR_x 'ET' CHAR_y ;
  135.  
  136. *======================================================================*
  137. * Initialisation de la table pour appel a PASAPAS *
  138. *======================================================================*
  139. TAB1 = 'TABLE' ;
  140. TAB1.'MODELE' = MO ;
  141. TAB1.'CARACTERISTIQUES' = MA ;
  142. TAB1.'BLOCAGES_MECANIQUES' = BLTOT ;
  143. TAB1.'CHARGEMENT' = CHARTOT ;
  144. **** LG
  145. *TAB1.'PRECISION' = 1.E-6 ;
  146. *TAB1.'FTOL' = 1.E-5 ;
  147. *TAB1.'MTOL' = 1.E-5 ;
  148. *
  149. TAB1.'CONVERGENCE_FORCEE' = FAUX ;
  150. TAB1.'GRANDS_DEPLACEMENTS' = VRAI ;
  151. TAB1.'TEMPS_CALCULES' = 'PROG' t_deb 'PAS' 0.1 t_fin ;
  152. TAB1.'TEMPS_SAUVES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  153. *
  154. L_abs = TAB1.'TEMPS_SAUVES' ;
  155. n_abs = 'DIMENSION' L_abs ;
  156. *
  157. PASAPAS TAB1 ;
  158. *
  159. * Quelques traces de controle apres calculs
  160. 'SI' GRAPH ;
  161. Defo_0 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 0. ;
  162. Defo_1 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 1. 'VERT' ;
  163. 'TRACER' (Defo_0 'ET' Defo_1)
  164. 'TITRE' ('CHAINE' title ' - DEFORMEES INITIALE ET FINALE') ;
  165. 'TRACER' MO (TAB1.'CONTRAINTES'.(n_abs-1))
  166. 'TITRE' ('CHAINE' title ' - CONTRAINTES EN FIN DE CALCUL') ;
  167. 'FINSI' ;
  168. *
  169. *======================================================================*
  170. * Construction de la solution analytique *
  171. *======================================================================*
  172. * Definitions :
  173. * - Allongement selon direction x : Lamx = 1 + (UX/Lg_x)
  174. * - Allongement selon direction y : Lamy = 1 + (UY/Lg_y)
  175. * - Densite d'energie de deformation hyperelastique : W(I1,I2)
  176. * - I1, I2 : trois invariants du tenseur de Cauchy-Green droit
  177. * Dans le cas du modele GD : Incompressible
  178. * Les contraintes de Cauchy sont calculables analytiquement :
  179. * - SCxx = 2.(Lamx**2 - (Lamx*Lamy)**-2).(dW/dI1 + Lamy**2.dW/dI2)
  180. * - SCyy = 2.(Lamy**2 - (Lamx*Lamy)**-2).(dW/dI1 + Lamx**2.dW/dI2)
  181. * - SCxy = 0 (pas de cisaillement)
  182. * - SCzz = 0 (hypothese des contraintes planes)
  183. *
  184. L_Un = 'PROG' n_abs '*' 1. ;
  185. Lamx = L_Un + (('IPOL' L_abs L_tps L_UX) / Lg_X) ;
  186. Lamy = L_Un + (('IPOL' L_abs L_tps L_UY) / Lg_Y) ;
  187. *
  188. L_z1 = Lamx * Lamx ; L_z2 = Lamy * Lamy ;
  189. L_z3 = L_z1 - ((L_z1*L_z2)**-1) ;
  190. L_z4 = L_z2 - ((L_z1*L_z2)**-1) ;
  191. *LG
  192. L_tr = L_Un * 3.;
  193. I1 = L_z1 + L_z2 + ((L_z1*L_z2)**-1);
  194. I2 =(L_z1 * L_z2) + (L_z1**-1) + (L_z2**-1);
  195. ************************************************************************
  196. dWI1= H1 * (exp (H3 *((I1 - L_tr)**2)));
  197. dWI2= 3. * H2 * L_Un / (I2**0.5);
  198. ************************************************************************
  199. SCxx_th = L_z3 * ((2.*dWI1*L_Un) + (2.*dWI2*L_z2)) ;
  200. SCyy_th = L_z4 * ((2.*dWI1*L_Un) + (2.*dWI2*L_z1)) ;
  201. SCxy_th = 0. * L_Un ;
  202.  
  203. *======================================================================*
  204. * Comparaison des resultats avec la solution analytique *
  205. *======================================================================*
  206. * La comparaison s'effectue entre les valeurs moyennes des contraintes
  207. * calculees et les solutions analytiques correspondantes.
  208. * On ne cherche pas a verifier l'uniformite du champ de contraintes.
  209. * (Faire le calcul en mettant GRAPH a VRAI et voir les isovaleurs !)
  210. *
  211. TabD = TAB1.'DEPLACEMENTS' ;
  212. TabS = TAB1.'CONTRAINTES' ;
  213. Confini = 'FORM' ;
  214. ChmUn = 'MANU' 'CHML' MO 'SCAL' 1. ;
  215. *
  216. SCxx = 'PROG' 0. ;
  217. SCyy = 'PROG' 0. ;
  218. SCxy = 'PROG' 0. ;
  219. 'REPETER' Boucle (n_abs - 1) ;
  220. 'FORM' (TabD.&Boucle) ;
  221. VolSU = 'INTG' MO ChmUn ;
  222. SCxx = SCxx 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXX')/VolSU)) ;
  223. SCyy = SCyy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYY')/VolSU)) ;
  224. SCxy = SCxy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXY')/VolSU)) ;
  225. 'FORM' Confini ;
  226. 'FIN' Boucle ;
  227. *
  228. * LG lamb
  229. L_abs = Lamy;
  230. *
  231. 'SI' GRAPH ;
  232. tlege = 'TABLE' ;
  233. tlege. 1 = 'MARQ CROI' ;
  234. tlege.'TITRE' = 'TABLE' ;
  235. tlege.'TITRE'. 1 = 'Numerique' ;
  236. tlege.'TITRE'. 2 = 'Analytique' ;
  237. Evxx = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXX' SCxx ;
  238. Evxx_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXX' SCxx_th ;
  239. 'DESSIN' (Evxx 'ET' Evxx_th) 'LEGE' tlege
  240. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XX (MPa)') ;
  241. Evyy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYY' SCyy ;
  242. Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYY' SCyy_th ;
  243. 'DESSIN' (Evyy 'ET' Evyy_th) 'LEGE' tlege
  244. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY YY (MPa)') ;
  245. Evxy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXY' SCxy ;
  246. Evxy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXY' SCxy_th ;
  247. 'DESSIN' (Evxy 'ET' Evxy_th) 'LEGE' tlege
  248. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (MPa)');
  249. 'FINSI' ;
  250. *
  251. * Tests de bon fonctionnement :
  252. r_xx = 'MAXIMUM' ('ABS' (SCxx - SCxx_th)) ;
  253. r_yy = 'MAXIMUM' ('ABS' (SCyy - SCyy_th)) ;
  254. r_xy = 'MAXIMUM' ('ABS' (SCxy - SCxy_th)) ;
  255. *
  256. MESS ' RESULTATS : ' title ;
  257. MESS ' ------------------------------------------------ ';
  258. 'SAUTER' 1 'LIGNE' ;
  259. 'MESS' ' Tests de bon fonctionnement :' ;
  260. 'MESS' ' -------------------------------' ;
  261. 'MESS' ' Comparaison effectuee sur les contraintes de Cauchy' ;
  262. 'MESS' ' Ecart maximal en valeur absolue entre la valeur moyenne '
  263. 'calculee' ;
  264. 'MESS' ' et la '
  265. 'solution analytique associee' ;
  266. 'MESS' ' Composante XX : ' r_xx ' MPa' ;
  267. 'MESS' ' Composante YY : ' r_yy ' MPa' ;
  268. 'MESS' ' Composante XY : ' r_xy ' MPa' ;
  269. 'SAUTER' 1 'LIGNE' ;
  270. * Ecart maximal tolere sur la contrainte (en MPa)
  271. Sigref = 1.E-3 ;
  272. 'SI' ('>EG' ('MAXIMUM' ('PROG' r_xx r_yy r_xy)) Sigref) ;
  273. 'MESS' ' ---------------------' ;
  274. 'MESS' ' ECHEC DU CAS-TEST !' ;
  275. 'MESS' ' ---------------------' ;
  276. 'ERREUR' 5 ;
  277. 'SINON' ;
  278. 'MESS' ' ----------------------' ;
  279. 'MESS' ' SUCCES DU CAS-TEST !' ;
  280. 'MESS' ' ----------------------' ;
  281. 'FINSI' ;
  282. 'SAUTER' 1 'LIGNE' ;
  283. 'FIN' ;
  284.  
  285.  
  286.  
  287.  
  288.  
  289.  
  290.  
  291.  
  292.  
  293.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales