Télécharger dessin.dgibi

Retour à la liste

Numérotation des lignes :

  1. * dessin.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *_____________________________________________________
  5. *
  6. * PROCEDURE WATERFALL (experimentale)
  7. *_____________________________________________________
  8. *
  9. * tracé Waterfall Cast3M (experimental) ____
  10. *
  11. * /\ .
  12. * _______/ \_/\____.-.._/ \__.---------._____
  13. *
  14. * /\
  15. * _____/\_/\____.-.._/ \__.--.------._____
  16. *
  17. DEBP WATERFALL ev1*'EVOLUTION' y1*'LISTREEL'
  18. moty1/'MOT' moopt1/'LISTMOTS' zcoef1/'FLOTTANT';
  19.  
  20. * initialisations
  21. ZLOGY = FAUX;
  22. * recup des entrees + verif
  23. n1 = DIME ev1;
  24. si (neg n1 (dime y1)); ERRE 625; finsi;
  25. si (neg (type moty1) (MOT 'MOT')); moty1='\c'; finsi;
  26. si (ega (type moopt1) (MOT 'LISTMOTS'));
  27. * veut-on changer l'echelle de y1
  28. * (sans toucher a celle des evolutions) ?
  29. ZLOGY = EXIS moopt1 'LOGY';
  30. finsi;
  31. si (neg (type zcoef1) (MOT 'FLOTTANT')); zcoef1=1.; finsi;
  32.  
  33. * calcul du facteur alpha
  34. * recherche de l'amplitude des evolutions
  35. lindic1 lx1 lf1 = MAXI 'ABS' ev1;
  36. * maxf1 = MAXI 'ABS' lf1;
  37. maxf1 = (SOMM (ABS lf1)) / n1;
  38. * recherche des espaces inter-y
  39. si ZLOGY;
  40. y1log = LOG y1;
  41. dy1 = ((maxi y1log) - (mini y1log)) / (n1 - 1);
  42. sinon;
  43. dy1 = ((maxi y1) - (mini y1)) / (n1 - 1);
  44. finsi;
  45. * calcul de alpha
  46. alpha1 = zcoef1 * dy1 / maxf1;
  47.  
  48. * creation d'une nouvelle evolution prete a tracer
  49. * recup des parametres de l'evolution de depart
  50. coco1 = EXTR ev1 'COUL';
  51. xlabel1 = EXTR ev1 'LEGX' 1;
  52. * ylabel1 = EXTR ev1 'LEGY' 1;
  53. * on ordonne selon y1 decroissant
  54. li1 = lect 1 pas 1 n1;
  55. y2 li2 = ORDO 'DECROISSANT' y1 li1;
  56. * boucle sur les evol elementaires --> nouvelle evol
  57. ev2 = VIDE 'EVOLUTIO';
  58. REPE BEV1 n1;
  59. * choix de l'evol a traiter en premier
  60. i2 = EXTR li2 &BEV1;
  61. y2j = EXTR y2 &BEV1;
  62. * dernier parametre : la couleur
  63. coco2 = EXTR coco1 i2;
  64. molege1 = CHAI moty1 '=' FORMAT '(G10.2)' y2j;
  65. * recup des listreels
  66. xprog2 = EXTR ev1 'ABSC' i2;
  67. fprog1 = EXTR ev1 'ORDO' i2;
  68. * application de alpha aux evolutions
  69. si ZLOGY;
  70. * de maniere a avoir LOG(f2) = LOG(y) + a*f1
  71. fprog2 = y2j * (exp (alpha1 * fprog1));
  72. sinon;
  73. * de maniere a avoir f2 = y + a*f1
  74. fprog2 = y2j + (alpha1 * fprog1);
  75. finsi;
  76. * stockage
  77. ev2 = ev2 et (EVOL coco2 'MANU' 'LEGE' molege1 xlabel1 xprog2 moty1 fprog2);
  78. FIN BEV1;
  79.  
  80. FINP ev2;
  81. *_____________________________________________________
  82.  
  83.  
  84. *----------------------------------------------------------------------*
  85. * cas-test de la directive DESSIN. *
  86. *----------------------------------------------------------------------*
  87. OPTI 'TRAC' 'PSC' 'EPTR' 5 ;
  88. OPTI 'POTR' 'HELVETICA_16' ;
  89. * rem : il faudrait aussi tester avec
  90. * OPTI TRAC 'X';
  91. * OPTI TRAC 'OPEN' ;
  92.  
  93. * CB : TESTE DES CAS PARTICULIERS AYANT CONDUIT A DES ERREURS PAR LE PASSE
  94. * 1
  95. X1 =PROG -2. PAS 1. 750. ;
  96. Y1 =EXP (-1. * X1);
  97. EV1 = EVOL 'ROUG' MANU X1 Y1;
  98. DESS EV1 YBOR 0. 1.;
  99.  
  100. * 2
  101. X11 =PROG -2. PAS 1. 750. ;
  102. Y11 =EXP (-1. * X11);
  103. EV11 = EVOL 'ROUG' MANU Y11 X11;
  104. DESS EV11 XBOR 0. 1.;
  105.  
  106. * 3
  107. X2 = PROG -1 0. 1. 1.;
  108. Y2 = PROG -1 0. 1. 1.;
  109. EV2 = EVOL 'ROUG' MANU X2 Y2;
  110. DESS EV2 YBOR 0. 1.;
  111.  
  112. * 4
  113. X21 = PROG -1 0. 1. 1.;
  114. Y21 = PROG -1 0. 1. 1.;
  115. EV21 = EVOL 'ROUG' MANU Y21 X21;
  116. DESS EV21 XBOR 0. 1.;
  117.  
  118. * 5
  119. X3 = PROG 0. 1. ;
  120. Y3 = PROG -0.1 1.2 ;
  121. EV3 = EVOL 'ROUG' MANU X3 Y3;
  122. DESS EV3 YBOR 0. 1.;
  123.  
  124. * 6
  125. X31 = PROG 0. 1. ;
  126. Y31 = PROG -0.1 1.2 ;
  127. EV31 = EVOL 'ROUG' MANU Y31 X31;
  128. DESS EV31 XBOR 0. 1.;
  129.  
  130. * 7
  131. X4 = PROG 0. 1. ;
  132. Y4 = PROG 1.2 -1.2 ;
  133. EV4 = EVOL 'ROUG' MANU X4 Y4;
  134. DESS EV4 YBOR 0. 1.;
  135.  
  136. * 8
  137. X41 = PROG 0. 1. ;
  138. Y41 = PROG 1.2 -1.2 ;
  139. EV41 = EVOL 'ROUG' MANU Y41 X41;
  140. DESS EV41 XBOR 0. 1.;
  141.  
  142. * 9
  143. X5 = PROG 0. ;
  144. Y5 = PROG 1.2 ;
  145. EV5 = EVOL 'ROUG' MANU X5 Y5;
  146. DESS EV5 YBOR 0. 1.;
  147.  
  148. * 10
  149. X51 = PROG 0. ;
  150. Y51 = PROG 1.2 ;
  151. EV51 = EVOL 'ROUG' MANU Y51 X51;
  152. DESS EV51 XBOR 0. 1.;
  153.  
  154. * 11
  155. X6 = PROG 0. ;
  156. Y6 = PROG 0.5 ;
  157. EV6 = EVOL 'ROUG' MANU X6 Y6;
  158. DESS EV6 YBOR 0. 1.;
  159.  
  160. * 12
  161. X61 = PROG 0. ;
  162. Y61 = PROG 0.5 ;
  163. EV61 = EVOL 'ROUG' MANU Y61 X61;
  164. DESS EV61 XBOR 0. 1.;
  165.  
  166. * 13
  167. X7 = PROG ;
  168. Y7 = PROG ;
  169. EV7 = EVOL 'ROUG' MANU X7 Y7;
  170. DESS EV7 YBOR 0. 1.;
  171.  
  172. * 14
  173. X71 = PROG ;
  174. Y71 = PROG ;
  175. EV71 = EVOL 'ROUG' MANU Y71 X71;
  176. DESS EV71 XBOR 0. 1.;
  177.  
  178.  
  179. *
  180. * ON TESTE D'ABORD LES ECHELLE ET GRADUATIONS ************************
  181. * (SP)
  182. EV1 = EVOL 'BLEU' 'MANU' (PROG -1. -0.5 0.5 1. 2.)
  183. (PROG 1.E-3 0. 0. 5.E-4 7E-2) ;
  184. DESS EV1 'TITR' ' Sans option' ;
  185.  
  186. DESS EV1 'XBOR' -1.5 2.5
  187. 'TITR' ' Bornes sur X [-1.5 2.5] ' ;
  188.  
  189. DESS EV1 'YBOR' -0.5E-2 7.5E-2
  190. 'TITR' ' Bornes sur Y [-0.5E-2 7.5E-2] ' ;
  191.  
  192. DESS EV1 'XBOR' -1.5 2.5 'YBOR' -0.5E-2 7.5E-2
  193. 'TITR' ' Bornes sur X & Y ' ;
  194.  
  195. DESS EV1 'XBOR' -1.5 2.5 'YBOR' -0.5E-2 7.5E-2
  196. 'XGRA' +0.5 'YGRA' +0.5E-2
  197. 'TITR' ' Bornes sur X-Y & les intervalles de graduations donnes ' ;
  198.  
  199. DESS EV1 'XBOR' -1.5 2.5 'YBOR' -0.5E-2 7.5E-2
  200. 'XGRA' +0.5 'YGRA' +0.5E-2
  201. 'AXES' 'GRIL' 'POIN'
  202. 'TITR' ' La grille & les axes en PLUS ' ;
  203.  
  204.  
  205. * ON TESTE ENSUITE D'AUTRES OPTIONS AVEC UN SYSTEME 2DDL **************
  206. * LEGENDE, TITRES, CENTREMENT, GRILLE ...
  207. * (BP)
  208. * w donné en rad/s
  209. T1=2.;
  210. w1=(2.*pi)/T1;
  211. T2=5.;
  212. w2=(2.*pi)/T2;
  213. xp = prog 0. PAS 0.1 20.;
  214.  
  215. * castem utilise les degrés
  216. yp = 100. * (sin ((180/pi)*w1*xp));
  217. yp2 = 110. * (sin ((180/pi)*w2*xp));
  218.  
  219. ev1 = evol bleu manu xp yp;
  220. ev2 = evol roug manu xp yp2;
  221.  
  222. tdess1 = tabl;
  223. tdess1 . 1 = mot ' REMP MARQ PLUS REGU';
  224. tdess1 . 'TITRE' = tabl;
  225. ent1 = enti w1;
  226. decim1 = (enti (10.*w1)) - (10*ent1);
  227. ent2 = enti w2;
  228. decim2 = (enti (10.*w2)) - (10*ent2);
  229. tdess1 . 'TITRE' . 1 = chai '\W=' ent1 '.' decim1 'rad.s^{-1}';
  230. tdess1 . 2 = mot 'MARQ ROND REGU';
  231. tdess1 . 'TITRE' . 2 = chai '\W=' ent2 '.' decim2 'rad.s^{-1}';
  232.  
  233. DESS (ev1 et ev2)
  234. 'TITR' 'Déplacement x_{\W}(t) = sin(\Wt)'
  235. 'TITX' 't(s)' 'POSX' 'CENT'
  236. 'TITY' 'Dépl u_{A}^{1} (m)' 'POSY' 'CENT'
  237. 'LEGE' 'SO' tdess1;
  238.  
  239. DESS (ev1 et ev2)
  240. 'TITR' 'Déplacement x_{\W}(t) = sin(\Wt)'
  241. 'TITX' 't(s)' 'POSX' 'CENT'
  242. 'YBOR' -110. 110. 'YGRA' 22
  243. 'TITY' 'Dépl u_{A} (m^{1})' 'POSY' 'CENT'
  244. 'LEGE' tdess1;
  245.  
  246. DESS (ev1 et ev2)
  247. 'TITR' 'Déplacement x_{\W}(t) = sin(\Wt)'
  248. 'TITX' 't(s)'
  249. 'XBOR' 0. T2
  250. 'YBOR' -110. 110. 'YGRA' 22.
  251. 'TITY' 'Déplacement x (m)'
  252. 'LEGE' tdess1;
  253.  
  254. *** systeme 2ddl : fonction de tranfert : amplitude et phase ***
  255. ev1tot = VIDE 'EVOLUTION';
  256. ev2tot = VIDE 'EVOLUTION';
  257. * liscoul = mots VIOL BLEU TURQ BLEU ORAN AZUR ROUG ;
  258. liscoul = mots VIOL BLEU TURQ OLIV ORAN AZUR ROUG ;
  259. tdess2 = tabl;
  260. tdess2 . 1 = mot 'MARQ PLUS REGU';
  261. tdess2 . 2 = mot 'MARQ ROND REGU';
  262. tdess2 . 3 = mot 'MARQ CROI REGU';
  263. tdess2 . 4 = mot 'MARQ CARR REGU';
  264. tdess2 . 5 = mot 'MARQ TRIU REGU';
  265. tdess2 . 6 = mot 'MARQ ETOI REGU';
  266. tdess2 . 7 = mot 'MARQ TRID REGU';
  267. tdess2 . 'TITRE' = tabl;
  268.  
  269. xi1 = 0.02 ; xi2 = 0.05;
  270. xi1p = prog 0.001 0.002 0.01 0.02 0.05 0.1 0.15 ;
  271. xi2p = xi1p * (xi2 / xi1);
  272.  
  273. nxi = dime xi1p;
  274. ixi = 0;
  275. repe Bxi nxi; ixi = ixi + 1 ;
  276.  
  277. xi1 = extr xi1p ixi;
  278. xi2 = extr xi2p ixi;
  279. mess ixi ' xi_1=' xi1 ' xi_2=' xi2 ;
  280.  
  281. moxi1 = chai (enti (1000 * (xi1 - (enti xi1))));
  282. si (ega (dime moxi1) 1); moxi1 = chai '00' moxi1; fins;
  283. si (ega (dime moxi1) 2); moxi1 = chai '0' moxi1; fins;
  284. moxi1 = chai (enti xi1) '.' moxi1;
  285. tdess2 . 'TITRE' . ixi = chai '\x_{1}=' (moxi1);
  286.  
  287. m1=2.; k1 = m1*(w1**2); c1 = 2.*xi1*w1*k1;
  288. m2=1.; k2 = m2*(w2**2); c2 = 2.*xi2*w2*k2;
  289. mess w1 m1 k1 c1;
  290. mess w2 m2 k2 c2;
  291.  
  292. wpadim = prog 0. PAS 0.002 2.;
  293. wp = w1 * wpadim;
  294. np = dime wp;
  295. unp = prog np*1.;
  296.  
  297. A_R = ((k1 + k2)*unp) - ((wp**2)*m1);
  298. A_I = wp*(c1 + c2);
  299. B_R = -1.*k2*unp;
  300. B_I = -1.*c2*wp;
  301. D_R = (k2*unp) - ((wp**2)*m2);
  302. D_I = wp*c2;
  303.  
  304. Den_R = (A_R*D_R) - (A_I*D_I) - (B_R**2) + (B_I**2) ;
  305. Den_I = (A_R*D_I) + (A_I*D_R) - (2.*B_R*B_I);
  306. Den2 = (Den_R**2) + (Den_I**2);
  307.  
  308. * pour simplifier on excite seulement en F1 et en phase
  309. F1_R = 1.;
  310. Num11_R = ((Den_R*D_R) - (Den_I*D_I)) * F1_R;
  311. Num11_I = ((Den_R*D_I) - (Den_I*D_R)) * F1_R;
  312. Num12_R = -1.*((Den_R*B_R) - (Den_I*B_I)) * F1_R;
  313. Num12_I = -1.*((Den_R*B_I) - (Den_I*B_R)) * F1_R;
  314.  
  315. X1_R = Num11_R / Den2;
  316. X1_I = Num11_I / Den2;
  317. X2_R = Num12_R / Den2;
  318. X2_I = Num12_I / Den2;
  319.  
  320. X1_AMP = ((X1_R**2)+(X1_I**2))**0.5;
  321. X1_PHA = ATG X1_I X1_R;
  322. X2_AMP = ((X2_R**2)+(X2_I**2))**0.5;
  323. X2_PHA = ATG X2_I X2_R;
  324.  
  325. ev1_amp = evol BLEU manu wpadim X1_AMP;
  326. ev2_amp = evol ROUG manu wpadim X2_AMP;
  327. ev1_pha = evol BLEU manu wpadim X1_PHA;
  328. ev2_pha = evol ROUG manu wpadim X2_PHA;
  329.  
  330. si (xi1 ega 0.02);
  331. tdess1 . 'TITRE' . 1 = mot 'X_{1}';
  332. tdess1 . 'TITRE' . 2 = mot 'X_{2}';
  333.  
  334. * 'Y LOG + titres X et Y centres + LEGE XY'
  335. tit2ddl = chai 'Système à 2ddl : '
  336. '\w_{1}=0.5 \w_{2}=0.2 \x_{1}=2% \x_{2}=5%';
  337. DESS (ev1_amp et ev2_amp)
  338. 'LOGY' 'YBOR' 1.E-3 1.E1
  339. 'GRIL' 'POIN' 'GRIS'
  340. 'TITR' tit2ddl
  341. 'TITX' '\W (Hz)' 'POSX' 'CENT'
  342. 'TITY' 'amplitude |x| (m)' 'POSY' 'CENT'
  343. 'LEGE' 'XY' 1.5 0.8 tdess1;
  344.  
  345. DESS (ev1_pha et ev2_pha)
  346. 'YBOR' -180. 180. 'YGRA' 90.
  347. 'GRIL' 'POIN' 'GRIS'
  348. 'TITR' tit2ddl
  349. 'TITX' '\W (Hz)' 'POSX' 'CENT'
  350. 'TITY' 'phase \j(x) (m)' 'POSY' 'CENT'
  351. 'LEGE' 'XY' 1.5 160 tdess1;
  352.  
  353. fins;
  354.  
  355. ev1tot = ev1tot et (ev1_amp coul (extr liscoul ixi));
  356. ev2tot = ev2tot et (ev2_amp coul (extr liscoul ixi));
  357.  
  358. fin Bxi;
  359.  
  360.  
  361. * ON CONTINUE AVEC D'AUTRES OPTIONS
  362. * (BP)
  363.  
  364. tit2 = chai 'Evolution avec l`amortissement \x';
  365. DESS ev1tot
  366. 'GRIL' 'POIN' 'GRIS' 'TITR' tit2
  367. 'LOGY'
  368. 'TITX' '\W (Hz)' 'POSX' 'CENT'
  369. 'TITY' '|X_{1}| (m)' 'POSY' 'CENT'
  370. 'LEGE' 'XY' 1.45 9. tdess2;
  371. *rem : 'amplitude |X_{1}| (m)' est trop long (limite a 20 caracteres)!
  372. * 'TITY' 'amplitude |X_{1}| (m)' 'POSY' 'CENT'
  373.  
  374. * test de loption LIGNE_VARIABLE
  375. * on définit les style des (np-1) segments
  376. * (=0 lign, =2 tirr, ... =5 pointilles)
  377. nps3 = np / 3;
  378. ltirr2 = lect nps3*0 nps3*5 (np - 1 - (2*nps3))*1;
  379. ltirr3 = lect nps3*1 nps3*2 (np - 1 - (2*nps3))*0;
  380. tdess2 . 'LIGNE_VARIABLE' = TABL;
  381. tdess2 . 'LIGNE_VARIABLE' . 2 = ltirr2;
  382. tdess2 . 'LIGNE_VARIABLE' . 3 = ltirr2;
  383. tdess2 . 'LIGNE_VARIABLE' . 5 = ltirr3;
  384. DESS ev1tot
  385. 'GRIL' 'POIN' 'GRIS' 'TITR' tit2
  386. LOGY
  387. 'TITX' '\W (Hz)' 'POSX' 'CENT'
  388. 'TITY' '|X_{1}| (m)' 'POSY' 'CENT'
  389. 'LEGE' 'XY' 1.45 9. tdess2;
  390.  
  391. * test pour faire des waterfall (+ option REMP BLAN)
  392. * (bp,2019)
  393. * dess ev1tot;
  394. ev1log = WATERFALL ev1tot xi1p '\x' (mots 'LOGY');
  395. repe Bxi nxi;
  396. tdess2 . &Bxi = CHAI tdess2 . &Bxi ' REMP BLAN';
  397. fin Bxi;
  398. dess ev1log 'LOGY' 'LEGE' tdess2;
  399.  
  400.  
  401. *----------------------------------------------------------------------*
  402. * trace d'histogrammes *
  403. *----------------------------------------------------------------------*
  404.  
  405. * bruit blanc Gaussien
  406. NN = 10000 ;
  407. LTIRAG1 = BRUI 'BLAN' 'GAUS' 0. 2. NN ;
  408. LTIRAG2 = BRUI 'BLAN' 'GAUS' 0. 2. NN ;
  409. * calcul du nombre de classes (entieres)
  410. IMAX1 = ENTI 'SUPERIEUR' (MAXI LTIRAG1);
  411. IMIN1 = ENTI 'INFERIEUR' (MINI LTIRAG1);
  412. * boucle sur les classes
  413. NC = IMAX1 - IMIN1;
  414. LCOMPT1 = PROG NC*0. ;
  415. LCOMPT2 = PROG NC*0. ;
  416. IFIN1 = IMIN1;
  417. REPE BC NC;
  418. IDEB1 = IFIN1;
  419. IFIN1 = IFIN1 + 1;
  420. NC1 = MASQ LTIRAG1 'COMPRIS' IDEB1 IFIN1 'SOMME';
  421. REMP LCOMPT1 &BC NC1;
  422. NC2 = MASQ LTIRAG2 'COMPRIS' IDEB1 IFIN1 'SOMME';
  423. REMP LCOMPT2 &BC NC2;
  424. FIN BC;
  425.  
  426. list LCOMPT1;
  427.  
  428. * test de la procedure @HISTOGR
  429. TOPT1 = TABL ;
  430. TOPT1 . 'HPOS' = FLOT IMIN1 ;
  431. TOPT1 . 'DESS' = 'GRIL AXES' ;
  432. TOPT1 . 'COUL' = mot 'OCEA';
  433. @HISTOGR LCOMPT1 TOPT1 FAUX ;
  434.  
  435. * recup des evolutions pour trace plus evolues
  436. rainbow = mots 'MARI' 'MARI' 'MARI' 'BLEU' 'BLEU' 'AZUR' 'CYAN' 'TURQ'
  437. 'VERT' 'OR' 'ORAN' 'ROUG' 'BRIQ' 'BRIQ' 'BRUN' 'BRUN' 'BRUN' ;
  438. TOPT1 = TABL ; TOPT1 . 'COUL' = rainbow;
  439. evhist1 Thist = @HISTOGR LCOMPT1 TOPT1 VRAI ;
  440. TOPT2 = TABL ; TOPT2 . 'COUL' = rainbow;
  441. TOPT2 . 'NOMS' = TABL;
  442. repe b NC; TOPT2 . 'NOMS' . &b = chai &b ''; fin b;
  443. evhist2 Thist2 = @HISTOGR (-1.*LCOMPT2) TOPT2 VRAI ;
  444.  
  445. *DESS evhist1 Thist;
  446. *DESS evhist2 Thist2;
  447. * DESS (evhist1 et evhist2) Thist;
  448. * avec Legende
  449. repe b NC;
  450. Thist . &b = MOT 'REMP MARQ TRID';
  451. * Thist . (NC + &b) = MOT 'REMP MARQ TRIU';
  452. Thist . (NC + &b) = MOT 'MARQ TRIU';
  453. fin b;
  454. DESS (evhist1 et evhist2) Thist YBOR -2500 2500 YGRA 500;
  455.  
  456.  
  457. *------------------------------------------------------*
  458. * Test des couleurs *
  459. *------------------------------------------------------*
  460.  
  461. coul3 = mots 'INDI' 'VIOL' 'MARI' 'BLEU' 'AZUR' 'CYAN'
  462. 'TURQ' 'OCEA' 'BOUT' 'VERT' 'OLIV' 'LIME'
  463. 'JAUN' 'OR' 'BRON'
  464. 'ORAN' 'CORA' 'ROUG' 'BRIQ'
  465. 'BRUN' 'CARA' 'BEIG' 'KAKI' 'POUR' 'ROSE' 'PEAU' 'LAVA'
  466. 'BLAN' 'GRIS' 'NOIR' ;
  467. n3 = dime coul3;
  468. xx = prog 0. 1.;
  469. yy = prog 1. 1.;
  470. ev = vide EVOLUTIO;
  471. T = tabl;
  472. repe b n3;
  473. c = extr coul3 &b;
  474. ev =ev et (evol c 'MANU' xx (&b * yy));
  475. T . &b = chai 'LABEL' ' ' c ' REGU';
  476. fin b;
  477.  
  478. dess ev T XBOR 0. 1.2;
  479.  
  480.  
  481. FIN ;
  482.  
  483.  
  484.  
  485.  
  486.  
  487.  
  488.  
  489.  
  490.  
  491.  
  492.  
  493.  
  494.  
  495.  
  496.  
  497.  
  498.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales