Télécharger elas19.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : elas19.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * CAS TEST DU 93/11/4
  5. SAUT PAGE;
  6. OPTI TRAC BENS;
  7. ************************************************************
  8. *
  9. * TEST ELAS19
  10. *
  11. * modelisation de la section rectangulaire d'une poutre
  12. * soumise a 2 moments de flexion mfx et mfy et a un effort
  13. * normal
  14. * le calcul est effectue en deformation plane generalisee
  15. * on recherche la contrainte en un point p8 de la section
  16. * on compare ensuite au resultat theorique
  17. *
  18. ************************************************************
  19. *
  20. OPTI ECHO 1;
  21. *
  22. OPTI DIME 2 ELEM QUA8 MODE PLAN DEFO ;
  23. opti epsilon lineaire;
  24. *
  25. GRAPH = 'N';
  26. *
  27. *===========================================================
  28. * geometrie : maillage
  29. *===========================================================
  30. *
  31. * dimension en metres
  32. *
  33. * points
  34. *
  35. P1 = 1. -2.;
  36. P2 = 1. 2.;
  37. P3 = -1. 2.;
  38. P4 = -1. -2.;
  39. *
  40. * droite et lignes
  41. *
  42. * coefficient de finesse du maillage
  43. *
  44. N = 6;
  45. M = 4;
  46. *
  47. D1 = P1 D N P2 ;
  48. D2 = P2 D M P3 ;
  49. D3 = P3 D N P4 ;
  50. D4 = P4 D M P1 ;
  51. *
  52. * maillage
  53. *
  54. SURF1 = DALL D1 D2 D3 D4;
  55. *
  56. SI (NEG GRAPH 'N');
  57. TITR 'PLANGENE1 : MAILLAGE';
  58. TRAC QUAL SURF1;
  59. FINSI;
  60. *
  61. * on definit le point support de la deformation
  62. * plane generalisee
  63. *
  64. PG = 0. 0.;
  65. OPTI MODE PLAN GENE ;
  66. *
  67. ELSURF1 = NBEL SURF1;
  68. NOSURF1 = NBNO SURF1;
  69. *
  70. *
  71. *===========================================================
  72. * modele - materiau
  73. * rigidite
  74. *===========================================================
  75. *
  76. MO = MODE SURF1 MECANIQUE ELASTIQUE QUA8 DPGE PG;
  77. MA = MATE MO YOUN 2E11 NU 0.3;
  78. RI1 = RIGI MO MA;
  79. *
  80. *===========================================================
  81. * bloquages - conditions aux limites
  82. *===========================================================
  83. *
  84. P5 = SURF1 POINT PROC (0. 2.);
  85. P6 = SURF1 POINT PROC (0. 0.);
  86. B1 = BLOQ DEPL P6;
  87. B2 = BLOQ UX P5;
  88. RI = RI1 ET B1 ET B2;
  89. *
  90. *===========================================================
  91. * forces
  92. *===========================================================
  93. *
  94. F1 = FORC FZ 1E10 PG;
  95. F2 = MOME MX 1E9 PG;
  96. F3 = MOME MY 1E8 PG;
  97. F = F1 ET F2 ET F3;
  98. *
  99. *===========================================================
  100. * resolution : champs de deplacement
  101. *===========================================================
  102. *
  103. DEP1 = RESO RI F;
  104. *
  105. *===========================================================
  106. * extraction d'une contrainte
  107. * et comparaison avec solution analytique
  108. *===========================================================
  109. *
  110. * calcul du champs de contraintes totales
  111. *
  112. SIG1 = SIGM MO MA DEP1;
  113. *
  114. SI (NEG GRAPH 'N');
  115. SZZ1 = EXCO SMZZ SIG1;
  116. TITR 'PLANGENE1 : CONTRAINTES NORMALES';
  117. TRAC QUAL SZZ1 MO SURF1;
  118. FINSI;
  119. *
  120. CHAM1 = CHAN NOEUD MO SIG1;
  121. CHPO1 = CHAN CHPO MO CHAM1;
  122. *
  123. * extraction d'une contrainte au point P8
  124. * et comparaison avec la solution analytique
  125. *
  126. P8 = SURF1 POINT PROC (.5 .5);
  127. *
  128. SMZZC = EXTR CHPO1 SMZZ P8;
  129. *
  130. * calcul de la contrainte theorique
  131. *
  132. X2 = COOR 1 P8;
  133. X3 = COOR 2 P8;
  134. FNORM = 1E10;
  135. MFX = 1E9;
  136. MFY = 1E8;
  137. SMZZT =(FNORM/8)-(X2*MFY/2.6666666666666) +(X3*MFX/10.6666666666666);
  138. *
  139. * calcul de l'ecart avec la solution de reference
  140. *
  141. ERGZZC = 100*(ABS((SMZZT-SMZZC)/SMZZT));
  142. *
  143. *==========================================================
  144. * affichage des resultats
  145. *==========================================================
  146. *
  147. MESS ' RESULTATS : TEST PLANGENE ';
  148. MESS '---------------------------';
  149. *
  150. MESS 'on cherche la contrainte en un point du maillage';
  151. MESS 'elle est comparee a une valeur obtenue analytiquement en ce même point';
  152. MESS ' Contrainte normale theorique :' SMZZT 'MPa';
  153. MESS ' Contrainte normale calculee :' SMZZC 'MPa';
  154. MESS ' Soit un ecart de :' ERGZZC '%';
  155. *
  156. MESS ' Nombre d elements :' ELSURF1;
  157. MESS ' Nombre de noeuds :' NOSURF1;
  158. MESS ' soit ' (NOSURF1 * 3) 'd.d.l.';
  159. *==================================================================*
  160. *
  161. *==================================================================
  162. * code fonctionnement
  163. *==================================================================
  164. *
  165. * L'ecart maximum entre valeur theorique et calculee doit etre
  166. * inferieure a 0.0005%.
  167. *
  168. SI (ERGZZC <EG 0.0005);
  169. ERRE 0;
  170. SINON;
  171. ERRE 5;
  172. FINSI;
  173. *
  174. *==================================================================
  175. * Temps de calcul et fin
  176. *==================================================================
  177. *
  178. TEMPS;
  179. *
  180. FIN;
  181. *
  182.  
  183.  
  184.  
  185.  
  186.  
  187.  
  188.  
  189.  
  190.  
  191.  
  192.  
  193.  
  194.  
  195.  
  196.  
  197.  
  198.  
  199.  
  200.  
  201.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales