Télécharger la plaquette Cast3M


fr en

Télécharger cou21.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  cou21.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. OPTI ECHO 0 ;
  5. SAUT PAGE ;
  6. MESS '                                                       ';
  7. MESS '                                                       ';
  8. MESS '  TEST AVEC 2 CUBES ET UN JOINT  (2D)                  ';
  9. MESS '  LE CUBE DU HAUT EST SOUMIS A UN DEPLACEMENT IMPOSE.  ';
  10. MESS '  L EVOLUTION DU CHARGEMENT EST TELLE QUE LE JOINT     ';
  11. MESS '  S OUVRE, PUIS SE REFERME, PUIS SE COMPRIME, ET ENFIN ';
  12. MESS '  S OUVRE DE NOUVEAU                                   ';
  13. MESS '  LE JOINT A AU DEPART UN JEU INITIAL                  ';
  14. MESS '                                                       ';
  15. MESS '                                                       ';
  16. MESS '                                                       ';
  17. MESS '               B _______________ C                     ';
  18. MESS '                |               |                      ';
  19. MESS '                |               |                      ';
  20. MESS '                |               |                      ';
  21. MESS '                |               |                      ';
  22. MESS '                |  ^     ^    ^ |                      ';
  23. MESS '                |__|_____|____|_|                      ';
  24. MESS '               A|               |H                     ';
  25. MESS '               G|_______________|D                     ';
  26. MESS '                |               |                      ';
  27. MESS '                |               |                      ';
  28. MESS '                |               |                      ';
  29. MESS '                |               |                      ';
  30. MESS '                |_______________|                      ';
  31. MESS '               K                 F                     ';
  32. MESS '                                                       ';
  33. MESS '  JOINT FORME DES NOEUDS GDHA                          ';
  34. MESS '  CONDITIONS AUX LIMITES  :                            ';
  35. MESS '       - K F  BLOQUES EN UX ET EN UY                   ';
  36. MESS '       - B C  BLOQUES EN UX ET EN UY                   ';
  37. MESS '  CHARGEMENT              :                            ';
  38. MESS '       - DEPLACEMENT IMPOSE SUR AH                     ';
  39. MESS '                                                       ';
  40. ********************************************************************
  41. *
  42. OPTION DIME 2 ;
  43. OPTION ELEM SEG2 MODE PLAN CONT ;
  44. *
  45. * ----------DEFINITION DE LA GEOMETRIE DU CUBE ----------
  46. *
  47. A = 0.00  0.30 ;
  48. B = 0.00  1.30;
  49. C = 4.00  1.30 ;
  50. H = 4.00  0.30 ;
  51. K = 0.00 -1.00 ;
  52. F = 4.00 -1.00 ;
  53. *
  54. G = 0.00 0.00 ;
  55. D = 4.00 0.00 ;
  56. *
  57. * ----------                  LIGNE                  ----------
  58. *
  59. AB =  A DROIT 1 B ;
  60. BC =  B DROIT 1 C ;
  61. CH =  C DROIT 1 H ;
  62. HA =  H DROIT 1 A ;
  63. AH =  A DROIT 1 H ;
  64. *
  65. DG =  D DROIT 1 G ;
  66. DF =  D DROIT 1 F ;
  67. FK =  F DROIT 1 K ;
  68. KG =  K DROIT 1 G ;
  69. *
  70. * ----------            MAILLAGE DU CUBE                 ----------
  71. *
  72. OPTION ELEM QUA4 MODE PLAN CONT ;
  73. *
  74. CUB1 = DALLER AB BC CH HA PLAN ;
  75. CUB2 = DALLER KG DG DF FK PLAN ;
  76. *  quelques definitions pour la verif finale
  77. P4 = NOEUD 4 ;
  78. P1 = NOEUD 1 ;
  79. P8 = NOEUD 8 ;
  80. P7 = NOEUD 7 ;
  81. *
  82. * ----------DEFINITION DE LA GEOMETRIE DU JOINT----------
  83. *
  84. * JOINT FORME DES NOEUDS H A D G
  85. *
  86. * ----------         MAILLAGE                ----------
  87. *
  88. OPTION ELEM RAC2 ;
  89. *
  90. JOINT = RACC 0.3001 HA DG ;
  91. JOINT = RACC 0.3001 (INVE HA) ( INVE DG) ;
  92. *
  93. * ----------      MAILLAGE TOTAL               ----------
  94. *
  95. CUBE = CUB1 ET CUB2    ;
  96. GEOTOT = CUBE ET JOINT ;
  97. *trac geotot ;
  98. *
  99. * ----------     DEFINITION DES CONDITIONS AUX LIMITES   ----------
  100. *
  101. *
  102. *
  103. *                        CUBE 
  104. *
  105. CLBX  = BLOQ B UX  ;
  106. CLBY  = BLOQ B UY  ;
  107. CLB   = CLBX ET CLBY ;
  108. *
  109. CLCX  = BLOQ C UX  ;
  110. CLCY  = BLOQ C UY  ;
  111. CLC   = CLCX ET CLCY ;
  112. *
  113. CLKY  = BLOQ K UY  ;
  114. CLKX  = BLOQ K UX  ;
  115. CLK   = CLKY ET CLKX ;
  116. *
  117. CLFY  = BLOQ F UY  ;
  118. CLFX  = BLOQ F UX  ;
  119. CLF   = CLFY ET CLFX ;
  120. *
  121. cl5  = bloq ha uy ;
  122. dep5 = depi cl5 1.0 ;
  123. *
  124. CLCUBE = CLB ET CLC ET CLF ET CLK ET cl5 ;
  125. *
  126. * ----------       CONDITIONS AUX LIMITES TOTALES   ----------
  127. *
  128. CLTOT = CLCUBE ;
  129. *
  130. * ----------        DEFINITION DU MODELE DES CUBES       ----------
  131. *
  132. MODCUB = MODE CUBE 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' ;
  133. MACUB  = MATE MODCUB YOUN 100.0 NU 0.000001  ;
  134. *
  135. * ----------         DEFINITION DU MODELE DU JOINT      ----------
  136. *
  137. MODJOI = MODE JOINT MECANIQUE ELASTIQUE PLASTIQUE COULOMB JOI2 ;
  138. MAJOI  = MATE MODJOI KS   1000.0  KN   100.0   EF  150.0    ECN  0.05
  139.                      COHE 2.0     FRIC 45.0    ;
  140. *
  141. * ---------- MODELE ET MATERIAU DE TOUTE LA STRUCTURE ----------
  142. *
  143. MODTOT = MODCUB ET MODJOI;
  144. MATTOT = MACUB  ET MAJOI ;
  145. *
  146. * ----------        DEFINITION DU CHARGEMENT         ----------
  147. *                                                           
  148.    L51 = PROG 0.0  1.0  2.0   3.0   4.0 ; 
  149.    L52 = PROG 0.0  1.0  0.0  -0.5   1.0 ;   
  150.    EV5 = EVOL MANU X L51 Y L52 ;
  151.    CAR = CHAR 'DIMP' DEP5 EV5;
  152. *
  153. * ----------            RESOLUTION            ----------
  154. *
  155.    TAB = TABLE ;
  156.    LIS1 = PROG 0.0 PAS 0.5 4.0 ; 
  157.    DEFH = (MANU CHML MODCUB EIXX 0.0 EIYY 0.0 EIZZ 0.0 GIXY 0.0
  158.            STRESSES TYPE 'DEFORMATIONS INELASTIQUES') ET
  159.           (MANU CHML MODJOI FRSN 0.0 FRN 0.3
  160.            STRESSES TYPE 'DEFORMATIONS INELASTIQUES') ;
  161.    TAB.'DEFORMATIONS_INELASTIQUES' = TABLE;
  162.    TAB.'DEFORMATIONS_INELASTIQUES' . 0 = DEFH;
  163.    TAB.'BLOCAGES_MECANIQUES' = CLTOT;
  164.    TAB.'MODELE' = MODTOT;
  165.    TAB.'CHARGEMENT' = CAR;
  166.    TAB.'TEMPS_CALCULES' = LIS1;
  167.    TAB.'CARACTERISTIQUES' = MATTOT;
  168.    TAB.'HYPOTHESE_DEFORMATIONS' = 'LINEAIRE' ;
  169. TMASAU=table;
  170. tab . 'MES_SAUVEGARDES'=TMASAU;
  171. TMASAU .'DEFTO'=VRAI;
  172. TMASAU .'DEFIN'=VRAI;
  173. PASAPAS TAB ;
  174. *
  175. * ---------- POST TRAITEMENT ----------
  176. *
  177. *
  178. * -----RECUPERATION DE LA TABLE DES DEPLACEMENTS
  179. *
  180. dtab1=tab.temps;
  181. *
  182. ndime=dime dtab1 ;
  183. *
  184. * ----- EXTRACTION DES DIFFERENTES TABLES
  185. *
  186. *                                    DEPLACEMENTS 
  187. *
  188. i=0 ;
  189. REPETER BOU1 (ndime-1) ;
  190.    i=i+1 ;
  191.    dep1=tab.deplacements.i ;
  192.    sig1=tab.contraintes.i ;
  193.    var1=tab.variables_internes.i ;
  194.    defp=tab.deformations_inelastiques.i ;
  195.    eps1 = epsi modjoi dep1 ;
  196. *
  197. * ----- REDUCTION DES CHPOINTS A L'ELEMENT JOINT 
  198. *
  199. *
  200. *
  201. *
  202. DPTCU1 = REDU DEP1 CUB1  ;
  203. SIGCU1 = REDU SIG1 CUB1  ;
  204. DPTCU2 = REDU DEP1 CUB2  ;
  205. SIGCU2 = REDU SIG1 CUB2  ;
  206. DPTJOI = REDU DEP1 JOINT ;
  207. SIGJOI = REDU SIG1 JOINT ;
  208. DEFJOI = REDU EPS1 JOINT ;
  209. DEPJOI = REDU DEFP JOINT ;
  210. VARJOI = REDU VAR1 JOINT ;
  211. *
  212. mess '               '   ;
  213. mess ' PAS DE TEMPS  ' i ;
  214. mess ' ____________  '   ;
  215. mess '               '   ;
  216. mess ' deplacements du cube 1  '   ; 
  217. *list dptcu1 ;
  218. mess '               '   ;
  219. mess ' deplacements du cube 2  '   ; 
  220. *list dptcu2 ;
  221. mess '               '   ;
  222. mess ' deplacements du joint   '   ; 
  223. *list dptjoi ;
  224. mess '               '   ;
  225. mess ' contraintes du cube 1    '   ; 
  226. *list sigcu1 ;
  227. mess '               '   ;
  228. mess ' contraintes du cube 2    '   ; 
  229. *list sigcu2 ;
  230. mess '               '   ;
  231. mess ' contraintes du joint  '   ; 
  232. *list sigjoi ;
  233. mess '               '   ;
  234. mess ' def totales'   ;
  235. *list defjoi ;
  236. mess '               '   ;
  237. mess ' def inelasti. '   ;
  238. *list depjoi ;
  239. mess ' variables internes '   ;
  240. *list varjoi ;
  241. *
  242. fin bou1 ;
  243. *
  244. DEP11 = EXTR DPTCU1 UY P1 ;
  245. DEP14 = EXTR DPTCU1 UY P4 ;
  246. DEP28 = EXTR DPTCU2 UY P8 ;
  247. DEP27 = EXTR DPTCU2 UY P7 ;
  248. *
  249. SMY1  = EXTR SIGCU1 SMYY 1 1 1  ;
  250. *
  251. SMNJ  = EXTR SIGJOI SMN 1 1 1   ;
  252. DEPJ  = EXTR DEPJOI FRN 1 1 1   ;
  253. STAJ  = EXTR VARJOI STAT 1 1 1  ;
  254.  
  255. *
  256. SI (EGA I 8)  ;
  257. *
  258. *   DEPLACEMENTS DU CUBE 1 
  259. *
  260.  DIF11 = DEP11-1.0 ;
  261.  DIF14 = DEP14-1.0 ;
  262.  T11 = ABS(DIF11) ;
  263.  T14 = ABS(DIF14) ;
  264.     SI (( T11 <EG 1.E-4   ) ET ( T14 <EG 1.E-4   ));
  265.       ERRE 0 ;
  266.     SINON ;
  267.       ERRE 5 ;
  268.     FINSI ;
  269. *
  270.  T28 = ABS(DEP28) ;
  271.  T27 = ABS(DEP27) ;
  272.     SI ( ( T28 <EG 1.E-4   ) ET ( T27  <EG 1.E-4 ));
  273.       ERRE 0 ;
  274.     SINON ;
  275.       ERRE 5 ;
  276.     FINSI ;
  277. *
  278. *   CONTRAINTES DU CUBE 1 
  279. *
  280.   DIS1 = SMY1+1.E2 ;
  281.   TI1  = ABS(DIS1) ;
  282.     SI ( TI1 <EG 1.E-4 ) ;
  283.       ERRE 0 ;
  284.     SINON ;
  285.       ERRE 5 ;
  286.     FINSI ;
  287. *
  288. *   CONTRAINTES DU JOINT 
  289. *
  290.   DIJ1 = DEPJ-1.3 ;
  291.   DIA1 = STAJ-1.0 ;
  292.   TIM1 = ABS(SMNJ) ;
  293.   TIJ1 = ABS(DIJ1) ;
  294.   TIA1 = ABS(DIA1) ;
  295.     SI ( ( TIM1 <EG 1.E-4 ) ET ( TIJ1 <EG 1.E-4 )
  296.       ET ( TIA1 <EG 1.E-4 ) ) ;
  297.       ERRE 0 ;
  298.     SINON ;
  299.       ERRE 5 ;
  300.     FINSI ;
  301. *
  302. FINSI ;
  303. fin;
  304.  
  305.  
  306.  
  307.  
  308.  
  309.  
  310.  
  311.  
  312.  
  313.  
  314.  
  315.  
  316.  
  317.  
  318.  
  319.  
  320.  
  321.  
  322.  
  323.  
  324.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales