Télécharger aerosol1.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : aerosol1.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. GRAPH = FAUX ;
  6.  
  7. **************************************************************************
  8. * AEROSOL1.DGIBI *
  9. **************************************************************************
  10. * *
  11. * NATURE DU PROBLEME : TRANSPORT DE PARTICULES AVEC DEPOT *
  12. * CONVECTION FORCEE *
  13. * CALCUL DE L'ECOULEMENT DANS UN PREMIER TEMPS *
  14. * CALCUL DU TRANSPORT DANS UN DEUXIEME TEMPS *
  15. * TURBULENT *
  16. * *
  17. * ALGORITHME : SEMI-IMPLICITE *
  18. * *
  19. * OPERATEURS : NSKE , FPU *
  20. * TSCAL , ECHIMP , KFPA *
  21. * *
  22. * GEOMETRIE : LOCAL 2D *
  23. * *
  24. * TEST SUR LA VITESSE DE DEPOT EN 2 POINTS DE LA COUCHE LIMITE *
  25. * *
  26. *P.CORNET-SEMT/TTMF-DECEMBRE 1997 *
  27. **************************************************************************
  28.  
  29. *---------------------- CREATION DU MAILLAGE -----------------------------------
  30.  
  31. TITRE 'MAILLAGE AEROSOL POUR TURBULENCE' ;
  32. OPTION DIME 2 ELEM QUA4 ;
  33.  
  34. * EPAISSEUR DE LA COUCHE LIMITE :
  35.  
  36. E = 0.05 ;
  37.  
  38. * POINTS :
  39.  
  40. PA1 = 0. 0. ;
  41.  
  42. PB1 = E E ;
  43. PB2 = E 6.5 ;
  44. PB3 = E 7. ;
  45. PB4 = E 9. ;
  46. PB5 = E 9.5 ;
  47. PB6 = E 25. ;
  48. PB7 = E 41. ;
  49. PB8 = E (50.-E) ;
  50.  
  51. PC1 = (20.-E) E ;
  52. PC2 = (20.-E) 6.5 ;
  53. PC3 = (20.-E) 7. ;
  54. PC4 = (20.-E) 9. ;
  55. PC5 = (20.-E) 9.5 ;
  56. PC6 = (20.-E) 25. ;
  57. PC7 = (20.-E) 41. ;
  58. PC8 = (20.-E) (50.-E) ;
  59.  
  60. PE8 = (8.+E) (50.-E) ;
  61. PE9 = (8.+E) 53. ;
  62.  
  63. PH8 = (12.-E) (50.-E) ;
  64. PH9 = (12.-E) 53. ;
  65.  
  66. * SEGMENTS ELEMENTAIRES :
  67.  
  68. DB12 = PB1 DROIT 13 PB2 ;
  69. DB23 = PB2 DROIT 1 PB3 ;
  70. DB34 = PB3 DROIT 4 PB4 ;
  71. DB45 = PB4 DROIT 1 PB5 ;
  72. DB56 = PB5 DROIT DINI 0.5 DFIN 2. PB6 ;
  73. DB67 = PB6 DROIT DINI 2. DFIN 0.5 PB7 ;
  74. DB78 = PB7 DROIT 18 PB8 ;
  75.  
  76. DC12 = PC1 DROIT 13 PC2 ;
  77. DC23 = PC2 DROIT 1 PC3 ;
  78. DC34 = PC3 DROIT 4 PC4 ;
  79. DC45 = PC4 DROIT 1 PC5 ;
  80. DC56 = PC5 DROIT DINI 0.5 DFIN 2. PC6 ;
  81. DC67 = PC6 DROIT DINI 2. DFIN 0.5 PC7 ;
  82. DC78 = PC7 DROIT 18 PC8 ;
  83.  
  84. DB1 = DB12 et DB23 et DB34 et DB45 et DB56 ;
  85. DB2 = DB67 et DB78 ;
  86. DB1 = inve DB1 ;
  87. DB2 = inve DB2 ;
  88.  
  89. DD1 = DC12 et DC23 et DC34 et DC45 et DC56 ;
  90. DD2 = DC67 et DC78 ;
  91.  
  92. DE89 = PE8 DROIT 5 PE9 ;
  93. DE98 = INVE DE89 ;
  94. DH89 = PH8 DROIT 5 PH9 ;
  95. DHE9 = PH9 DROIT 8 PE9 ;
  96.  
  97. DBC1 = PB1 DROIT 40 PC1 ;
  98. DBC6 = PB6 DROIT 40 PC6 ;
  99. DCB6 = INVE DBC6 ;
  100.  
  101. DEH8 = PE8 DROIT 8 PH8 ;
  102. DHE8 = inve DEH8 ;
  103. DAE8 = PB8 DROIT 16 PE8 ;
  104. DEA8 = INVE DAE8 ;
  105. DDH8 = PC8 DROIT 16 PH8 ;
  106.  
  107. DDA8 = DDH8 et DHE8 et DEA8 ;
  108.  
  109. DA58 = DB56 et DB67 et DB78 ;
  110. DA85 = inve DA58 ;
  111. DA21 = inve DB12 ;
  112. CLEXT1 = DA21 et DBC1 et DD1 et DD2 et DDH8 et DH89 ;
  113. CLEXT2 = DE98 et DEA8 et DA85 ;
  114.  
  115. * DOMAINE TOTAL :
  116.  
  117. DOMBAS = DBC1 DD1 DCB6 DB1 DALLER PLAN ;
  118. DOMHAU = DBC6 DD2 DDA8 DB2 DALLER PLAN ;
  119. DOMSORT = DEH8 DH89 DHE9 DE98 DALLER PLAN ;
  120. DOMTOT1 = DOMBAS ET DOMHAU ET DOMSORT ;
  121.  
  122. * ON NOMME LES OBJETS MAILLAGE INTERESSANTS :
  123.  
  124. DENTREE = DB34 ;
  125. dentree = inve dentree ;
  126. DSORTIE = DHE9 ;
  127. DSORTI2 = DHE8 ;
  128. DCOUPE = DBC6 ;
  129. DENTREV = DB23 ET DB34 ET DB45 ;
  130.  
  131. TROUS = DENTREE ET DSORTIE ;
  132. BORTOT = CONTOUR DOMTOT1 ;
  133. BORDOM = BORTOT DIFF TROUS ;
  134. CLPRES = CLEXT1 ET CLEXT2 ;
  135.  
  136. DOMTOT = ORIENTER DOMTOT1 ;
  137. DEPL DOMTOT HOMO 0.1 PA1 ;
  138.  
  139. *-------------------- CREATION DES MODELES NAVIER_STOKES -----------------------
  140.  
  141. MDOMTOT = CHAN DOMTOT QUAF ;
  142. MCLEXT1 = CHAN CLEXT1 QUAF ;
  143. MCLEXT2 = CHAN CLEXT2 QUAF ;
  144. MCLPRES = CHAN CLPRES QUAF ;
  145. MBORDOM = CHAN BORDOM QUAF ;
  146. ELIM (MDOMTOT et MCLEXT1 et MCLEXT2 et MCLPRES et MBORDOM) 1.E-2 ;
  147.  
  148. $DOMTOT = MODE MDOMTOT 'NAVIER_STOKES' LINE ;
  149. $CLEXT1 = MODE MCLEXT1 'NAVIER_STOKES' LINE ;
  150. $CLEXT2 = MODE MCLEXT2 'NAVIER_STOKES' LINE ;
  151. $CLPRES = MODE MCLPRES 'NAVIER_STOKES' LINE ;
  152. $BORDOM = MODE MBORDOM 'NAVIER_STOKES' LINE ;
  153. DOMA $DOMTOT 'IMPR' ;
  154.  
  155. *-------------- PARAMETRES DU PROBLEME : AIR ET PARTICULES ---------------------
  156.  
  157. NU = 1.5E-5 ;
  158. U0 = 0.75 ;
  159. K0 = (U0/100.)**2. ;
  160. E0 = K0**(1.5)/0.2 ;
  161.  
  162. C0 = 1. ;
  163. RAP = 0.5E-6 ;
  164. ROP = 1000. ;
  165. ROG = 0. -9810. ;
  166. VS0 = 12277.*RAP*RAP*9.81*ROP ;
  167. DIF0 = 1./(5.62E21*NU*RAP) ;
  168. VAR = EXP(1.667E7*RAP) ;
  169. VS0 = VS0*(1. + (8.296E-8/RAP) + (2.64E-8/(RAP*VAR))) ;
  170. DIF0 = DIF0*(1. + (8.296E-8/RAP) + (2.64E-8/(RAP*VAR))) ;
  171.  
  172. YP1 = 0.15 ;
  173. YP2 = 0.30 ;
  174.  
  175. UET0 = U0/100 ;
  176. UET1 = kcht $CLEXT1 'SCAL' 'CENTRE' UET0 ;
  177. UET2 = kcht $CLEXT2 'SCAL' 'CENTRE' UET0 ;
  178. NUT = kcht $DOMTOT 'SCAL' 'CENTRE' 1.e-10 ;
  179.  
  180.  
  181. *-------------- DEFINITION DES TABLES POUR LE CALCUL DU REGIME -----------------
  182. *-------------------- PERMANENT ETABLI POUR L'AIR ------------------------------
  183.  
  184. rv = eqex $DOMTOT 'ITMA' 100 'ALFA' 0.8 'TFINAL' 0.1
  185. 'ZONE' $DOMTOT 'OPER' 'NSKE' NU NUT 'INCO' 'UN' 'KN' 'EN'
  186. 'ZONE' $CLEXT1 'OPER' 'FPU' NU UET1 YP1 'INCO' 'UN' 'KN' 'EN'
  187. 'ZONE' $CLEXT2 'OPER' 'FPU' NU UET2 YP2 'INCO' 'UN' 'KN' 'EN'
  188. ;
  189.  
  190. rv = eqex rv OPTI EFM1 'CENTREE'
  191. 'ZONE' $DOMTOT 'OPER' 'DFDT' 1. 'UN' 'DELTAT' 'INCO' 'UN'
  192. 'ZONE' $DOMTOT 'OPER' 'DFDT' 1. 'KN' 'DELTAT' 'INCO' 'KN'
  193. 'ZONE' $DOMTOT 'OPER' 'DFDT' 1. 'EN' 'DELTAT' 'INCO' 'EN'
  194. ;
  195.  
  196. rv = eqex rv
  197. 'CLIM' 'KN' 'TIMP' DENTREE K0 'EN' 'TIMP' DENTREE E0
  198. 'UN' 'UIMP' DENTREE U0 'UN' 'VIMP' DENTREE 0. ;
  199.  
  200. rvp= eqpr $DOMTOT
  201. 'ZONE' $DOMTOT 'OPER' 'PRESSION' 0.
  202. 'ZONE' $CLPRES 'OPER' 'VNIMP' 0.;
  203.  
  204. *----------------------- INITIALISATIONS ---------------------------------
  205.  
  206. rv.inco=table 'INCO' ;
  207. rv.inco.'UN' = kcht $DOMTOT 'VECT' 'SOMMET' (1.E-5 1.E-5 ) ;
  208. rv.inco.'KN' = kcht $DOMTOT 'SCAL' 'SOMMET' 1.E-8 ;
  209. rv.inco.'EN' = kcht $DOMTOT 'SCAL' 'SOMMET' 1.E-10 ;
  210. rv.'FIDT' = 1 ;
  211. rv.'PASDETPS'.'DELTAT' = 0.01 ;
  212.  
  213. rv.pression=rvp ;
  214.  
  215. *------------------ CALCUL DE L'ECOULEMENT D'AIR -------------------------------
  216.  
  217. EXEC rv ;
  218.  
  219. *------------------ DONNEES POUR L'EQUATION DE CONCENTRATION -------------------
  220.  
  221. CHPC = DOMA $DOMTOT 'NORMALE' ;
  222. NORM1 = KCHT $CLEXT1 vect centre CHPC ;
  223. NORM2 = KCHT $CLEXT2 vect centre CHPC ;
  224.  
  225. VSF = kcht $DOMTOT 'VECT' 'SOMMET' ( 0. VS0 ) ;
  226. VSF = CHAN 'ATTRIBUT' VSF 'NATURE' 'DISCRET' ;
  227. VS0 = 0. - VS0 ;
  228. VSP = kcht $BORDOM 'VECT' 'SOMMET' ( 0. VS0 ) ;
  229. VSP = CHAN 'ATTRIBUT' VSP 'NATURE' 'DISCRET' ;
  230. VS = kcht $DOMTOT 'VECT' 'SOMMET' (VSF et VSP) ;
  231. VN = kops (rv.inco.'UN') '-' VS ;
  232.  
  233. KN = abs (rv.inco.'KN') ;
  234. EN = abs (rv.inco.'EN') ;
  235. KN = kops (kops KN '*' KN) '/' EN ;
  236. DIF = kops (kops KN '*' 0.09) '+' DIF0 ;
  237.  
  238. AK1 = KFPA NU YP1 UET1 NORM1 ROG RAP ;
  239. AK2 = KFPA NU YP2 UET2 NORM2 ROG RAP ;
  240.  
  241. *------------ TABLE POUR LE CALCUL DES CONCENTRATIONS --------------------------
  242.  
  243. CONC=TABLE 'ARG';
  244. TETA1=KCHT $CLEXT1 'SCAL' 'CENTRE' 0.;
  245. TETA2=KCHT $CLEXT2 'SCAL' 'CENTRE' 0.;
  246.  
  247. RV1 = EQEX $DOMTOT 'ITMA' 100 'ALFA' 0.7 'TFINAL' 0.1
  248. 'ZONE' $DOMTOT 'OPER' TSCAL 'DIFFU' 'VITESSE' 0. 'INCO' 'CN'
  249. OPTI EFM1 'CENTREE'
  250. 'ZONE' $CLEXT1 'OPER' ECHIMP AK1 TETA1 'INCO' 'CN'
  251. 'ZONE' $CLEXT2 'OPER' ECHIMP AK2 TETA2 'INCO' 'CN'
  252. 'ZONE' $DOMTOT 'OPER' DFDT 1. 'CN' 'DELTAT' 'INCO' 'CN'
  253.  
  254. *---- conditions aux limites : -----
  255. 'CLIM' 'CN' 'TIMP' DENTREE C0 ;
  256.  
  257.  
  258. *------------------------ INITIALISATIONS --------------------------------
  259.  
  260. RV1.INCO=TABLE 'INCO' ;
  261. RV1.INCO.'CN' = KCHT $DOMTOT 'SCAL' 'SOMMET' 0. ;
  262. RV1.'INCO'.VITESSE= VN ;
  263. RV1.'INCO'.DIFFU = (NOEL $DOMTOT DIF) ;
  264. RV1.'FIDT'= 1 ;
  265.  
  266. *-------------------- EXECUTION : CONCENTRATION --------------------------------
  267.  
  268. EXEC RV1 ;
  269.  
  270. *-------------------- DESSINS --------------------------------------------
  271.  
  272. SI GRAPH ;
  273.  
  274. UET1NCH = ELNO $CLEXT1 UET1 ;
  275. UET2NCH = ELNO $CLEXT2 UET2 ;
  276. AKE1 = ELNO $CLEXT1 AK1 ;
  277. AKE2 = ELNO $CLEXT2 AK2 ;
  278.  
  279. TITRE 'VITESSES DES PARTICULES' ;
  280. UNCH = VECT (RV1.'INCO'.VITESSE) 1. UX UY VERT ;
  281. TRAC UNCH BORDOM ;
  282.  
  283. TITRE 'UET LE LONG DE LA COUCHE LIMITE 1 ' ;
  284. EVUT1CS = EVOL CHPO UET1NCH CLEXT1 ;
  285. DESS EVUT1CS ;
  286.  
  287. TITRE 'AK LE LONG DE LA COUCHE LIMITE 1 ' ;
  288. EVAK1CS = EVOL CHPO AKE1 CLEXT1 ;
  289. DESS EVAK1CS ;
  290.  
  291. TITRE 'UET LE LONG DE LA COUCHE LIMITE 2 ' ;
  292. EVUT2CS = EVOL CHPO UET2NCH CLEXT2 ;
  293. DESS EVUT2CS ;
  294.  
  295. TITRE 'AK LE LONG DE LA COUCHE LIMITE 2 ' ;
  296. EVAK2CS = EVOL CHPO AKE2 CLEXT2 ;
  297. DESS EVAK2CS ;
  298.  
  299. TITRE 'CONCENTRATIONS' ;
  300. TRAC DOMTOT (RV1.INCO.'CN') BORDOM ;
  301.  
  302. FINSI ;
  303.  
  304. *-------------------- TEST SUR LA VITESSE DE DEPOT -----------------------
  305.  
  306. P1 = 1.0 (E/10.) ;
  307. P2 = (E/10.) 2.5 ;
  308. PT1 = (DOMA $CLEXT1 CENTRE) 'POIN' 'PROC' P1 ;
  309. PT2 = (DOMA $CLEXT2 CENTRE) 'POIN' 'PROC' P2 ;
  310. VD1 = 'EXTR' AK1 SCAL PT1 ;
  311. VD2 = 'EXTR' AK2 SCAL PT2 ;
  312. DV1 = (VD1 - 3.52115E-05)/3.52115E-05 ;
  313. DV2 = (VD2 - 6.66232E-08)/6.66232E-08 ;
  314.  
  315. SI ( (ABS DV1) > 0.05 ) ;
  316. ERREUR 5 ;
  317. FINSI ;
  318.  
  319. SI ( (ABS DV2) > 0.05 ) ;
  320. ERREUR 5 ;
  321. FINSI ;
  322.  
  323. FIN ;
  324.  
  325.  
  326.  
  327.  
  328.  
  329.  
  330.  
  331.  
  332.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales