Télécharger gatt_dpg.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : gatt_dpg.dgibi
  2. *
  3. * Test gatt_dpg.dgibi: Jeux de données
  4. * ---------------------------------------
  5. *
  6. 'OPTI' 'DIME' 2 'MODE' 'PLAN' 'GENE' ;
  7. 'OPTI' 'ELEM' 'QUA8' ;
  8. 'OPTI' 'TRAC' 'PSC' ;
  9. 'TEMPS' 'ZERO' ;
  10. L = 'MOT' LIST ; F = 'MOT' FIN ;
  11. *
  12. ***********************************************************
  13. * TEST DE VALIDATION *
  14. * ------------------ *
  15. * MODELE GATT_MONERIE *
  16. * AFA3GLAA INCOMPRESSIBLE AVEC COUPLAGE DYNAMIQUE *
  17. * *
  18. * MAILLAGE: *
  19. * EPROUVETTE CARRE *
  20. * *
  21. * CHARGEMENT: *
  22. * CONTRAINTE DE COMPRESSION IMPOSEE (ESSAI DE FLUAGE) *
  23. * TEMPERATURE CONSTANTE *
  24. * DENSITE DE FISSIONS CONSTANTE *
  25. * PRIMAIRE - MECANISMES 1 ET 2 - IRRADIATION *
  26. * DENSIFICATION - GONFLEMENT *
  27. ***********************************************************
  28. *
  29. GRAPH = FAUX ;
  30. LISTCOUR = VRAI ;
  31. *
  32. NE = 1 ;
  33. H = 1. ;
  34. *
  35. OO = 0. 0. ;
  36. A1 = H 0. ;
  37. A2 = H H ;
  38. A3 = 0. H ;
  39. *
  40. LB = 'DROIT' NE OO A1 ;
  41. LD = 'DROIT' NE A1 A2 ;
  42. LH = 'DROIT' NE A2 A3 ;
  43. LG = 'DROIT' NE A3 OO ;
  44. *
  45. SU1 = 'DALL' LB LD LH LG 'PLAN' ;
  46. *
  47. MODL1= MODE SU1 MECANIQUE ELASTIQUE
  48. VISCOPLASTIQUE GATT_MONERIE 'DPGE' OO ;
  49. *
  50. * ----------------------*
  51. * Materiau GATT_MONERIE *
  52. * ----------------------*
  53. TE1 = 1300. + 273. ;
  54. PO = 4.9E-2 ;
  55. DF1 = 1.E18 ;
  56. *
  57. TA = @GATTPAR '/u2/castem/divers/fichier_gatt' ;
  58. *
  59. TA.'BP' = 0. ;
  60. TA.'POR0' = PO ;
  61. TA.'CR' = 0.16E-2 ;
  62. *
  63. MATREE = MATE MODL1 'YOUN' (TA.'YOUN') ;
  64. PP = 'MANU' 'CHML' MODL1 'T' TE1 'PORO' PO RIGIDITE ;
  65. EE = 'VARI' 'NUAG' MODL1 MATREE PP ;
  66. *
  67. MATR11 = 'MATE' MODL1 'YOUN' EE 'NU' 0. 'RHO' 10950. 'ALPH' 0. ;
  68. *
  69. MATR12 = 'MATE' MODL1
  70. 'R' (TA.'R') 'DG0' (TA.'DG0') 'DG' (TA.'DGCR')
  71. 'K1' (TA.'K1') 'M1' (TA.'M1') 'Q1' (TA.'Q1') 'N1' (TA.'N1')
  72. 'K2' (TA.'K2') 'M2' (TA.'M2') 'Q2' (TA.'Q2') 'N2' (TA.'N2')
  73. 'OMEG' (TA.'OMEG') 'H' (TA.'H') 'Q' (TA.'Q') 'BETA' (TA.'BETA')
  74. 'K' (TA.'K') 'A' (TA.'A') 'Q3' (TA.'Q3') 'N3' (TA.'N3')
  75. 'CR' (TA.'CR') 'CR1' (TA.'CR1') 'CR2' (TA.'CR2') 'CR3' (TA.'CR3');
  76. *
  77. MATR13 = 'MATE' MODL1
  78. 'KP' (TA.'KPAF') 'AP' (TA.'AP') 'BP' (TA.'BP') 'QP' (TA.'QP') ;
  79. *
  80. MATR14 = 'MATE' MODL1
  81. 'ADEN' TA.'ADEN' 'KGON' TA.'KGON'.
  82. 'POR0' (TA.'POR0') 'BUMI' (TA.'BUMI') 'EFIS' (TA.'EFIS') ;
  83. *
  84. * TYPE = 0. combustible UO2 sinon combustible AFA3GLAA
  85. * COMP = 0. combustible incompressible sinon compressible
  86. * DYN = 0. couplage dynamique sinon statique
  87. *
  88. MATR15 = 'MATE' MODL1 'TYPE' 1. 'COMP' 1. 'DYN' 1. ;
  89. *
  90. MATR16 = 'MATE' MODL1
  91. 'DYN1' (TA.'DYN1') 'DYN2' (TA.'DYN2') 'DYN3' (TA.'DYN3') ;
  92. *
  93. MATR1 = MATR11 'ET' MATR12 'ET' MATR13 'ET' MATR14 'ET'
  94. MATR15 'ET' MATR16 ;
  95. *
  96. * -----------------------*
  97. * Conditions aux limites *
  98. * -----------------------*
  99. CLYB = 'BLOQ' 'UY' LB ;
  100. CLXG = 'BLOQ' 'UX' LG ;
  101. CLT = CLYB 'ET' CLXG ;
  102. *
  103. TMIL = 1.E6 ;
  104. TFIN = 2.E6 ;
  105. *
  106. RHO0 = 1. - TA.'POR0' ;
  107. AKBU = TA.'EFIS'*270./238./10950./RHO0*DF1 ;
  108. * CE QUI SUIT EST VRAI CAR LE FLUX DE FISSIONS EST CONSTANT
  109. TBU = (TA.'BUMI' / AKBU) - 1. ;
  110. TTBU = ('ENTI' (TBU/10000.)) * 10000. ;
  111. *-------------------*
  112. * Instants calcules *
  113. *-------------------*
  114. 'SI' LISTCOUR ;
  115. *--------------
  116. LIST1 = 'PROG' 0 'PAS' 0.1 1 'PAS' 1 10 'PAS' 10 100 'PAS' 100 1000
  117. 'PAS' 500 15000 ;
  118. 'SINON' ;
  119. *--------
  120. LIST1 = 'PROG' 0 'PAS' 0.1 1 'PAS' 1 10 'PAS' 10 100 'PAS' 100 1000
  121. 'PAS' 500 30000 ;
  122. 'FINSI' ;
  123. *--------
  124. * ------------------------------*
  125. * Chargement cte en temperature *
  126. * ------------------------------*
  127. CHTEMP = 'MANU' 'CHPO' SU1 1 'T' 1. ;
  128. EVT = 'EVOL' 'MANU' ('PROG' 0. (2.*TFIN))
  129. ('PROG' TE1 TE1) ;
  130. CHARTEMP = 'CHAR' 'T' CHTEMP EVT ;
  131. * -------------------------------------*
  132. * Chargement cte en densite de fission *
  133. * -------------------------------------*
  134. CHFISS = 'MANU' 'CHPO' SU1 1 'DFIS' 1. ;
  135. EVF = 'EVOL' 'MANU' ('PROG' 0. (2.*TFIN))
  136. ('PROG' DF1 DF1) ;
  137. CHARFISS = 'CHAR' 'DFIS' CHFISS EVF ;
  138. * -----------------------*
  139. * Chargement en pression *
  140. * -----------------------*
  141. valpres = 60E6 ;
  142. compr = 'PRES' 'MASS' MODL1 valpres LH ;
  143. EVP = 'EVOL' 'MANU' ('PROG' 0. 1. (2.*TFIN))
  144. ('PROG' 0. 1. 1.) ;
  145. CHARMECA = 'CHAR' 'MECA' compr EVP ;
  146. *
  147. CHARTOT = CHARMECA 'ET' CHARTEMP 'ET' CHARFISS ;
  148. * ---------------------------------------*
  149. * Variables internes initiales 'PORO'=PO *
  150. * ---------------------------------------*
  151. VAR00 = 'ZERO' MODL1 'VARINTER' ;
  152. VAR01 = 'MANU' 'CHML' MODL1 'PORO' PO
  153. 'TYPE' 'VARIABLES INTERNES' 'STRESSES' ;
  154. VAR0 = VAR00 + VAR01 ;
  155. *
  156. *
  157. TAB1 = TABLE ;
  158. TAB1.'TEMPERATURES' = TABLE ;
  159. TAB1.'VARIABLES_INTERNES'= TABLE ;
  160. TAB1.'BLOCAGES_MECANIQUES' = CLT ;
  161. TAB1.'MODELE' = MODL1 ;
  162. TAB1.'CHARGEMENT' = CHARTOT ;
  163. TAB1.'TEMPERATURES' . 0 = CHTEMP ;
  164. TAB1.'VARIABLES_INTERNES' . 0 = VAR0 ;
  165. TAB1.'CARACTERISTIQUES' = MATR1 ;
  166. TAB1.'TEMPS_CALCULES' = LIST1 ;
  167. TAB1.'TEMPS_SAUVES' = LIST1 ;
  168. *
  169. TMASAU = TABLE ;
  170. tab1 . 'MES_SAUVEGARDES' = TMASAU ;
  171. TMASAU .'DEFTO' = VRAI ;
  172. TMASAU .'DEFIN' = VRAI ;
  173. *
  174. PASAPAS TAB1 ;
  175. *
  176. *
  177. *
  178. *****************************************
  179. * CONTROLE DES RESULTATS *
  180. *****************************************
  181. *
  182. *
  183. AP = TA.'AP' ;
  184. BP = TA.'BP' ;
  185. N1 = TA.'N1' ;
  186. N2 = TA.'N2' ;
  187. DG = TA.'DGCR' ;
  188. *
  189. * Facteurs multiplicatifs dus au dopage par le Chrome
  190. WC1 = 'TANH' ( (TA.'CR' - TA.'CR2') / TA.'CR3' ) ;
  191. WC1 = 1. + ( 0.5 * TA.'CR1' * (1. + WC1) ) ;
  192. CV = 180. / PI ;
  193. WC2 = 1. - ( 'COS' (CV * DG / TA.'DG0') ) ;
  194. WC2 = 2. * (TA.'DG0'**TA.'M2') * WC2 ;
  195. *
  196. * Calcul de TO pour la fonction de couplage dynamique
  197. TO = 'TANH' ( (TA.'DYN2' - TE1) / TA.'DYN3' ) ;
  198. TO = TA.'DYN1' * (1. + TO) ;
  199. TO = TO + 1. ;
  200. *
  201. BUMI = TA.'BUMI' ;
  202. AKEVD = AKBU*TA.'KGON' ;
  203. ADEN = TA.'ADEN' ;
  204. KGON = TA.'KGON' ;
  205. * -------------------------------------------------------------------*
  206. * Calcul de la cte AAAA intervenant ds le calcul de la def. de dens. *
  207. * -------------------------------------------------------------------*
  208. BUMAX0=60.D0*BUMI ;
  209. CRIT=1.D-10 ;
  210. 'REPE' BLOC 100 ;
  211. BUMAX = BUMI* ('EXP' (1. - (ADEN/(KGON*BUMAX0)))) ;
  212. BUMAX = (0.2*BUMAX) + (0.8*BUMAX0) ;
  213. TEST='ABS' ((BUMAX-BUMAX0)/BUMAX0) ;
  214. 'SI' ('<' TEST CRIT) ;
  215. 'QUIT' BLOC ;
  216. 'FINS' ;
  217. BUMAX0=BUMAX ;
  218. 'FIN' BLOC ;
  219. AAAA = (-1.D0*RHO0*(ADEN-(KGON*BUMAX))) /
  220. ((1.D0+ADEN)*(LOG(BUMAX/BUMI))) ;
  221. *
  222. * -----------------------*
  223. * Controle des resultats *
  224. * -----------------------*
  225. SS = TAB1 . 'CONTRAINTES' ;
  226. VV = TAB1 . 'VARIABLES_INTERNES' ;
  227. IN = TAB1 . 'DEFORMATIONS_INELASTIQUES' ;
  228. NCONT = ('DIME' (TAB1 . 'CONTRAINTES')) - 1 ;
  229. *
  230. ERMAX1 = 0. ;
  231. ERMAX2 = 0. ;
  232. *
  233. Lzeit = 'PROG' ;
  234. Lteta = 'PROG' ;
  235. Lteta_c = 'PROG' ;
  236. Lepsv = 'PROG' ;
  237. Lepsv_c = 'PROG' ;
  238. *
  239. ind0 = 9 ;
  240. zeit0 = 1. ;
  241. *
  242. epsv0 = 'MAXI' ('EXCO' IN.(ind0 + 1) 'EIYY') ;
  243. *
  244. 'REPE' BLOC (NCONT - ind0) ;
  245. *
  246. ind = ind0 + &BLOC ;
  247. *
  248. * ----------------------------------------------------
  249. * SMYY = valpres ET LES AUTRES COMPOSANTES SONT NULLES
  250. * ----------------------------------------------------
  251. SMYY = -1. * valpres ;
  252. SSM = SMYY / 3. ;
  253. SSEQ = 'ABS' SMYY ;
  254. * Deviateur des contraintes
  255. SSPRIM2 = SMYY - SSM ;
  256. * Contrainte YY calculee
  257. sy_c = 'MAXI' ('EXCO' SS.ind 'SMYY') ;
  258. * --------------------------------------------------------------
  259. * VITESSE DE DEFORMATION VISCO-PLASTIQUE EVP D"ORIGINE THERMIQUE
  260. * --------------------------------------------------------------
  261. *-- fluage primaire
  262. *
  263. EVP02 = -1.5 * TA.'KPAF' *
  264. ('EXP' (-1.*TA.'QP'/(TA.'R'*TE1))) * (SSEQ**AP) ;
  265. *
  266. *-- fluage secondaire (2 mecanismes)
  267. *
  268. * on teste la porosite :
  269. PP = 'MAXI' ('EXCO' VV . &BLOC 'PORO') ;
  270. ECART1 = 'ABS' ((PP - PO) / PO) ;
  271. ERMAX1 = 'MAXI' ('PROG' ECART1 ERMAX1) ;
  272. *
  273. A1 = (N1* (PP**(-1./N1) - 1.)**(-2.*N1/(N1+1.))) ;
  274. B1 = (1. + (2.*PP/3.))/ ((1. - PP) **(2.*N1/(N1+1.))) ;
  275. B1 = B1 + (A1/4.) ;
  276. A1 = 0. ;
  277. *
  278. A2 = (N2* (PP**(-1./N2) - 1.)**(-2.*N2/(N2+1.))) ;
  279. B2 = (1. + (2.*PP/3.))/ ((1. - PP) **(2.*N2/(N2+1.))) ;
  280. B2 = B2 + (A2/4.) ;
  281. A2 = 0. ;
  282. *
  283. EVP12 = 0.5 * (TA.'K1' * (DG**TA.'M1') * WC1 *
  284. ('EXP' (-1.*TA.'Q1'/(TA.'R'*TE1))) *
  285. (((A1*((1.5*SSM)**2)) + (B1*(SSEQ ** 2)))**((N1-1.)/2.)) *
  286. ((A1*1.5*SSM) + (3.*B1*SSPRIM2))) ;
  287. *
  288. EVP22 = 0.5 * (TA.'K2' * WC2 * ('EXP' (-1.*TA.'Q2'/(TA.'R'*TE1))) *
  289. (((A2*((1.5*SSM)**2)) + (B2*(SSEQ ** 2)))**((N2-1.)/2.)) *
  290. ((A2*1.5*SSM) + (3.*B2*SSPRIM2))) ;
  291. * -----------------------------
  292. * FONCTION DE COUPLAGE STATIQUE
  293. * -----------------------------
  294. TETA0 = 0.5 * TA.'BETA' *
  295. (1. +
  296. ('TANH' ((TE1 - (TA.'OMEG' * (SSEQ**(-1.*TA.'Q')))) / TA.'H'))) ;
  297. * ------------------------------
  298. * FONCTION DE COUPLAGE DYNAMIQUE
  299. * ------------------------------
  300. zeit = TAB1.'TEMPS'.ind ;
  301. duree = zeit - zeit0 ;
  302. TETA = ( 1. + (zeit/TO) ) ** -1 ;
  303. TETA = TETA0 * (1. - TETA) ;
  304. * Fonction de couplage dynamique calculee
  305. teta_c = 'MAXI' ('EXCO' VV.ind 'TETA') ;
  306. * ----------------------------------
  307. * VITESSE DE DEFORMATION IRRADIATION
  308. * ----------------------------------
  309. EVIR2 = 1.5 * TA.'A' * DF1 * (SSEQ **(TA.'N3' - 1.)) *
  310. ('EXP' (-1.*TA.'Q3'/(TA.'R'*TE1))) * SSPRIM2 ;
  311. * ------------------------------------
  312. * DEFORMATION VISCO-PLASTIQUE SELON YY
  313. * ------------------------------------
  314. KFI = 1.+(TA.'K'*DF1) ;
  315. EPSVa = EVIR2 + ( KFI * (EVP02+EVP12) ) ;
  316. EPSVb = KFI * (EVP22 - EVP12) ;
  317. INTGTETA = 'LOG' ( 1. + (duree/TO) ) ;
  318. INTGTETA = TO * INTGTETA ;
  319. INTGTETA = TETA0 * (duree - INTGTETA) ;
  320. epsv = (EPSVa * duree) + (EPSVb * INTGTETA) ;
  321. epsv = epsv0 + epsv ;
  322. * Deformation viscoplastique calculee
  323. epsv_c = 'MAXI' ('EXCO' IN.ind 'EIYY') ;
  324. * On teste la deformation viscoplastique :
  325. ECART2 = 'ABS' ((epsv_c - epsv) / epsv) ;
  326. ERMAX2 = 'MAXI' ('PROG' ECART2 ERMAX2) ;
  327. *
  328. Lzeit = Lzeit 'ET' ('PROG' zeit) ;
  329. Lteta = Lteta 'ET' ('PROG' TETA) ;
  330. Lteta_c = Lteta_c 'ET' ('PROG' teta_c) ;
  331. Lepsv = Lepsv 'ET' ('PROG' epsv) ;
  332. Lepsv_c = Lepsv_c 'ET' ('PROG' epsv_c) ;
  333. *
  334. 'FIN' BLOC ;
  335. *
  336. 'SI' (ERMAX1 '&lt;EG' 1E-5) ;
  337. 'ERRE' 0 ;
  338. 'SINO' ;
  339. 'MESS' 'POROSITE NON CONSTANTE' ;
  340. 'MESS' 'ERREUR MAXIMALE POROSITE :'
  341. ERMAX1 '> 1E-5 ' ;
  342. 'ERRE' 5 ;
  343. 'FINS' ;
  344. *
  345. 'SI' ( ERMAX2 '&lt;EG' 0.05) ;
  346. 'ERRE' 0 ;
  347. 'SINO' ;
  348. 'MESS' 'ERREUR MAXIMALE DEFORMATION VISCOPLASTIQUE :'
  349. ERMAX2 '> 0.05 ' ;
  350. 'ERRE' 5 ;
  351. 'FINS' ;
  352. *
  353. *
  354. 'SI' GRAPH ;
  355. 'TITR' 'Deformations planes general. : Fonction de couplage dynamique';
  356. EVTETA = 'EVOL' 'MANU' 'Temps' Lzeit 'TETA' Lteta ;
  357. EVTETA_C = 'EVOL' 'MANU' 'Temps' Lzeit 'TETA' Lteta_c ;
  358. TAD = TABLE ;
  359. TAD . 1 = 'TIRC' ;
  360. TAD . 2 = 'TIRR' ;
  361. TAD . 'TITRE' = TABLE ;
  362. TAD . 'TITRE' . 1 = 'TETA THEORIQUE' ;
  363. TAD . 'TITRE' . 2 = 'TETA CALCULEE' ;
  364. 'DESS' (EVTETA 'ET' EVTETA_C) TAD 'LEGE' ;
  365. *
  366. 'TITR' 'Deformations planes general. : Deformation viscoplastique' ;
  367. EVEPSV = 'EVOL' 'MANU' 'Temps' Lzeit 'EPSV' Lepsv ;
  368. EVEPSV_C = 'EVOL' 'MANU' 'Temps' Lzeit 'EPSV' Lepsv_c ;
  369. TAD = TABLE ;
  370. TAD . 1 = 'TIRC' ;
  371. TAD . 2 = 'TIRR' ;
  372. TAD . 'TITRE' = TABLE ;
  373. TAD . 'TITRE' . 1 = 'EPSV THEORIQUE' ;
  374. TAD . 'TITRE' . 2 = 'EPSV CALCULEE' ;
  375. 'DESS' (EVEPSV 'ET' EVEPSV_C) TAD 'LEGE' ;
  376. 'FINS' ;
  377. *
  378. 'FIN';
  379.  
  380.  
  381.  
  382.  
  383.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales