Télécharger bide2tract.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : bide2tract.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *======================================================================*
  5. * MODELE HYPERELASTIQUE BIDERMAN INCOMPRESSIBLE *
  6. * EN GRANDES TRANSFORMATIONS - CONTRAINTES PLANES *
  7. * *
  8. * TEST DE VALIDATION DU MODELE : TRACTION BIAXIALE DANS LE PLAN X,Y *
  9. * COMPARAISON AVEC LA SOLUTION ANALYTIQUE *
  10. * *
  11. * *
  12. * Contribution de Laurent Gornet - Ecole Centrale de Nantes (2010) *
  13. *======================================================================*
  14. * Pour plus d'informations, voir la presentation de L. Gornet lors *
  15. * du Club Cast3m 2009, disponible sur le site Web de Cast3m. *
  16. *======================================================================*
  17. * Exemple d'utilisation d'un modele UMAT en grandes transformations *
  18. * *
  19. * Note : Actuellement en grandes deformations dans PASAPAS, le modele *
  20. * ne peut contenir que des modeles de type UMAT. On ne peut *
  21. * pas melanger les derivees objectives et les modeles de C3m. *
  22. *======================================================================*
  23. *======================================================================*
  24.  
  25. 'OPTION' 'DIME' 2 'MODE' 'PLAN' 'CONT' 'ECHO' 0 ;
  26. option epsilon 'UTILISATEUR';
  27. *
  28. * Mettre VRAI si l'on souhaite divers traces.
  29. GRAPH = FAUX ;
  30. *GRAPH = VRAI ;
  31.  
  32.  
  33. title = 'CHAINE' 'BIDERMAN - ' 'TRACTION BIAXIALE XY' ;
  34.  
  35.  
  36. *======================================================================*
  37. * Geometrie - Maillage *
  38. *======================================================================*
  39. * Longueur (direction x) de la plaque/membrane :
  40. Lg_x = 1. ;
  41. * Largeur (direction y) de la plaque/membrane :
  42. Lg_y = 0.5 ;
  43. * Nombre d'elements selon les directions x et y :
  44. Nel_x = 5 ;
  45. Nel_y = 3 ;
  46. *
  47. *Nel_x = 30 ;
  48. *Nel_y = 10 ;
  49. *
  50. 'OPTION' 'ELEM' 'QUA8' ;
  51. *
  52. P1 = 0. 0. ;
  53. P2 = Lg_x 0. ;
  54. P3 = Lg_x Lg_y ;
  55. P4 = 0. Lg_y ;
  56. *
  57. L1 = 'DROITE' Nel_x P1 P2 ;
  58. L2 = 'DROITE' Nel_y P2 P3 ;
  59. L3 = 'DROITE' Nel_x P3 P4 ;
  60. L4 = 'DROITE' Nel_y P4 P1 ;
  61. *
  62. SU = 'DALLER' L1 L2 L3 L4 ;
  63. 'SI' GRAPH ;
  64. 'TRACER' SU 'TITRE' ('CHAINE' title ' - MAILLAGE') ;
  65. 'FINSI' ;
  66.  
  67. *======================================================================*
  68. * Modele - Materiau - Caracteristiques (en MPa) *
  69. *======================================================================*
  70. 'SI' (('NEG' ('VALEUR' 'DIME') 2) 'OU'
  71. ('NEG' ('VALEUR' 'MODE') 'PLANCONT')) ;
  72. 'MESS' 'Ce modele ne fonctionne qu en 2D CONTRAINTES PLANES' ;
  73. 'ERREUR' 5 ;
  74. 'FINSI' ;
  75. *
  76. * Ne pas oublier de definir les parametres lies a l'elasticite.
  77. * Meme si ce n'est pas utilise dans le modele, cela est utile pour
  78. * l'operateur de convergence mecanique de PASAPAS-INCREME.
  79. *
  80. LCMAT =MOTS 'YOUN' 'NU ' 'C01' 'C10' 'C20' 'C30' ;
  81. MO = MODE SU 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'
  82. 'NON_LINEAIRE' 'UTILISATEUR'
  83. 'NUME_LOI' 35 'C_MATERIAU' LCMAT ;
  84. * Calcul du Module d'Young
  85. * Coefficients du modele de BIDERMAN (en MPa) :
  86. C1 = 0.183 ; C2 = 0.0034 ;
  87. *
  88. * On fixe le coefficient de Poisson XNU a une valeur proche de 0.5
  89. * du fait de l'incompressibilite inherente au modele.
  90. * Le module de Young YOU est alors connu, car, pour ce modele, le
  91. * module de cisaillement MU vaut : MU = YOU/(2*(1+XNU)) = 2.(C1+C2)
  92. * Il s'agit de la valeur initiale et de la borne inferieure dans le cas
  93. * de la traction. En fonction du niveau de deformation atteinte en
  94. * traction, il faut augmenter cette valeur afin de pouvoir faire
  95. * converger les calculs. Prendre des valeurs superieures n'entraine pas
  96. * de modification des resultats, cela modifie seulement le nombre
  97. * d'iterations mecaniques.
  98. * Par ex. : pour 1000 %, il faut multiplier par 30 la valeur initiale.
  99. * Si l'on se contente de 10., les calculs s'arretent vers 900 %.
  100. *
  101. XNU = 0.499 ;
  102. YOUini = 3.*(2.*(C1+C2)) ; YOU = 1000. * YOUini ;
  103. *
  104. *Parametres du modèle Bidermann : essais Treloar/Kawabata MPa
  105. C01 = 0.0233;
  106. C10 = 0.208 ;
  107. C20 = -0.0024 ;
  108. C30 = 0.0005 ;
  109. *
  110. MA = MATE MO 'YOUN' YOU 'NU ' XNU 'C01' C01 'C10' C10
  111. 'C20' C20 'C30' C30 ;
  112.  
  113. *======================================================================*
  114. * Conditions aux limites - Chargement bi-axe *
  115. *======================================================================*
  116. BL1 = 'BLOQUER' 'UY ' L1 ;
  117. BL2 = 'BLOQUER' 'UY ' L3 ;
  118. BL4 = 'BLOQUER' 'UX ' L4 ;
  119. BL3 = 'BLOQUER' 'UX ' L2 ;
  120. BLTOT = BL1 'ET' BL2 'ET' BL3 'ET' BL4 ;
  121. *
  122. * Definition des instants du chargement :
  123. t_deb = 0. ; t_fin = 10. ;
  124. L_tps = 'PROG' t_deb t_fin ;
  125. * Deplacement suivant X :
  126. FF_x = 'DEPIMP' BL3 1. ;
  127. L_UX = 'PROG' 0. (5. * Lg_x) ;
  128. EV_x = 'EVOL' 'MANU' 'TEMPS' L_tps 'LAMX' L_UX ;
  129. CHAR_x = 'CHARGEMENT' 'DIMP' FF_x EV_x ;
  130. * Deplacement suivant Y :
  131. L_UY = 'PROG' 0. ( 2. * Lg_y) ;
  132. FF_y = 'DEPIMP' BL2 1. ;
  133. EV_y = 'EVOL' 'MANU' 'TEMPS' L_tps 'LAMY' L_UY ;
  134. CHAR_y = 'CHARGEMENT' 'DIMP' FF_y EV_y ;
  135. *
  136. CHARTOT = CHAR_x 'ET' CHAR_y ;
  137.  
  138. *======================================================================*
  139. * Initialisation de la table pour appel a PASAPAS *
  140. *======================================================================*
  141. TAB1 = 'TABLE' ;
  142. TAB1.'MODELE' = MO ;
  143. TAB1.'CARACTERISTIQUES' = MA ;
  144. TAB1.'BLOCAGES_MECANIQUES' = BLTOT ;
  145. TAB1.'CHARGEMENT' = CHARTOT ;
  146. **** LG
  147. *TAB1.'PRECISION' = 1.E-6 ;
  148. *TAB1.'FTOL' = 1.E-5 ;
  149. *TAB1.'MTOL' = 1.E-5 ;
  150. *
  151. TAB1.'CONVERGENCE_FORCEE' = FAUX ;
  152. TAB1.'GRANDS_DEPLACEMENTS' = VRAI ;
  153. TAB1.'TEMPS_CALCULES' = 'PROG' t_deb 'PAS' 0.1 t_fin ;
  154. TAB1.'TEMPS_SAUVES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  155. *
  156. L_abs = TAB1.'TEMPS_SAUVES' ;
  157. n_abs = 'DIMENSION' L_abs ;
  158. *
  159. PASAPAS TAB1 ;
  160. *
  161. * Quelques traces de controle apres calculs
  162. 'SI' GRAPH ;
  163. Defo_0 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 0. ;
  164. Defo_1 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 1. 'VERT' ;
  165. 'TRACER' (Defo_0 'ET' Defo_1)
  166. 'TITRE' ('CHAINE' title ' - DEFORMEES INITIALE ET FINALE') ;
  167. 'TRACER' MO (TAB1.'CONTRAINTES'.(n_abs-1))
  168. 'TITRE' ('CHAINE' title ' - CONTRAINTES EN FIN DE CALCUL') ;
  169. 'FINSI' ;
  170. *
  171. *======================================================================*
  172. * Construction de la solution analytique *
  173. *======================================================================*
  174. * Definitions :
  175. * - Allongement selon direction x : Lamx = 1 + (UX/Lg_x)
  176. * - Allongement selon direction y : Lamy = 1 + (UY/Lg_y)
  177. * - Densite d'energie de deformation hyperelastique : W(I1,I2)
  178. * - I1, I2 : trois invariants du tenseur de Cauchy-Green droit
  179. * Dans le cas du modele de BIDERMAN :
  180. * dW/dI1 = C10+2*C20*(i1-3)+3*C30*(i1-3)**2
  181. * dW/dI2 = C01
  182. * Les contraintes de Cauchy sont calculables analytiquement :
  183. * - SCxx = 2.(Lamx**2 - (Lamx*Lamy)**-2).(dW/dI1 + Lamy**2.dW/dI2)
  184. * - SCyy = 2.(Lamy**2 - (Lamx*Lamy)**-2).(dW/dI1 + Lamx**2.dW/dI2)
  185. * - SCxy = 0 (pas de cisaillement)
  186. * - SCzz = 0 (hypothese des contraintes planes)
  187. *
  188. L_Un = 'PROG' n_abs '*' 1. ;
  189. Lamx = L_Un + (('IPOL' L_abs L_tps L_UX) / Lg_X) ;
  190. Lamy = L_Un + (('IPOL' L_abs L_tps L_UY) / Lg_Y) ;
  191. *
  192. L_z1 = Lamx * Lamx ; L_z2 = Lamy * Lamy ;
  193. L_z3 = L_z1 - ((L_z1*L_z2)**-1) ;
  194. L_z4 = L_z2 - ((L_z1*L_z2)**-1) ;
  195. *LG
  196. L_tr = L_Un * 3.;
  197. I1 = L_z1 + L_z2 + ((L_z1*L_z2)**-1);
  198. I2 =(L_z1 * L_z2) + (L_z1**-1) + (L_z2**-1);
  199. *dWI1 = C1;
  200. *dWI2 = C2;
  201. *
  202. dWI1=(C10 * L_Un)+(2.*C20*(I1 - L_tr))+(3.*C30*((I1 - L_tr)**2.));
  203. dWI2=C01 ;
  204. *
  205. SCxx_th = L_z3 * ((2.*dWI1*L_Un) + (2.*dWI2*L_z2)) ;
  206. SCyy_th = L_z4 * ((2.*dWI1*L_Un) + (2.*dWI2*L_z1)) ;
  207. SCxy_th = 0. * L_Un ;
  208.  
  209. *======================================================================*
  210. * Comparaison des resultats avec la solution analytique *
  211. *======================================================================*
  212. * La comparaison s'effectue entre les valeurs moyennes des contraintes
  213. * calculees et les solutions analytiques correspondantes.
  214. * On ne cherche pas a verifier l'uniformite du champ de contraintes.
  215. * (Faire le calcul en mettant GRAPH a VRAI et voir les isovaleurs !)
  216. *
  217. TabD = TAB1.'DEPLACEMENTS' ;
  218. TabS = TAB1.'CONTRAINTES' ;
  219. Confini = 'FORM' ;
  220. ChmUn = 'MANU' 'CHML' MO 'SCAL' 1. ;
  221. *
  222. SCxx = 'PROG' 0. ;
  223. SCyy = 'PROG' 0. ;
  224. SCxy = 'PROG' 0. ;
  225. 'REPETER' Boucle (n_abs - 1) ;
  226. 'FORM' (TabD.&Boucle) ;
  227. VolSU = 'INTG' MO ChmUn ;
  228. SCxx = SCxx 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXX')/VolSU)) ;
  229. SCyy = SCyy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYY')/VolSU)) ;
  230. SCxy = SCxy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXY')/VolSU)) ;
  231. 'FORM' Confini ;
  232. 'FIN' Boucle ;
  233. *
  234. * LG lamb
  235. L_abs = Lamy;
  236. *
  237. 'SI' GRAPH ;
  238. tlege = 'TABLE' ;
  239. tlege. 1 = 'MARQ CROI' ;
  240. tlege.'TITRE' = 'TABLE' ;
  241. tlege.'TITRE'. 1 = 'Numerique' ;
  242. tlege.'TITRE'. 2 = 'Analytique' ;
  243. Evxx = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXX' SCxx ;
  244. Evxx_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXX' SCxx_th ;
  245. 'DESSIN' (Evxx 'ET' Evxx_th) 'LEGE' tlege
  246. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XX (MPa)') ;
  247. Evyy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYY' SCyy ;
  248. Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYY' SCyy_th ;
  249. 'DESSIN' (Evyy 'ET' Evyy_th) 'LEGE' tlege
  250. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY YY (MPa)') ;
  251. Evxy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXY' SCxy ;
  252. Evxy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXY' SCxy_th ;
  253. 'DESSIN' (Evxy 'ET' Evxy_th) 'LEGE' tlege
  254. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (MPa)');
  255. 'FINSI' ;
  256. *
  257. * Tests de bon fonctionnement :
  258. r_xx = 'MAXIMUM' ('ABS' (SCxx - SCxx_th)) ;
  259. r_yy = 'MAXIMUM' ('ABS' (SCyy - SCyy_th)) ;
  260. r_xy = 'MAXIMUM' ('ABS' (SCxy - SCxy_th)) ;
  261. *
  262. MESS ' RESULTATS : ' title ;
  263. MESS ' ------------------------------------------------ ';
  264. 'SAUTER' 1 'LIGNE' ;
  265. 'MESS' ' Tests de bon fonctionnement :' ;
  266. 'MESS' ' -------------------------------' ;
  267. 'MESS' ' Comparaison effectuee sur les contraintes de Cauchy' ;
  268. 'MESS' ' Ecart maximal en valeur absolue entre la valeur moyenne '
  269. 'calculee' ;
  270. 'MESS' ' et la '
  271. 'solution analytique associee' ;
  272. 'MESS' ' Composante XX : ' r_xx ' MPa' ;
  273. 'MESS' ' Composante YY : ' r_yy ' MPa' ;
  274. 'MESS' ' Composante XY : ' r_xy ' MPa' ;
  275. 'SAUTER' 1 'LIGNE' ;
  276. * Ecart maximal tolere sur la contrainte (en MPa)
  277. Sigref = 1.E-3 ;
  278. 'SI' ('>EG' ('MAXIMUM' ('PROG' r_xx r_yy r_xy)) Sigref) ;
  279. 'MESS' ' ---------------------' ;
  280. 'MESS' ' ECHEC DU CAS-TEST !' ;
  281. 'MESS' ' ---------------------' ;
  282. 'ERREUR' 5 ;
  283. 'SINON' ;
  284. 'MESS' ' ----------------------' ;
  285. 'MESS' ' SUCCES DU CAS-TEST !' ;
  286. 'MESS' ' ----------------------' ;
  287. 'FINSI' ;
  288. 'SAUTER' 1 'LIGNE' ;
  289.  
  290. 'FIN' ;
  291.  
  292.  
  293.  
  294.  
  295.  
  296.  
  297.  
  298.  
  299.  
  300.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales