Télécharger la plaquette Cast3M


fr en

Télécharger dy_devo1.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : dy_devo1.dgibi
  2. *
  3.  
  4. *********************************************************************
  5. *                                                                   *
  6. *      VALIDATION DE LA LIAISON COUPLAGE_DEPLACEMENT base A         *
  7. *      OPTION FONCTION_CONVOLUTION DE L'OPERATEUR DYNE              *
  8. *      modele GRANGER PAIDOUSSIS                                    *
  9. *      (UTILISEE POUR LE CALCUL DES FORCES FLUIDELASTIQUES)         *
  10. *      EXEMPLE INSPIRE DU TEST38 de GERBOISE                        *
  11. *                                                                   *
  12. *      CREATION : BP, 2017-01-05                                    *
  13. *                                                                   *
  14. *      MANIP TGV-ICE (CEA,DEN,DM2S,SEMT,DYN)                        *
  15. *                                                                   *
  16. *        Y                                                          *
  17. *       /|\                                                         *
  18. *        |                                                          *
  19. *                                                                   *
  20. *        P1   P2 P3                      P4 P5 P6                   *
  21. *                __________________________                         *
  22. *        |------||                         |||                      *
  23. *        |      ||                         |||    ------>X          *
  24. *        |------||_________________________|||                      *
  25. *          LAME          TUBE            RONDELLE 2                 *
  26. *              RONDELLE 1                                           *
  27. *                                                                   *
  28. *      HYPOTHESES SIMPLIFICATRICES :                                *
  29. *      -1 seul mode                                                 *
  30. *      -pas de forces turbulentes                                   *
  31. *                                                                   *
  32. *********************************************************************
  33.  
  34.  
  35. *********************************************************************
  36. *     Parametres globaux
  37. *********************************************************************
  38. GRAPH = FAUX; COMPLET = FAUX;
  39. * GRAPH = VRAI; COMPLET = VRAI;
  40.  
  41. OPTION DIME 3 ELEM SEG2 ;
  42. OPTION 'TRAC' 'PSC' 'EPTR' 5 'POTR' 'HELVETICA_16';
  43.  
  44. * point de vue
  45.   oeil = 0. -10. 0.;
  46. * nombre de modes a calculer
  47.   NMODE = 1;
  48. *   NMODE = 3;
  49. *   NMODE = 10;
  50.  
  51. *********************************************************************
  52. *     DEFINITION DU MODELE 
  53. *********************************************************************
  54.  
  55. *--------------------- Valeurs Numériques ----------------
  56.  
  57.  xpas = 45e-3 ;
  58. * position de l'accelero
  59.  xA = 160e-3;
  60.  
  61. * Lame Flexible
  62.  ll = 100E-3 ;
  63.  a = 25E-3 ;
  64.  b = 4E-3 ;
  65.  SL = a*b ;
  66.  ILy = a*(b**3)/12 ;
  67.  ILz = b*(a**3)/12 ;
  68.  ILx = 0.292*(a**3)*(b**3)/((a**2)+(b**2)) ;
  69.  
  70. * Tube
  71.  R = 15E-3 ;
  72.  D = 2*R   ;
  73.  e = 0.5E-3 ;
  74.  L = 298E-3 ;
  75.  ST  = pi*((R**2)-((R-e)**2)) ;
  76.  
  77. * Module Young 
  78.   YE=2.1E11 ;
  79.  
  80. * Rondelle cote lame
  81.  e1 = 6E-3 ;
  82.  SR1 = pi*(D**2)/4 ;
  83.  
  84. * Rondelle cote libre - definition en deux parties
  85.  e2 = 15.8E-3 ;
  86.  e3 = 0.8E-3 ;
  87.  SR2 = pi*((D**2)-((D-(2*(e+e3)))**2))/4 ;
  88.  SR3 = SR1 ;
  89.  
  90.  
  91. * Coefficient de confinement des tubes
  92.  DDe = (0.56*xpas/D+1.07)*xpas/D ;
  93.  beta = (DDe**2+1)/(DDe**2-1) ;
  94.  
  95. * Masse ajoutee d'eau sous forme de masse volumique
  96.  Rhos  = 7800.0 ;
  97.  roflu = 1000.0;
  98.  maslin = beta*roflu*pi*(D**2)/4 ;
  99.  maslin1 = roflu*pi*(a**2) ;
  100.  mvo = maslin1/SL + Rhos ;
  101.  mv  = maslin/ST  + Rhos ;
  102.  mv1 = maslin/SR1 + Rhos ;
  103.  mv2 = maslin/SR2 + Rhos ;
  104.  mv3 = maslin/SR3 + Rhos ;
  105.  
  106. *------------------------- Géométrie ---------------------
  107.  
  108.  P1 = 0.       0. 0. ;
  109.  P2 = ll       0. 0. ;
  110.  P3 = ll+e1    0. 0. ;
  111.  P4 = ll+L-e2  0. 0. ;
  112.  P5 = ll+L-e3  0. 0. ;
  113. *  P6 = ll+L     0. 0. ;
  114.  
  115.  L1 =  DROI 10  P1 P2 ;
  116.  L3 =  DROI 1   P2 P3 ;
  117.  L4 =  DROI 40  P3 P4 ;
  118.  L5 =  DROI 2   P4 P5 ;
  119. *  L6 =  DROI 1   P5 P6 ;
  120. *  L0 = L1 ET L3 ET L4 ET L5 ET L6;
  121.  L0 = L1 ET L3 ET L4 ET L5 ;
  122.  
  123. *-------------------------- Modèle -----------------------
  124.  
  125.  MDL1 = MODEL L1  MECANIQUE ELASTIQUE POUT ;
  126.  MDL3 = MODEL L3  MECANIQUE TUYAU ;
  127.  MDL4 = MODEL L4  MECANIQUE TUYAU ;
  128.  MDL5 = MODEL L5  MECANIQUE TUYAU ;
  129. *  MDL6 = MODEL L6  MECANIQUE TUYAU ;
  130. *  MDL  = MDL1 ET MDL3 ET MDL4 ET MDL5 ET MDL6;
  131.  MDL  = MDL1 ET MDL3 ET MDL4 ET MDL5;
  132.  
  133. *-------------- Matériaux et Caractéristiques ------------
  134.  
  135.  MAT1 = MATE MDL1  YOUN YE NU 0.3 RHO mvo ;
  136.  MAT3 = MATE MDL3  YOUN YE NU 0.3 RHO mv1 ;
  137.  MAT4 = MATE MDL4  YOUN YE NU 0.3 RHO mv ;
  138.  MAT5 = MATE MDL5  YOUN YE NU 0.3 RHO mv2 ;
  139. *  MAT6 = MATE MDL6  YOUN YE NU 0.3 RHO mv3 ;
  140. *  MAT  = MAT1 ET MAT3 ET MAT4 ET MAT5 ET MAT6;
  141.  MAT  = MAT1 ET MAT3 ET MAT4 ET MAT5;
  142.  
  143.  CAR1 = CARA MDL1  SECT SL INRY ILy INRZ ILz TORS ILx ;
  144.  CAR3 = CARA MDL3  RAYO R EPAI R  ;
  145.  CAR4 = CARA MDL4  RAYO R EPAI e  ;
  146.  CAR5 = CARA MDL5  RAYO R EPAI (e+e3) ;
  147. *  CAR6 = CARA MDL6  RAYO R EPAI R  ;
  148. *  CAR =  CAR1 ET CAR3 ET CAR4 ET CAR5 ET CAR6;
  149.  CAR =  CAR1 ET CAR3 ET CAR4 ET CAR5;
  150.  
  151. *------------- Matrices de Rigidité et de Masse ----------
  152.  
  153.  Ks0 = RIGI MDL (MAT ET CAR) ;
  154.  Ms  = MASS MDL (MAT ET CAR) ;
  155.  
  156.  
  157. *------------ Condition Limite en Déplacement ------------
  158.  
  159.  BLQs =    BLOQ UZ RY P1 ;
  160.  BLQplan = BLOQ UX UY RX RZ (L0) ;
  161.  
  162.  Ks = Ks0 ET BLQs ET BLQplan  ;
  163.  
  164. * RESOU tous bete
  165.  F6 = FORC 'FZ' P5 1.;
  166.  u6 = RESO Ks F6;
  167.  residu = F6 - (Ks*u6);
  168.  list (resu residu);
  169.  
  170. * taille de maille 
  171.   jac1 = JACO MDL;
  172.   trac jac1 MDL;
  173.   mess  (mini jac1) (maxi jac1);
  174.  
  175. *------------------Calcul des Modes Propres --------------
  176.  
  177.  BMOD = VIBR 'IRAM' 0. NMODE Ks Ms ;
  178.  BMOD.'MODES' = NNOR BMOD.'MODES' ( mots UX UY UZ ) ;
  179.  TBM = BMOD . 'MODES';
  180.  
  181.   POSTVIBR BMOD;  
  182.  
  183. * amortissement modal xi_i  
  184.   LIS_XI = PROG 0.009173 0.001553 0.000914 0.000596 0.000532 
  185.                 0.000361 0.000363 0.000258 0.000269 0.000204;
  186.   LIS_XI = EXTR LIS_XI (LECT 1 PAS 1 NMODE) ;         
  187.  
  188.  
  189. *********************************************************************
  190. *     Définition du profil de VITESSE et de Vmoy
  191. *********************************************************************
  192. *
  193. *   0m/s            3.4 m/s
  194. *           ^    ^    ^    ^    ^
  195. *           |    |    |    |    |
  196. * +---------+-------------------+-------> X
  197. * 0        ll                 ll+L
  198. *
  199. * d'ou la vitesse moyenne sur le profil complet
  200. Vmoy1 = 3.4 ;
  201. Vmoy  = Vmoy1 * (L / (ll+L));
  202. mess 'Vmoy1='Vmoy1 'm/s sur ['ll (ll+L)']  -->  Vmoy=' Vmoy 'm/s';
  203.  
  204.  
  205. *********************************************************************
  206. *  COEFFICIENTS temporels du MODELE DE GRANGER PAIDOUSSIS
  207. *********************************************************************
  208.  
  209.   D_EXT = 30.E-3 ;
  210.   RHO_2 = 1000.0 ;
  211.   DCLDX = -8.11 ;
  212.   CD    = 0.256 ;
  213.   ALPHA = PROG  1.258145697069813  -2.258327764366904;
  214.   DELTA = PROG  0.220857290865074  32.121982253844081;
  215.  
  216.  
  217. *********************************************************************
  218. *  DEFINITION DES TABLES NECESSAIRES AU CALCUL NON LINEAIRE
  219. *********************************************************************
  220.  
  221. *----------------------------------------------*
  222. *  CONDITIONS INITIALES
  223. *----------------------------------------------*
  224.  
  225.   TAB_INIT = TABLE 'INITIAL' ;
  226.  
  227.  
  228. *----------------------------------------------*
  229. *  CHARGEMENT = PETIT CHOC INITIAL POUR LANCER L'INSTABILITE
  230. *----------------------------------------------*
  231. *
  232.   PY1 = TBM . 1 . 'POINT_REPERE' ;
  233.   GFC1 = MANU CHPO PY1 1 'FALF' 1. ;
  234.   LFC1 = PROG 0. 1. 0. 0. ;
  235.   LTEMPS = PROG 0. 1E-2 2E-2 100.  ;
  236.   EVTC   = EVOL 'BRIQ' MANU LTEMPS LFC1 ;
  237. * dess EVTC 'XBOR' 0. 1.;
  238.   CHARG1 = CHAR GFC1 EVTC ;
  239.   TAB_CHAR = TABLE 'CHARGEMENT';
  240.   TAB_CHAR . 'BASE_A' = CHARG1; 
  241.  
  242. *----------------------------------------------*
  243. *     Les FORCES DE CHOC
  244. *----------------------------------------------*
  245.  
  246.   jeu1 = 1.5E-3;
  247.   PCHOC  = L0 POIN PROCH (0.248 0. 0.);
  248.   list PCHOC;
  249.   TL1 = TABLE 'LIAISON_ELEMENTAIRE' ;
  250.   TL1.'TYPE_LIAISON' = MOT 'POINT_CERCLE_FROTTEMENT' ;
  251.   TL1.'SUPPORT'                  =    PCHOC      ;
  252.   TL1.'RAIDEUR'                  =    1.0E6   ;
  253.   TL1.'RAYON'                    =    jeu1  ;
  254.   TL1.'NORMALE'                  = ( 1.0  0.0  0.0 ) ;
  255.   TL1.'EXCENTRATION'             = ( 0.0  0.0  0.0 ) ;
  256.   TL1.'RAIDEUR_TANGENTIELLE'     =    0.0     ;
  257.   TL1.'AMORTISSEMENT_TANGENTIEL' =    0.0     ;
  258.   TL1.'COEFFICIENT_GLISSEMENT'   =    0.0     ;
  259.   TL1.'COEFFICIENT_ADHERENCE'    =    0.0     ;
  260.  
  261. *----------------------------------------------*
  262. *     Les FORCES FLUIDELASTIQUES
  263. *----------------------------------------------*
  264.  
  265.   TFL1 = TABL 'LIAISON_ELEMENTAIRE';
  266.   TFL1 . 'TYPE_LIAISON'             = MOT  'COUPLAGE_DEPLACEMENT';
  267.   TFL1 . 'SUPPORT'                  = PY1;
  268.   TFL1 . 'ORIGINE'                  = PY1;
  269.   TFL1 . 'FONCTION_CONVOLUTION'     = MOT  'GRANGER_PAIDOUSSIS'  ;
  270.   TFL1 . 'ALPHA'   = PROG  1.258145697069813  -2.258327764366904;
  271.   TFL1 . 'DELTA'   = PROG  0.220857290865074  32.121982253844081;
  272.   TFL1 . 'VITESSE'                  = Vmoy1;
  273.   TFL1 . 'DIAMETRE'                 = D_EXT;
  274.   TFL1 . 'COEFFICIENT'              =  -0.61649988E+06  ;
  275.  
  276.   TFL2 = TABL 'LIAISON_ELEMENTAIRE';
  277.   TFL2 . 'TYPE_LIAISON'    = MOT   'COUPLAGE_VITESSE';    
  278.   TFL2 . 'SUPPORT'         = PY1;            
  279.   TFL2 . 'ORIGINE'         = PY1;            
  280.   TFL2 . 'COEFFICIENT'     =  -0.15152040E+01;     
  281.  
  282. * rem: les COEFFICIENTs sont issus de calculs GERBOISE
  283.  
  284.  
  285. *----------------------------------------------*
  286. *     Regroupement des LIAISONS
  287. *----------------------------------------------*
  288.   TAB_LIAI   = TABLE 'LIAISON' ;
  289.   TAB_LIAI . 'LIAISON_A' = TABLE 'LIAISON_A';
  290.   TAB_LIAI . 'LIAISON_A' . 1 = TFL1;
  291.   TAB_LIAI . 'LIAISON_A' . 2 = TFL2;
  292.   TAB_LIAI . 'LIAISON_B' = TABLE 'LIAISON_B';
  293.   TAB_LIAI . 'LIAISON_B' . 1 = TL1;
  294.  
  295. *----------------------------------------------*
  296. *     L'AMORTISSEMENT
  297. *----------------------------------------------*
  298.   TAB_AMOR = TABLE 'AMORTISSEMENT';
  299.   TAB_AMOR . 'AMORTISSEMENT' = AMOR BMOD (100.*LIS_XI);
  300.  
  301. *----------------------------------------------*
  302. *     Les SORTIES
  303. *----------------------------------------------*
  304. *
  305.   TAB_SORT = TABLE 'SORTIE' ;
  306.   TAB_SORT . 'VARIABLE' = TABLE 'SORTIE';
  307.   TAB_SORT . 'VARIABLE' . 'DEPLACEMENT'  = VRAI ;  
  308.   TAB_SORT . 'VARIABLE' . 'VITESSE'      = VRAI ;  
  309.   TAB_SORT . 'VARIABLE' . 'TYPE_SORTIE'  = MOT 'LISTREEL';
  310.  
  311.  
  312. *********************************************************************
  313. *     CALCUL NON LINEAIRE
  314. *********************************************************************
  315.  
  316. * PARAMETRES :
  317. * sortie tous les 'PAS_SAUVES' pas de temps (1 par defaut)
  318.   nexpS = 2;
  319.   nSORT = 2 ** nexpS;
  320. * pour avoir un bilan d'energie propre
  321. * nSORT = 1;
  322.   PAS_TEMP  = 2.5E-5  ;
  323.   si COMPLET;  nbloc     = 100; nexp      = 15;
  324.   sinon;       nbloc     = 4;   nexp      = 16;
  325.   finsi;
  326.   NB_PAS    = 2 ** nexp ;
  327.   nfft = nexp - nexpS;
  328.  
  329. * BOUCLE SUR LES BLOCS
  330.   TR1 = tabl;
  331.   REPE BBLOC nbloc;
  332.  
  333.     SI ( EGA &BBLOC 1 );  
  334.       TDY  =  DYNE  'DE_VOGELAERE' BMOD TAB_CHAR TAB_SORT TAB_LIAI
  335.                                    TAB_AMOR NB_PAS PAS_TEMP nSORT ;
  336.     SINON;
  337.       TAB_INIT . 'REPRISE' = TDY . 'REPRISE' ;
  338.       TDY = 'DYNE' 'DE_VOGELAERE' BMOD TAB_CHAR TAB_SORT TAB_LIAI
  339.                           TAB_AMOR TAB_INIT NB_PAS PAS_TEMP nSORT ;
  340.     FINSI;
  341.     TR1 . &BBLOC = TDY;
  342.  
  343.   FIN BBLOC;
  344.  
  345.  
  346. *********************************************************************
  347. *  POST TRAITEMENT
  348. *********************************************************************
  349.  
  350. *-----------------------------------------------------------------------
  351. *  TRACES 
  352. *-----------------------------------------------------------------------
  353.  
  354.   moncoco  = MOTS   'JAUN' 'LIME' 'OLIV' 'BOUT'
  355.                     'TURQ' 'CYAN' 'AZUR' 'BLEU' 'VIOL' 'INDI' ;
  356.   ewQVQ = VIDE 'EVOLUTION' ;
  357.   ewDSP = VIDE 'EVOLUTION' ;
  358.   TDESS1 = TABL;
  359.   TDESS1 . 'TITRE' = TABL;
  360.   PRRICE = PROG;
  361.   NB_PAS2 = NB_PAS / nSORT;
  362.   NB_PAS3 = NB_PAS2 - 1;
  363.   pr1 = prog 0. pas 1. NB_PAS3;
  364.   hann1 = 0.5 * (1. - (cos (360./NB_PAS3 * pr1)));
  365.  
  366.  
  367. * BOUCLE SUR LES BLOCS
  368.   REPE BBLOC nbloc;
  369.  
  370. *   recup des donnees du bloc  
  371.     si COMPLET; coco = MOT 'VIOL';
  372.     sinon;      coco = EXTR moncoco &BBLOC;
  373.     finsi;
  374.     TDYN1 = TR1 . &BBLOC;
  375.  
  376. *   grandeurs sorties  (temps et deplacement, vitesse modales)
  377.     prtim1  = TDYN1 . 'TEMPS_DE_SORTIE';
  378.     mess '>>> bloc ' &BBLOC ' : ' (dime prtim1) ' pas sauves';
  379.     prQ1    = TDYN1 . 'DEPLACEMENT' . PY1;
  380.     prVQ1   = TDYN1 . 'VITESSE'     . PY1;
  381.  
  382.     evQ1  = EVOL coco 'MANU' 't (s)' prtim1 'Q1' prQ1;
  383. *     evVQ1 = EVOL coco 'MANU' 't (s)' prtim1 'VQ1' prVQ1;
  384. *   diagramme de phase
  385.     evQVQ = EVOL coco 'MANU'  'Q1' prQ1 'VQ1' prVQ1;
  386.     ewQVQ = ewQVQ ET evQVQ;
  387.  
  388. *   calcul du spectre
  389.     si (ega &BBLOC 1);
  390.       prtim2= enle prtim1 (NB_PAS2 + 1);
  391.       prQ2  = enle prQ1   (NB_PAS2 + 1);
  392.     sinon;
  393.       prtim2=prtim1; prQ2=prQ1;
  394.     finsi;
  395.     evQ2  = EVOL coco 'MANU' 't (s)' prtim2 'Q1' (hann1*prQ2);
  396.     evDSP1 = DSPR nfft evQ1 'FMAX' 200. coco;
  397.     evDSP2 = DSPR nfft evQ2 'FMAX' 200. 'PEAU';
  398.     ewDSP = ewDSP ET evDSP1;
  399.  
  400. *   titres des courbes
  401.     tdeb = extr prtim1 1;
  402.     tfin = extr prtim1 (dime prtim1);
  403.     TDESS1 . 'TITRE' . &BBLOC 
  404.     = CHAI 't\Î[' FORMAT '(F4.2)' tdeb '-' FORMAT '(F4.2)' tfin ']'; 
  405.  
  406. *   FREQUENCE DE RICE (OU FREQUENCE CENTRALE) 
  407.     n1 = DIME prVQ1;
  408.     MOY_V  = (SOMM prVQ1) / n1;
  409.     MOY_V2 = (SOMM (prVQ1**2)) / n1;
  410.     SIG_V  = (MOY_V2 - (MOY_V**2))**0.5;
  411.     MOY_U  = (SOMM prQ1) / n1;
  412.     MOY_U2 = (SOMM (prQ1**2)) / n1;
  413.     SIG_U  = (MOY_U2 - (MOY_U**2))**0.5; 
  414.     XRICE = (0.5 / PI) * SIG_V / SIG_U;
  415.     PRRICE = PRRICE ET XRICE;
  416.  
  417. *   petit trace mignon
  418.     SI GRAPH;
  419. *     dess evDSP1 'LOGY' 'YBOR' 1.E-14 1.E-5
  420.       dess (evDSP1 et evDSP2) 'LOGY' 'YBOR' 1.E-14 1.E-6
  421.        'TITRE' (chai 'bloc ' &BBLOC ' t=' tfin 's');
  422.     FINSI;
  423.  
  424.   FIN BBLOC;
  425.  
  426.   evRICE = evol 'BOUT' MANU 'bloc'  (prog 1 pas 1 nbloc) 
  427.                             'f_{Rice} (Hz)' PRRICE;
  428. SI GRAPH;
  429.   dess ewQVQ TDESS1 'LEGE';
  430.   dess ewDSP TDESS1 'LOGY';
  431.   dess evRICE;
  432. FINSI;
  433.  
  434. *-----------------------------------------------------------------------
  435. *  TEST DE NON REGRESSION 
  436. *-----------------------------------------------------------------------
  437.  
  438. * TEST 
  439.   XREF = 28.55;
  440.   XTOL = 0.005 ;
  441.   XERR = ABS (XRICE - XREF) / XREF;
  442.   MESS XRICE XERR XTOL;
  443.  
  444. SI (XERR > XTOL) ;
  445.   MESS 'IL Y A UNE ERREUR !' ;
  446.   ERRE 5 ;
  447. SINON ;
  448.   MESS 'AUCUN PROBLEME DETECTE !' ;
  449. FINSI ;  
  450.  
  451. *-----------------------------------------------------------------------
  452. * performances
  453. *-----------------------------------------------------------------------
  454.   TEMP IMPR MAXI CPU;
  455.  
  456. FIN ; 
  457.  
  458.  
  459.  
  460.  
  461.  
  462.  
  463.  
  464.  
  465.  
  466.  
  467.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales