Télécharger flam1.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : flam1.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Test Flam1.dgibi: Jeux de données *
  5. * --------------------------------- *
  6. * *
  7.  
  8. *******************************************************
  9. * TEST FLAM1
  10. *
  11. * FLAMBAGE EULERIEN D'UNE POUTRE
  12. * ENCASTREE A UNE EXTREMITE
  13. *
  14. * Dans cet exemple on se propose d'étudier le flambage
  15. * d'une poutre encastrée à une de ses extrémités et
  16. * soumise à une force parallele à la poutre et
  17. * appliquée à l'extrémité libre de la poutre.
  18. *
  19. * Le flambage est visualisé en fin de calcul et le
  20. * multiplicateur de chargement calculé est comparé à
  21. * celui obtenu par la théorie (41.123).
  22. *******************************************************
  23.  
  24. GRAPH = 'N';
  25.  
  26. SAUT PAGE;
  27. SI (NEG GRAPH 'N') ;
  28. OPTI ECHO 1 ;
  29. OPTI TRAC PSC ;
  30. SINO ;
  31. OPTI ECHO 0 ;
  32. FINSI ;
  33.  
  34. SAUT PAGE;
  35.  
  36. TITRE ' FLAMBAGE D UNE POUTRE ENCASTREE ' ;
  37. OPTI DIME 2 ELEM SEG2 MODE PLAN CONT ;
  38. OPTI EPSI LINEAIRE;
  39.  
  40.  
  41. TEMPS ;
  42. *
  43. *------------- DEFINITION DU MAILLAGE -----------------
  44. *
  45. DENSITE 1. ;
  46. P1 = 50. 0. ;
  47. P2 = 50. 10. ;
  48. L1 = P1 D P2 ;
  49. *
  50. SI (NEG GRAPH 'N');
  51. TRAC 'QUAL' L1 ;
  52. FINSI;
  53. *
  54. *--------- CREATION DU MODELE ET DE MMODEL ------------
  55. *
  56. MOD1 = MODE L1 MECANIQUE ELASTIQUE COQ2;
  57.  
  58. *
  59. * -------- DEFINITION DES CARACTERISTIQUES ------------
  60. * ----------- MATERIELLES ET GEOMETRIQUES ------------
  61. *
  62. MAT1 = MATE MOD1 YOUN 20000. NU 0.3 ;
  63. CAR1 = CARA MOD1 EPAI 1. ;
  64. MAT1=MAT1 ET CAR1;
  65. *
  66. *--------- CALCUL DES RIGIDITES ELEMENTAIRES ----------
  67. *----------- ET DEFINITIONS DES BLOCAGES --------------
  68. *
  69. RIG1 = RIGI MOD1 MAT1 ;
  70. BL1 = BLOQUE DEPL ROTA P1 ;
  71. RIG11 = RIG1 ET BL1;
  72. *
  73. *------------- DEFINITION DU CHARGEMENT ---------------
  74. *
  75. FE1 = FORC ( 0 -1. ) P2 ;
  76. *
  77. *------- RESOLUTION ET CALCUL DES CONTRAINTES ---------
  78. *
  79. DEP1 = RESO RIG11 FE1 ;
  80. SIG1 = SIGM 'LINE' MOD1 MAT1 DEP1 ;
  81. *
  82. *--- CALCUL DE LA MATRICE DES CONTRAINTES INITIALES ---
  83. *
  84. KSI1 = KSIGMA MOD1 SIG1 CAR1 'FLAM' ;
  85. *
  86. *----------- INITIALISATION DE LA TABLE ---------------
  87. *--------- EN ENTREE DE LA PROCEDURE FLAMBAGE ---------
  88. *
  89. ETAB = TABLE ;
  90. ETAB.'CLIM' = BL1 ;
  91. ETAB.'SIG1' = SIG1;
  92. ETAB.'MATE' = MAT1;
  93. ETAB.'LAM1' = 0.001 ;
  94. ETAB.'LAM2' = 100. ;
  95. ETAB.'NMOD' = 1 ;
  96. ETAB.'OBJM' = MOD1;
  97. *
  98. *--------- APPEL A LA PROCEDURE DE FLAMBAGE -----------
  99. *
  100. SAUT PAGE ;
  101. STAB = FLAMBAGE ETAB ;
  102. *
  103. *------------ RECUPERATION DES RESULTATS --------------
  104. *
  105. LA1 = STAB . 1 . LAMB ;
  106. SAUT PAGE ;
  107. *
  108. *------------ DESSIN DU MODE DE FLAMBAGE --------------
  109. *
  110. MM1 = STAB . 1 . DEPL ;
  111. DE = DEFO MM1 L1 1. VERT ;
  112. DA = DEFO MM1 L1 0. NOIR ;
  113.  
  114. SI (NEG GRAPH 'N');
  115. TRAC ( DE ET DA ) ;
  116. FINSI;
  117.  
  118. LREF = 41.123;
  119. ERR=100*(ABS(LREF - LA1)/LREF);
  120. *
  121. MESS ' ' ;
  122. MESS ' ' ;
  123. MESS ' MULTIPLICATEUR DU CHARGEMENT ' ;
  124. MESS ' ' ;
  125. MESS ' SOLUTION ANALYTIQUE : ' LREF;
  126. MESS ' SOLUTION CALCULEE : ' LA1 ;
  127. MESS ' SOIT UN ECART DE : ' ERR '%' ;
  128.  
  129. TEMPS ;
  130.  
  131. *------------ CODE DE BON FONCTIONNEMENT --------------
  132. SI (ERR < 1e-3);
  133. ERRE 0;
  134. SINON;
  135. ERRE 5;
  136. FINSI;
  137.  
  138. FIN;
  139.  
  140.  
  141.  
  142.  
  143.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales